configure.ac

   1 ##
   2 ## This file is part of the libsigrok project.
   3 ##
   4 ## Copyright (C) 2010-2012 Bert Vermeulen <bert@biot.com>
   5 ## Copyright (C) 2012 Alexandru Gagniuc <mr.nuke.me@gmail.com>
   6 ##
   7 ## This program is free software: you can redistribute it and/or modify
   8 ## it under the terms of the GNU General Public License as published by
   9 ## the Free Software Foundation, either version 3 of the License, or
  10 ## (at your option) any later version.
  11 ##
  12 ## This program is distributed in the hope that it will be useful,
  13 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ## GNU General Public License for more details.
  16 ##
  17 ## You should have received a copy of the GNU General Public License
  18 ## along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19 ##
  20
  21 # We require at least autoconf 2.63 (AC_INIT format changed there).
  22 AC_PREREQ([2.63])
  23
  24 AC_INIT([libsigrok], [0.4.0],
  25         [sigrok-devel@lists.sourceforge.net],
  26         [libsigrok], [http://www.sigrok.org])
  27 AC_CONFIG_MACRO_DIR([m4])
  28 AC_CONFIG_AUX_DIR([autostuff])
  29 AC_CONFIG_HEADERS([config.h include/libsigrok/version.h])
  30
  31 # We require at least automake 1.11 (needed for 'silent rules').
  32 AM_INIT_AUTOMAKE([1.11 -Wall -Werror no-define nostdinc subdir-objects check-news color-tests])
  33 AM_SILENT_RULES([yes])
  34 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  35
  36 AC_CANONICAL_HOST
  37
  38 # Checks for programs.
  39 AC_PROG_CC
  40 AC_PROG_CXX
  41 AC_PROG_INSTALL
  42 AC_PROG_LN_S
  43
  44 # Required for per-target flags or subdir-objects with C sources.
  45 AM_PROG_CC_C_O
  46
  47 # Set the standard the C library headers should conform to.
  48 AH_VERBATIM([_POSIX_C_SOURCE], [/* The targeted POSIX standard. */
  49 #ifndef _POSIX_C_SOURCE
  50 # define _POSIX_C_SOURCE 200112L
  51 #endif])
  52
  53 # Get compiler versions.
  54 SR_PROG_VERSION([$CC], [sr_cc_version])
  55 SR_PROG_VERSION([$CXX], [sr_cxx_version])
  56
  57 # Check for optional make features.
  58 SR_PROG_MAKE_ORDER_ONLY
  59
  60 # Initialize libtool.
  61 LT_INIT
  62
  63 # Set up the libsigrok version defines.
  64 SR_PKG_VERSION_SET([SR_PACKAGE_VERSION], [AC_PACKAGE_VERSION])
  65
  66 # Library version for libsigrok (NOT the same as the package version).
  67 # Carefully read the libtool docs before updating these numbers!
  68 # The algorithm for determining which number to change (and how) is nontrivial!
  69 # http://www.gnu.org/software/libtool/manual/libtool.html#Updating-version-info
  70 SR_LIB_VERSION_SET([SR_LIB_VERSION], [2:0:0])
  71
  72 AM_CONDITIONAL([WIN32], [test -z "${host_os##mingw*}" || test -z "${host_os##cygwin*}"])
  73
  74 #############################
  75 ##  Optional dependencies  ##
  76 #############################
  77
  78 AC_LANG([C])
  79
  80 # Initialize pkg-config.
  81 # We require at least 0.22, as "Requires.private" behaviour changed there.
  82 PKG_PROG_PKG_CONFIG([0.22])
  83
  84 # Keep track of all checked modules so we can list them at the end.
  85 SR_PKG_CHECK_SUMMARY([sr_pkglibs_summary])
  86
  87 # Collect the pkg-config module names of all dependencies in SR_PKGLIBS.
  88 # These are used to derive the compiler flags and for the "Requires.private"
  89 # field in the generated libsigrok.pc file.
  90 SR_VAR_OPT_PKG([SR_PKGLIBS], [sr_deps_avail])
  91 SR_PKGLIBS_TESTS=
  92 SR_PKGLIBS_CXX=
  93 SR_PKGLIBS_PYTHON=
  94 SR_EXTRA_LIBS=
  95
  96 SR_ARG_OPT_PKG([libserialport], [LIBSERIALPORT], [NEED_SERIAL],
  97         [libserialport >= 0.1.1])
  98
  99 SR_ARG_OPT_PKG([libftdi], [LIBFTDI],,
 100         [libftdi1 >= 1.0], [libftdi >= 0.16])
 101
 102 # FreeBSD comes with an "integrated" libusb-1.0-style USB API.
 103 # This means libusb-1.0 is always available; no need to check for it.
 104 # On Windows, require the latest version we can get our hands on,
 105 # until the new generic event handling has seen an official release.
 106 AS_CASE([$host_os],
 107         [freebsd*], [sr_libusb_req='libusb-1.0' sr_have_libusb=yes],
 108         [mingw*], [sr_libusb_req='libusb-1.0 >= 1.0.20'],
 109         [sr_libusb_req='libusb-1.0 >= 1.0.16'])
 110
 111 SR_ARG_OPT_PKG([libusb], [LIBUSB_1_0], [NEED_USB],
 112         [$sr_libusb_req])
 113
 114 SR_ARG_OPT_PKG([librevisa], [LIBREVISA], [NEED_VISA],
 115         [librevisa >= 0.0.20130412])
 116
 117 SR_ARG_OPT_PKG([libgpib], [LIBGPIB], [NEED_GPIB],
 118         [libgpib])
 119
 120 SR_ARG_OPT_CHECK([libieee1284], [LIBIEEE1284],, [
 121         sr_save_LIBS=$LIBS
 122         LIBS="-lieee1284 $LIBS"
 123         AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <ieee1284.h>]],
 124                                 [[(void) ieee1284_open(0, 0, 0);]])],
 125                 [sr_have_libieee1284=yes], [sr_have_libieee1284=no])
 126         LIBS=$sr_save_LIBS
 127 ])
 128 AS_IF([test "x$sr_have_libieee1284" = xyes],
 129         [SR_PREPEND([SR_EXTRA_LIBS], [-lieee1284])])
 130
 131 ######################
 132 ##  Feature checks  ##
 133 ######################
 134
 135 # The Check unit testing framework is optional. Disable if not found.
 136 SR_PKG_CHECK([check], [SR_PKGLIBS_TESTS], [check >= 0.9.4])
 137 AM_CONDITIONAL([HAVE_CHECK], [test "x$sr_have_check" = xyes])
 138
 139 # Enable the C99 standard if possible, and enforce the use
 140 # of SR_API to explicitly mark all public API functions.
 141 SR_EXTRA_CFLAGS=
 142 SR_CHECK_COMPILE_FLAGS([SR_EXTRA_CFLAGS], [C99], [-std=c99 -c99 -AC99 -qlanglvl=extc99])
 143 SR_CHECK_COMPILE_FLAGS([SR_EXTRA_CFLAGS], [visibility], [-fvisibility=hidden])
 144
 145 SR_ARG_ENABLE_WARNINGS([SR_WFLAGS], [-Wall], [-Wall -Wextra -Wmissing-prototypes])
 146
 147 # Check host characteristics.
 148 AC_SYS_LARGEFILE
 149 AC_C_BIGENDIAN
 150
 151 AC_CHECK_HEADERS([sys/mman.h], [SR_APPEND([sr_deps_avail], [sys_mman_h])])
 152 AC_CHECK_HEADERS([sys/ioctl.h], [SR_APPEND([sr_deps_avail], [sys_ioctl_h])])
 153 AC_CHECK_HEADERS([sys/timerfd.h], [SR_APPEND([sr_deps_avail], [sys_timerfd_h])])
 154
 155 # We need to link against the Winsock2 library for SCPI over TCP.
 156 AS_CASE([$host_os], [mingw*], [SR_PREPEND([SR_EXTRA_LIBS], [-lws2_32])])
 157
 158 # libm (the standard math library) is always needed.
 159 SR_SEARCH_LIBS([SR_EXTRA_LIBS], [pow], [m])
 160
 161 # RPC is only needed for VXI support.
 162 AC_CACHE_CHECK([for RPC support], [sr_cv_have_rpc],
 163         [AC_LINK_IFELSE([AC_LANG_PROGRAM(
 164                         [[#include <rpc/rpc.h>]m4_newline[CLIENT *rpc_test(void);]],
 165                         [[(void) clnt_create("", 0, 0, "");]])],
 166                 [sr_cv_have_rpc=yes], [sr_cv_have_rpc=no])])
 167 AS_IF([test "x$sr_cv_have_rpc" = xyes],
 168         [AC_DEFINE([HAVE_RPC], [1], [Specifies whether we have RPC support.])])
 169 # VXI support is only compiled if RPC support was found.
 170 AM_CONDITIONAL([NEED_RPC], [test "x$sr_cv_have_rpc" = xyes])
 171
 172 ########################
 173 ##  Hardware drivers  ##
 174 ########################
 175
 176 # Keep track of all drivers so we can list them at the end.
 177 SR_VAR_SUMMARY([sr_driver_summary])
 178
 179 # Check whether the sr_deps_avail list contains all of the arguments.
 180 # Unavailable dependencies are collected in sr_deps_missing.
 181 sr_check_driver_deps() {
 182         sr_deps_missing=
 183         for sr_dep
 184         do
 185                 AS_CASE([" $sr_deps_avail "], [*" $sr_dep "*],,
 186                         [SR_APPEND([sr_deps_missing], [', '], [$sr_dep])])
 187         done
 188         test -z "$sr_deps_missing" || return 1
 189 }
 190
 191 AC_ARG_ENABLE([all-drivers],
 192         [AS_HELP_STRING([--enable-all-drivers],
 193                         [enable all drivers by default [default=yes]])],
 194         [], [enable_all_drivers=yes])
 195
 196 ## _SR_DRIVER(Device name, driver-name, var-name, [dependencies...])
 197 m4_define([_SR_DRIVER], [
 198         AC_ARG_ENABLE([$2],
 199                 [AS_HELP_STRING([--enable-$2], [enable $1 support])],
 200                 [$3=$enableval], [$3=$enable_all_drivers])
 201
 202         AS_IF([test "x[$]$3" = xyes], [sr_hw_info=yes[]m4_ifval([$4], [
 203                 sr_check_driver_deps $4 \
 204                         || $3=no sr_hw_info="no (missing: $sr_deps_missing)"
 205         ])], [sr_hw_info='no (disabled)'])
 206         sr_driver_summary_append "$2" "$sr_hw_info"
 207
 208         AM_CONDITIONAL([$3], [test "x[$]$3" = xyes])
 209         AM_COND_IF([$3], [AC_DEFINE([HAVE_$3], [1], [Whether to support $1 device.])])
 210 ])
 211
 212 ## SR_DRIVER(Device name, driver-name, [dependencies...])
 213 m4_define([SR_DRIVER],
 214         [_SR_DRIVER([$1], [$2], m4_expand([AS_TR_CPP([HW_$2])]), [$3])])
 215
 216 SR_DRIVER([Agilent DMM], [agilent-dmm], [libserialport])
 217 SR_DRIVER([Appa 55II], [appa-55ii], [libserialport])
 218 SR_DRIVER([ASIX SIGMA/SIGMA2], [asix-sigma], [libftdi])
 219 SR_DRIVER([Atten PPS3xxx], [atten-pps3xxx], [libserialport])
 220 SR_DRIVER([BayLibre ACME], [baylibre-acme], [sys_timerfd_h])
 221 SR_DRIVER([BeagleLogic], [beaglelogic], [sys_mman_h sys_ioctl_h])
 222 SR_DRIVER([Brymen BM86x], [brymen-bm86x], [libusb])
 223 SR_DRIVER([Brymen DMM], [brymen-dmm], [libserialport])
 224 SR_DRIVER([CEM DT-885x], [cem-dt-885x], [libserialport])
 225 SR_DRIVER([Center 3xx], [center-3xx], [libserialport])
 226 SR_DRIVER([ChronoVu LA], [chronovu-la], [libusb libftdi])
 227 SR_DRIVER([Colead SLM], [colead-slm], [libserialport])
 228 SR_DRIVER([Conrad DIGI 35 CPU], [conrad-digi-35-cpu], [libserialport])
 229 SR_DRIVER([DER EE DE-5000], [deree-de5000], [libserialport])
 230 SR_DRIVER([demo], [demo])
 231 SR_DRIVER([Fluke DMM], [fluke-dmm], [libserialport])
 232 SR_DRIVER([fx2lafw], [fx2lafw], [libusb])
 233 SR_DRIVER([GMC MH 1x/2x], [gmc-mh-1x-2x], [libserialport])
 234 SR_DRIVER([GW Instek GDS-800], [gwinstek-gds-800], [libserialport])
 235 SR_DRIVER([Hameg HMO], [hameg-hmo], [libserialport])
 236 SR_DRIVER([Hantek DSO], [hantek-dso], [libusb])
 237 SR_DRIVER([Hung-Chang DSO-2100], [hung-chang-dso-2100], [libieee1284])
 238 SR_DRIVER([Ikalogic Scanalogic-2], [ikalogic-scanalogic2], [libusb])
 239 SR_DRIVER([Ikalogic Scanaplus], [ikalogic-scanaplus], [libftdi])
 240 SR_DRIVER([Kecheng KC-330B], [kecheng-kc-330b], [libusb])
 241 SR_DRIVER([KERN scale], [kern-scale], [libserialport])
 242 SR_DRIVER([Korad KDxxxxP], [korad-kdxxxxp], [libserialport])
 243 SR_DRIVER([Lascar EL-USB], [lascar-el-usb], [libusb])
 244 SR_DRIVER([Manson HCS-3xxx], [manson-hcs-3xxx], [libserialport])
 245 SR_DRIVER([maynuo-m97], [maynuo-m97])
 246 SR_DRIVER([MIC 985xx], [mic-985xx], [libserialport])
 247 SR_DRIVER([Motech LPS 30x], [motech-lps-30x], [libserialport])
 248 SR_DRIVER([Norma DMM], [norma-dmm], [libserialport])
 249 SR_DRIVER([OpenBench Logic Sniffer], [openbench-logic-sniffer], [libserialport])
 250 SR_DRIVER([Pipistrello-OLS], [pipistrello-ols], [libftdi])
 251 SR_DRIVER([Rigol DS], [rigol-ds])
 252 SR_DRIVER([Saleae Logic16], [saleae-logic16], [libusb])
 253 SR_DRIVER([SCPI PPS], [scpi-pps])
 254 SR_DRIVER([serial DMM], [serial-dmm], [libserialport])
 255 SR_DRIVER([Sysclk LWLA], [sysclk-lwla], [libusb])
 256 SR_DRIVER([Teleinfo], [teleinfo], [libserialport])
 257 SR_DRIVER([Testo], [testo], [libusb])
 258 SR_DRIVER([Tondaj SL-814], [tondaj-sl-814], [libserialport])
 259 SR_DRIVER([UNI-T DMM], [uni-t-dmm], [libusb])
 260 SR_DRIVER([UNI-T UT32x], [uni-t-ut32x], [libusb])
 261 SR_DRIVER([Victor DMM], [victor-dmm], [libusb])
 262 SR_DRIVER([Yokogawa DL/DLM], [yokogawa-dlm])
 263 SR_DRIVER([ZEROPLUS Logic Cube], [zeroplus-logic-cube], [libusb])
 264
 265 ###############################
 266 ##  Language bindings setup  ##
 267 ###############################
 268
 269 AC_LANG([C++])
 270 SR_ARG_ENABLE_WARNINGS([SR_WXXFLAGS], [-Wall], [-Wall -Wextra])
 271
 272 AC_ARG_ENABLE([bindings],
 273         [AS_HELP_STRING([--enable-bindings], [build language bindings [default=yes]])],
 274         [], [enable_bindings=yes])
 275
 276 AC_ARG_ENABLE([cxx],
 277         [AS_HELP_STRING([--enable-cxx], [build C++ bindings [default=yes]])],
 278         [], [enable_cxx=$enable_bindings])
 279
 280 AC_ARG_ENABLE([python],
 281         [AS_HELP_STRING([--enable-python], [build Python bindings [default=yes]])],
 282         [], [enable_python=$enable_bindings])
 283
 284 AC_ARG_ENABLE([java],
 285         [AS_HELP_STRING([--enable-java], [build Java bindings [default=yes]])],
 286         [], [enable_java=$enable_bindings])
 287
 288 ####################
 289 ##  C++ bindings  ##
 290 ####################
 291
 292 sr_cxx_missing=
 293
 294 # Check if the C++ compiler supports the C++11 standard.
 295 AX_CXX_COMPILE_STDCXX_11([noext], [optional])
 296 AS_IF([test "x$HAVE_CXX11" != x1],
 297         [SR_APPEND([sr_cxx_missing], [', '], ['C++11'])])
 298
 299 # The C++ bindings need glibmm.
 300 SR_PKG_CHECK([glibmm], [SR_PKGLIBS_CXX], [glibmm-2.4 >= 2.32.0])
 301 AS_IF([test "x$sr_have_glibmm" != xyes],
 302         [SR_APPEND([sr_cxx_missing], [', '], [glibmm])])
 303
 304 # The C++ bindings use Doxygen to parse libsigrok symbols.
 305 AC_CHECK_PROG([HAVE_DOXYGEN], [doxygen], [yes], [no])
 306 AS_IF([test "x$HAVE_DOXYGEN" != xyes],
 307         [SR_APPEND([sr_cxx_missing], [', '], [Doxygen])])
 308
 309 # Python is needed for the C++ bindings.
 310 AM_PATH_PYTHON([2.7],
 311         [HAVE_PYTHON=yes],
 312         [HAVE_PYTHON=no
 313         SR_APPEND([sr_cxx_missing], [', '], [Python])])
 314
 315 AS_IF([test -z "$sr_cxx_missing"],
 316         [BINDINGS_CXX=$enable_cxx], [BINDINGS_CXX=no])
 317 AM_CONDITIONAL([BINDINGS_CXX], [test "x$BINDINGS_CXX" = xyes])
 318
 319 # C++ bindings want stoi and stod.
 320 AM_COND_IF([BINDINGS_CXX], [
 321         AC_CACHE_CHECK([for stoi and stod], [sr_cv_have_stoi_stod],
 322                 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <string>]],
 323                                 [[(void) std::stoi("1"); (void) std::stod("1.0");]])],
 324                         [sr_cv_have_stoi_stod=yes], [sr_cv_have_stoi_stod=no])])
 325         AS_IF([test "x$sr_cv_have_stoi_stod" = xyes],
 326                 [AC_DEFINE([HAVE_STOI_STOD], [1],
 327                         [Specifies whether we have the stoi and stod functions.])])
 328 ])
 329
 330 #######################
 331 ##  Python bindings  ##
 332 #######################
 333
 334 AS_IF([test "x$BINDINGS_CXX" = xyes],
 335         [sr_python_missing=],
 336         [sr_python_missing='C++ bindings'])
 337
 338 # Extract major and minor version number of the Python interpreter.
 339 sr_pymajor=${PYTHON_VERSION%%.*}
 340 sr_pyminor=${PYTHON_VERSION#*.}
 341
 342 # The Python bindings need Python development files. Check for either
 343 # Python 3 or Python 2 headers depending on the interpreter version.
 344 SR_PKG_CHECK([python_dev], [SR_PKGLIBS_PYTHON],
 345         [python = $PYTHON_VERSION],
 346         [python$sr_pymajor = $PYTHON_VERSION],
 347         [python$sr_pymajor$sr_pyminor = $PYTHON_VERSION],
 348         [python-$PYTHON_VERSION = $PYTHON_VERSION])
 349
 350 AS_IF([test "x$sr_have_python_dev" != xyes],
 351         [SR_APPEND([sr_python_missing], [', '], [Headers])])
 352
 353 # PyGObject is needed for the Python bindings.
 354 SR_PKG_CHECK([pygobject], [SR_PKGLIBS_PYTHON], [pygobject-3.0 >= 3.0.0])
 355 AS_IF([test "x$sr_have_pygobject" != xyes],
 356         [SR_APPEND([sr_python_missing], [', '], [PyGObject])])
 357
 358 PKG_CHECK_EXISTS([pygobject-3.0 < 3.7.91],
 359         [AC_DEFINE([PYGOBJECT_FLAGS_SIGNED], [1],
 360                 [Whether last argument to pyg_flags_get_value() is signed.])])
 361
 362 # The Python bindings need the setuptools and numpy Python modules.
 363 # We'll let it go through even if the AX macro wasn't found, as the
 364 # Python modules may still be there.
 365 m4_ifdef([AX_PYTHON_MODULE], [
 366         AX_PYTHON_MODULE([setuptools])
 367         AX_PYTHON_MODULE([numpy])
 368 ], [
 369         HAVE_PYMOD_SETUPTOOLS=yes
 370         HAVE_PYMOD_NUMPY=yes
 371         m4_warn([unsupported],
 372                 [Missing macro AX_PYTHON_MODULE: no check for setuptools and numpy])
 373 ])
 374 AS_IF([test "x$HAVE_PYMOD_SETUPTOOLS" != xyes],
 375         [SR_APPEND([sr_python_missing], [', '], [setuptools])])
 376 AS_IF([test "x$HAVE_PYMOD_NUMPY" != xyes],
 377         [SR_APPEND([sr_python_missing], [', '], [numpy])])
 378
 379 # The Python bindings use SWIG to generate code.
 380 AC_CHECK_PROGS([SWIG], [swig swig3.0 swig2.0])
 381 AS_IF([test "x$SWIG" = x],
 382         [SR_APPEND([sr_python_missing], [', '], [SWIG])])
 383
 384 AS_IF([test -z "$sr_python_missing"],
 385         [BINDINGS_PYTHON=$enable_python], [BINDINGS_PYTHON=no])
 386 AM_CONDITIONAL([BINDINGS_PYTHON], [test "x$BINDINGS_PYTHON" = xyes])
 387
 388 ####################
 389 ##  Java bindings ##
 390 ####################
 391
 392 AS_IF([test "x$BINDINGS_CXX" = xyes],
 393         [sr_java_missing=],
 394         [sr_java_missing='C++ bindings'])
 395
 396 # The Java bindings use SWIG to generate code.
 397 AS_IF([test "x$SWIG" = x],
 398         [SR_APPEND([sr_java_missing], [', '], [SWIG])])
 399
 400 # Find Java compiler and JNI includes for Java bindings.
 401 AC_CHECK_PROG([HAVE_JAVAC], [javac], [yes], [no])
 402 AS_IF([test "x$HAVE_JAVAC" = xno],
 403         [SR_APPEND([sr_java_missing], [', '], [JavaC])])
 404
 405 AC_ARG_WITH([jni-include-path],
 406         [AS_HELP_STRING([[--with-jni-include-path=DIR-LIST (space-separated)]],
 407                 [specify JNI include directories [default=detect]])],
 408         [JNI_INCLUDE_DIRS=" $withval"], [JNI_INCLUDE_DIRS=])
 409
 410 JNI_CPPFLAGS=
 411 AS_IF([test "x$enable_java$HAVE_JAVAC" = xyesyes], [
 412         AX_PROG_JAVAC
 413         AS_IF([test -z "$JNI_INCLUDE_DIRS" && test "x$cross_compiling" != xyes], [
 414                 ## Work around the totally broken logic in AX_JNI_INCLUDE_DIR:
 415                 ## If we can find jni.h without any special search path, skip
 416                 ## the execution of the broken macro to increase our chances of
 417                 ## success.
 418                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <jni.h>]], [])],,
 419                         [AX_JNI_INCLUDE_DIR])
 420         ])
 421 ])
 422 for sr_dir in $JNI_INCLUDE_DIRS
 423 do
 424         SR_APPEND([JNI_CPPFLAGS], ["-I$sr_dir"])
 425 done
 426 AC_SUBST([JNI_CPPFLAGS])
 427
 428 sr_save_cppflags=$CPPFLAGS
 429 SR_APPEND([CPPFLAGS], [$JNI_CPPFLAGS])
 430 AC_CHECK_HEADER([jni.h],,
 431         [SR_APPEND([sr_java_missing], [', '], ['JNI headers'])])
 432 CPPFLAGS=$sr_save_cppflags
 433
 434 AS_IF([test -z "$sr_java_missing"],
 435         [BINDINGS_JAVA=$enable_java], [BINDINGS_JAVA=no])
 436 AM_CONDITIONAL([BINDINGS_JAVA], [test "x$BINDINGS_JAVA" = xyes])
 437
 438 ##############################
 439 ##  Finalize configuration  ##
 440 ##############################
 441
 442 # Add mandatory dependencies to module list.
 443 SR_APPEND([SR_PKGLIBS], ['libzip >= 0.10'])
 444 AC_SUBST([SR_PKGLIBS])
 445
 446 # Retrieve the compile and link flags for all modules combined.
 447 # Also, bail out at this point if any module dependency is not met.
 448 PKG_CHECK_MODULES([LIBSIGROK], [glib-2.0 >= 2.32.0 $SR_PKGLIBS])
 449 PKG_CHECK_MODULES([TESTS], [$SR_PKGLIBS_TESTS glib-2.0 $SR_PKGLIBS])
 450
 451 # SR_PKGLIBS_CXX may be empty, so only invoke these checks when
 452 # the C++ bindings are enabled.
 453 AM_COND_IF([BINDINGS_CXX], [
 454         PKG_CHECK_MODULES([LIBSIGROKCXX], [$SR_PKGLIBS_CXX])
 455         PKG_CHECK_MODULES([PYSIGROK], [$SR_PKGLIBS_PYTHON $SR_PKGLIBS_CXX])
 456 ])
 457
 458 # Check for specific libusb features, now that we know the CFLAGS.
 459 AC_LANG([C])
 460 sr_save_cflags=$CFLAGS
 461 sr_save_libs=$LIBS
 462 CFLAGS="$LIBSIGROK_CFLAGS $CFLAGS"
 463 LIBS="$LIBSIGROK_LIBS $LIBS"
 464 AC_CHECK_TYPES([libusb_os_handle],
 465         [sr_have_libusb_os_handle=yes], [sr_have_libusb_os_handle=no],
 466         [[#include <libusb.h>]])
 467 AC_CHECK_FUNCS([zip_discard])
 468 LIBS=$sr_save_libs
 469 CFLAGS=$sr_save_cflags
 470
 471 AM_COND_IF([NEED_USB], [AS_CASE([$sr_have_libusb_os_handle:$host_os], [no:mingw*],
 472         [AC_MSG_ERROR([Windows builds require the event-abstraction branch of libusb])])])
 473
 474 sr_glib_version=`$PKG_CONFIG --modversion glib-2.0 2>&AS_MESSAGE_LOG_FD`
 475 sr_libzip_version=`$PKG_CONFIG --modversion libzip 2>&AS_MESSAGE_LOG_FD`
 476
 477 AC_DEFINE_UNQUOTED([CONF_LIBZIP_VERSION], ["$sr_libzip_version"],
 478         [Build-time version of libzip.])
 479 AC_DEFINE_UNQUOTED([CONF_HOST], ["$host"],
 480         [The canonical host libsigrok will run on.])
 481
 482 AC_CONFIG_FILES([Makefile libsigrok.pc bindings/cxx/libsigrokcxx.pc])
 483
 484 AC_OUTPUT
 485
 486 # Prepare bindings report messages.
 487 m4_define([SR_PREPARE_BINDING_REPORT], [
 488         sr_report_$1=
 489         test -z "$sr_$1_missing" || sr_report_$1=" (missing: $sr_$1_missing)"
 490         test "x$enable_$1" = xyes || sr_report_$1=' (disabled)'
 491 ])
 492 m4_map_args([SR_PREPARE_BINDING_REPORT], [cxx], [python], [java])
 493
 494 cat >&AS_MESSAGE_FD <<_EOF
 495
 496 libsigrok configuration summary:
 497  - Package version................. $SR_PACKAGE_VERSION
 498  - Library ABI version............. $SR_LIB_VERSION
 499  - Prefix.......................... $prefix
 500  - Building on..................... $build
 501  - Building for.................... $host
 502
 503 Compile configuration:
 504  - C compiler...................... $CC
 505  - C compiler version.............. $sr_cc_version
 506  - C compiler flags................ $CFLAGS
 507  - Additional C compiler flags..... $SR_EXTRA_CFLAGS
 508  - C compiler warnings............. $SR_WFLAGS
 509  - C++ compiler.................... $CXX
 510  - C++ compiler version............ $sr_cxx_version
 511  - C++ compiler flags.............. $CXXFLAGS
 512  - C++ compiler warnings........... $SR_WXXFLAGS
 513
 514 Detected libraries (required):
 515  - glib-2.0 >= 2.32.0.............. $sr_glib_version
 516  - libzip >= 0.10.................. $sr_libzip_version
 517
 518 Detected libraries (optional):
 519 $sr_pkglibs_summary
 520 Enabled hardware drivers:
 521 $sr_driver_summary
 522 Enabled SCPI backends:
 523  - TCP............................. yes
 524  - RPC............................. $sr_cv_have_rpc
 525  - serial.......................... $sr_have_libserialport
 526  - VISA............................ $sr_have_librevisa
 527  - GPIB............................ $sr_have_libgpib
 528  - USBTMC.......................... $sr_have_libusb
 529
 530 Enabled language bindings:
 531  - C++............................. $BINDINGS_CXX$sr_report_cxx
 532  - Python.......................... $BINDINGS_PYTHON$sr_report_python
 533  - Java............................ $BINDINGS_JAVA$sr_report_java
 534
 535 _EOF