configure.ac

   1 ##
   2 ## This file is part of the libsigrok project.
   3 ##
   4 ## Copyright (C) 2010-2012 Bert Vermeulen <bert@biot.com>
   5 ## Copyright (C) 2012 Alexandru Gagniuc <mr.nuke.me@gmail.com>
   6 ##
   7 ## This program is free software: you can redistribute it and/or modify
   8 ## it under the terms of the GNU General Public License as published by
   9 ## the Free Software Foundation, either version 3 of the License, or
  10 ## (at your option) any later version.
  11 ##
  12 ## This program is distributed in the hope that it will be useful,
  13 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ## GNU General Public License for more details.
  16 ##
  17 ## You should have received a copy of the GNU General Public License
  18 ## along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19 ##
  20
  21 # We require at least autoconf 2.63 (AC_INIT format changed there).
  22 AC_PREREQ([2.63])
  23
  24 AC_INIT([libsigrok], [0.6.0],
  25         [sigrok-devel@lists.sourceforge.net],
  26         [libsigrok], [http://www.sigrok.org])
  27 AC_CONFIG_MACRO_DIR([m4])
  28 AC_CONFIG_AUX_DIR([autostuff])
  29 AC_CONFIG_HEADERS([config.h include/libsigrok/version.h])
  30
  31 # We require at least automake 1.11 (needed for 'silent rules').
  32 AM_INIT_AUTOMAKE([1.11 -Wall -Werror no-define nostdinc subdir-objects check-news color-tests])
  33 AM_SILENT_RULES([yes])
  34 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  35
  36 AC_CANONICAL_HOST
  37
  38 # Checks for programs.
  39 AC_PROG_CC
  40 AC_PROG_CXX
  41 AC_PROG_INSTALL
  42 AC_PROG_LN_S
  43
  44 # Required for per-target flags or subdir-objects with C sources.
  45 AM_PROG_CC_C_O
  46
  47 # Set the standard the C library headers should conform to.
  48 AH_VERBATIM([_POSIX_C_SOURCE], [/* The targeted POSIX standard. */
  49 #ifndef _POSIX_C_SOURCE
  50 # define _POSIX_C_SOURCE 200112L
  51 #endif])
  52
  53 # Get compiler versions.
  54 SR_PROG_VERSION([$CC], [sr_cc_version])
  55 SR_PROG_VERSION([$CXX], [sr_cxx_version])
  56
  57 # Check for optional make features.
  58 SR_PROG_MAKE_ORDER_ONLY
  59
  60 # Initialize libtool.
  61 LT_INIT
  62
  63 # Set up the libsigrok version defines.
  64 SR_PKG_VERSION_SET([SR_PACKAGE_VERSION], [AC_PACKAGE_VERSION])
  65
  66 # Library version for libsigrok (NOT the same as the package version).
  67 # Carefully read the libtool docs before updating these numbers!
  68 # The algorithm for determining which number to change (and how) is nontrivial!
  69 # http://www.gnu.org/software/libtool/manual/libtool.html#Updating-version-info
  70 # Format: current:revision:age.
  71 SR_LIB_VERSION_SET([SR_LIB_VERSION], [4:0:0])
  72
  73 AM_CONDITIONAL([WIN32], [test -z "${host_os##mingw*}" || test -z "${host_os##cygwin*}"])
  74
  75 #############################
  76 ##  Optional dependencies  ##
  77 #############################
  78
  79 AC_LANG([C])
  80
  81 # Initialize pkg-config.
  82 # We require at least 0.22, as "Requires.private" behaviour changed there.
  83 PKG_PROG_PKG_CONFIG([0.22])
  84
  85 # Keep track of all checked modules so we can list them at the end.
  86 SR_PKG_CHECK_SUMMARY([sr_pkglibs_summary])
  87
  88 # Collect the pkg-config module names of all dependencies in SR_PKGLIBS.
  89 # These are used to derive the compiler flags and for the "Requires.private"
  90 # field in the generated libsigrok.pc file.
  91 SR_VAR_OPT_PKG([SR_PKGLIBS], [sr_deps_avail])
  92 SR_PKGLIBS_TESTS=
  93 SR_PKGLIBS_CXX=
  94 SR_PKGLIBS_PYTHON=
  95 SR_PKGLIBS_RUBY=
  96 SR_EXTRA_LIBS=
  97 SR_EXTRA_CXX_LIBS=
  98
  99 SR_ARG_OPT_PKG([libserialport], [LIBSERIALPORT], ,
 100         [libserialport >= 0.1.1])
 101
 102 SR_ARG_OPT_PKG([libftdi], [LIBFTDI], , [libftdi1 >= 1.0])
 103
 104 # pkg-config file names: MinGW/MacOSX: hidapi; Linux: hidapi-hidraw/-libusb
 105 SR_ARG_OPT_PKG([libhidapi], [LIBHIDAPI], ,
 106         [hidapi >= 0.8.0], [hidapi-hidraw >= 0.8.0], [hidapi-libusb >= 0.8.0])
 107
 108 SR_ARG_OPT_PKG([libbluez], [LIBBLUEZ], , [bluez >= 4.0])
 109
 110 SR_ARG_OPT_PKG([libnettle], [LIBNETTLE], , [nettle])
 111
 112 # FreeBSD comes with an "integrated" libusb-1.0-style USB API.
 113 # This means libusb-1.0 is always available; no need to check for it.
 114 # On Windows, require the latest version we can get our hands on,
 115 # until the new generic event handling has seen an official release.
 116 AS_CASE([$host_os],
 117         [freebsd*], [sr_libusb_req='libusb-1.0' sr_have_libusb=yes],
 118         [mingw*], [sr_libusb_req='libusb-1.0 >= 1.0.20'],
 119         [sr_libusb_req='libusb-1.0 >= 1.0.16'])
 120
 121 SR_ARG_OPT_PKG([libusb], [LIBUSB_1_0], [NEED_USB],
 122         [$sr_libusb_req])
 123
 124 SR_ARG_OPT_PKG([librevisa], [LIBREVISA], [NEED_VISA],
 125         [librevisa >= 0.0.20130412])
 126
 127 SR_ARG_OPT_PKG([libgpib], [LIBGPIB], [NEED_GPIB],
 128         [libgpib])
 129
 130 SR_ARG_OPT_CHECK([libieee1284], [LIBIEEE1284],, [
 131         sr_save_LIBS=$LIBS
 132         LIBS="-lieee1284 $LIBS"
 133         AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <ieee1284.h>]],
 134                                 [[(void) ieee1284_open(0, 0, 0);]])],
 135                 [sr_have_libieee1284=yes], [sr_have_libieee1284=no])
 136         LIBS=$sr_save_LIBS
 137 ])
 138 AS_IF([test "x$sr_have_libieee1284" = xyes],
 139         [SR_PREPEND([SR_EXTRA_LIBS], [-lieee1284])])
 140
 141 SR_ARG_OPT_PKG([libgio], [LIBGIO], , [gio-2.0 >= 2.24.0])
 142
 143 # See if any of the (potentially platform specific) libs are available
 144 # which provide some means of Bluetooth communication.
 145 AS_IF([test "x$sr_have_libbluez" = xyes],
 146         sr_have_bluetooth=yes, sr_have_bluetooth=no)
 147 AS_IF([test "x$sr_have_bluetooth" = xyes],
 148         [AC_DEFINE([HAVE_BLUETOOTH], [1], [Specifies whether Bluetooth communication is supported.])])
 149 AS_IF([test "x$sr_have_bluetooth" = xyes],
 150         [SR_APPEND([sr_deps_avail], [bluetooth_comm])])
 151
 152 AS_IF([test "x$sr_have_libserialport" = xyes -o "x$sr_have_libhidapi" = xyes -o "x$sr_have_bluetooth" = xyes],
 153         sr_have_serial_comm=yes, sr_have_serial_comm=no)
 154 AS_IF([test "x$sr_have_serial_comm" = xyes],
 155         [AC_DEFINE([HAVE_SERIAL_COMM], [1], [Specifies whether serial communication is supported.])])
 156 AS_IF([test "x$sr_have_serial_comm" = xyes],
 157         [SR_APPEND([sr_deps_avail], [serial_comm])])
 158 AM_CONDITIONAL([NEED_SERIAL], [test "x$sr_have_serial_comm" = xyes])
 159
 160 ######################
 161 ##  Feature checks  ##
 162 ######################
 163
 164 # The Check unit testing framework is optional. Disable if not found.
 165 SR_PKG_CHECK([check], [SR_PKGLIBS_TESTS], [check >= 0.9.4])
 166 AM_CONDITIONAL([HAVE_CHECK], [test "x$sr_have_check" = xyes])
 167
 168 # Enable the C99 standard if possible, and enforce the use
 169 # of SR_API to explicitly mark all public API functions.
 170 SR_EXTRA_CFLAGS=
 171 SR_CHECK_COMPILE_FLAGS([SR_EXTRA_CFLAGS], [C99], [-std=c99 -c99 -AC99 -qlanglvl=extc99])
 172 SR_CHECK_COMPILE_FLAGS([SR_EXTRA_CFLAGS], [visibility], [-fvisibility=hidden])
 173
 174 SR_ARG_ENABLE_WARNINGS([SR_WFLAGS], [-Wall], [-Wall -Wextra -Wmissing-prototypes])
 175
 176 # Check host characteristics.
 177 AC_SYS_LARGEFILE
 178 AC_C_BIGENDIAN
 179
 180 AC_CHECK_HEADERS([sys/mman.h], [SR_APPEND([sr_deps_avail], [sys_mman_h])])
 181 AC_CHECK_HEADERS([sys/ioctl.h], [SR_APPEND([sr_deps_avail], [sys_ioctl_h])])
 182 AC_CHECK_HEADERS([sys/timerfd.h], [SR_APPEND([sr_deps_avail], [sys_timerfd_h])])
 183
 184 # We need to link against the Winsock2 library for SCPI over TCP.
 185 AS_CASE([$host_os], [mingw*], [SR_PREPEND([SR_EXTRA_LIBS], [-lws2_32])])
 186
 187 # libm (the standard math library) is always needed.
 188 SR_SEARCH_LIBS([SR_EXTRA_LIBS], [pow], [m])
 189
 190 # RPC is only needed for VXI support.
 191 AC_CACHE_CHECK([for RPC support], [sr_cv_have_rpc],
 192         [AC_LINK_IFELSE([AC_LANG_PROGRAM(
 193                         [[#include <rpc/rpc.h>]m4_newline[CLIENT *rpc_test(void);]],
 194                         [[(void) clnt_create("", 0, 0, "");]])],
 195                 [sr_cv_have_rpc=yes], [sr_cv_have_rpc=no])])
 196 AS_IF([test "x$sr_cv_have_rpc" = xyes],
 197         [AC_DEFINE([HAVE_RPC], [1], [Specifies whether we have RPC support.])])
 198 # VXI support is only compiled if RPC support was found.
 199 AM_CONDITIONAL([NEED_RPC], [test "x$sr_cv_have_rpc" = xyes])
 200
 201 # Check for compiler support of 128 bit integers
 202 AC_CHECK_TYPES([__int128_t, __uint128_t], [], [], [])
 203
 204 ########################
 205 ##  Hardware drivers  ##
 206 ########################
 207
 208 # Keep track of all drivers so we can list them at the end.
 209 SR_VAR_SUMMARY([sr_driver_summary])
 210
 211 # Check whether the sr_deps_avail list contains all of the arguments.
 212 # Unavailable dependencies are collected in sr_deps_missing.
 213 sr_check_driver_deps() {
 214         sr_deps_missing=
 215         for sr_dep
 216         do
 217                 AS_CASE([" $sr_deps_avail "], [*" $sr_dep "*],,
 218                         [SR_APPEND([sr_deps_missing], [', '], [$sr_dep])])
 219         done
 220         test -z "$sr_deps_missing" || return 1
 221 }
 222
 223 AC_ARG_ENABLE([all-drivers],
 224         [AS_HELP_STRING([--enable-all-drivers],
 225                         [enable all drivers by default [default=yes]])],
 226         [], [enable_all_drivers=yes])
 227
 228 ## _SR_DRIVER(Device name, driver-name, var-name, [dependencies...])
 229 m4_define([_SR_DRIVER], [
 230         AC_ARG_ENABLE([$2],
 231                 [AS_HELP_STRING([--enable-$2], [enable $1 support])],
 232                 [$3=$enableval], [$3=$enable_all_drivers])
 233
 234         AS_IF([test "x[$]$3" = xyes], [sr_hw_info=yes[]m4_ifval([$4], [
 235                 sr_check_driver_deps $4 \
 236                         || $3=no sr_hw_info="no (missing: $sr_deps_missing)"
 237         ])], [sr_hw_info='no (disabled)'])
 238         sr_driver_summary_append "$2" "$sr_hw_info"
 239
 240         AM_CONDITIONAL([$3], [test "x[$]$3" = xyes])
 241         AM_COND_IF([$3], [AC_DEFINE([HAVE_$3], [1], [Whether to support $1 device.]) AC_DEFINE([HAVE_DRIVERS], [1], [Whether at least one driver is enabled.])])
 242 ])
 243
 244 ## SR_DRIVER(Device name, driver-name, [dependencies...])
 245 m4_define([SR_DRIVER],
 246         [_SR_DRIVER([$1], [$2], m4_expand([AS_TR_CPP([HW_$2])]), [$3])])
 247
 248 SR_DRIVER([Agilent DMM], [agilent-dmm], [serial_comm])
 249 SR_DRIVER([Appa 55II], [appa-55ii], [serial_comm])
 250 SR_DRIVER([Arachnid Labs Re:load Pro], [arachnid-labs-re-load-pro], [serial_comm])
 251 SR_DRIVER([ASIX SIGMA/SIGMA2], [asix-sigma], [libftdi])
 252 SR_DRIVER([Atten PPS3xxx], [atten-pps3xxx], [serial_comm])
 253 SR_DRIVER([BayLibre ACME], [baylibre-acme], [sys_timerfd_h])
 254 SR_DRIVER([BeagleLogic], [beaglelogic], [sys_mman_h sys_ioctl_h])
 255 SR_DRIVER([Brymen DMM], [brymen-dmm], [serial_comm])
 256 SR_DRIVER([CEM DT-885x], [cem-dt-885x], [serial_comm])
 257 SR_DRIVER([Center 3xx], [center-3xx], [serial_comm])
 258 SR_DRIVER([ChronoVu LA], [chronovu-la], [libusb libftdi])
 259 SR_DRIVER([Colead SLM], [colead-slm], [serial_comm])
 260 SR_DRIVER([Conrad DIGI 35 CPU], [conrad-digi-35-cpu], [serial_comm])
 261 SR_DRIVER([demo], [demo])
 262 SR_DRIVER([DreamSourceLab DSLogic], [dreamsourcelab-dslogic], [libusb])
 263 SR_DRIVER([Fluke 45], [fluke-45])
 264 SR_DRIVER([Fluke DMM], [fluke-dmm], [serial_comm])
 265 SR_DRIVER([FTDI LA], [ftdi-la], [libusb libftdi])
 266 SR_DRIVER([fx2lafw], [fx2lafw], [libusb])
 267 SR_DRIVER([GMC MH 1x/2x], [gmc-mh-1x-2x], [serial_comm])
 268 SR_DRIVER([GW Instek GDS-800], [gwinstek-gds-800], [serial_comm])
 269 SR_DRIVER([GW Instek GPD], [gwinstek-gpd], [serial_comm])
 270 SR_DRIVER([Hameg HMO], [hameg-hmo], [serial_comm])
 271 SR_DRIVER([Hantek 4032L], [hantek-4032l], [libusb])
 272 SR_DRIVER([Hantek 6xxx], [hantek-6xxx], [libusb])
 273 SR_DRIVER([Hantek DSO], [hantek-dso], [libusb])
 274 SR_DRIVER([HP 3457A], [hp-3457a])
 275 SR_DRIVER([HP 3478A], [hp-3478a], [libgpib])
 276 SR_DRIVER([Hung-Chang DSO-2100], [hung-chang-dso-2100], [libieee1284])
 277 SR_DRIVER([Ikalogic Scanalogic-2], [ikalogic-scanalogic2], [libusb])
 278 SR_DRIVER([Ikalogic Scanaplus], [ikalogic-scanaplus], [libftdi])
 279 SR_DRIVER([IPDBG LA], [ipdbg-la])
 280 SR_DRIVER([ITECH IT8500], [itech-it8500])
 281 SR_DRIVER([Kecheng KC-330B], [kecheng-kc-330b], [libusb])
 282 SR_DRIVER([KERN scale], [kern-scale], [serial_comm])
 283 SR_DRIVER([Kingst LA2016], [kingst-la2016], [libusb])
 284 SR_DRIVER([Korad KAxxxxP], [korad-kaxxxxp], [serial_comm])
 285 SR_DRIVER([Lascar EL-USB], [lascar-el-usb], [libusb])
 286 SR_DRIVER([LeCroy LogicStudio], [lecroy-logicstudio], [libusb])
 287 SR_DRIVER([LeCroy X-Stream], [lecroy-xstream])
 288 SR_DRIVER([Manson HCS-3xxx], [manson-hcs-3xxx], [serial_comm])
 289 SR_DRIVER([Mastech MS6514], [mastech-ms6514], [serial_comm])
 290 SR_DRIVER([maynuo-m97], [maynuo-m97])
 291 SR_DRIVER([MIC 985xx], [mic-985xx], [serial_comm])
 292 SR_DRIVER([Microchip PICkit2], [microchip-pickit2], [libusb])
 293 SR_DRIVER([Mooshimeter DMM], [mooshimeter-dmm], [bluetooth_comm libgio])
 294 SR_DRIVER([Motech LPS 30x], [motech-lps-30x], [serial_comm])
 295 SR_DRIVER([Norma DMM], [norma-dmm], [serial_comm])
 296 SR_DRIVER([OpenBench Logic Sniffer], [openbench-logic-sniffer], [serial_comm])
 297 SR_DRIVER([PCE PCE-322A], [pce-322a], [serial_comm])
 298 SR_DRIVER([Pipistrello-OLS], [pipistrello-ols], [libftdi])
 299 SR_DRIVER([RDTech DPSxxxx/DPHxxxx], [rdtech-dps], [serial_comm])
 300 SR_DRIVER([RDTech UMXX], [rdtech-um], [serial_comm])
 301 SR_DRIVER([RDTech TCXX], [rdtech-tc], [serial_comm libnettle])
 302 SR_DRIVER([Rigol DS], [rigol-ds])
 303 SR_DRIVER([Rigol DG], [rigol-dg])
 304 SR_DRIVER([Rohde&Schwarz SME-0x], [rohde-schwarz-sme-0x], [serial_comm])
 305 SR_DRIVER([Saleae Logic16], [saleae-logic16], [libusb])
 306 SR_DRIVER([Saleae Logic Pro], [saleae-logic-pro], [libusb])
 307 SR_DRIVER([SCPI DMM], [scpi-dmm])
 308 SR_DRIVER([SCPI PPS], [scpi-pps])
 309 SR_DRIVER([serial DMM], [serial-dmm], [serial_comm])
 310 SR_DRIVER([serial LCR], [serial-lcr], [serial_comm])
 311 SR_DRIVER([Siglent SDS], [siglent-sds])
 312 SR_DRIVER([Sysclk LWLA], [sysclk-lwla], [libusb])
 313 SR_DRIVER([Sysclk SLA5032], [sysclk-sla5032], [libusb])
 314 SR_DRIVER([Teleinfo], [teleinfo], [serial_comm])
 315 SR_DRIVER([Testo], [testo], [libusb])
 316 SR_DRIVER([Tondaj SL-814], [tondaj-sl-814], [serial_comm])
 317 SR_DRIVER([UNI-T DMM], [uni-t-dmm], [libusb])
 318 SR_DRIVER([UNI-T UT181A], [uni-t-ut181a], [serial_comm])
 319 SR_DRIVER([UNI-T UT32x], [uni-t-ut32x], [serial_comm])
 320 SR_DRIVER([Yokogawa DL/DLM], [yokogawa-dlm])
 321 SR_DRIVER([ZEROPLUS Logic Cube], [zeroplus-logic-cube], [libusb])
 322 SR_DRIVER([ZKETECH EBD-USB], [zketech-ebd-usb], [serial_comm])
 323
 324 ###############################
 325 ##  Language bindings setup  ##
 326 ###############################
 327
 328 AC_LANG([C++])
 329 SR_ARG_ENABLE_WARNINGS([SR_WXXFLAGS], [-Wall], [-Wall -Wextra])
 330
 331 AC_ARG_ENABLE([bindings],
 332         [AS_HELP_STRING([--enable-bindings], [build language bindings [default=yes]])],
 333         [], [enable_bindings=yes])
 334
 335 AC_ARG_ENABLE([cxx],
 336         [AS_HELP_STRING([--enable-cxx], [build C++ bindings [default=yes]])],
 337         [], [enable_cxx=$enable_bindings])
 338
 339 AC_ARG_ENABLE([python],
 340         [AS_HELP_STRING([--enable-python], [build Python bindings [default=yes]])],
 341         [], [enable_python=$enable_bindings])
 342
 343 AC_ARG_ENABLE([ruby],
 344         [AS_HELP_STRING([--enable-ruby], [build Ruby bindings [default=yes]])],
 345         [], [enable_ruby=$enable_bindings])
 346
 347 AC_ARG_ENABLE([java],
 348         [AS_HELP_STRING([--enable-java], [build Java bindings [default=yes]])],
 349         [], [enable_java=$enable_bindings])
 350
 351 ####################
 352 ##  C++ bindings  ##
 353 ####################
 354
 355 sr_cxx_missing=
 356
 357 # Check if the C++ compiler supports the C++11 standard.
 358 AX_CXX_COMPILE_STDCXX([11], [noext], [optional])
 359 AS_IF([test "x$HAVE_CXX11" != x1],
 360         [SR_APPEND([sr_cxx_missing], [', '], ['C++11'])])
 361
 362 # The C++ bindings need glibmm.
 363 SR_PKG_CHECK([glibmm], [SR_PKGLIBS_CXX], [glibmm-2.4 >= 2.32.0])
 364 AS_IF([test "x$sr_have_glibmm" != xyes],
 365         [SR_APPEND([sr_cxx_missing], [', '], [glibmm])])
 366
 367 # The C++ bindings use Doxygen to parse libsigrok symbols.
 368 AC_CHECK_PROG([HAVE_DOXYGEN], [doxygen], [yes], [no])
 369 AS_IF([test "x$HAVE_DOXYGEN" != xyes],
 370         [SR_APPEND([sr_cxx_missing], [', '], [Doxygen])])
 371
 372 # Link C++ code with gnustl_shared if it exists (Android)
 373 SR_SEARCH_LIBS([SR_EXTRA_CXX_LIBS], [__cxa_throw], [gnustl_shared])
 374
 375 # Python is needed for the C++ bindings.
 376 AM_PATH_PYTHON([2.7],
 377         [HAVE_PYTHON=yes],
 378         [HAVE_PYTHON=no
 379         SR_APPEND([sr_cxx_missing], [', '], [Python])])
 380
 381 AS_IF([test -z "$sr_cxx_missing"],
 382         [BINDINGS_CXX=$enable_cxx], [BINDINGS_CXX=no])
 383 AM_CONDITIONAL([BINDINGS_CXX], [test "x$BINDINGS_CXX" = xyes])
 384
 385 # C++ bindings want stoi and stod.
 386 AM_COND_IF([BINDINGS_CXX], [
 387         AC_CACHE_CHECK([for stoi and stod], [sr_cv_have_stoi_stod],
 388                 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <string>]],
 389                                 [[(void) std::stoi("1"); (void) std::stod("1.0");]])],
 390                         [sr_cv_have_stoi_stod=yes], [sr_cv_have_stoi_stod=no])])
 391         AS_IF([test "x$sr_cv_have_stoi_stod" = xyes],
 392                 [AC_DEFINE([HAVE_STOI_STOD], [1],
 393                         [Specifies whether we have the stoi and stod functions.])])
 394 ])
 395
 396 #######################
 397 ##  Python bindings  ##
 398 #######################
 399
 400 AS_IF([test "x$BINDINGS_CXX" = xyes],
 401         [sr_python_missing=],
 402         [sr_python_missing='C++ bindings'])
 403
 404 # Extract major and minor version number of the Python interpreter.
 405 sr_pymajor=${PYTHON_VERSION%%.*}
 406 sr_pyminor=${PYTHON_VERSION#*.}
 407
 408 # The Python bindings need Python development files. Check for either
 409 # Python 3 or Python 2 headers depending on the interpreter version.
 410 SR_PKG_CHECK([python_dev], [SR_PKGLIBS_PYTHON],
 411         [python = $PYTHON_VERSION],
 412         [python$sr_pymajor = $PYTHON_VERSION],
 413         [python$sr_pymajor$sr_pyminor = $PYTHON_VERSION],
 414         [python-$PYTHON_VERSION = $PYTHON_VERSION])
 415
 416 AS_IF([test "x$sr_have_python_dev" != xyes],
 417         [SR_APPEND([sr_python_missing], [', '], [Headers])])
 418
 419 # PyGObject is needed for the Python bindings.
 420 SR_PKG_CHECK([pygobject], [SR_PKGLIBS_PYTHON], [pygobject-3.0 >= 3.0.0])
 421 AS_IF([test "x$sr_have_pygobject" != xyes],
 422         [SR_APPEND([sr_python_missing], [', '], [PyGObject])])
 423
 424 PKG_CHECK_EXISTS([pygobject-3.0 < 3.7.91],
 425         [AC_DEFINE([PYGOBJECT_FLAGS_SIGNED], [1],
 426                 [Whether last argument to pyg_flags_get_value() is signed.])])
 427
 428 # The Python bindings need the setuptools and numpy Python modules.
 429 # We'll let it go through even if the AX macro wasn't found, as the
 430 # Python modules may still be there.
 431 m4_ifdef([AX_PYTHON_MODULE], [
 432         AX_PYTHON_MODULE([setuptools])
 433         AX_PYTHON_MODULE([numpy])
 434 ], [
 435         HAVE_PYMOD_SETUPTOOLS=yes
 436         HAVE_PYMOD_NUMPY=yes
 437         m4_warn([unsupported],
 438                 [Missing macro AX_PYTHON_MODULE: no check for setuptools and numpy])
 439 ])
 440 AS_IF([test "x$HAVE_PYMOD_SETUPTOOLS" != xyes],
 441         [SR_APPEND([sr_python_missing], [', '], [setuptools])])
 442 AS_IF([test "x$HAVE_PYMOD_NUMPY" != xyes],
 443         [SR_APPEND([sr_python_missing], [', '], [numpy])])
 444
 445 # The Python bindings use SWIG to generate code.
 446 AC_CHECK_PROGS([SWIG], [swig swig4.0 swig3.0 swig2.0])
 447 AS_IF([test "x$SWIG" != x],
 448     AC_MSG_CHECKING([for $SWIG version])
 449     [SWIG_VERSION=`$SWIG -version 2>&1 | sed -n 's/SWIG Version //p'`]
 450     AC_MSG_RESULT([$SWIG_VERSION]))
 451 AS_IF([test "x$SWIG" = x],
 452         [SR_APPEND([sr_python_missing], [', '], [SWIG])])
 453
 454 AS_IF([test -z "$sr_python_missing"],
 455         [BINDINGS_PYTHON=$enable_python], [BINDINGS_PYTHON=no])
 456 AM_CONDITIONAL([BINDINGS_PYTHON], [test "x$BINDINGS_PYTHON" = xyes])
 457
 458 #####################
 459 ##  Ruby bindings  ##
 460 #####################
 461
 462 AS_IF([test "x$BINDINGS_CXX" = xyes],
 463         [sr_ruby_missing=],
 464         [sr_ruby_missing='C++ bindings'])
 465
 466 AC_PATH_PROGS(RUBY, ["${RUBY-ruby}"], [])
 467 AS_IF([test "x$RUBY" != x],
 468         AC_MSG_CHECKING([for Ruby version])
 469     [RUBY_VERSION=`$RUBY -e 'puts RUBY_VERSION'`]
 470     AC_MSG_RESULT([$RUBY_VERSION])
 471     [RUBY_DLEXT=`$RUBY -rrbconfig -e 'puts RbConfig::CONFIG[["DLEXT"]]'`]
 472     AC_SUBST(RUBY_DLEXT))
 473
 474 AS_IF([test "x$RUBY" = x],
 475         [SR_APPEND([sr_ruby_missing], [', '], [Ruby])])
 476
 477 # Extract major and minor version number of the Ruby interpreter.
 478 sr_rbmajor=${RUBY_VERSION%%.*}
 479 sr_rbminor=${RUBY_VERSION#*.}
 480 sr_rbminor=${sr_rbminor%%.*}
 481
 482 # The Ruby bindings need Ruby development files.
 483 SR_PKG_CHECK([ruby_dev], [SR_PKGLIBS_RUBY],
 484         [ruby >= 2.5.0],
 485         [ruby-$sr_rbmajor.$sr_rbminor >= 2.5.0])
 486
 487 AS_IF([test "x$sr_have_ruby_dev" != xyes],
 488         [SR_APPEND([sr_ruby_missing], [', '], [Headers])])
 489
 490 # The Ruby bindings use SWIG >= 3.0.8 to generate code.
 491 AS_IF([test "x$SWIG" = x],
 492         [SR_APPEND([sr_ruby_missing], [', '], [SWIG])],
 493         [AS_VERSION_COMPARE($SWIG_VERSION, "3.0.8",
 494                 [SR_APPEND([sr_ruby_missing], [', '], ['SWIG >= 3.0.8'])])])
 495
 496 AS_IF([test -z "$sr_ruby_missing"],
 497         [BINDINGS_RUBY=$enable_ruby], [BINDINGS_RUBY=no])
 498 AM_CONDITIONAL([BINDINGS_RUBY], [test "x$BINDINGS_RUBY" = xyes])
 499
 500 ####################
 501 ##  Java bindings ##
 502 ####################
 503
 504 AS_IF([test "x$BINDINGS_CXX" = xyes],
 505         [sr_java_missing=],
 506         [sr_java_missing='C++ bindings'])
 507
 508 # The Java bindings use SWIG to generate code.
 509 AS_IF([test "x$SWIG" = x],
 510         [SR_APPEND([sr_java_missing], [', '], [SWIG])])
 511
 512 # Find Java compiler and JNI includes for Java bindings.
 513 AC_CHECK_PROG([HAVE_JAVAC], [javac], [yes], [no])
 514 AS_IF([test "x$HAVE_JAVAC" = xno],
 515         [SR_APPEND([sr_java_missing], [', '], [JavaC])])
 516
 517 AC_ARG_WITH([jni-include-path],
 518         [AS_HELP_STRING([[--with-jni-include-path=DIR-LIST (space-separated)]],
 519                 [specify JNI include directories [default=detect]])],
 520         [JNI_INCLUDE_DIRS=" $withval"], [JNI_INCLUDE_DIRS=])
 521
 522 JNI_CPPFLAGS=
 523 AS_IF([test "x$enable_java$HAVE_JAVAC" = xyesyes], [
 524         AX_PROG_JAVAC
 525         AS_IF([test -z "$JNI_INCLUDE_DIRS" && test "x$cross_compiling" != xyes], [
 526                 ## Work around the totally broken logic in AX_JNI_INCLUDE_DIR:
 527                 ## If we can find jni.h without any special search path, skip
 528                 ## the execution of the broken macro to increase our chances of
 529                 ## success.
 530                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <jni.h>]], [])],,
 531                         [AX_JNI_INCLUDE_DIR])
 532         ])
 533 ])
 534 for sr_dir in $JNI_INCLUDE_DIRS
 535 do
 536         SR_APPEND([JNI_CPPFLAGS], ["-I$sr_dir"])
 537 done
 538 AC_SUBST([JNI_CPPFLAGS])
 539
 540 sr_save_cppflags=$CPPFLAGS
 541 SR_APPEND([CPPFLAGS], [$JNI_CPPFLAGS])
 542 AC_CHECK_HEADER([jni.h],,
 543         [SR_APPEND([sr_java_missing], [', '], ['JNI headers'])])
 544 CPPFLAGS=$sr_save_cppflags
 545
 546 AS_IF([test -z "$sr_java_missing"],
 547         [BINDINGS_JAVA=$enable_java], [BINDINGS_JAVA=no])
 548 AM_CONDITIONAL([BINDINGS_JAVA], [test "x$BINDINGS_JAVA" = xyes])
 549
 550 ##############################
 551 ##  Finalize configuration  ##
 552 ##############################
 553
 554 # Add mandatory dependencies to module list.
 555 SR_APPEND([SR_PKGLIBS], ['libzip >= 0.10'])
 556 AC_SUBST([SR_PKGLIBS])
 557
 558 # Retrieve the compile and link flags for all modules combined.
 559 # Also, bail out at this point if any module dependency is not met.
 560 PKG_CHECK_MODULES([LIBSIGROK], [glib-2.0 >= 2.32.0 $SR_PKGLIBS])
 561 PKG_CHECK_MODULES([TESTS], [$SR_PKGLIBS_TESTS glib-2.0 $SR_PKGLIBS])
 562
 563 # SR_PKGLIBS_CXX may be empty, so only invoke these checks when
 564 # the C++ bindings are enabled.
 565 AM_COND_IF([BINDINGS_CXX], [
 566         PKG_CHECK_MODULES([LIBSIGROKCXX], [$SR_PKGLIBS_CXX])
 567         PKG_CHECK_MODULES([PYSIGROK], [$SR_PKGLIBS_PYTHON $SR_PKGLIBS_CXX])
 568         PKG_CHECK_MODULES([RBSIGROK], [$SR_PKGLIBS_RUBY $SR_PKGLIBS_CXX], [AC_SUBST(RBSIGROK_EXTDIR, "lib/$($PKG_CONFIG --variable=sitearch $SR_PKGLIBS_RUBY)/$($PKG_CONFIG --variable=RUBY_BASE_NAME $SR_PKGLIBS_RUBY)/vendor_ruby/$($PKG_CONFIG --variable=ruby_version $SR_PKGLIBS_RUBY)")])
 569 ])
 570
 571 # Check for specific libusb features, now that we know the CFLAGS.
 572 AC_LANG([C])
 573 sr_save_cflags=$CFLAGS
 574 sr_save_libs=$LIBS
 575 CFLAGS="$LIBSIGROK_CFLAGS $CFLAGS"
 576 LIBS="$LIBSIGROK_LIBS $LIBS"
 577 AC_CHECK_TYPES([libusb_os_handle],
 578         [sr_have_libusb_os_handle=yes], [sr_have_libusb_os_handle=no],
 579         [[#include <libusb.h>]])
 580 AC_CHECK_FUNCS([zip_discard])
 581 LIBS=$sr_save_libs
 582 CFLAGS=$sr_save_cflags
 583
 584 AM_COND_IF([NEED_USB], [AS_CASE([$sr_have_libusb_os_handle:$host_os], [no:mingw*],
 585         [AC_MSG_ERROR([Windows builds require the event-abstraction branch of libusb])])])
 586
 587 sr_glib_version=`$PKG_CONFIG --modversion glib-2.0 2>&AS_MESSAGE_LOG_FD`
 588 sr_libzip_version=`$PKG_CONFIG --modversion libzip 2>&AS_MESSAGE_LOG_FD`
 589
 590 AC_DEFINE_UNQUOTED([CONF_LIBZIP_VERSION], ["$sr_libzip_version"],
 591         [Build-time version of libzip.])
 592 AC_DEFINE_UNQUOTED([CONF_HOST], ["$host"],
 593         [The canonical host libsigrok will run on.])
 594
 595 AC_CONFIG_FILES([Makefile libsigrok.pc bindings/cxx/libsigrokcxx.pc])
 596
 597 AC_OUTPUT
 598
 599 # Prepare bindings report messages.
 600 m4_define([SR_PREPARE_BINDING_REPORT], [
 601         sr_report_$1=
 602         test -z "$sr_$1_missing" || sr_report_$1=" (missing: $sr_$1_missing)"
 603         test "x$enable_$1" = xyes || sr_report_$1=' (disabled)'
 604 ])
 605 m4_map_args([SR_PREPARE_BINDING_REPORT], [cxx], [python], [ruby], [java])
 606
 607 cat >&AS_MESSAGE_FD <<_EOF
 608
 609 libsigrok configuration summary:
 610  - Package version................. $SR_PACKAGE_VERSION
 611  - Library ABI version............. $SR_LIB_VERSION
 612  - Prefix.......................... $prefix
 613  - Building on..................... $build
 614  - Building for.................... $host
 615  - Building shared / static........ $enable_shared / $enable_static
 616
 617 Compile configuration:
 618  - C compiler...................... $CC
 619  - C compiler version.............. $sr_cc_version
 620  - C compiler flags................ $CFLAGS
 621  - Additional C compiler flags..... $SR_EXTRA_CFLAGS
 622  - C compiler warnings............. $SR_WFLAGS
 623  - C++ compiler.................... $CXX
 624  - C++ compiler version............ $sr_cxx_version
 625  - C++ compiler flags.............. $CXXFLAGS
 626  - C++ compiler warnings........... $SR_WXXFLAGS
 627  - Linker flags.................... $LDFLAGS
 628
 629 Detected libraries (required):
 630  - glib-2.0 >= 2.32.0.............. $sr_glib_version
 631  - libzip >= 0.10.................. $sr_libzip_version
 632
 633 Detected libraries (optional):
 634 $sr_pkglibs_summary
 635 Enabled hardware drivers:
 636 $sr_driver_summary
 637 Enabled serial communication transports:
 638   - serial comm ................... $sr_have_serial_comm
 639   - libserialport ................. $sr_have_libserialport
 640   - hidapi ........................ $sr_have_libhidapi
 641   - bluetooth ..................... $sr_have_bluetooth
 642   - bluez ......................... $sr_have_libbluez
 643
 644 Enabled SCPI backends:
 645  - TCP............................. yes
 646  - RPC............................. $sr_cv_have_rpc
 647  - serial.......................... $sr_have_serial_comm
 648  - VISA............................ $sr_have_librevisa
 649  - GPIB............................ $sr_have_libgpib
 650  - USBTMC.......................... $sr_have_libusb
 651
 652 Enabled language bindings:
 653  - C++............................. $BINDINGS_CXX$sr_report_cxx
 654  - Python.......................... $BINDINGS_PYTHON$sr_report_python
 655  - Ruby............................ $BINDINGS_RUBY$sr_report_ruby
 656  - Java............................ $BINDINGS_JAVA$sr_report_java
 657
 658 _EOF
 659
 660 # Emit a warning if the C++ bindings are not being built.
 661 AM_COND_IF([BINDINGS_CXX], [], [
 662 cat >&AS_MESSAGE_FD <<_EOF
 663 ===============================================================================
 664 WARNING WARNING WARNING WARNING WARNING WARNING WARNING WARNING WARNING WARNING
 665 ===============================================================================
 666 ===                                                                         ===
 667 ===         The libsigrok C++ bindings are not being built since you        ===
 668 ===             are missing one or more dependencies (see above)!           ===
 669 ===                                                                         ===
 670 ===      This means you won't be able to compile frontends that require     ===
 671 ===  the C++ bindings (such as PulseView)! You also won't be able to build  ===
 672 ===     other bindings and frontends using those (such as sigrok-meter)!    ===
 673 ===                                                                         ===
 674 ===============================================================================
 675 WARNING WARNING WARNING WARNING WARNING WARNING WARNING WARNING WARNING WARNING
 676 ===============================================================================
 677
 678 _EOF
 679 ])