configure.ac

   1 ##
   2 ## This file is part of the libsigrok project.
   3 ##
   4 ## Copyright (C) 2010-2012 Bert Vermeulen <bert@biot.com>
   5 ## Copyright (C) 2012 Alexandru Gagniuc <mr.nuke.me@gmail.com>
   6 ##
   7 ## This program is free software: you can redistribute it and/or modify
   8 ## it under the terms of the GNU General Public License as published by
   9 ## the Free Software Foundation, either version 3 of the License, or
  10 ## (at your option) any later version.
  11 ##
  12 ## This program is distributed in the hope that it will be useful,
  13 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ## GNU General Public License for more details.
  16 ##
  17 ## You should have received a copy of the GNU General Public License
  18 ## along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19 ##
  20
  21 # We require at least autoconf 2.63 (AC_INIT format changed there).
  22 AC_PREREQ([2.63])
  23
  24 AC_INIT([libsigrok], [0.6.0],
  25         [sigrok-devel@lists.sourceforge.net],
  26         [libsigrok], [http://www.sigrok.org])
  27 AC_CONFIG_MACRO_DIR([m4])
  28 AC_CONFIG_AUX_DIR([autostuff])
  29 AC_CONFIG_HEADERS([config.h include/libsigrok/version.h])
  30
  31 # We require at least automake 1.11 (needed for 'silent rules').
  32 AM_INIT_AUTOMAKE([1.11 -Wall -Werror no-define nostdinc subdir-objects check-news color-tests])
  33 AM_SILENT_RULES([yes])
  34 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  35
  36 AC_CANONICAL_HOST
  37
  38 # Checks for programs.
  39 AC_PROG_CC
  40 AC_PROG_CXX
  41 AC_PROG_INSTALL
  42 AC_PROG_LN_S
  43
  44 # Required for per-target flags or subdir-objects with C sources.
  45 AM_PROG_CC_C_O
  46
  47 # Set the standard the C library headers should conform to.
  48 AH_VERBATIM([_POSIX_C_SOURCE], [/* The targeted POSIX standard. */
  49 #ifndef _POSIX_C_SOURCE
  50 # define _POSIX_C_SOURCE 200112L
  51 #endif])
  52
  53 # Get compiler versions.
  54 SR_PROG_VERSION([$CC], [sr_cc_version])
  55 SR_PROG_VERSION([$CXX], [sr_cxx_version])
  56
  57 # Check for optional make features.
  58 SR_PROG_MAKE_ORDER_ONLY
  59
  60 # Initialize libtool.
  61 LT_INIT
  62
  63 # Set up the libsigrok version defines.
  64 SR_PKG_VERSION_SET([SR_PACKAGE_VERSION], [AC_PACKAGE_VERSION])
  65
  66 # Library version for libsigrok (NOT the same as the package version).
  67 # Carefully read the libtool docs before updating these numbers!
  68 # The algorithm for determining which number to change (and how) is nontrivial!
  69 # http://www.gnu.org/software/libtool/manual/libtool.html#Updating-version-info
  70 # Format: current:revision:age.
  71 SR_LIB_VERSION_SET([SR_LIB_VERSION], [4:0:0])
  72
  73 AM_CONDITIONAL([WIN32], [test -z "${host_os##mingw*}" || test -z "${host_os##cygwin*}"])
  74
  75 #############################
  76 ##  Optional dependencies  ##
  77 #############################
  78
  79 AC_LANG([C])
  80
  81 # Initialize pkg-config.
  82 # We require at least 0.22, as "Requires.private" behaviour changed there.
  83 PKG_PROG_PKG_CONFIG([0.22])
  84
  85 # Keep track of all checked modules so we can list them at the end.
  86 SR_PKG_CHECK_SUMMARY([sr_pkglibs_summary])
  87
  88 # Collect the pkg-config module names of all dependencies in SR_PKGLIBS.
  89 # These are used to derive the compiler flags and for the "Requires.private"
  90 # field in the generated libsigrok.pc file.
  91 SR_VAR_OPT_PKG([SR_PKGLIBS], [sr_deps_avail])
  92 SR_PKGLIBS_TESTS=
  93 SR_PKGLIBS_CXX=
  94 SR_PKGLIBS_PYTHON=
  95 SR_PKGLIBS_RUBY=
  96 SR_EXTRA_LIBS=
  97 SR_EXTRA_CXX_LIBS=
  98
  99 SR_ARG_OPT_PKG([libserialport], [LIBSERIALPORT], ,
 100         [libserialport >= 0.1.1])
 101
 102 SR_ARG_OPT_PKG([libftdi], [LIBFTDI], , [libftdi1 >= 1.0])
 103
 104 # pkg-config file names: MinGW/MacOSX: hidapi; Linux: hidapi-hidraw/-libusb
 105 SR_ARG_OPT_PKG([libhidapi], [LIBHIDAPI], ,
 106         [hidapi >= 0.8.0], [hidapi-hidraw >= 0.8.0], [hidapi-libusb >= 0.8.0])
 107
 108 SR_ARG_OPT_PKG([libbluez], [LIBBLUEZ], , [bluez >= 4.0])
 109
 110 # FreeBSD comes with an "integrated" libusb-1.0-style USB API.
 111 # This means libusb-1.0 is always available; no need to check for it.
 112 # On Windows, require the latest version we can get our hands on,
 113 # until the new generic event handling has seen an official release.
 114 AS_CASE([$host_os],
 115         [freebsd*], [sr_libusb_req='libusb-1.0' sr_have_libusb=yes],
 116         [mingw*], [sr_libusb_req='libusb-1.0 >= 1.0.20'],
 117         [sr_libusb_req='libusb-1.0 >= 1.0.16'])
 118
 119 SR_ARG_OPT_PKG([libusb], [LIBUSB_1_0], [NEED_USB],
 120         [$sr_libusb_req])
 121
 122 SR_ARG_OPT_PKG([librevisa], [LIBREVISA], [NEED_VISA],
 123         [librevisa >= 0.0.20130412])
 124
 125 SR_ARG_OPT_PKG([libgpib], [LIBGPIB], [NEED_GPIB],
 126         [libgpib])
 127
 128 SR_ARG_OPT_CHECK([libieee1284], [LIBIEEE1284],, [
 129         sr_save_LIBS=$LIBS
 130         LIBS="-lieee1284 $LIBS"
 131         AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <ieee1284.h>]],
 132                                 [[(void) ieee1284_open(0, 0, 0);]])],
 133                 [sr_have_libieee1284=yes], [sr_have_libieee1284=no])
 134         LIBS=$sr_save_LIBS
 135 ])
 136 AS_IF([test "x$sr_have_libieee1284" = xyes],
 137         [SR_PREPEND([SR_EXTRA_LIBS], [-lieee1284])])
 138
 139 SR_ARG_OPT_PKG([libgio], [LIBGIO], , [gio-2.0 >= 2.24.0])
 140
 141 # See if any of the (potentially platform specific) libs are available
 142 # which provide some means of Bluetooth communication.
 143 AS_IF([test "x$sr_have_libbluez" = xyes],
 144         sr_have_bluetooth=yes, sr_have_bluetooth=no)
 145 AS_IF([test "x$sr_have_bluetooth" = xyes],
 146         [AC_DEFINE([HAVE_BLUETOOTH], [1], [Specifies whether Bluetooth communication is supported.])])
 147 AS_IF([test "x$sr_have_bluetooth" = xyes],
 148         [SR_APPEND([sr_deps_avail], [bluetooth_comm])])
 149
 150 AS_IF([test "x$sr_have_libserialport" = xyes -o "x$sr_have_libhidapi" = xyes -o "x$sr_have_bluetooth" = xyes],
 151         sr_have_serial_comm=yes, sr_have_serial_comm=no)
 152 AS_IF([test "x$sr_have_serial_comm" = xyes],
 153         [AC_DEFINE([HAVE_SERIAL_COMM], [1], [Specifies whether serial communication is supported.])])
 154 AS_IF([test "x$sr_have_serial_comm" = xyes],
 155         [SR_APPEND([sr_deps_avail], [serial_comm])])
 156 AM_CONDITIONAL([NEED_SERIAL], [test "x$sr_have_serial_comm" = xyes])
 157
 158 ######################
 159 ##  Feature checks  ##
 160 ######################
 161
 162 # The Check unit testing framework is optional. Disable if not found.
 163 SR_PKG_CHECK([check], [SR_PKGLIBS_TESTS], [check >= 0.9.4])
 164 AM_CONDITIONAL([HAVE_CHECK], [test "x$sr_have_check" = xyes])
 165
 166 # Enable the C99 standard if possible, and enforce the use
 167 # of SR_API to explicitly mark all public API functions.
 168 SR_EXTRA_CFLAGS=
 169 SR_CHECK_COMPILE_FLAGS([SR_EXTRA_CFLAGS], [C99], [-std=c99 -c99 -AC99 -qlanglvl=extc99])
 170 SR_CHECK_COMPILE_FLAGS([SR_EXTRA_CFLAGS], [visibility], [-fvisibility=hidden])
 171
 172 SR_ARG_ENABLE_WARNINGS([SR_WFLAGS], [-Wall], [-Wall -Wextra -Wmissing-prototypes])
 173
 174 # Check host characteristics.
 175 AC_SYS_LARGEFILE
 176 AC_C_BIGENDIAN
 177
 178 AC_CHECK_HEADERS([sys/mman.h], [SR_APPEND([sr_deps_avail], [sys_mman_h])])
 179 AC_CHECK_HEADERS([sys/ioctl.h], [SR_APPEND([sr_deps_avail], [sys_ioctl_h])])
 180 AC_CHECK_HEADERS([sys/timerfd.h], [SR_APPEND([sr_deps_avail], [sys_timerfd_h])])
 181
 182 # We need to link against the Winsock2 library for SCPI over TCP.
 183 AS_CASE([$host_os], [mingw*], [SR_PREPEND([SR_EXTRA_LIBS], [-lws2_32])])
 184
 185 # libm (the standard math library) is always needed.
 186 SR_SEARCH_LIBS([SR_EXTRA_LIBS], [pow], [m])
 187
 188 # RPC is only needed for VXI support.
 189 AC_CACHE_CHECK([for RPC support], [sr_cv_have_rpc],
 190         [AC_LINK_IFELSE([AC_LANG_PROGRAM(
 191                         [[#include <rpc/rpc.h>]m4_newline[CLIENT *rpc_test(void);]],
 192                         [[(void) clnt_create("", 0, 0, "");]])],
 193                 [sr_cv_have_rpc=yes], [sr_cv_have_rpc=no])])
 194 AS_IF([test "x$sr_cv_have_rpc" = xyes],
 195         [AC_DEFINE([HAVE_RPC], [1], [Specifies whether we have RPC support.])])
 196 # VXI support is only compiled if RPC support was found.
 197 AM_CONDITIONAL([NEED_RPC], [test "x$sr_cv_have_rpc" = xyes])
 198
 199 # Check for compiler support of 128 bit integers
 200 AC_CHECK_TYPES([__int128_t, __uint128_t], [], [], [])
 201
 202 # Availability of bt_put_le16() depends on the bluez library version.
 203 AC_CACHE_CHECK([for bt_put_le16], [sr_cv_have_btputle16],
 204         [AC_LINK_IFELSE([AC_LANG_PROGRAM(
 205                         [[#include <bluetooth/bluetooth.h>]],
 206                         [[bt_put_le16(0, (void *)0);]])],
 207                 [sr_cv_have_btputle16=yes], [sr_cv_have_btputle16=no])])
 208 AS_IF([test "x$sr_cv_have_btputle16" = xyes],
 209         [AC_DEFINE([HAVE_BT_PUT_LE16], [1], [Specifies whether we have bt_put_le16().])])
 210
 211 ########################
 212 ##  Hardware drivers  ##
 213 ########################
 214
 215 # Keep track of all drivers so we can list them at the end.
 216 SR_VAR_SUMMARY([sr_driver_summary])
 217
 218 # Check whether the sr_deps_avail list contains all of the arguments.
 219 # Unavailable dependencies are collected in sr_deps_missing.
 220 sr_check_driver_deps() {
 221         sr_deps_missing=
 222         for sr_dep
 223         do
 224                 AS_CASE([" $sr_deps_avail "], [*" $sr_dep "*],,
 225                         [SR_APPEND([sr_deps_missing], [', '], [$sr_dep])])
 226         done
 227         test -z "$sr_deps_missing" || return 1
 228 }
 229
 230 AC_ARG_ENABLE([all-drivers],
 231         [AS_HELP_STRING([--enable-all-drivers],
 232                         [enable all drivers by default [default=yes]])],
 233         [], [enable_all_drivers=yes])
 234
 235 ## _SR_DRIVER(Device name, driver-name, var-name, [dependencies...])
 236 m4_define([_SR_DRIVER], [
 237         AC_ARG_ENABLE([$2],
 238                 [AS_HELP_STRING([--enable-$2], [enable $1 support])],
 239                 [$3=$enableval], [$3=$enable_all_drivers])
 240
 241         AS_IF([test "x[$]$3" = xyes], [sr_hw_info=yes[]m4_ifval([$4], [
 242                 sr_check_driver_deps $4 \
 243                         || $3=no sr_hw_info="no (missing: $sr_deps_missing)"
 244         ])], [sr_hw_info='no (disabled)'])
 245         sr_driver_summary_append "$2" "$sr_hw_info"
 246
 247         AM_CONDITIONAL([$3], [test "x[$]$3" = xyes])
 248         AM_COND_IF([$3], [AC_DEFINE([HAVE_$3], [1], [Whether to support $1 device.]) AC_DEFINE([HAVE_DRIVERS], [1], [Whether at least one driver is enabled.])])
 249 ])
 250
 251 ## SR_DRIVER(Device name, driver-name, [dependencies...])
 252 m4_define([SR_DRIVER],
 253         [_SR_DRIVER([$1], [$2], m4_expand([AS_TR_CPP([HW_$2])]), [$3])])
 254
 255 SR_DRIVER([Agilent DMM], [agilent-dmm], [serial_comm])
 256 SR_DRIVER([Appa 55II], [appa-55ii], [serial_comm])
 257 SR_DRIVER([Arachnid Labs Re:load Pro], [arachnid-labs-re-load-pro], [serial_comm])
 258 SR_DRIVER([ASIX SIGMA/SIGMA2], [asix-sigma], [libftdi])
 259 SR_DRIVER([Atten PPS3xxx], [atten-pps3xxx], [serial_comm])
 260 SR_DRIVER([BayLibre ACME], [baylibre-acme], [sys_timerfd_h])
 261 SR_DRIVER([BeagleLogic], [beaglelogic], [sys_mman_h sys_ioctl_h])
 262 SR_DRIVER([Brymen DMM], [brymen-dmm], [serial_comm])
 263 SR_DRIVER([CEM DT-885x], [cem-dt-885x], [serial_comm])
 264 SR_DRIVER([Center 3xx], [center-3xx], [serial_comm])
 265 SR_DRIVER([ChronoVu LA], [chronovu-la], [libusb libftdi])
 266 SR_DRIVER([Colead SLM], [colead-slm], [serial_comm])
 267 SR_DRIVER([Conrad DIGI 35 CPU], [conrad-digi-35-cpu], [serial_comm])
 268 SR_DRIVER([demo], [demo])
 269 SR_DRIVER([DreamSourceLab DSLogic], [dreamsourcelab-dslogic], [libusb])
 270 SR_DRIVER([Fluke 45], [fluke-45])
 271 SR_DRIVER([Fluke DMM], [fluke-dmm], [serial_comm])
 272 SR_DRIVER([FTDI LA], [ftdi-la], [libusb libftdi])
 273 SR_DRIVER([fx2lafw], [fx2lafw], [libusb])
 274 SR_DRIVER([GMC MH 1x/2x], [gmc-mh-1x-2x], [serial_comm])
 275 SR_DRIVER([GW Instek GDS-800], [gwinstek-gds-800], [serial_comm])
 276 SR_DRIVER([GW Instek GPD], [gwinstek-gpd], [serial_comm])
 277 SR_DRIVER([Hameg HMO], [hameg-hmo], [serial_comm])
 278 SR_DRIVER([Hantek 4032L], [hantek-4032l], [libusb])
 279 SR_DRIVER([Hantek 6xxx], [hantek-6xxx], [libusb])
 280 SR_DRIVER([Hantek DSO], [hantek-dso], [libusb])
 281 SR_DRIVER([HP 3457A], [hp-3457a])
 282 SR_DRIVER([HP 3478A], [hp-3478a], [libgpib])
 283 SR_DRIVER([Hung-Chang DSO-2100], [hung-chang-dso-2100], [libieee1284])
 284 SR_DRIVER([Ikalogic Scanalogic-2], [ikalogic-scanalogic2], [libusb])
 285 SR_DRIVER([Ikalogic Scanaplus], [ikalogic-scanaplus], [libftdi])
 286 SR_DRIVER([IPDBG LA], [ipdbg-la])
 287 SR_DRIVER([Kecheng KC-330B], [kecheng-kc-330b], [libusb])
 288 SR_DRIVER([KERN scale], [kern-scale], [serial_comm])
 289 SR_DRIVER([Korad KAxxxxP], [korad-kaxxxxp], [serial_comm])
 290 SR_DRIVER([Lascar EL-USB], [lascar-el-usb], [libusb])
 291 SR_DRIVER([LeCroy LogicStudio], [lecroy-logicstudio], [libusb])
 292 SR_DRIVER([LeCroy X-Stream], [lecroy-xstream])
 293 SR_DRIVER([Manson HCS-3xxx], [manson-hcs-3xxx], [serial_comm])
 294 SR_DRIVER([Mastech MS6514], [mastech-ms6514], [serial_comm])
 295 SR_DRIVER([maynuo-m97], [maynuo-m97])
 296 SR_DRIVER([MIC 985xx], [mic-985xx], [serial_comm])
 297 SR_DRIVER([Microchip PICkit2], [microchip-pickit2], [libusb])
 298 SR_DRIVER([Mooshimeter DMM], [mooshimeter-dmm], [bluetooth_comm libgio])
 299 SR_DRIVER([Motech LPS 30x], [motech-lps-30x], [serial_comm])
 300 SR_DRIVER([Norma DMM], [norma-dmm], [serial_comm])
 301 SR_DRIVER([OpenBench Logic Sniffer], [openbench-logic-sniffer], [serial_comm])
 302 SR_DRIVER([PCE PCE-322A], [pce-322a], [serial_comm])
 303 SR_DRIVER([Pipistrello-OLS], [pipistrello-ols], [libftdi])
 304 SR_DRIVER([RDTech DPSxxxx/DPHxxxx], [rdtech-dps], [serial_comm])
 305 SR_DRIVER([RDTech UMXX], [rdtech-um], [serial_comm])
 306 SR_DRIVER([Rigol DS], [rigol-ds])
 307 SR_DRIVER([Rohde&Schwarz SME-0x], [rohde-schwarz-sme-0x], [serial_comm])
 308 SR_DRIVER([Saleae Logic16], [saleae-logic16], [libusb])
 309 SR_DRIVER([Saleae Logic Pro], [saleae-logic-pro], [libusb])
 310 SR_DRIVER([SCPI DMM], [scpi-dmm])
 311 SR_DRIVER([SCPI PPS], [scpi-pps])
 312 SR_DRIVER([serial DMM], [serial-dmm], [serial_comm])
 313 SR_DRIVER([serial LCR], [serial-lcr], [serial_comm])
 314 SR_DRIVER([Siglent SDS], [siglent-sds])
 315 SR_DRIVER([Sysclk LWLA], [sysclk-lwla], [libusb])
 316 SR_DRIVER([Sysclk SLA5032], [sysclk-sla5032], [libusb])
 317 SR_DRIVER([Teleinfo], [teleinfo], [serial_comm])
 318 SR_DRIVER([Testo], [testo], [libusb])
 319 SR_DRIVER([Tondaj SL-814], [tondaj-sl-814], [serial_comm])
 320 SR_DRIVER([UNI-T DMM], [uni-t-dmm], [libusb])
 321 SR_DRIVER([UNI-T UT181A], [uni-t-ut181a], [serial_comm])
 322 SR_DRIVER([UNI-T UT32x], [uni-t-ut32x], [serial_comm])
 323 SR_DRIVER([Yokogawa DL/DLM], [yokogawa-dlm])
 324 SR_DRIVER([ZEROPLUS Logic Cube], [zeroplus-logic-cube], [libusb])
 325 SR_DRIVER([ZKETECH EBD-USB], [zketech-ebd-usb], [serial_comm])
 326
 327 ###############################
 328 ##  Language bindings setup  ##
 329 ###############################
 330
 331 AC_LANG([C++])
 332 SR_ARG_ENABLE_WARNINGS([SR_WXXFLAGS], [-Wall], [-Wall -Wextra])
 333
 334 AC_ARG_ENABLE([bindings],
 335         [AS_HELP_STRING([--enable-bindings], [build language bindings [default=yes]])],
 336         [], [enable_bindings=yes])
 337
 338 AC_ARG_ENABLE([cxx],
 339         [AS_HELP_STRING([--enable-cxx], [build C++ bindings [default=yes]])],
 340         [], [enable_cxx=$enable_bindings])
 341
 342 AC_ARG_ENABLE([python],
 343         [AS_HELP_STRING([--enable-python], [build Python bindings [default=yes]])],
 344         [], [enable_python=$enable_bindings])
 345
 346 AC_ARG_ENABLE([ruby],
 347         [AS_HELP_STRING([--enable-ruby], [build Ruby bindings [default=no]])],
 348         [], [enable_ruby=no])
 349
 350 AC_ARG_ENABLE([java],
 351         [AS_HELP_STRING([--enable-java], [build Java bindings [default=yes]])],
 352         [], [enable_java=$enable_bindings])
 353
 354 ####################
 355 ##  C++ bindings  ##
 356 ####################
 357
 358 sr_cxx_missing=
 359
 360 # Check if the C++ compiler supports the C++11 standard.
 361 AX_CXX_COMPILE_STDCXX([11], [noext], [optional])
 362 AS_IF([test "x$HAVE_CXX11" != x1],
 363         [SR_APPEND([sr_cxx_missing], [', '], ['C++11'])])
 364
 365 # The C++ bindings need glibmm.
 366 SR_PKG_CHECK([glibmm], [SR_PKGLIBS_CXX], [glibmm-2.4 >= 2.32.0])
 367 AS_IF([test "x$sr_have_glibmm" != xyes],
 368         [SR_APPEND([sr_cxx_missing], [', '], [glibmm])])
 369
 370 # The C++ bindings use Doxygen to parse libsigrok symbols.
 371 AC_CHECK_PROG([HAVE_DOXYGEN], [doxygen], [yes], [no])
 372 AS_IF([test "x$HAVE_DOXYGEN" != xyes],
 373         [SR_APPEND([sr_cxx_missing], [', '], [Doxygen])])
 374
 375 # Link C++ code with gnustl_shared if it exists (Android)
 376 SR_SEARCH_LIBS([SR_EXTRA_CXX_LIBS], [__cxa_throw], [gnustl_shared])
 377
 378 # Python is needed for the C++ bindings.
 379 AM_PATH_PYTHON([2.7],
 380         [HAVE_PYTHON=yes],
 381         [HAVE_PYTHON=no
 382         SR_APPEND([sr_cxx_missing], [', '], [Python])])
 383
 384 AS_IF([test -z "$sr_cxx_missing"],
 385         [BINDINGS_CXX=$enable_cxx], [BINDINGS_CXX=no])
 386 AM_CONDITIONAL([BINDINGS_CXX], [test "x$BINDINGS_CXX" = xyes])
 387
 388 # C++ bindings want stoi and stod.
 389 AM_COND_IF([BINDINGS_CXX], [
 390         AC_CACHE_CHECK([for stoi and stod], [sr_cv_have_stoi_stod],
 391                 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <string>]],
 392                                 [[(void) std::stoi("1"); (void) std::stod("1.0");]])],
 393                         [sr_cv_have_stoi_stod=yes], [sr_cv_have_stoi_stod=no])])
 394         AS_IF([test "x$sr_cv_have_stoi_stod" = xyes],
 395                 [AC_DEFINE([HAVE_STOI_STOD], [1],
 396                         [Specifies whether we have the stoi and stod functions.])])
 397 ])
 398
 399 #######################
 400 ##  Python bindings  ##
 401 #######################
 402
 403 AS_IF([test "x$BINDINGS_CXX" = xyes],
 404         [sr_python_missing=],
 405         [sr_python_missing='C++ bindings'])
 406
 407 # Extract major and minor version number of the Python interpreter.
 408 sr_pymajor=${PYTHON_VERSION%%.*}
 409 sr_pyminor=${PYTHON_VERSION#*.}
 410
 411 # The Python bindings need Python development files. Check for either
 412 # Python 3 or Python 2 headers depending on the interpreter version.
 413 SR_PKG_CHECK([python_dev], [SR_PKGLIBS_PYTHON],
 414         [python = $PYTHON_VERSION],
 415         [python$sr_pymajor = $PYTHON_VERSION],
 416         [python$sr_pymajor$sr_pyminor = $PYTHON_VERSION],
 417         [python-$PYTHON_VERSION = $PYTHON_VERSION])
 418
 419 AS_IF([test "x$sr_have_python_dev" != xyes],
 420         [SR_APPEND([sr_python_missing], [', '], [Headers])])
 421
 422 # PyGObject is needed for the Python bindings.
 423 SR_PKG_CHECK([pygobject], [SR_PKGLIBS_PYTHON], [pygobject-3.0 >= 3.0.0])
 424 AS_IF([test "x$sr_have_pygobject" != xyes],
 425         [SR_APPEND([sr_python_missing], [', '], [PyGObject])])
 426
 427 PKG_CHECK_EXISTS([pygobject-3.0 < 3.7.91],
 428         [AC_DEFINE([PYGOBJECT_FLAGS_SIGNED], [1],
 429                 [Whether last argument to pyg_flags_get_value() is signed.])])
 430
 431 # The Python bindings need the setuptools and numpy Python modules.
 432 # We'll let it go through even if the AX macro wasn't found, as the
 433 # Python modules may still be there.
 434 m4_ifdef([AX_PYTHON_MODULE], [
 435         AX_PYTHON_MODULE([setuptools])
 436         AX_PYTHON_MODULE([numpy])
 437 ], [
 438         HAVE_PYMOD_SETUPTOOLS=yes
 439         HAVE_PYMOD_NUMPY=yes
 440         m4_warn([unsupported],
 441                 [Missing macro AX_PYTHON_MODULE: no check for setuptools and numpy])
 442 ])
 443 AS_IF([test "x$HAVE_PYMOD_SETUPTOOLS" != xyes],
 444         [SR_APPEND([sr_python_missing], [', '], [setuptools])])
 445 AS_IF([test "x$HAVE_PYMOD_NUMPY" != xyes],
 446         [SR_APPEND([sr_python_missing], [', '], [numpy])])
 447
 448 # The Python bindings use SWIG to generate code.
 449 AC_CHECK_PROGS([SWIG], [swig swig4.0 swig3.0 swig2.0])
 450 AS_IF([test "x$SWIG" != x],
 451     AC_MSG_CHECKING([for $SWIG version])
 452     [SWIG_VERSION=`$SWIG -version 2>&1 | sed -n 's/SWIG Version //p'`]
 453     AC_MSG_RESULT([$SWIG_VERSION]))
 454 AS_IF([test "x$SWIG" = x],
 455         [SR_APPEND([sr_python_missing], [', '], [SWIG])])
 456
 457 AS_IF([test -z "$sr_python_missing"],
 458         [BINDINGS_PYTHON=$enable_python], [BINDINGS_PYTHON=no])
 459 AM_CONDITIONAL([BINDINGS_PYTHON], [test "x$BINDINGS_PYTHON" = xyes])
 460
 461 #####################
 462 ##  Ruby bindings  ##
 463 #####################
 464
 465 AS_IF([test "x$BINDINGS_CXX" = xyes],
 466         [sr_ruby_missing=],
 467         [sr_ruby_missing='C++ bindings'])
 468
 469 AC_PATH_PROGS(RUBY, ["${RUBY-ruby}"], [])
 470 AS_IF([test "x$RUBY" != x],
 471         AC_MSG_CHECKING([for Ruby version])
 472     [RUBY_VERSION=`$RUBY -e 'puts RUBY_VERSION'`]
 473     AC_MSG_RESULT([$RUBY_VERSION])
 474     [RUBY_DLEXT=`$RUBY -rrbconfig -e 'puts RbConfig::CONFIG[["DLEXT"]]'`]
 475     AC_SUBST(RUBY_DLEXT))
 476
 477 AS_IF([test "x$RUBY" = x],
 478         [SR_APPEND([sr_ruby_missing], [', '], [Ruby])])
 479
 480 # Extract major and minor version number of the Ruby interpreter.
 481 sr_rbmajor=${RUBY_VERSION%%.*}
 482 sr_rbminor=${RUBY_VERSION#*.}
 483 sr_rbminor=${sr_rbminor%%.*}
 484
 485 # The Ruby bindings need Ruby development files.
 486 SR_PKG_CHECK([ruby_dev], [SR_PKGLIBS_RUBY],
 487         [ruby],
 488         [ruby-$sr_rbmajor.$sr_rbminor])
 489
 490 AS_IF([test "x$sr_have_ruby_dev" != xyes],
 491         [SR_APPEND([sr_ruby_missing], [', '], [Headers])])
 492
 493 # The Ruby bindings use SWIG >= 3.0.8 to generate code.
 494 AS_IF([test "x$SWIG" = x],
 495         [SR_APPEND([sr_ruby_missing], [', '], [SWIG])],
 496         [AS_VERSION_COMPARE($SWIG_VERSION, "3.0.8",
 497                 [SR_APPEND([sr_ruby_missing], [', '], ['SWIG >= 3.0.8'])])])
 498
 499 AS_IF([test -z "$sr_ruby_missing"],
 500         [BINDINGS_RUBY=$enable_ruby], [BINDINGS_RUBY=no])
 501 AM_CONDITIONAL([BINDINGS_RUBY], [test "x$BINDINGS_RUBY" = xyes])
 502
 503 ####################
 504 ##  Java bindings ##
 505 ####################
 506
 507 AS_IF([test "x$BINDINGS_CXX" = xyes],
 508         [sr_java_missing=],
 509         [sr_java_missing='C++ bindings'])
 510
 511 # The Java bindings use SWIG to generate code.
 512 AS_IF([test "x$SWIG" = x],
 513         [SR_APPEND([sr_java_missing], [', '], [SWIG])])
 514
 515 # Find Java compiler and JNI includes for Java bindings.
 516 AC_CHECK_PROG([HAVE_JAVAC], [javac], [yes], [no])
 517 AS_IF([test "x$HAVE_JAVAC" = xno],
 518         [SR_APPEND([sr_java_missing], [', '], [JavaC])])
 519
 520 AC_ARG_WITH([jni-include-path],
 521         [AS_HELP_STRING([[--with-jni-include-path=DIR-LIST (space-separated)]],
 522                 [specify JNI include directories [default=detect]])],
 523         [JNI_INCLUDE_DIRS=" $withval"], [JNI_INCLUDE_DIRS=])
 524
 525 JNI_CPPFLAGS=
 526 AS_IF([test "x$enable_java$HAVE_JAVAC" = xyesyes], [
 527         AX_PROG_JAVAC
 528         AS_IF([test -z "$JNI_INCLUDE_DIRS" && test "x$cross_compiling" != xyes], [
 529                 ## Work around the totally broken logic in AX_JNI_INCLUDE_DIR:
 530                 ## If we can find jni.h without any special search path, skip
 531                 ## the execution of the broken macro to increase our chances of
 532                 ## success.
 533                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <jni.h>]], [])],,
 534                         [AX_JNI_INCLUDE_DIR])
 535         ])
 536 ])
 537 for sr_dir in $JNI_INCLUDE_DIRS
 538 do
 539         SR_APPEND([JNI_CPPFLAGS], ["-I$sr_dir"])
 540 done
 541 AC_SUBST([JNI_CPPFLAGS])
 542
 543 sr_save_cppflags=$CPPFLAGS
 544 SR_APPEND([CPPFLAGS], [$JNI_CPPFLAGS])
 545 AC_CHECK_HEADER([jni.h],,
 546         [SR_APPEND([sr_java_missing], [', '], ['JNI headers'])])
 547 CPPFLAGS=$sr_save_cppflags
 548
 549 AS_IF([test -z "$sr_java_missing"],
 550         [BINDINGS_JAVA=$enable_java], [BINDINGS_JAVA=no])
 551 AM_CONDITIONAL([BINDINGS_JAVA], [test "x$BINDINGS_JAVA" = xyes])
 552
 553 ##############################
 554 ##  Finalize configuration  ##
 555 ##############################
 556
 557 # Add mandatory dependencies to module list.
 558 SR_APPEND([SR_PKGLIBS], ['libzip >= 0.10'])
 559 AC_SUBST([SR_PKGLIBS])
 560
 561 # Retrieve the compile and link flags for all modules combined.
 562 # Also, bail out at this point if any module dependency is not met.
 563 PKG_CHECK_MODULES([LIBSIGROK], [glib-2.0 >= 2.32.0 $SR_PKGLIBS])
 564 PKG_CHECK_MODULES([TESTS], [$SR_PKGLIBS_TESTS glib-2.0 $SR_PKGLIBS])
 565
 566 # SR_PKGLIBS_CXX may be empty, so only invoke these checks when
 567 # the C++ bindings are enabled.
 568 AM_COND_IF([BINDINGS_CXX], [
 569         PKG_CHECK_MODULES([LIBSIGROKCXX], [$SR_PKGLIBS_CXX])
 570         PKG_CHECK_MODULES([PYSIGROK], [$SR_PKGLIBS_PYTHON $SR_PKGLIBS_CXX])
 571         PKG_CHECK_MODULES([RBSIGROK], [$SR_PKGLIBS_RUBY $SR_PKGLIBS_CXX], [AC_SUBST(RBSIGROK_EXTDIR, "lib/$($PKG_CONFIG --variable=sitearch $SR_PKGLIBS_RUBY)/$($PKG_CONFIG --variable=RUBY_BASE_NAME $SR_PKGLIBS_RUBY)/vendor_ruby/$($PKG_CONFIG --variable=ruby_version $SR_PKGLIBS_RUBY)")])
 572 ])
 573
 574 # Check for specific libusb features, now that we know the CFLAGS.
 575 AC_LANG([C])
 576 sr_save_cflags=$CFLAGS
 577 sr_save_libs=$LIBS
 578 CFLAGS="$LIBSIGROK_CFLAGS $CFLAGS"
 579 LIBS="$LIBSIGROK_LIBS $LIBS"
 580 AC_CHECK_TYPES([libusb_os_handle],
 581         [sr_have_libusb_os_handle=yes], [sr_have_libusb_os_handle=no],
 582         [[#include <libusb.h>]])
 583 AC_CHECK_FUNCS([zip_discard])
 584 LIBS=$sr_save_libs
 585 CFLAGS=$sr_save_cflags
 586
 587 AM_COND_IF([NEED_USB], [AS_CASE([$sr_have_libusb_os_handle:$host_os], [no:mingw*],
 588         [AC_MSG_ERROR([Windows builds require the event-abstraction branch of libusb])])])
 589
 590 sr_glib_version=`$PKG_CONFIG --modversion glib-2.0 2>&AS_MESSAGE_LOG_FD`
 591 sr_libzip_version=`$PKG_CONFIG --modversion libzip 2>&AS_MESSAGE_LOG_FD`
 592
 593 AC_DEFINE_UNQUOTED([CONF_LIBZIP_VERSION], ["$sr_libzip_version"],
 594         [Build-time version of libzip.])
 595 AC_DEFINE_UNQUOTED([CONF_HOST], ["$host"],
 596         [The canonical host libsigrok will run on.])
 597
 598 AC_CONFIG_FILES([Makefile libsigrok.pc bindings/cxx/libsigrokcxx.pc])
 599
 600 AC_OUTPUT
 601
 602 # Prepare bindings report messages.
 603 m4_define([SR_PREPARE_BINDING_REPORT], [
 604         sr_report_$1=
 605         test -z "$sr_$1_missing" || sr_report_$1=" (missing: $sr_$1_missing)"
 606         test "x$enable_$1" = xyes || sr_report_$1=' (disabled)'
 607 ])
 608 m4_map_args([SR_PREPARE_BINDING_REPORT], [cxx], [python], [ruby], [java])
 609
 610 cat >&AS_MESSAGE_FD <<_EOF
 611
 612 libsigrok configuration summary:
 613  - Package version................. $SR_PACKAGE_VERSION
 614  - Library ABI version............. $SR_LIB_VERSION
 615  - Prefix.......................... $prefix
 616  - Building on..................... $build
 617  - Building for.................... $host
 618  - Building shared / static........ $enable_shared / $enable_static
 619
 620 Compile configuration:
 621  - C compiler...................... $CC
 622  - C compiler version.............. $sr_cc_version
 623  - C compiler flags................ $CFLAGS
 624  - Additional C compiler flags..... $SR_EXTRA_CFLAGS
 625  - C compiler warnings............. $SR_WFLAGS
 626  - C++ compiler.................... $CXX
 627  - C++ compiler version............ $sr_cxx_version
 628  - C++ compiler flags.............. $CXXFLAGS
 629  - C++ compiler warnings........... $SR_WXXFLAGS
 630  - Linker flags.................... $LDFLAGS
 631
 632 Detected libraries (required):
 633  - glib-2.0 >= 2.32.0.............. $sr_glib_version
 634  - libzip >= 0.10.................. $sr_libzip_version
 635
 636 Detected libraries (optional):
 637 $sr_pkglibs_summary
 638 Enabled hardware drivers:
 639 $sr_driver_summary
 640 Enabled serial communication transports:
 641   - serial comm ................... $sr_have_serial_comm
 642   - libserialport ................. $sr_have_libserialport
 643   - hidapi ........................ $sr_have_libhidapi
 644   - bluetooth ..................... $sr_have_bluetooth
 645   - bluez ......................... $sr_have_libbluez
 646
 647 Enabled SCPI backends:
 648  - TCP............................. yes
 649  - RPC............................. $sr_cv_have_rpc
 650  - serial.......................... $sr_have_serial_comm
 651  - VISA............................ $sr_have_librevisa
 652  - GPIB............................ $sr_have_libgpib
 653  - USBTMC.......................... $sr_have_libusb
 654
 655 Enabled language bindings:
 656  - C++............................. $BINDINGS_CXX$sr_report_cxx
 657  - Python.......................... $BINDINGS_PYTHON$sr_report_python
 658  - Ruby............................ $BINDINGS_RUBY$sr_report_ruby
 659  - Java............................ $BINDINGS_JAVA$sr_report_java
 660
 661 _EOF
 662
 663 # Emit a warning if the C++ bindings are not being built.
 664 AM_COND_IF([BINDINGS_CXX], [], [
 665 cat >&AS_MESSAGE_FD <<_EOF
 666 ===============================================================================
 667 WARNING WARNING WARNING WARNING WARNING WARNING WARNING WARNING WARNING WARNING
 668 ===============================================================================
 669 ===                                                                         ===
 670 ===         The libsigrok C++ bindings are not being built since you        ===
 671 ===             are missing one or more dependencies (see above)!           ===
 672 ===                                                                         ===
 673 ===      This means you won't be able to compile frontends that require     ===
 674 ===  the C++ bindings (such as PulseView)! You also won't be able to build  ===
 675 ===     other bindings and frontends using those (such as sigrok-meter)!    ===
 676 ===                                                                         ===
 677 ===============================================================================
 678 WARNING WARNING WARNING WARNING WARNING WARNING WARNING WARNING WARNING WARNING
 679 ===============================================================================
 680
 681 _EOF
 682 ])