configure.ac

   1 ##
   2 ## This file is part of the libsigrok project.
   3 ##
   4 ## Copyright (C) 2010-2012 Bert Vermeulen <bert@biot.com>
   5 ## Copyright (C) 2012 Alexandru Gagniuc <mr.nuke.me@gmail.com>
   6 ##
   7 ## This program is free software: you can redistribute it and/or modify
   8 ## it under the terms of the GNU General Public License as published by
   9 ## the Free Software Foundation, either version 3 of the License, or
  10 ## (at your option) any later version.
  11 ##
  12 ## This program is distributed in the hope that it will be useful,
  13 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ## GNU General Public License for more details.
  16 ##
  17 ## You should have received a copy of the GNU General Public License
  18 ## along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19 ##
  20
  21 # We require at least autoconf 2.63 (AC_INIT format changed there).
  22 AC_PREREQ([2.63])
  23
  24 # libsigrok package version number (NOT the same as shared lib version!).
  25 m4_define([sr_package_version_major], [0])
  26 m4_define([sr_package_version_minor], [4])
  27 m4_define([sr_package_version_micro], [0])
  28 m4_define([sr_package_version_suffix], [-git])
  29 m4_define([sr_package_version], [sr_package_version_major.sr_package_version_minor.sr_package_version_micro[]sr_package_version_suffix])
  30
  31 AC_INIT([libsigrok], [sr_package_version], [sigrok-devel@lists.sourceforge.net],
  32         [libsigrok], [http://www.sigrok.org])
  33 AC_CONFIG_HEADER([config.h])
  34 AC_CONFIG_MACRO_DIR([autostuff])
  35 AC_CONFIG_AUX_DIR([autostuff])
  36
  37 # We require at least automake 1.11 (needed for 'silent rules').
  38 AM_INIT_AUTOMAKE([1.11 -Wall -Werror subdir-objects check-news color-tests])
  39 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  40 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  41
  42 AH_TOP([#ifndef SR_CONFIG_H
  43 #define SR_CONFIG_H    /* To stop multiple inclusions. */])
  44 AH_BOTTOM([#endif /* SR_CONFIG_H */])
  45
  46 # Enable more compiler warnings via -Wall and -Wextra. Add -fvisibility=hidden
  47 # and enforce use of SR_API to explicitly mark all public API functions.
  48 COMMON_FLAGS="$CFLAGS -Wall -Wextra -fvisibility=hidden"
  49 CFLAGS="$COMMON_FLAGS -std=c11 -D_POSIX_C_SOURCE=200112L -Wmissing-prototypes"
  50 CXXFLAGS="-std=c++11 $COMMON_FLAGS"
  51
  52 # Checks for programs.
  53 AC_PROG_CC
  54 AC_PROG_CPP
  55 AC_PROG_CXX
  56 AC_PROG_INSTALL
  57 AC_PROG_LN_S
  58
  59 # Required for per-target flags or subdir-objects with C sources.
  60 AM_PROG_CC_C_O
  61
  62 # Initialize libtool.
  63 LT_INIT
  64
  65 # Initialize pkg-config.
  66 # We require at least 0.22, as "Requires.private" behaviour changed there.
  67 PKG_PROG_PKG_CONFIG([0.22])
  68
  69 # Library version for libsigrok (NOT the same as the package version).
  70 # Carefully read the libtool docs before updating these numbers!
  71 # The algorithm for determining which number to change (and how) is nontrivial!
  72 # http://www.gnu.org/software/libtool/manual/libtool.html#Updating-version-info
  73 SR_LIB_VERSION_CURRENT=2
  74 SR_LIB_VERSION_REVISION=0
  75 SR_LIB_VERSION_AGE=0
  76 SR_LIB_VERSION="$SR_LIB_VERSION_CURRENT:$SR_LIB_VERSION_REVISION:$SR_LIB_VERSION_AGE"
  77 SR_LIB_LDFLAGS="-version-info $SR_LIB_VERSION"
  78 AC_SUBST(SR_LIB_VERSION_CURRENT)
  79 AC_SUBST(SR_LIB_VERSION_REVISION)
  80 AC_SUBST(SR_LIB_VERSION_AGE)
  81 AC_SUBST(SR_LIB_VERSION)
  82 AC_SUBST(SR_LIB_LDFLAGS)
  83
  84 AC_ARG_ENABLE(all-drivers, AC_HELP_STRING([--enable-all-drivers],
  85         [enable all drivers by default [default=yes]]),
  86         [HW_ENABLED_DEFAULT="$enableval"],
  87         [HW_ENABLED_DEFAULT="yes"])
  88
  89 # Usage: DRIVER([Device name], [driver-name])
  90 # An optional third argument [no] disables that driver.
  91 m4_define([driverize], [m4_tolower(m4_bpatsubst([$1], [[^0-9a-zA-Z-]+], [-]))])
  92 m4_define([upperize], [m4_toupper(m4_bpatsubst([$1], [[^0-9a-zA-Z_]+], [_]))])
  93 AC_DEFUN([DRIVER], [
  94         if test -z "$3"; then
  95                 default=$HW_ENABLED_DEFAULT
  96         else
  97                 default="$3"
  98         fi
  99         AC_ARG_ENABLE($2, AC_HELP_STRING([--enable-$2], [enable $1 support]),
 100                 [m4_join([], [HW_], upperize([$2]))="$enableval"],
 101                 [m4_join([], [HW_], upperize([$2]))=$default])
 102         dots=$(echo -n ".............................." | cut -c 1-$(expr 32 - $(echo -n $2|wc -c)))
 103         driver_summary="${driver_summary}  - $2${dots} \${m4_join([], [HW_], upperize([$2]))}@"
 104 ])
 105
 106 DRIVER([Agilent DMM], [agilent-dmm])
 107 DRIVER([Appa 55II], [appa-55ii])
 108 DRIVER([ASIX SIGMA/SIGMA2], [asix-sigma])
 109 DRIVER([Atten PPS3xxx], [atten-pps3xxx])
 110 DRIVER([BayLibre ACME], [baylibre-acme])
 111 DRIVER([BeagleLogic], [beaglelogic])
 112 DRIVER([Brymen BM86x], [brymen-bm86x])
 113 DRIVER([Brymen DMM], [brymen-dmm])
 114 DRIVER([CEM DT-885x], [cem-dt-885x])
 115 DRIVER([Center 3xx], [center-3xx])
 116 DRIVER([ChronoVu LA], [chronovu-la])
 117 DRIVER([Colead SLM], [colead-slm])
 118 DRIVER([Conrad DIGI 35 CPU], [conrad-digi-35-cpu])
 119 DRIVER([DER EE DE-5000], [deree-de5000])
 120 DRIVER([demo], [demo])
 121 DRIVER([Fluke DMM], [fluke-dmm])
 122 DRIVER([fx2lafw], [fx2lafw])
 123 DRIVER([GMC MH 1x/2x], [gmc-mh-1x-2x])
 124 DRIVER([Hameg HMO], [hameg-hmo])
 125 DRIVER([Hantek DSO], [hantek-dso])
 126 DRIVER([Ikalogic Scanalogic-2], [ikalogic-scanalogic2])
 127 DRIVER([Ikalogic Scanaplus], [ikalogic-scanaplus])
 128 DRIVER([Kecheng KC-330B], [kecheng-kc-330b])
 129 DRIVER([Lascar EL-USB], [lascar-el-usb])
 130 DRIVER([Manson HCS-3xxx], [manson-hcs-3xxx])
 131 DRIVER([maynuo-m97], [maynuo-m97])
 132 DRIVER([MIC 985xx], [mic-985xx])
 133 DRIVER([Motech LPS 30x], [motech-lps-30x])
 134 DRIVER([Norma DMM], [norma-dmm])
 135 DRIVER([OpenBench Logic Sniffer], [openbench-logic-sniffer])
 136 DRIVER([Pipistrello-OLS], [pipistrello-ols])
 137 DRIVER([Rigol DS], [rigol-ds])
 138 DRIVER([Saleae Logic16], [saleae-logic16])
 139 DRIVER([SCPI PPS], [scpi-pps])
 140 DRIVER([serial DMM], [serial-dmm])
 141 DRIVER([Sysclk LWLA], [sysclk-lwla])
 142 DRIVER([Teleinfo], [teleinfo])
 143 DRIVER([Testo], [testo])
 144 DRIVER([Tondaj SL-814], [tondaj-sl-814])
 145 DRIVER([UNI-T DMM], [uni-t-dmm])
 146 DRIVER([UNI-T UT32x], [uni-t-ut32x])
 147 DRIVER([Victor DMM], [victor-dmm])
 148 DRIVER([Yokogawa DL/DLM], [yokogawa-dlm])
 149 DRIVER([ZEROPLUS Logic Cube], [zeroplus-logic-cube])
 150
 151 AC_ARG_ENABLE(libserialport,
 152         AC_HELP_STRING([--disable-libserialport],
 153         [disable libserialport support [default=detect]]))
 154
 155 AC_ARG_ENABLE(libftdi,
 156         AC_HELP_STRING([--disable-libftdi],
 157         [disable libftdi support [default=detect]]))
 158
 159 AC_ARG_ENABLE(libusb,
 160         AC_HELP_STRING([--disable-libusb],
 161         [disable libusb support [default=detect]]))
 162
 163 # Language binding '--enable' options:
 164
 165 AC_ARG_ENABLE(bindings,
 166         AC_HELP_STRING([--enable-bindings],
 167         [build language bindings [default=yes]]),
 168         [BINDINGS_ALL="$enableval"], [BINDINGS_ALL="yes"])
 169
 170 AC_ARG_ENABLE(cxx,
 171         AC_HELP_STRING([--enable-cxx],
 172         [build C++ bindings [default=yes]]),
 173         [BINDINGS_CXX="$enableval"], [BINDINGS_CXX=$BINDINGS_ALL])
 174
 175 AC_ARG_ENABLE(python,
 176         AC_HELP_STRING([--enable-python],
 177         [build Python bindings [default=yes]]),
 178         [BINDINGS_PYTHON="$enableval"], [BINDINGS_PYTHON=$BINDINGS_ALL])
 179
 180 AC_ARG_ENABLE(java,
 181         AC_HELP_STRING([--enable-java],
 182         [build Java bindings [default=yes]]),
 183         [BINDINGS_JAVA="$enableval"], [BINDINGS_JAVA=$BINDINGS_ALL])
 184
 185 AC_ARG_WITH(jni-include-path,
 186         AC_HELP_STRING([--with-jni-include-path=path],
 187         [specify include path for JNI [default=autodetect]]),
 188         [JNI_INCLUDE_DIRS="$withval"], [JNI_INCLUDE_DIRS=auto])
 189
 190 # Check if the C++ compiler supports the C++11 standard.
 191
 192 m4_ifdef([AX_CXX_COMPILE_STDCXX_11], [AX_CXX_COMPILE_STDCXX_11(,[optional])],
 193         [AC_MSG_NOTICE([Missing macro m4_toupper(aX_CXX_COMPILE_STDCXX_11), no C++11 check])])
 194
 195 if test "x$HAVE_CXX11" != "x1"; then
 196         BINDINGS_CXX="no"; cxx_msg="C++11 compiler required"
 197 fi
 198
 199 # The C++ bindings use Doxygen to parse libsigrok symbols.
 200 AC_CHECK_PROG([HAVE_DOXYGEN], [doxygen], [yes])
 201 if test "x$HAVE_DOXYGEN" != "xyes"; then
 202         BINDINGS_CXX="no"; cxx_msg="Doxygen required"
 203 fi
 204
 205 # Python is needed for the C++ bindings.
 206 AM_PATH_PYTHON([2.7], [HAVE_PYTHON="yes"],
 207         [HAVE_PYTHON="no"; BINDINGS_CXX="no"; cxx_msg="Python required"])
 208
 209 # The Python bindings need Python development files.
 210 PKG_CHECK_MODULES([python], [python >= 2.7],
 211         [CXXFLAGS="$CXXFLAGS $python_CFLAGS";
 212         CXXLIBS="$CXXLIBS $python_LIBS"],
 213 [PKG_CHECK_MODULES([python27], [python-2.7 >= 2.7],
 214         [CXXFLAGS="$CXXFLAGS $python27_CFLAGS";
 215         CXXLIBS="$CXXLIBS $python27_LIBS"],
 216                 [BINDINGS_PYTHON="no"; python_msg="Python headers required"])])
 217
 218 # The Python bindings need the setuptools Python module.
 219 m4_ifdef([AX_PYTHON_MODULE], [AX_PYTHON_MODULE([setuptools])],
 220         # We'll let it go through even if the macro wasn't found, the Python
 221         # module may still be there.
 222         [HAVE_PYTHON_SETUPTOOLS="yes";
 223                 AC_MSG_NOTICE([Missing macro m4_toupper(aX_PYTHON_MODULE), no setuptools check])]
 224 )
 225 if test "x$HAVE_PYMOD_SETUPTOOLS" != "xyes"; then
 226         BINDINGS_PYTHON="no"; python_msg="Python setuptools module required"
 227 fi
 228
 229 # The Python and Java bindings use SWIG to generate code.
 230 AC_CHECK_PROG([HAVE_SWIG], [swig], [yes])
 231 if test "x$HAVE_SWIG" != "xyes"; then
 232         BINDINGS_PYTHON="no"; python_msg="SWIG required"
 233         BINDINGS_JAVA="no"; java_msg="SWIG required"
 234 fi
 235
 236 # Checks for libraries.
 237
 238 case "$host" in
 239 *mingw*)
 240         # We need to link against the Winsock2 library for SCPI over TCP.
 241         LIBS="$LIBS -lws2_32";;
 242 esac
 243
 244 # This variable collects the pkg-config names of all detected libs.
 245 # It is then used to construct the "Requires.private:" field in the
 246 # libsigrok.pc file.
 247 SR_PKGLIBS=""
 248
 249 # libm (the standard math library) is always needed.
 250 AC_SEARCH_LIBS([pow], [m])
 251
 252 # RPC is only needed for VXI support.
 253 AC_MSG_CHECKING([for RPC support])
 254 AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <rpc/rpc.h>],
 255                         [CLIENT *rpc_test(void)],
 256                         [{ return clnt_create("", 0, 0, ""); }])],
 257                 [AC_MSG_RESULT([yes]); have_rpc=1],
 258                 [AC_MSG_RESULT([no]);  have_rpc=0])
 259 # Define HAVE_RPC in config.h if we found RPC support.
 260 AC_DEFINE_UNQUOTED(HAVE_RPC, [$have_rpc], [Specifies whether we have RPC support.])
 261 # VXI support is only compiled if RPC support was found.
 262 AM_CONDITIONAL(NEED_RPC, test "x$have_rpc" != "x0")
 263
 264 AC_DEFINE_UNQUOTED(HOST, ["$host"], [.])
 265
 266 # libglib-2.0 is always needed. Abort if it's not found.
 267 # Note: glib-2.0 is part of the libsigrok API (hard pkg-config requirement).
 268 # We require at least 2.32.0 due to e.g. g_variant_new_fixed_array().
 269 AM_PATH_GLIB_2_0([2.32.0],
 270         [LIB_CFLAGS="$LIB_CFLAGS $GLIB_CFLAGS"; LIBS="$LIBS $GLIB_LIBS"])
 271
 272 # libzip is always needed. Abort if it's not found.
 273 PKG_CHECK_MODULES([libzip], [libzip >= 0.10],
 274         [LIB_CFLAGS="$LIB_CFLAGS $libzip_CFLAGS"; LIBS="$LIBS $libzip_LIBS";
 275         SR_PKGLIBS="$SR_PKGLIBS libzip"])
 276 libzip_ver=`$PKG_CONFIG --modversion libzip`
 277 AC_DEFINE_UNQUOTED(HAVE_LIBZIP_VER, ["$libzip_ver"], [.])
 278
 279 # libserialport is only needed for some hardware drivers. Disable the
 280 # respective drivers if it is not found.
 281 if test "x$enable_libserialport" != "xno"; then
 282         PKG_CHECK_MODULES([libserialport], [libserialport >= 0.1.1],
 283                 [have_libserialport="yes"; LIB_CFLAGS="$LIB_CFLAGS $libserialport_CFLAGS";
 284                 LIBS="$LIBS $libserialport_LIBS";
 285                 SR_PKGLIBS="$SR_PKGLIBS libserialport"],
 286                 [have_libserialport="no"])
 287         if test "x$enable_libserialport$have_libserialport" = "xyesno"; then
 288                 AC_MSG_ERROR([libserialport support requested, but it was not found.])
 289         fi
 290 else
 291         have_libserialport="no"
 292 fi
 293 if test "x$have_libserialport" = "xno"; then
 294         HW_AGILENT_DMM="no"; HW_APPA_55II="no";
 295         HW_ATTEN_PPS3XXX="no"; HW_BRYMEN_DMM="no"; HW_CEM_DT_885X="no";
 296         HW_CENTER_3XX="no"; HW_COLEAD_SLM="no"; HW_CONRAD_DIGI_35_CPU="no";
 297         HW_DEREE_DE5000="no"; HW_FLUKE_DMM="no"; HW_GMC_MH_1X_2X="no";
 298         HW_HAMEG_HMO="no"; HW_MANSON_HCS_3XXX="no"; HW_MIC_985XX="no";
 299         HW_MOTECH_LPS_30X="no"; HW_NORMA_DMM="no";
 300         HW_OPENBENCH_LOGIC_SNIFFER="no"; HW_SERIAL_DMM="no";
 301         HW_TELEINFO="no"; HW_TONDAJ_SL_814="no";
 302 else
 303         # Define HAVE_LIBSERIALPORT in config.h if we found libserialport.
 304         AC_DEFINE_UNQUOTED(HAVE_LIBSERIALPORT, [1],
 305                 [Specifies whether we have libserialport.])
 306 fi
 307
 308 # Serial port helper code is only compiled in if libserialport was found.
 309 AM_CONDITIONAL(NEED_SERIAL, test "x$have_libserialport" != xno)
 310
 311 # The VISA SCPI backend is only compiled in if librevisa was found.
 312 PKG_CHECK_MODULES([librevisa], [librevisa >= 0.0.20130412],
 313         [have_librevisa="yes"; LIB_CFLAGS="$LIB_CFLAGS $librevisa_CFLAGS";
 314         LIBS="$LIBS $librevisa_LIBS";
 315         SR_PKGLIBS="$SR_PKGLIBS librevisa"],
 316         [have_librevisa="no"])
 317 AM_CONDITIONAL(NEED_VISA, test "x$have_librevisa" != xno)
 318 if test "x$have_librevisa" != "xno"; then
 319         # Define HAVE_LIBREVISA in config.h if we found librevisa.
 320         AC_DEFINE_UNQUOTED(HAVE_LIBREVISA, [1],
 321                 [Specifies whether we have librevisa.])
 322         librevisa_ver=`$PKG_CONFIG --modversion librevisa`
 323         AC_DEFINE_UNQUOTED(HAVE_LIBREVISA_VER, ["$librevisa_ver"], [.])
 324 fi
 325
 326 # The GPIB SCPI backend is only compiled in if libgpib is found.
 327 PKG_CHECK_MODULES([libgpib], [libgpib],
 328         [have_libgpib="yes"; LIB_CFLAGS="$LIB_CFLAGS $libgpib_CFLAGS";
 329         LIBS="$LIBS $libgpib_LIBS";
 330         SR_PKGLIBS="$SR_PKGLIBS libgpib"],
 331         [have_libgpib="no"])
 332 AM_CONDITIONAL(NEED_GPIB, test "x$have_libgpib" != xno)
 333 if test "x$have_libgpib" != "xno"; then
 334         # Define HAVE_LIBGPIB in config.h if we found libgpib.
 335         AC_DEFINE_UNQUOTED(HAVE_LIBGPIB, [1],
 336                 [Specifies whether we have libgpib.])
 337         libgpib_ver=`$PKG_CONFIG --modversion libgpib`
 338         AC_DEFINE_UNQUOTED(HAVE_LIBGPIB_VER, ["$libgpib_ver"], [.])
 339 fi
 340
 341 # libusb-1.0 is only needed for some hardware drivers. Disable the respective
 342 # drivers if it is not found.
 343 if test "x$enable_libusb" != "xno"; then
 344         case "$host" in
 345         *freebsd*)
 346                 # FreeBSD comes with an "integrated" libusb-1.0-style USB API.
 347                 # This means libusb-1.0 is always available, no need to check for it,
 348                 # and no need to (potentially) disable any drivers if it's not found.
 349                 have_libusb1_0="yes"
 350                 ;;
 351         *)
 352                 PKG_CHECK_MODULES([libusb], [libusb-1.0 >= 1.0.16],
 353                         [have_libusb1_0="yes"; LIB_CFLAGS="$LIB_CFLAGS $libusb_CFLAGS";
 354                         LIBS="$LIBS $libusb_LIBS";
 355                         SR_PKGLIBS="$SR_PKGLIBS libusb-1.0"],
 356                         [have_libusb1_0="no"])
 357                 if test "x$enable_libusb$have_libusb1_0" = "xyesno"; then
 358                         AC_MSG_ERROR([libusb support requested, but it was not found.])
 359                 fi
 360                 ;;
 361         esac
 362 else
 363         have_libusb1_0="no"
 364 fi
 365 if test "x$have_libusb1_0" = "xno"; then
 366         HW_BRYMEN_BM86X="no"; HW_FX2LAFW="no";
 367         HW_HANTEK_DSO="no"; HW_IKALOGIC_SCANALOGIC2="no";
 368         HW_KECHENG_KC_330B="no"; HW_LASCAR_EL_USB="no";
 369         HW_SYSCLK_LWLA="no"; HW_TESTO="no"; HW_UNI_T_DMM="no";
 370         HW_UNI_T_UT32X="no"; HW_VICTOR_DMM="no";
 371         HW_ZEROPLUS_LOGIC_CUBE="no"; HW_SALEAE_LOGIC16="no";
 372 else
 373         # Define HAVE_LIBUSB_1_0 in config.h if we found libusb-1.0.
 374         AC_DEFINE_UNQUOTED(HAVE_LIBUSB_1_0, [1],
 375                 [Specifies whether we have libusb-1.0.])
 376 fi
 377
 378 # USB + FX2 firmware helper code is only compiled in if libusb-1.0 was found.
 379 AM_CONDITIONAL(NEED_USB, test "x$have_libusb1_0" != xno)
 380
 381 # libftdi is only needed for some hardware drivers. Disable them if not found.
 382 if test "x$enable_libftdi" != "xno"; then
 383         PKG_CHECK_MODULES([libftdi], [libftdi >= 0.16],
 384                 [have_libftdi="yes"; LIB_CFLAGS="$LIB_CFLAGS $libftdi_CFLAGS";
 385                 LIBS="$LIBS $libftdi_LIBS"; SR_PKGLIBS="$SR_PKGLIBS libftdi";
 386                 libftdi_ver=`$PKG_CONFIG --modversion libftdi`],
 387                 [PKG_CHECK_MODULES([libftdi1], [libftdi1 >= 1.0],
 388                         [LIB_CFLAGS="$LIB_CFLAGS $libftdi1_CFLAGS";
 389                         LIBS="$LIBS $libftdi1_LIBS";
 390                         SR_PKGLIBS="$SR_PKGLIBS libftdi1";
 391                         libftdi_ver=`$PKG_CONFIG --modversion libftdi1`],
 392                         [have_libftdi="no"])])
 393         if test "x$enable_libftdi$have_libftdi" = "xyesno"; then
 394                 AC_MSG_ERROR([libftdi support requested, but it was not found.])
 395         fi
 396 else
 397         have_libftdi="no"
 398 fi
 399 if test "x$have_libftdi" = "xno"; then
 400         HW_ASIX_SIGMA="no"; HW_CHRONOVU_LA="no"; HW_IKALOGIC_SCANAPLUS="no";
 401         HW_PIPISTRELLO_OLS="no";
 402 else
 403         # Define HAVE_LIBFTDI in config.h if we found libftdi.
 404         AC_DEFINE_UNQUOTED(HAVE_LIBFTDI, [1],
 405                 [Specifies whether we have libftdi.])
 406         AC_DEFINE_UNQUOTED(HAVE_LIBFTDI_VER, ["$libftdi_ver"], [.])
 407 fi
 408
 409 # glibmm-2.4 is needed for the C++ bindings.
 410 PKG_CHECK_MODULES([glibmm], [glibmm-2.4 >= 2.32.0],
 411         [CXXFLAGS="$CXXFLAGS $glibmm_CFLAGS";
 412         CXXLIBS="$CXXLIBS $glibmm_LIBS"],
 413         [BINDINGS_CXX="no"; cxx_msg="glibmm required"])
 414
 415 # C++ bindings want stoi and stod.
 416 if test "x$BINDINGS_CXX" = "xyes"; then
 417         AC_LANG_PUSH([C++])
 418         AC_MSG_CHECKING([for stoi and stod])
 419         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <string>],
 420                 [{ return std::stoi("1") + std::stod("1.0"); }])],
 421                 [AC_MSG_RESULT([yes]);
 422                 AC_DEFINE_UNQUOTED(HAVE_STOI_STOD, [1],
 423                 [Specifies whether we have the stoi and stod functions.])],
 424                 [AC_MSG_RESULT([no])])
 425         AC_LANG_POP([C++])
 426 fi
 427
 428 # PyGObject is needed for the Python bindings.
 429 PKG_CHECK_MODULES([pygobject], [pygobject-3.0 >= 3.0.0],
 430         [CXXFLAGS="$CXXFLAGS $pygobject_CFLAGS";
 431         CXXLIBS="$CXXLIBS $pygobject_LIBS";
 432         PKG_CHECK_MODULES([pygobject_3_7_91], [pygobject-3.0 >= 3.7.91],
 433                 [pyg_flags_signed=0], [pyg_flags_signed=1]);
 434         AC_DEFINE_UNQUOTED(PYGOBJECT_FLAGS_SIGNED, [$pyg_flags_signed],
 435                 [Whether last argument to pyg_flags_get_value() is signed.])],
 436         [BINDINGS_PYTHON="no"; python_msg="Python pygobject module required"])
 437
 438 # The Check unit testing framework is optional. Disable if not found.
 439 PKG_CHECK_MODULES([check], [check >= 0.9.4],
 440         [have_check="yes"], [have_check="no"])
 441 AM_CONDITIONAL(HAVE_CHECK, test x"$have_check" = "xyes")
 442
 443 # The BeagleLogic driver needs sys/mman.h and sys/ioctl.h. Don't try to
 444 # build it if these headers aren't available.
 445 AC_CHECK_HEADERS([sys/mman.h sys/ioctl.h], [], [HW_BEAGLELOGIC="no"])
 446
 447 # The BayLibre ACME driver needs sys/timerfd.h. Don't try to build it if
 448 # this header isn't available.
 449 AC_CHECK_HEADERS([sys/timerfd.h], [], [HW_BAYLIBRE_ACME="no"])
 450
 451 # The ACME driver can only be built for Linux.
 452 case "$host" in
 453         *linux*) ;;
 454         *) HW_BAYLIBRE_ACME="no" ;;
 455 esac
 456
 457 AC_SUBST(SR_PKGLIBS)
 458
 459 CFLAGS="$CFLAGS -Iinclude/libsigrok -I${srcdir}/include/libsigrok $LIB_CFLAGS"
 460 CXXFLAGS="$CXXFLAGS -Iinclude/libsigrok -I${srcdir}/include -Ibindings/cxx -Ibindings/cxx/include/libsigrokcxx -I${srcdir}/bindings/cxx/include $LIB_CFLAGS"
 461
 462 # Find Java compiler and JNI includes for Java bindings.
 463 AC_CHECK_PROG([HAVE_JAVAC], [javac], [yes], [no])
 464 if test "x$HAVE_JAVAC" = "xyes" && test "x$BINDINGS_JAVA" = "xyes"; then
 465         AX_PROG_JAVAC
 466         if test "x$JNI_INCLUDE_DIRS" = "xauto"; then
 467                 if test "x$cross_compiling" = "xyes"; then
 468                         JNI_INCLUDE_DIRS=
 469                 else
 470                         AX_JNI_INCLUDE_DIR
 471                 fi
 472         fi
 473         for JNI_INCLUDE_DIR in $JNI_INCLUDE_DIRS; do
 474                 CXXFLAGS="$CXXFLAGS -I$JNI_INCLUDE_DIR"
 475         done
 476         AC_LANG_PUSH([C++])
 477         AC_CHECK_HEADERS([jni.h], [], [BINDINGS_JAVA="no"; java_msg="Java JNI headers required"])
 478         AC_LANG_POP([C++])
 479 else
 480         BINDINGS_JAVA="no"; java_msg="Java compiler required"
 481 fi
 482
 483 # Python and Java bindings depend on C++ bindings.
 484 if test "x$BINDINGS_CXX" != "xyes"; then
 485         BINDINGS_PYTHON="no"; python_msg="C++ bindings required"
 486         BINDINGS_JAVA="no"; java_msg="C++ bindings required"
 487 fi
 488
 489 # Now set AM_CONDITIONALs and AC_DEFINEs for the enabled/disabled drivers.
 490
 491 AC_DEFUN([DRIVER2], [
 492         AM_CONDITIONAL($1, test "x$2" = "xyes")
 493         if test "x$2" = "xyes"; then AC_DEFINE($3, 1, [.]) fi
 494 ])
 495
 496 DRIVER2([HW_AGILENT_DMM], [$HW_AGILENT_DMM], [HAVE_HW_AGILENT_DMM])
 497 DRIVER2([HW_APPA_55II], [$HW_APPA_55II], [HAVE_HW_APPA_55II])
 498 DRIVER2([HW_ASIX_SIGMA], [$HW_ASIX_SIGMA], [HAVE_HW_ASIX_SIGMA])
 499 DRIVER2([HW_ATTEN_PPS3XXX], [$HW_ATTEN_PPS3XXX], [HAVE_HW_ATTEN_PPS3XXX])
 500 DRIVER2([HW_BAYLIBRE_ACME], [$HW_BAYLIBRE_ACME], [HAVE_HW_BAYLIBRE_ACME])
 501 DRIVER2([HW_BEAGLELOGIC], [$HW_BEAGLELOGIC], [HAVE_HW_BEAGLELOGIC])
 502 DRIVER2([HW_BRYMEN_BM86X], [$HW_BRYMEN_BM86X], [HAVE_HW_BRYMEN_BM86X])
 503 DRIVER2([HW_BRYMEN_DMM], [$HW_BRYMEN_DMM], [HAVE_HW_BRYMEN_DMM])
 504 DRIVER2([HW_CEM_DT_885X], [$HW_CEM_DT_885X], [HAVE_HW_CEM_DT_885X])
 505 DRIVER2([HW_CENTER_3XX], [$HW_CENTER_3XX], [HAVE_HW_CENTER_3XX])
 506 DRIVER2([HW_CHRONOVU_LA], [$HW_CHRONOVU_LA], [HAVE_HW_CHRONOVU_LA])
 507 DRIVER2([HW_COLEAD_SLM], [$HW_COLEAD_SLM], [HAVE_HW_COLEAD_SLM])
 508 DRIVER2([HW_CONRAD_DIGI_35_CPU], [$HW_CONRAD_DIGI_35_CPU], [HAVE_HW_CONRAD_DIGI_35_CPU])
 509 DRIVER2([HW_DEMO], [$HW_DEMO], [HAVE_HW_DEMO])
 510 DRIVER2([HW_DEREE_DE5000], [$HW_DEREE_DE5000], [HAVE_HW_DEREE_DE5000])
 511 DRIVER2([HW_FLUKE_DMM], [$HW_FLUKE_DMM], [HAVE_HW_FLUKE_DMM])
 512 DRIVER2([HW_FX2LAFW], [$HW_FX2LAFW], [HAVE_HW_FX2LAFW])
 513 DRIVER2([HW_GMC_MH_1X_2X], [$HW_GMC_MH_1X_2X], [HAVE_HW_GMC_MH_1X_2X])
 514 DRIVER2([HW_HAMEG_HMO], [$HW_HAMEG_HMO], [HAVE_HW_HAMEG_HMO])
 515 DRIVER2([HW_HANTEK_DSO], [$HW_HANTEK_DSO], [HAVE_HW_HANTEK_DSO])
 516 DRIVER2([HW_IKALOGIC_SCANALOGIC2], [$HW_IKALOGIC_SCANALOGIC2], [HAVE_HW_IKALOGIC_SCANALOGIC2])
 517 DRIVER2([HW_IKALOGIC_SCANAPLUS], [$HW_IKALOGIC_SCANAPLUS], [HAVE_HW_IKALOGIC_SCANAPLUS])
 518 DRIVER2([HW_KECHENG_KC_330B], [$HW_KECHENG_KC_330B], [HAVE_HW_KECHENG_KC_330B])
 519 DRIVER2([HW_LASCAR_EL_USB], [$HW_LASCAR_EL_USB], [HAVE_HW_LASCAR_EL_USB])
 520 DRIVER2([HW_MANSON_HCS_3XXX], [$HW_MANSON_HCS_3XXX], [HAVE_HW_MANSON_HCS_3XXX])
 521 DRIVER2([HW_MAYNUO_M97], [$HW_MAYNUO_M97], [HAVE_HW_MAYNUO_M97])
 522 DRIVER2([HW_MIC_985XX], [$HW_MIC_985XX], [HAVE_HW_MIC_985XX])
 523 DRIVER2([HW_MOTECH_LPS_30X], [$HW_MOTECH_LPS_30X], [HAVE_HW_MOTECH_LPS_30X])
 524 DRIVER2([HW_NORMA_DMM], [$HW_NORMA_DMM], [HAVE_HW_NORMA_DMM])
 525 DRIVER2([HW_OPENBENCH_LOGIC_SNIFFER], [$HW_OPENBENCH_LOGIC_SNIFFER], [HAVE_HW_OPENBENCH_LOGIC_SNIFFER])
 526 DRIVER2([HW_PIPISTRELLO_OLS], [$HW_PIPISTRELLO_OLS], [HAVE_HW_PIPISTRELLO_OLS])
 527 DRIVER2([HW_RIGOL_DS], [$HW_RIGOL_DS], [HAVE_HW_RIGOL_DS])
 528 DRIVER2([HW_SALEAE_LOGIC16], [$HW_SALEAE_LOGIC16], [HAVE_HW_SALEAE_LOGIC16])
 529 DRIVER2([HW_SCPI_PPS], [$HW_SCPI_PPS], [HAVE_HW_SCPI_PPS])
 530 DRIVER2([HW_SERIAL_DMM], [$HW_SERIAL_DMM], [HAVE_HW_SERIAL_DMM])
 531 DRIVER2([HW_SYSCLK_LWLA], [$HW_SYSCLK_LWLA], [HAVE_HW_SYSCLK_LWLA])
 532 DRIVER2([HW_TELEINFO], [$HW_TELEINFO], [HAVE_HW_TELEINFO])
 533 DRIVER2([HW_TESTO], [$HW_TESTO], [HAVE_HW_TESTO])
 534 DRIVER2([HW_TONDAJ_SL_814], [$HW_TONDAJ_SL_814], [HAVE_HW_TONDAJ_SL_814])
 535 DRIVER2([HW_UNI_T_DMM], [$HW_UNI_T_DMM], [HAVE_HW_UNI_T_DMM])
 536 DRIVER2([HW_UNI_T_UT32X], [$HW_UNI_T_UT32X], [HAVE_HW_UNI_T_UT32X])
 537 DRIVER2([HW_VICTOR_DMM], [$HW_VICTOR_DMM], [HAVE_HW_VICTOR_DMM])
 538 DRIVER2([HW_YOKOGAWA_DLM], [$HW_YOKOGAWA_DLM], [HAVE_HW_YOKOGAWA_DLM])
 539 DRIVER2([HW_ZEROPLUS_LOGIC_CUBE], [$HW_ZEROPLUS_LOGIC_CUBE], [HAVE_HW_ZEROPLUS_LOGIC_CUBE])
 540
 541 AM_CONDITIONAL(BINDINGS_CXX, test x$BINDINGS_CXX = xyes)
 542
 543 AM_CONDITIONAL(BINDINGS_PYTHON, test x$BINDINGS_PYTHON = xyes)
 544
 545 AM_CONDITIONAL(BINDINGS_JAVA, test x$BINDINGS_JAVA = xyes)
 546
 547 # Checks for header files.
 548 # These are already implicitly checked: inttypes.h stdint.h stdlib.h string.h
 549 # unistd.h memory.h strings.h dlfcn.h sys/types.h sys/stat.h.
 550
 551 # Checks for typedefs, structures, and compiler characteristics.
 552 AC_C_BIGENDIAN
 553
 554 AC_SUBST(FIRMWARE_DIR, "$datadir/sigrok-firmware")
 555 AC_SUBST(MAKEFLAGS, '--no-print-directory')
 556 AC_SUBST(AM_LIBTOOLFLAGS, '--silent')
 557
 558 SR_PACKAGE_VERSION_MAJOR=sr_package_version_major
 559 SR_PACKAGE_VERSION_MINOR=sr_package_version_minor
 560 SR_PACKAGE_VERSION_MICRO=sr_package_version_micro
 561 SR_PACKAGE_VERSION=sr_package_version
 562
 563 AC_SUBST(SR_PACKAGE_VERSION_MAJOR)
 564 AC_SUBST(SR_PACKAGE_VERSION_MINOR)
 565 AC_SUBST(SR_PACKAGE_VERSION_MICRO)
 566 AC_SUBST(SR_PACKAGE_VERSION)
 567
 568 AC_CONFIG_FILES([Makefile include/libsigrok/version.h libsigrok.pc
 569         bindings/cxx/libsigrokcxx.pc])
 570
 571 AC_OUTPUT
 572
 573 echo
 574 echo "libsigrok configuration summary:"
 575 echo
 576 echo "  - Package version (major.minor.micro):    $SR_PACKAGE_VERSION"
 577 echo "  - Library version (current:revision:age): $SR_LIB_VERSION"
 578 echo "  - Prefix: $prefix"
 579 echo "  - Building on: $build"
 580 echo "  - Building for: $host"
 581 echo
 582 echo "Detected libraries:"
 583 echo
 584
 585 # Note: This only works for libs with pkg-config integration.
 586 for lib in "glib-2.0 >= 2.32.0" "libzip >= 0.10" "libserialport >= 0.1.1" \
 587         "librevisa >= 0.0.20130412" "libusb-1.0 >= 1.0.16" "libftdi >= 0.16" \
 588         "libftdi1 >= 1.0" "libgpib" "glibmm-2.4 >= 2.32.0" \
 589         "pygobject-3.0 >= 3.0.0" "check >= 0.9.4"
 590 do
 591         optional="OPTIONAL"
 592         if test "x$lib" = "xglib-2.0 >= 2.32.0"; then optional="REQUIRED"; fi
 593         if test "x$lib" = "xlibzip >= 0.10"; then optional="REQUIRED"; fi
 594         if `$PKG_CONFIG --exists $lib`; then
 595                 ver=`$PKG_CONFIG --modversion $lib`
 596                 answer="yes ($ver)"
 597         else
 598                 answer="no"
 599         fi
 600         echo "  - ($optional) $lib: $answer"
 601 done
 602
 603 eval echo -e "@Enabled hardware drivers:@@${driver_summary}" | tr @ \\n
 604
 605 # Prepare final bindings report messages.
 606 final_cxx=""
 607 final_python=""
 608 final_java=""
 609 if test "$enable_bindings" = "no"; then
 610         final_cxx=" (disabled)"
 611         final_python=" (disabled)"
 612         final_java=" (disabled)"
 613 else
 614         if test "$enable_cxx" = "no"; then
 615                 final_cxx=" (disabled)"
 616         elif test "$BINDINGS_CXX" = "no"; then
 617                 final_cxx=" ($cxx_msg)"
 618         fi
 619         if test "$enable_python" = "no"; then
 620                 final_python=" (disabled)"
 621         elif test "$BINDINGS_PYTHON" = "no"; then
 622                 final_python=" ($python_msg)"
 623         fi
 624         if test "$enable_java" = "no"; then
 625                 final_java=" (disabled)"
 626         elif test "$BINDINGS_JAVA" = "no"; then
 627                 final_java=" ($java_msg)"
 628         fi
 629 fi
 630
 631 echo "Enabled SCPI backends:"
 632 echo " - TCP............................. yes"
 633 if test "x$have_rpc" = "x0"; then
 634 echo " - RPC............................. no"
 635 else
 636 echo " - RPC............................. yes"
 637 fi
 638 echo " - serial.......................... $have_libserialport"
 639 echo " - VISA............................ $have_librevisa"
 640 echo " - GPIB............................ $have_libgpib"
 641 echo " - USBTMC.......................... $have_libusb1_0"
 642 echo
 643
 644 echo "Enabled language bindings:"
 645 echo " - C++............................. $BINDINGS_CXX$final_cxx"
 646 echo " - Python.......................... $BINDINGS_PYTHON$final_python"
 647 echo " - Java............................ $BINDINGS_JAVA$final_java"
 648 echo