configure.ac

   1 ##
   2 ## This file is part of the libsigrok project.
   3 ##
   4 ## Copyright (C) 2010-2012 Bert Vermeulen <bert@biot.com>
   5 ## Copyright (C) 2012 Alexandru Gagniuc <mr.nuke.me@gmail.com>
   6 ##
   7 ## This program is free software: you can redistribute it and/or modify
   8 ## it under the terms of the GNU General Public License as published by
   9 ## the Free Software Foundation, either version 3 of the License, or
  10 ## (at your option) any later version.
  11 ##
  12 ## This program is distributed in the hope that it will be useful,
  13 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ## GNU General Public License for more details.
  16 ##
  17 ## You should have received a copy of the GNU General Public License
  18 ## along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19 ##
  20
  21 # We require at least autoconf 2.63 (AC_INIT format changed there).
  22 AC_PREREQ([2.63])
  23
  24 AC_INIT([libsigrok], [0.6.0],
  25         [sigrok-devel@lists.sourceforge.net],
  26         [libsigrok], [http://www.sigrok.org])
  27 AC_CONFIG_MACRO_DIR([m4])
  28 AC_CONFIG_AUX_DIR([autostuff])
  29 AC_CONFIG_HEADERS([config.h include/libsigrok/version.h])
  30
  31 # We require at least automake 1.11 (needed for 'silent rules').
  32 AM_INIT_AUTOMAKE([1.11 -Wall -Werror no-define nostdinc subdir-objects check-news color-tests])
  33 AM_SILENT_RULES([yes])
  34 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  35
  36 AC_CANONICAL_HOST
  37
  38 # Checks for programs.
  39 AC_PROG_CC
  40 AC_PROG_CXX
  41 AC_PROG_INSTALL
  42 AC_PROG_LN_S
  43
  44 # Required for per-target flags or subdir-objects with C sources.
  45 AM_PROG_CC_C_O
  46
  47 # Set the standard the C library headers should conform to.
  48 AH_VERBATIM([_POSIX_C_SOURCE], [/* The targeted POSIX standard. */
  49 #ifndef _POSIX_C_SOURCE
  50 # define _POSIX_C_SOURCE 200112L
  51 #endif])
  52
  53 # Get compiler versions.
  54 SR_PROG_VERSION([$CC], [sr_cc_version])
  55 SR_PROG_VERSION([$CXX], [sr_cxx_version])
  56
  57 # Check for optional make features.
  58 SR_PROG_MAKE_ORDER_ONLY
  59
  60 # Initialize libtool.
  61 LT_INIT
  62
  63 # Set up the libsigrok version defines.
  64 SR_PKG_VERSION_SET([SR_PACKAGE_VERSION], [AC_PACKAGE_VERSION])
  65
  66 # Library version for libsigrok (NOT the same as the package version).
  67 # Carefully read the libtool docs before updating these numbers!
  68 # The algorithm for determining which number to change (and how) is nontrivial!
  69 # http://www.gnu.org/software/libtool/manual/libtool.html#Updating-version-info
  70 # Format: current:revision:age.
  71 SR_LIB_VERSION_SET([SR_LIB_VERSION], [4:0:0])
  72
  73 AM_CONDITIONAL([WIN32], [test -z "${host_os##mingw*}" || test -z "${host_os##cygwin*}"])
  74
  75 #############################
  76 ##  Optional dependencies  ##
  77 #############################
  78
  79 AC_LANG([C])
  80
  81 # Initialize pkg-config.
  82 # We require at least 0.22, as "Requires.private" behaviour changed there.
  83 PKG_PROG_PKG_CONFIG([0.22])
  84
  85 # Keep track of all checked modules so we can list them at the end.
  86 SR_PKG_CHECK_SUMMARY([sr_pkglibs_summary])
  87
  88 # Collect the pkg-config module names of all dependencies in SR_PKGLIBS.
  89 # These are used to derive the compiler flags and for the "Requires.private"
  90 # field in the generated libsigrok.pc file.
  91 SR_VAR_OPT_PKG([SR_PKGLIBS], [sr_deps_avail])
  92 SR_PKGLIBS_TESTS=
  93 SR_PKGLIBS_CXX=
  94 SR_PKGLIBS_PYTHON=
  95 SR_PKGLIBS_RUBY=
  96 SR_EXTRA_LIBS=
  97 SR_EXTRA_CXX_LIBS=
  98
  99 SR_ARG_OPT_PKG([libserialport], [LIBSERIALPORT], ,
 100         [libserialport >= 0.1.1])
 101
 102 SR_ARG_OPT_PKG([libftdi], [LIBFTDI], , [libftdi1 >= 1.0])
 103
 104 # pkg-config file names: MinGW/MacOSX: hidapi; Linux: hidapi-hidraw/-libusb
 105 SR_ARG_OPT_PKG([libhidapi], [LIBHIDAPI], ,
 106         [hidapi >= 0.8.0], [hidapi-hidraw >= 0.8.0], [hidapi-libusb >= 0.8.0])
 107
 108 SR_ARG_OPT_PKG([libbluez], [LIBBLUEZ], , [bluez >= 4.0])
 109
 110 SR_ARG_OPT_PKG([libnettle], [LIBNETTLE], , [nettle])
 111
 112 # FreeBSD comes with an "integrated" libusb-1.0-style USB API.
 113 # This means libusb-1.0 is always available; no need to check for it.
 114 # On Windows, require the latest version we can get our hands on,
 115 # until the new generic event handling has seen an official release.
 116 AS_CASE([$host_os],
 117         [freebsd*], [sr_libusb_req='libusb-1.0' sr_have_libusb=yes],
 118         [mingw*], [sr_libusb_req='libusb-1.0 >= 1.0.20'],
 119         [sr_libusb_req='libusb-1.0 >= 1.0.16'])
 120
 121 SR_ARG_OPT_PKG([libusb], [LIBUSB_1_0], [NEED_USB],
 122         [$sr_libusb_req])
 123
 124 SR_ARG_OPT_PKG([librevisa], [LIBREVISA], [NEED_VISA],
 125         [librevisa >= 0.0.20130412])
 126
 127 SR_ARG_OPT_PKG([libgpib], [LIBGPIB], [NEED_GPIB],
 128         [libgpib])
 129
 130 SR_ARG_OPT_CHECK([libieee1284], [LIBIEEE1284],, [
 131         sr_save_LIBS=$LIBS
 132         LIBS="-lieee1284 $LIBS"
 133         AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <ieee1284.h>]],
 134                                 [[(void) ieee1284_open(0, 0, 0);]])],
 135                 [sr_have_libieee1284=yes], [sr_have_libieee1284=no])
 136         LIBS=$sr_save_LIBS
 137 ])
 138 AS_IF([test "x$sr_have_libieee1284" = xyes],
 139         [SR_PREPEND([SR_EXTRA_LIBS], [-lieee1284])])
 140
 141 SR_ARG_OPT_PKG([libgio], [LIBGIO], , [gio-2.0 >= 2.24.0])
 142
 143 # See if any of the (potentially platform specific) libs are available
 144 # which provide some means of Bluetooth communication.
 145 AS_IF([test "x$sr_have_libbluez" = xyes],
 146         sr_have_bluetooth=yes, sr_have_bluetooth=no)
 147 AS_IF([test "x$sr_have_bluetooth" = xyes],
 148         [AC_DEFINE([HAVE_BLUETOOTH], [1], [Specifies whether Bluetooth communication is supported.])])
 149 AS_IF([test "x$sr_have_bluetooth" = xyes],
 150         [SR_APPEND([sr_deps_avail], [bluetooth_comm])])
 151
 152 AS_IF([test "x$sr_have_libserialport" = xyes -o "x$sr_have_libhidapi" = xyes -o "x$sr_have_bluetooth" = xyes],
 153         sr_have_serial_comm=yes, sr_have_serial_comm=no)
 154 AS_IF([test "x$sr_have_serial_comm" = xyes],
 155         [AC_DEFINE([HAVE_SERIAL_COMM], [1], [Specifies whether serial communication is supported.])])
 156 AS_IF([test "x$sr_have_serial_comm" = xyes],
 157         [SR_APPEND([sr_deps_avail], [serial_comm])])
 158 AM_CONDITIONAL([NEED_SERIAL], [test "x$sr_have_serial_comm" = xyes])
 159
 160 ######################
 161 ##  Feature checks  ##
 162 ######################
 163
 164 # The Check unit testing framework is optional. Disable if not found.
 165 SR_PKG_CHECK([check], [SR_PKGLIBS_TESTS], [check >= 0.9.4])
 166 AM_CONDITIONAL([HAVE_CHECK], [test "x$sr_have_check" = xyes])
 167
 168 # Enable the C99 standard if possible, and enforce the use
 169 # of SR_API to explicitly mark all public API functions.
 170 SR_EXTRA_CFLAGS=
 171 SR_CHECK_COMPILE_FLAGS([SR_EXTRA_CFLAGS], [C99], [-std=c99 -c99 -AC99 -qlanglvl=extc99])
 172 SR_CHECK_COMPILE_FLAGS([SR_EXTRA_CFLAGS], [visibility], [-fvisibility=hidden])
 173
 174 SR_ARG_ENABLE_WARNINGS([SR_WFLAGS], [-Wall], [-Wall -Wextra -Wmissing-prototypes])
 175
 176 # Check host characteristics.
 177 AC_SYS_LARGEFILE
 178 AC_C_BIGENDIAN
 179
 180 AC_CHECK_HEADERS([sys/mman.h], [SR_APPEND([sr_deps_avail], [sys_mman_h])])
 181 AC_CHECK_HEADERS([sys/ioctl.h], [SR_APPEND([sr_deps_avail], [sys_ioctl_h])])
 182 AC_CHECK_HEADERS([sys/timerfd.h], [SR_APPEND([sr_deps_avail], [sys_timerfd_h])])
 183
 184 # We need to link against the Winsock2 library for SCPI over TCP.
 185 AS_CASE([$host_os], [mingw*], [SR_PREPEND([SR_EXTRA_LIBS], [-lws2_32])])
 186
 187 # libm (the standard math library) is always needed.
 188 SR_SEARCH_LIBS([SR_EXTRA_LIBS], [pow], [m])
 189
 190 # RPC is only needed for VXI support.
 191 AC_CACHE_CHECK([for RPC support], [sr_cv_have_rpc],
 192         [AC_LINK_IFELSE([AC_LANG_PROGRAM(
 193                         [[#include <rpc/rpc.h>]m4_newline[CLIENT *rpc_test(void);]],
 194                         [[(void) clnt_create("", 0, 0, "");]])],
 195                 [sr_cv_have_rpc=yes], [sr_cv_have_rpc=no])])
 196 AS_IF([test "x$sr_cv_have_rpc" = xyes],
 197         [AC_DEFINE([HAVE_RPC], [1], [Specifies whether we have RPC support.])])
 198 # VXI support is only compiled if RPC support was found.
 199 AM_CONDITIONAL([NEED_RPC], [test "x$sr_cv_have_rpc" = xyes])
 200
 201 # Check for compiler support of 128 bit integers
 202 AC_CHECK_TYPES([__int128_t, __uint128_t], [], [], [])
 203
 204 ########################
 205 ##  Hardware drivers  ##
 206 ########################
 207
 208 # Keep track of all drivers so we can list them at the end.
 209 SR_VAR_SUMMARY([sr_driver_summary])
 210
 211 # Check whether the sr_deps_avail list contains all of the arguments.
 212 # Unavailable dependencies are collected in sr_deps_missing.
 213 sr_check_driver_deps() {
 214         sr_deps_missing=
 215         for sr_dep
 216         do
 217                 AS_CASE([" $sr_deps_avail "], [*" $sr_dep "*],,
 218                         [SR_APPEND([sr_deps_missing], [', '], [$sr_dep])])
 219         done
 220         test -z "$sr_deps_missing" || return 1
 221 }
 222
 223 AC_ARG_ENABLE([all-drivers],
 224         [AS_HELP_STRING([--enable-all-drivers],
 225                         [enable all drivers by default [default=yes]])],
 226         [], [enable_all_drivers=yes])
 227
 228 ## _SR_DRIVER(Device name, driver-name, var-name, [dependencies...])
 229 m4_define([_SR_DRIVER], [
 230         AC_ARG_ENABLE([$2],
 231                 [AS_HELP_STRING([--enable-$2], [enable $1 support])],
 232                 [$3=$enableval], [$3=$enable_all_drivers])
 233
 234         AS_IF([test "x[$]$3" = xyes], [sr_hw_info=yes[]m4_ifval([$4], [
 235                 sr_check_driver_deps $4 \
 236                         || $3=no sr_hw_info="no (missing: $sr_deps_missing)"
 237         ])], [sr_hw_info='no (disabled)'])
 238         sr_driver_summary_append "$2" "$sr_hw_info"
 239
 240         AM_CONDITIONAL([$3], [test "x[$]$3" = xyes])
 241         AM_COND_IF([$3], [AC_DEFINE([HAVE_$3], [1], [Whether to support $1 device.]) AC_DEFINE([HAVE_DRIVERS], [1], [Whether at least one driver is enabled.])])
 242 ])
 243
 244 ## SR_DRIVER(Device name, driver-name, [dependencies...])
 245 m4_define([SR_DRIVER],
 246         [_SR_DRIVER([$1], [$2], m4_expand([AS_TR_CPP([HW_$2])]), [$3])])
 247
 248 SR_DRIVER([Agilent DMM], [agilent-dmm], [serial_comm])
 249 SR_DRIVER([Appa 55II], [appa-55ii], [serial_comm])
 250 SR_DRIVER([Arachnid Labs Re:load Pro], [arachnid-labs-re-load-pro], [serial_comm])
 251 SR_DRIVER([ASIX SIGMA/SIGMA2], [asix-sigma], [libftdi])
 252 SR_DRIVER([Atten PPS3xxx], [atten-pps3xxx], [serial_comm])
 253 SR_DRIVER([BayLibre ACME], [baylibre-acme], [sys_timerfd_h])
 254 SR_DRIVER([BeagleLogic], [beaglelogic], [sys_mman_h sys_ioctl_h])
 255 SR_DRIVER([Brymen DMM], [brymen-dmm], [serial_comm])
 256 SR_DRIVER([CEM DT-885x], [cem-dt-885x], [serial_comm])
 257 SR_DRIVER([Center 3xx], [center-3xx], [serial_comm])
 258 SR_DRIVER([ChronoVu LA], [chronovu-la], [libusb libftdi])
 259 SR_DRIVER([Colead SLM], [colead-slm], [serial_comm])
 260 SR_DRIVER([Conrad DIGI 35 CPU], [conrad-digi-35-cpu], [serial_comm])
 261 SR_DRIVER([demo], [demo])
 262 SR_DRIVER([DreamSourceLab DSLogic], [dreamsourcelab-dslogic], [libusb])
 263 SR_DRIVER([Fluke 45], [fluke-45])
 264 SR_DRIVER([Fluke DMM], [fluke-dmm], [serial_comm])
 265 SR_DRIVER([FTDI LA], [ftdi-la], [libusb libftdi])
 266 SR_DRIVER([fx2lafw], [fx2lafw], [libusb])
 267 SR_DRIVER([GMC MH 1x/2x], [gmc-mh-1x-2x], [serial_comm])
 268 SR_DRIVER([GW Instek GDS-800], [gwinstek-gds-800], [serial_comm])
 269 SR_DRIVER([GW Instek GPD], [gwinstek-gpd], [serial_comm])
 270 SR_DRIVER([Hameg HMO], [hameg-hmo], [serial_comm])
 271 SR_DRIVER([Hantek 4032L], [hantek-4032l], [libusb])
 272 SR_DRIVER([Hantek 6xxx], [hantek-6xxx], [libusb])
 273 SR_DRIVER([Hantek DSO], [hantek-dso], [libusb])
 274 SR_DRIVER([HP 3457A], [hp-3457a])
 275 SR_DRIVER([HP 3478A], [hp-3478a], [libgpib])
 276 SR_DRIVER([Hung-Chang DSO-2100], [hung-chang-dso-2100], [libieee1284])
 277 SR_DRIVER([Ikalogic Scanalogic-2], [ikalogic-scanalogic2], [libusb])
 278 SR_DRIVER([Ikalogic Scanaplus], [ikalogic-scanaplus], [libftdi])
 279 SR_DRIVER([IPDBG LA], [ipdbg-la])
 280 SR_DRIVER([Kecheng KC-330B], [kecheng-kc-330b], [libusb])
 281 SR_DRIVER([KERN scale], [kern-scale], [serial_comm])
 282 SR_DRIVER([Kingst LA2016], [kingst-la2016], [libusb])
 283 SR_DRIVER([Korad KAxxxxP], [korad-kaxxxxp], [serial_comm])
 284 SR_DRIVER([Lascar EL-USB], [lascar-el-usb], [libusb])
 285 SR_DRIVER([LeCroy LogicStudio], [lecroy-logicstudio], [libusb])
 286 SR_DRIVER([LeCroy X-Stream], [lecroy-xstream])
 287 SR_DRIVER([Manson HCS-3xxx], [manson-hcs-3xxx], [serial_comm])
 288 SR_DRIVER([Mastech MS6514], [mastech-ms6514], [serial_comm])
 289 SR_DRIVER([maynuo-m97], [maynuo-m97])
 290 SR_DRIVER([MIC 985xx], [mic-985xx], [serial_comm])
 291 SR_DRIVER([Microchip PICkit2], [microchip-pickit2], [libusb])
 292 SR_DRIVER([Mooshimeter DMM], [mooshimeter-dmm], [bluetooth_comm libgio])
 293 SR_DRIVER([Motech LPS 30x], [motech-lps-30x], [serial_comm])
 294 SR_DRIVER([Norma DMM], [norma-dmm], [serial_comm])
 295 SR_DRIVER([OpenBench Logic Sniffer], [openbench-logic-sniffer], [serial_comm])
 296 SR_DRIVER([PCE PCE-322A], [pce-322a], [serial_comm])
 297 SR_DRIVER([Pipistrello-OLS], [pipistrello-ols], [libftdi])
 298 SR_DRIVER([RDTech DPSxxxx/DPHxxxx], [rdtech-dps], [serial_comm])
 299 SR_DRIVER([RDTech UMXX], [rdtech-um], [serial_comm])
 300 SR_DRIVER([RDTech TCXX], [rdtech-tc], [serial_comm libnettle])
 301 SR_DRIVER([Rigol DS], [rigol-ds])
 302 SR_DRIVER([Rigol DG], [rigol-dg])
 303 SR_DRIVER([Rohde&Schwarz SME-0x], [rohde-schwarz-sme-0x], [serial_comm])
 304 SR_DRIVER([Saleae Logic16], [saleae-logic16], [libusb])
 305 SR_DRIVER([Saleae Logic Pro], [saleae-logic-pro], [libusb])
 306 SR_DRIVER([SCPI DMM], [scpi-dmm])
 307 SR_DRIVER([SCPI PPS], [scpi-pps])
 308 SR_DRIVER([serial DMM], [serial-dmm], [serial_comm])
 309 SR_DRIVER([serial LCR], [serial-lcr], [serial_comm])
 310 SR_DRIVER([Siglent SDS], [siglent-sds])
 311 SR_DRIVER([Sysclk LWLA], [sysclk-lwla], [libusb])
 312 SR_DRIVER([Sysclk SLA5032], [sysclk-sla5032], [libusb])
 313 SR_DRIVER([Teleinfo], [teleinfo], [serial_comm])
 314 SR_DRIVER([Testo], [testo], [libusb])
 315 SR_DRIVER([Tondaj SL-814], [tondaj-sl-814], [serial_comm])
 316 SR_DRIVER([UNI-T DMM], [uni-t-dmm], [libusb])
 317 SR_DRIVER([UNI-T UT181A], [uni-t-ut181a], [serial_comm])
 318 SR_DRIVER([UNI-T UT32x], [uni-t-ut32x], [serial_comm])
 319 SR_DRIVER([Yokogawa DL/DLM], [yokogawa-dlm])
 320 SR_DRIVER([ZEROPLUS Logic Cube], [zeroplus-logic-cube], [libusb])
 321 SR_DRIVER([ZKETECH EBD-USB], [zketech-ebd-usb], [serial_comm])
 322
 323 ###############################
 324 ##  Language bindings setup  ##
 325 ###############################
 326
 327 AC_LANG([C++])
 328 SR_ARG_ENABLE_WARNINGS([SR_WXXFLAGS], [-Wall], [-Wall -Wextra])
 329
 330 AC_ARG_ENABLE([bindings],
 331         [AS_HELP_STRING([--enable-bindings], [build language bindings [default=yes]])],
 332         [], [enable_bindings=yes])
 333
 334 AC_ARG_ENABLE([cxx],
 335         [AS_HELP_STRING([--enable-cxx], [build C++ bindings [default=yes]])],
 336         [], [enable_cxx=$enable_bindings])
 337
 338 AC_ARG_ENABLE([python],
 339         [AS_HELP_STRING([--enable-python], [build Python bindings [default=yes]])],
 340         [], [enable_python=$enable_bindings])
 341
 342 AC_ARG_ENABLE([ruby],
 343         [AS_HELP_STRING([--enable-ruby], [build Ruby bindings [default=yes]])],
 344         [], [enable_ruby=$enable_bindings])
 345
 346 AC_ARG_ENABLE([java],
 347         [AS_HELP_STRING([--enable-java], [build Java bindings [default=yes]])],
 348         [], [enable_java=$enable_bindings])
 349
 350 ####################
 351 ##  C++ bindings  ##
 352 ####################
 353
 354 sr_cxx_missing=
 355
 356 # Check if the C++ compiler supports the C++11 standard.
 357 AX_CXX_COMPILE_STDCXX([11], [noext], [optional])
 358 AS_IF([test "x$HAVE_CXX11" != x1],
 359         [SR_APPEND([sr_cxx_missing], [', '], ['C++11'])])
 360
 361 # The C++ bindings need glibmm.
 362 SR_PKG_CHECK([glibmm], [SR_PKGLIBS_CXX], [glibmm-2.4 >= 2.32.0])
 363 AS_IF([test "x$sr_have_glibmm" != xyes],
 364         [SR_APPEND([sr_cxx_missing], [', '], [glibmm])])
 365
 366 # The C++ bindings use Doxygen to parse libsigrok symbols.
 367 AC_CHECK_PROG([HAVE_DOXYGEN], [doxygen], [yes], [no])
 368 AS_IF([test "x$HAVE_DOXYGEN" != xyes],
 369         [SR_APPEND([sr_cxx_missing], [', '], [Doxygen])])
 370
 371 # Link C++ code with gnustl_shared if it exists (Android)
 372 SR_SEARCH_LIBS([SR_EXTRA_CXX_LIBS], [__cxa_throw], [gnustl_shared])
 373
 374 # Python is needed for the C++ bindings.
 375 AM_PATH_PYTHON([2.7],
 376         [HAVE_PYTHON=yes],
 377         [HAVE_PYTHON=no
 378         SR_APPEND([sr_cxx_missing], [', '], [Python])])
 379
 380 AS_IF([test -z "$sr_cxx_missing"],
 381         [BINDINGS_CXX=$enable_cxx], [BINDINGS_CXX=no])
 382 AM_CONDITIONAL([BINDINGS_CXX], [test "x$BINDINGS_CXX" = xyes])
 383
 384 # C++ bindings want stoi and stod.
 385 AM_COND_IF([BINDINGS_CXX], [
 386         AC_CACHE_CHECK([for stoi and stod], [sr_cv_have_stoi_stod],
 387                 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <string>]],
 388                                 [[(void) std::stoi("1"); (void) std::stod("1.0");]])],
 389                         [sr_cv_have_stoi_stod=yes], [sr_cv_have_stoi_stod=no])])
 390         AS_IF([test "x$sr_cv_have_stoi_stod" = xyes],
 391                 [AC_DEFINE([HAVE_STOI_STOD], [1],
 392                         [Specifies whether we have the stoi and stod functions.])])
 393 ])
 394
 395 #######################
 396 ##  Python bindings  ##
 397 #######################
 398
 399 AS_IF([test "x$BINDINGS_CXX" = xyes],
 400         [sr_python_missing=],
 401         [sr_python_missing='C++ bindings'])
 402
 403 # Extract major and minor version number of the Python interpreter.
 404 sr_pymajor=${PYTHON_VERSION%%.*}
 405 sr_pyminor=${PYTHON_VERSION#*.}
 406
 407 # The Python bindings need Python development files. Check for either
 408 # Python 3 or Python 2 headers depending on the interpreter version.
 409 SR_PKG_CHECK([python_dev], [SR_PKGLIBS_PYTHON],
 410         [python = $PYTHON_VERSION],
 411         [python$sr_pymajor = $PYTHON_VERSION],
 412         [python$sr_pymajor$sr_pyminor = $PYTHON_VERSION],
 413         [python-$PYTHON_VERSION = $PYTHON_VERSION])
 414
 415 AS_IF([test "x$sr_have_python_dev" != xyes],
 416         [SR_APPEND([sr_python_missing], [', '], [Headers])])
 417
 418 # PyGObject is needed for the Python bindings.
 419 SR_PKG_CHECK([pygobject], [SR_PKGLIBS_PYTHON], [pygobject-3.0 >= 3.0.0])
 420 AS_IF([test "x$sr_have_pygobject" != xyes],
 421         [SR_APPEND([sr_python_missing], [', '], [PyGObject])])
 422
 423 PKG_CHECK_EXISTS([pygobject-3.0 < 3.7.91],
 424         [AC_DEFINE([PYGOBJECT_FLAGS_SIGNED], [1],
 425                 [Whether last argument to pyg_flags_get_value() is signed.])])
 426
 427 # The Python bindings need the setuptools and numpy Python modules.
 428 # We'll let it go through even if the AX macro wasn't found, as the
 429 # Python modules may still be there.
 430 m4_ifdef([AX_PYTHON_MODULE], [
 431         AX_PYTHON_MODULE([setuptools])
 432         AX_PYTHON_MODULE([numpy])
 433 ], [
 434         HAVE_PYMOD_SETUPTOOLS=yes
 435         HAVE_PYMOD_NUMPY=yes
 436         m4_warn([unsupported],
 437                 [Missing macro AX_PYTHON_MODULE: no check for setuptools and numpy])
 438 ])
 439 AS_IF([test "x$HAVE_PYMOD_SETUPTOOLS" != xyes],
 440         [SR_APPEND([sr_python_missing], [', '], [setuptools])])
 441 AS_IF([test "x$HAVE_PYMOD_NUMPY" != xyes],
 442         [SR_APPEND([sr_python_missing], [', '], [numpy])])
 443
 444 # The Python bindings use SWIG to generate code.
 445 AC_CHECK_PROGS([SWIG], [swig swig4.0 swig3.0 swig2.0])
 446 AS_IF([test "x$SWIG" != x],
 447     AC_MSG_CHECKING([for $SWIG version])
 448     [SWIG_VERSION=`$SWIG -version 2>&1 | sed -n 's/SWIG Version //p'`]
 449     AC_MSG_RESULT([$SWIG_VERSION]))
 450 AS_IF([test "x$SWIG" = x],
 451         [SR_APPEND([sr_python_missing], [', '], [SWIG])])
 452
 453 AS_IF([test -z "$sr_python_missing"],
 454         [BINDINGS_PYTHON=$enable_python], [BINDINGS_PYTHON=no])
 455 AM_CONDITIONAL([BINDINGS_PYTHON], [test "x$BINDINGS_PYTHON" = xyes])
 456
 457 #####################
 458 ##  Ruby bindings  ##
 459 #####################
 460
 461 AS_IF([test "x$BINDINGS_CXX" = xyes],
 462         [sr_ruby_missing=],
 463         [sr_ruby_missing='C++ bindings'])
 464
 465 AC_PATH_PROGS(RUBY, ["${RUBY-ruby}"], [])
 466 AS_IF([test "x$RUBY" != x],
 467         AC_MSG_CHECKING([for Ruby version])
 468     [RUBY_VERSION=`$RUBY -e 'puts RUBY_VERSION'`]
 469     AC_MSG_RESULT([$RUBY_VERSION])
 470     [RUBY_DLEXT=`$RUBY -rrbconfig -e 'puts RbConfig::CONFIG[["DLEXT"]]'`]
 471     AC_SUBST(RUBY_DLEXT))
 472
 473 AS_IF([test "x$RUBY" = x],
 474         [SR_APPEND([sr_ruby_missing], [', '], [Ruby])])
 475
 476 # Extract major and minor version number of the Ruby interpreter.
 477 sr_rbmajor=${RUBY_VERSION%%.*}
 478 sr_rbminor=${RUBY_VERSION#*.}
 479 sr_rbminor=${sr_rbminor%%.*}
 480
 481 # The Ruby bindings need Ruby development files.
 482 SR_PKG_CHECK([ruby_dev], [SR_PKGLIBS_RUBY],
 483         [ruby >= 2.5.0],
 484         [ruby-$sr_rbmajor.$sr_rbminor >= 2.5.0])
 485
 486 AS_IF([test "x$sr_have_ruby_dev" != xyes],
 487         [SR_APPEND([sr_ruby_missing], [', '], [Headers])])
 488
 489 # The Ruby bindings use SWIG >= 3.0.8 to generate code.
 490 AS_IF([test "x$SWIG" = x],
 491         [SR_APPEND([sr_ruby_missing], [', '], [SWIG])],
 492         [AS_VERSION_COMPARE($SWIG_VERSION, "3.0.8",
 493                 [SR_APPEND([sr_ruby_missing], [', '], ['SWIG >= 3.0.8'])])])
 494
 495 AS_IF([test -z "$sr_ruby_missing"],
 496         [BINDINGS_RUBY=$enable_ruby], [BINDINGS_RUBY=no])
 497 AM_CONDITIONAL([BINDINGS_RUBY], [test "x$BINDINGS_RUBY" = xyes])
 498
 499 ####################
 500 ##  Java bindings ##
 501 ####################
 502
 503 AS_IF([test "x$BINDINGS_CXX" = xyes],
 504         [sr_java_missing=],
 505         [sr_java_missing='C++ bindings'])
 506
 507 # The Java bindings use SWIG to generate code.
 508 AS_IF([test "x$SWIG" = x],
 509         [SR_APPEND([sr_java_missing], [', '], [SWIG])])
 510
 511 # Find Java compiler and JNI includes for Java bindings.
 512 AC_CHECK_PROG([HAVE_JAVAC], [javac], [yes], [no])
 513 AS_IF([test "x$HAVE_JAVAC" = xno],
 514         [SR_APPEND([sr_java_missing], [', '], [JavaC])])
 515
 516 AC_ARG_WITH([jni-include-path],
 517         [AS_HELP_STRING([[--with-jni-include-path=DIR-LIST (space-separated)]],
 518                 [specify JNI include directories [default=detect]])],
 519         [JNI_INCLUDE_DIRS=" $withval"], [JNI_INCLUDE_DIRS=])
 520
 521 JNI_CPPFLAGS=
 522 AS_IF([test "x$enable_java$HAVE_JAVAC" = xyesyes], [
 523         AX_PROG_JAVAC
 524         AS_IF([test -z "$JNI_INCLUDE_DIRS" && test "x$cross_compiling" != xyes], [
 525                 ## Work around the totally broken logic in AX_JNI_INCLUDE_DIR:
 526                 ## If we can find jni.h without any special search path, skip
 527                 ## the execution of the broken macro to increase our chances of
 528                 ## success.
 529                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <jni.h>]], [])],,
 530                         [AX_JNI_INCLUDE_DIR])
 531         ])
 532 ])
 533 for sr_dir in $JNI_INCLUDE_DIRS
 534 do
 535         SR_APPEND([JNI_CPPFLAGS], ["-I$sr_dir"])
 536 done
 537 AC_SUBST([JNI_CPPFLAGS])
 538
 539 sr_save_cppflags=$CPPFLAGS
 540 SR_APPEND([CPPFLAGS], [$JNI_CPPFLAGS])
 541 AC_CHECK_HEADER([jni.h],,
 542         [SR_APPEND([sr_java_missing], [', '], ['JNI headers'])])
 543 CPPFLAGS=$sr_save_cppflags
 544
 545 AS_IF([test -z "$sr_java_missing"],
 546         [BINDINGS_JAVA=$enable_java], [BINDINGS_JAVA=no])
 547 AM_CONDITIONAL([BINDINGS_JAVA], [test "x$BINDINGS_JAVA" = xyes])
 548
 549 ##############################
 550 ##  Finalize configuration  ##
 551 ##############################
 552
 553 # Add mandatory dependencies to module list.
 554 SR_APPEND([SR_PKGLIBS], ['libzip >= 0.10'])
 555 AC_SUBST([SR_PKGLIBS])
 556
 557 # Retrieve the compile and link flags for all modules combined.
 558 # Also, bail out at this point if any module dependency is not met.
 559 PKG_CHECK_MODULES([LIBSIGROK], [glib-2.0 >= 2.32.0 $SR_PKGLIBS])
 560 PKG_CHECK_MODULES([TESTS], [$SR_PKGLIBS_TESTS glib-2.0 $SR_PKGLIBS])
 561
 562 # SR_PKGLIBS_CXX may be empty, so only invoke these checks when
 563 # the C++ bindings are enabled.
 564 AM_COND_IF([BINDINGS_CXX], [
 565         PKG_CHECK_MODULES([LIBSIGROKCXX], [$SR_PKGLIBS_CXX])
 566         PKG_CHECK_MODULES([PYSIGROK], [$SR_PKGLIBS_PYTHON $SR_PKGLIBS_CXX])
 567         PKG_CHECK_MODULES([RBSIGROK], [$SR_PKGLIBS_RUBY $SR_PKGLIBS_CXX], [AC_SUBST(RBSIGROK_EXTDIR, "lib/$($PKG_CONFIG --variable=sitearch $SR_PKGLIBS_RUBY)/$($PKG_CONFIG --variable=RUBY_BASE_NAME $SR_PKGLIBS_RUBY)/vendor_ruby/$($PKG_CONFIG --variable=ruby_version $SR_PKGLIBS_RUBY)")])
 568 ])
 569
 570 # Check for specific libusb features, now that we know the CFLAGS.
 571 AC_LANG([C])
 572 sr_save_cflags=$CFLAGS
 573 sr_save_libs=$LIBS
 574 CFLAGS="$LIBSIGROK_CFLAGS $CFLAGS"
 575 LIBS="$LIBSIGROK_LIBS $LIBS"
 576 AC_CHECK_TYPES([libusb_os_handle],
 577         [sr_have_libusb_os_handle=yes], [sr_have_libusb_os_handle=no],
 578         [[#include <libusb.h>]])
 579 AC_CHECK_FUNCS([zip_discard])
 580 LIBS=$sr_save_libs
 581 CFLAGS=$sr_save_cflags
 582
 583 AM_COND_IF([NEED_USB], [AS_CASE([$sr_have_libusb_os_handle:$host_os], [no:mingw*],
 584         [AC_MSG_ERROR([Windows builds require the event-abstraction branch of libusb])])])
 585
 586 sr_glib_version=`$PKG_CONFIG --modversion glib-2.0 2>&AS_MESSAGE_LOG_FD`
 587 sr_libzip_version=`$PKG_CONFIG --modversion libzip 2>&AS_MESSAGE_LOG_FD`
 588
 589 AC_DEFINE_UNQUOTED([CONF_LIBZIP_VERSION], ["$sr_libzip_version"],
 590         [Build-time version of libzip.])
 591 AC_DEFINE_UNQUOTED([CONF_HOST], ["$host"],
 592         [The canonical host libsigrok will run on.])
 593
 594 AC_CONFIG_FILES([Makefile libsigrok.pc bindings/cxx/libsigrokcxx.pc])
 595
 596 AC_OUTPUT
 597
 598 # Prepare bindings report messages.
 599 m4_define([SR_PREPARE_BINDING_REPORT], [
 600         sr_report_$1=
 601         test -z "$sr_$1_missing" || sr_report_$1=" (missing: $sr_$1_missing)"
 602         test "x$enable_$1" = xyes || sr_report_$1=' (disabled)'
 603 ])
 604 m4_map_args([SR_PREPARE_BINDING_REPORT], [cxx], [python], [ruby], [java])
 605
 606 cat >&AS_MESSAGE_FD <<_EOF
 607
 608 libsigrok configuration summary:
 609  - Package version................. $SR_PACKAGE_VERSION
 610  - Library ABI version............. $SR_LIB_VERSION
 611  - Prefix.......................... $prefix
 612  - Building on..................... $build
 613  - Building for.................... $host
 614  - Building shared / static........ $enable_shared / $enable_static
 615
 616 Compile configuration:
 617  - C compiler...................... $CC
 618  - C compiler version.............. $sr_cc_version
 619  - C compiler flags................ $CFLAGS
 620  - Additional C compiler flags..... $SR_EXTRA_CFLAGS
 621  - C compiler warnings............. $SR_WFLAGS
 622  - C++ compiler.................... $CXX
 623  - C++ compiler version............ $sr_cxx_version
 624  - C++ compiler flags.............. $CXXFLAGS
 625  - C++ compiler warnings........... $SR_WXXFLAGS
 626  - Linker flags.................... $LDFLAGS
 627
 628 Detected libraries (required):
 629  - glib-2.0 >= 2.32.0.............. $sr_glib_version
 630  - libzip >= 0.10.................. $sr_libzip_version
 631
 632 Detected libraries (optional):
 633 $sr_pkglibs_summary
 634 Enabled hardware drivers:
 635 $sr_driver_summary
 636 Enabled serial communication transports:
 637   - serial comm ................... $sr_have_serial_comm
 638   - libserialport ................. $sr_have_libserialport
 639   - hidapi ........................ $sr_have_libhidapi
 640   - bluetooth ..................... $sr_have_bluetooth
 641   - bluez ......................... $sr_have_libbluez
 642
 643 Enabled SCPI backends:
 644  - TCP............................. yes
 645  - RPC............................. $sr_cv_have_rpc
 646  - serial.......................... $sr_have_serial_comm
 647  - VISA............................ $sr_have_librevisa
 648  - GPIB............................ $sr_have_libgpib
 649  - USBTMC.......................... $sr_have_libusb
 650
 651 Enabled language bindings:
 652  - C++............................. $BINDINGS_CXX$sr_report_cxx
 653  - Python.......................... $BINDINGS_PYTHON$sr_report_python
 654  - Ruby............................ $BINDINGS_RUBY$sr_report_ruby
 655  - Java............................ $BINDINGS_JAVA$sr_report_java
 656
 657 _EOF
 658
 659 # Emit a warning if the C++ bindings are not being built.
 660 AM_COND_IF([BINDINGS_CXX], [], [
 661 cat >&AS_MESSAGE_FD <<_EOF
 662 ===============================================================================
 663 WARNING WARNING WARNING WARNING WARNING WARNING WARNING WARNING WARNING WARNING
 664 ===============================================================================
 665 ===                                                                         ===
 666 ===         The libsigrok C++ bindings are not being built since you        ===
 667 ===             are missing one or more dependencies (see above)!           ===
 668 ===                                                                         ===
 669 ===      This means you won't be able to compile frontends that require     ===
 670 ===  the C++ bindings (such as PulseView)! You also won't be able to build  ===
 671 ===     other bindings and frontends using those (such as sigrok-meter)!    ===
 672 ===                                                                         ===
 673 ===============================================================================
 674 WARNING WARNING WARNING WARNING WARNING WARNING WARNING WARNING WARNING WARNING
 675 ===============================================================================
 676
 677 _EOF
 678 ])