configure.ac

   1 ##
   2 ## This file is part of the libsigrok project.
   3 ##
   4 ## Copyright (C) 2010-2012 Bert Vermeulen <bert@biot.com>
   5 ## Copyright (C) 2012 Alexandru Gagniuc <mr.nuke.me@gmail.com>
   6 ##
   7 ## This program is free software: you can redistribute it and/or modify
   8 ## it under the terms of the GNU General Public License as published by
   9 ## the Free Software Foundation, either version 3 of the License, or
  10 ## (at your option) any later version.
  11 ##
  12 ## This program is distributed in the hope that it will be useful,
  13 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ## GNU General Public License for more details.
  16 ##
  17 ## You should have received a copy of the GNU General Public License
  18 ## along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19 ##
  20
  21 # We require at least autoconf 2.63 (AC_INIT format changed there).
  22 AC_PREREQ([2.63])
  23
  24 AC_INIT([libsigrok], [0.6.0],
  25         [sigrok-devel@lists.sourceforge.net],
  26         [libsigrok], [http://www.sigrok.org])
  27 AC_CONFIG_MACRO_DIR([m4])
  28 AC_CONFIG_AUX_DIR([autostuff])
  29 AC_CONFIG_HEADERS([config.h include/libsigrok/version.h])
  30
  31 # We require at least automake 1.11 (needed for 'silent rules').
  32 AM_INIT_AUTOMAKE([1.11 -Wall -Werror no-define nostdinc subdir-objects check-news color-tests])
  33 AM_SILENT_RULES([yes])
  34 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  35
  36 AC_CANONICAL_HOST
  37
  38 # Checks for programs.
  39 AC_PROG_CC
  40 AC_PROG_CXX
  41 AC_PROG_INSTALL
  42 AC_PROG_LN_S
  43
  44 # Required for per-target flags or subdir-objects with C sources.
  45 AM_PROG_CC_C_O
  46
  47 # Set the standard the C library headers should conform to.
  48 AH_VERBATIM([_POSIX_C_SOURCE], [/* The targeted POSIX standard. */
  49 #ifndef _POSIX_C_SOURCE
  50 # define _POSIX_C_SOURCE 200112L
  51 #endif])
  52
  53 # Get compiler versions.
  54 SR_PROG_VERSION([$CC], [sr_cc_version])
  55 SR_PROG_VERSION([$CXX], [sr_cxx_version])
  56
  57 # Check for optional make features.
  58 SR_PROG_MAKE_ORDER_ONLY
  59
  60 # Initialize libtool.
  61 LT_INIT
  62
  63 # Set up the libsigrok version defines.
  64 SR_PKG_VERSION_SET([SR_PACKAGE_VERSION], [AC_PACKAGE_VERSION])
  65
  66 # Library version for libsigrok (NOT the same as the package version).
  67 # Carefully read the libtool docs before updating these numbers!
  68 # The algorithm for determining which number to change (and how) is nontrivial!
  69 # http://www.gnu.org/software/libtool/manual/libtool.html#Updating-version-info
  70 # Format: current:revision:age.
  71 SR_LIB_VERSION_SET([SR_LIB_VERSION], [4:0:0])
  72
  73 AM_CONDITIONAL([WIN32], [test -z "${host_os##mingw*}" || test -z "${host_os##cygwin*}"])
  74
  75 #############################
  76 ##  Optional dependencies  ##
  77 #############################
  78
  79 AC_LANG([C])
  80
  81 # Initialize pkg-config.
  82 # We require at least 0.22, as "Requires.private" behaviour changed there.
  83 PKG_PROG_PKG_CONFIG([0.22])
  84
  85 # Keep track of all checked modules so we can list them at the end.
  86 SR_PKG_CHECK_SUMMARY([sr_pkglibs_summary])
  87
  88 # Collect the pkg-config module names of all dependencies in SR_PKGLIBS.
  89 # These are used to derive the compiler flags and for the "Requires.private"
  90 # field in the generated libsigrok.pc file.
  91 SR_VAR_OPT_PKG([SR_PKGLIBS], [sr_deps_avail])
  92 SR_PKGLIBS_TESTS=
  93 SR_PKGLIBS_CXX=
  94 SR_PKGLIBS_PYTHON=
  95 SR_PKGLIBS_RUBY=
  96 SR_EXTRA_LIBS=
  97 SR_EXTRA_CXX_LIBS=
  98
  99 SR_ARG_OPT_PKG([libserialport], [LIBSERIALPORT], ,
 100         [libserialport >= 0.1.1])
 101
 102 SR_ARG_OPT_PKG([libftdi], [LIBFTDI], , [libftdi1 >= 1.0])
 103
 104 # pkg-config file names: MinGW/MacOSX: hidapi; Linux: hidapi-hidraw/-libusb
 105 SR_ARG_OPT_PKG([libhidapi], [LIBHIDAPI], ,
 106         [hidapi >= 0.8.0], [hidapi-hidraw >= 0.8.0], [hidapi-libusb >= 0.8.0])
 107
 108 SR_ARG_OPT_PKG([libbluez], [LIBBLUEZ], , [bluez >= 4.0])
 109
 110 # FreeBSD comes with an "integrated" libusb-1.0-style USB API.
 111 # This means libusb-1.0 is always available; no need to check for it.
 112 # On Windows, require the latest version we can get our hands on,
 113 # until the new generic event handling has seen an official release.
 114 AS_CASE([$host_os],
 115         [freebsd*], [sr_libusb_req='libusb-1.0' sr_have_libusb=yes],
 116         [mingw*], [sr_libusb_req='libusb-1.0 >= 1.0.20'],
 117         [sr_libusb_req='libusb-1.0 >= 1.0.16'])
 118
 119 SR_ARG_OPT_PKG([libusb], [LIBUSB_1_0], [NEED_USB],
 120         [$sr_libusb_req])
 121
 122 SR_ARG_OPT_PKG([librevisa], [LIBREVISA], [NEED_VISA],
 123         [librevisa >= 0.0.20130412])
 124
 125 SR_ARG_OPT_PKG([libgpib], [LIBGPIB], [NEED_GPIB],
 126         [libgpib])
 127
 128 SR_ARG_OPT_CHECK([libieee1284], [LIBIEEE1284],, [
 129         sr_save_LIBS=$LIBS
 130         LIBS="-lieee1284 $LIBS"
 131         AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <ieee1284.h>]],
 132                                 [[(void) ieee1284_open(0, 0, 0);]])],
 133                 [sr_have_libieee1284=yes], [sr_have_libieee1284=no])
 134         LIBS=$sr_save_LIBS
 135 ])
 136 AS_IF([test "x$sr_have_libieee1284" = xyes],
 137         [SR_PREPEND([SR_EXTRA_LIBS], [-lieee1284])])
 138
 139 SR_ARG_OPT_PKG([libgio], [LIBGIO], , [gio-2.0 >= 2.24.0])
 140
 141 # See if any of the (potentially platform specific) libs are available
 142 # which provide some means of Bluetooth communication.
 143 AS_IF([test "x$sr_have_libbluez" = xyes],
 144         sr_have_bluetooth=yes, sr_have_bluetooth=no)
 145 AS_IF([test "x$sr_have_bluetooth" = xyes],
 146         [AC_DEFINE([HAVE_BLUETOOTH], [1], [Specifies whether Bluetooth communication is supported.])])
 147 AS_IF([test "x$sr_have_bluetooth" = xyes],
 148         [SR_APPEND([sr_deps_avail], [bluetooth_comm])])
 149
 150 AS_IF([test "x$sr_have_libserialport" = xyes -o "x$sr_have_libhidapi" = xyes -o "x$sr_have_bluetooth" = xyes],
 151         sr_have_serial_comm=yes, sr_have_serial_comm=no)
 152 AS_IF([test "x$sr_have_serial_comm" = xyes],
 153         [AC_DEFINE([HAVE_SERIAL_COMM], [1], [Specifies whether serial communication is supported.])])
 154 AS_IF([test "x$sr_have_serial_comm" = xyes],
 155         [SR_APPEND([sr_deps_avail], [serial_comm])])
 156 AM_CONDITIONAL([NEED_SERIAL], [test "x$sr_have_serial_comm" = xyes])
 157
 158 ######################
 159 ##  Feature checks  ##
 160 ######################
 161
 162 # The Check unit testing framework is optional. Disable if not found.
 163 SR_PKG_CHECK([check], [SR_PKGLIBS_TESTS], [check >= 0.9.4])
 164 AM_CONDITIONAL([HAVE_CHECK], [test "x$sr_have_check" = xyes])
 165
 166 # Enable the C99 standard if possible, and enforce the use
 167 # of SR_API to explicitly mark all public API functions.
 168 SR_EXTRA_CFLAGS=
 169 SR_CHECK_COMPILE_FLAGS([SR_EXTRA_CFLAGS], [C99], [-std=c99 -c99 -AC99 -qlanglvl=extc99])
 170 SR_CHECK_COMPILE_FLAGS([SR_EXTRA_CFLAGS], [visibility], [-fvisibility=hidden])
 171
 172 SR_ARG_ENABLE_WARNINGS([SR_WFLAGS], [-Wall], [-Wall -Wextra -Wmissing-prototypes])
 173
 174 # Check host characteristics.
 175 AC_SYS_LARGEFILE
 176 AC_C_BIGENDIAN
 177
 178 AC_CHECK_HEADERS([sys/mman.h], [SR_APPEND([sr_deps_avail], [sys_mman_h])])
 179 AC_CHECK_HEADERS([sys/ioctl.h], [SR_APPEND([sr_deps_avail], [sys_ioctl_h])])
 180 AC_CHECK_HEADERS([sys/timerfd.h], [SR_APPEND([sr_deps_avail], [sys_timerfd_h])])
 181
 182 # We need to link against the Winsock2 library for SCPI over TCP.
 183 AS_CASE([$host_os], [mingw*], [SR_PREPEND([SR_EXTRA_LIBS], [-lws2_32])])
 184
 185 # libm (the standard math library) is always needed.
 186 SR_SEARCH_LIBS([SR_EXTRA_LIBS], [pow], [m])
 187
 188 # RPC is only needed for VXI support.
 189 AC_CACHE_CHECK([for RPC support], [sr_cv_have_rpc],
 190         [AC_LINK_IFELSE([AC_LANG_PROGRAM(
 191                         [[#include <rpc/rpc.h>]m4_newline[CLIENT *rpc_test(void);]],
 192                         [[(void) clnt_create("", 0, 0, "");]])],
 193                 [sr_cv_have_rpc=yes], [sr_cv_have_rpc=no])])
 194 AS_IF([test "x$sr_cv_have_rpc" = xyes],
 195         [AC_DEFINE([HAVE_RPC], [1], [Specifies whether we have RPC support.])])
 196 # VXI support is only compiled if RPC support was found.
 197 AM_CONDITIONAL([NEED_RPC], [test "x$sr_cv_have_rpc" = xyes])
 198
 199 # Check for compiler support of 128 bit integers
 200 AC_CHECK_TYPES([__int128_t, __uint128_t], [], [], [])
 201
 202 # Availability of bt_put_le16() depends on the bluez library version.
 203 AC_CACHE_CHECK([for bt_put_le16], [sr_cv_have_btputle16],
 204         [AC_LINK_IFELSE([AC_LANG_PROGRAM(
 205                         [[#include <bluetooth/bluetooth.h>]],
 206                         [[bt_put_le16(0, (void *)0);]])],
 207                 [sr_cv_have_btputle16=yes], [sr_cv_have_btputle16=no])])
 208 AS_IF([test "x$sr_cv_have_btputle16" = xyes],
 209         [AC_DEFINE([HAVE_BT_PUT_LE16], [1], [Specifies whether we have bt_put_le16().])])
 210
 211 ########################
 212 ##  Hardware drivers  ##
 213 ########################
 214
 215 # Keep track of all drivers so we can list them at the end.
 216 SR_VAR_SUMMARY([sr_driver_summary])
 217
 218 # Check whether the sr_deps_avail list contains all of the arguments.
 219 # Unavailable dependencies are collected in sr_deps_missing.
 220 sr_check_driver_deps() {
 221         sr_deps_missing=
 222         for sr_dep
 223         do
 224                 AS_CASE([" $sr_deps_avail "], [*" $sr_dep "*],,
 225                         [SR_APPEND([sr_deps_missing], [', '], [$sr_dep])])
 226         done
 227         test -z "$sr_deps_missing" || return 1
 228 }
 229
 230 AC_ARG_ENABLE([all-drivers],
 231         [AS_HELP_STRING([--enable-all-drivers],
 232                         [enable all drivers by default [default=yes]])],
 233         [], [enable_all_drivers=yes])
 234
 235 ## _SR_DRIVER(Device name, driver-name, var-name, [dependencies...])
 236 m4_define([_SR_DRIVER], [
 237         AC_ARG_ENABLE([$2],
 238                 [AS_HELP_STRING([--enable-$2], [enable $1 support])],
 239                 [$3=$enableval], [$3=$enable_all_drivers])
 240
 241         AS_IF([test "x[$]$3" = xyes], [sr_hw_info=yes[]m4_ifval([$4], [
 242                 sr_check_driver_deps $4 \
 243                         || $3=no sr_hw_info="no (missing: $sr_deps_missing)"
 244         ])], [sr_hw_info='no (disabled)'])
 245         sr_driver_summary_append "$2" "$sr_hw_info"
 246
 247         AM_CONDITIONAL([$3], [test "x[$]$3" = xyes])
 248         AM_COND_IF([$3], [AC_DEFINE([HAVE_$3], [1], [Whether to support $1 device.]) AC_DEFINE([HAVE_DRIVERS], [1], [Whether at least one driver is enabled.])])
 249 ])
 250
 251 ## SR_DRIVER(Device name, driver-name, [dependencies...])
 252 m4_define([SR_DRIVER],
 253         [_SR_DRIVER([$1], [$2], m4_expand([AS_TR_CPP([HW_$2])]), [$3])])
 254
 255 SR_DRIVER([Agilent DMM], [agilent-dmm], [serial_comm])
 256 SR_DRIVER([Appa 55II], [appa-55ii], [serial_comm])
 257 SR_DRIVER([Arachnid Labs Re:load Pro], [arachnid-labs-re-load-pro], [serial_comm])
 258 SR_DRIVER([ASIX SIGMA/SIGMA2], [asix-sigma], [libftdi])
 259 SR_DRIVER([Atten PPS3xxx], [atten-pps3xxx], [serial_comm])
 260 SR_DRIVER([BayLibre ACME], [baylibre-acme], [sys_timerfd_h])
 261 SR_DRIVER([BeagleLogic], [beaglelogic], [sys_mman_h sys_ioctl_h])
 262 SR_DRIVER([Brymen DMM], [brymen-dmm], [serial_comm])
 263 SR_DRIVER([CEM DT-885x], [cem-dt-885x], [serial_comm])
 264 SR_DRIVER([Center 3xx], [center-3xx], [serial_comm])
 265 SR_DRIVER([ChronoVu LA], [chronovu-la], [libusb libftdi])
 266 SR_DRIVER([Colead SLM], [colead-slm], [serial_comm])
 267 SR_DRIVER([Conrad DIGI 35 CPU], [conrad-digi-35-cpu], [serial_comm])
 268 SR_DRIVER([demo], [demo])
 269 SR_DRIVER([DreamSourceLab DSLogic], [dreamsourcelab-dslogic], [libusb])
 270 SR_DRIVER([Fluke 45], [fluke-45])
 271 SR_DRIVER([Fluke DMM], [fluke-dmm], [serial_comm])
 272 SR_DRIVER([FTDI LA], [ftdi-la], [libusb libftdi])
 273 SR_DRIVER([fx2lafw], [fx2lafw], [libusb])
 274 SR_DRIVER([GMC MH 1x/2x], [gmc-mh-1x-2x], [serial_comm])
 275 SR_DRIVER([GW Instek GDS-800], [gwinstek-gds-800], [serial_comm])
 276 SR_DRIVER([GW Instek GPD], [gwinstek-gpd], [serial_comm])
 277 SR_DRIVER([Hameg HMO], [hameg-hmo], [serial_comm])
 278 SR_DRIVER([Hantek 4032L], [hantek-4032l], [libusb])
 279 SR_DRIVER([Hantek 6xxx], [hantek-6xxx], [libusb])
 280 SR_DRIVER([Hantek DSO], [hantek-dso], [libusb])
 281 SR_DRIVER([HP 3457A], [hp-3457a])
 282 SR_DRIVER([HP 3478A], [hp-3478a], [libgpib])
 283 SR_DRIVER([Hung-Chang DSO-2100], [hung-chang-dso-2100], [libieee1284])
 284 SR_DRIVER([Ikalogic Scanalogic-2], [ikalogic-scanalogic2], [libusb])
 285 SR_DRIVER([Ikalogic Scanaplus], [ikalogic-scanaplus], [libftdi])
 286 SR_DRIVER([IPDBG LA], [ipdbg-la])
 287 SR_DRIVER([Kecheng KC-330B], [kecheng-kc-330b], [libusb])
 288 SR_DRIVER([KERN scale], [kern-scale], [serial_comm])
 289 SR_DRIVER([Korad KAxxxxP], [korad-kaxxxxp], [serial_comm])
 290 SR_DRIVER([Lascar EL-USB], [lascar-el-usb], [libusb])
 291 SR_DRIVER([LeCroy LogicStudio], [lecroy-logicstudio], [libusb])
 292 SR_DRIVER([LeCroy X-Stream], [lecroy-xstream])
 293 SR_DRIVER([Manson HCS-3xxx], [manson-hcs-3xxx], [serial_comm])
 294 SR_DRIVER([Mastech MS6514], [mastech-ms6514], [serial_comm])
 295 SR_DRIVER([maynuo-m97], [maynuo-m97])
 296 SR_DRIVER([MIC 985xx], [mic-985xx], [serial_comm])
 297 SR_DRIVER([Microchip PICkit2], [microchip-pickit2], [libusb])
 298 SR_DRIVER([Mooshimeter DMM], [mooshimeter-dmm], [bluetooth_comm libgio])
 299 SR_DRIVER([Motech LPS 30x], [motech-lps-30x], [serial_comm])
 300 SR_DRIVER([Norma DMM], [norma-dmm], [serial_comm])
 301 SR_DRIVER([OpenBench Logic Sniffer], [openbench-logic-sniffer], [serial_comm])
 302 SR_DRIVER([PCE PCE-322A], [pce-322a], [serial_comm])
 303 SR_DRIVER([Pipistrello-OLS], [pipistrello-ols], [libftdi])
 304 SR_DRIVER([RDTech DPSxxxx/DPHxxxx], [rdtech-dps], [serial_comm])
 305 SR_DRIVER([Rigol DS], [rigol-ds])
 306 SR_DRIVER([Rohde&Schwarz SME-0x], [rohde-schwarz-sme-0x], [serial_comm])
 307 SR_DRIVER([Saleae Logic16], [saleae-logic16], [libusb])
 308 SR_DRIVER([Saleae Logic Pro], [saleae-logic-pro], [libusb])
 309 SR_DRIVER([SCPI DMM], [scpi-dmm])
 310 SR_DRIVER([SCPI PPS], [scpi-pps])
 311 SR_DRIVER([serial DMM], [serial-dmm], [serial_comm])
 312 SR_DRIVER([serial LCR], [serial-lcr], [serial_comm])
 313 SR_DRIVER([Siglent SDS], [siglent-sds])
 314 SR_DRIVER([Sysclk LWLA], [sysclk-lwla], [libusb])
 315 SR_DRIVER([Sysclk SLA5032], [sysclk-sla5032], [libusb])
 316 SR_DRIVER([Teleinfo], [teleinfo], [serial_comm])
 317 SR_DRIVER([Testo], [testo], [libusb])
 318 SR_DRIVER([Tondaj SL-814], [tondaj-sl-814], [serial_comm])
 319 SR_DRIVER([UNI-T DMM], [uni-t-dmm], [libusb])
 320 SR_DRIVER([UNI-T UT181A], [uni-t-ut181a])
 321 SR_DRIVER([UNI-T UT32x], [uni-t-ut32x], [serial_comm])
 322 SR_DRIVER([Yokogawa DL/DLM], [yokogawa-dlm])
 323 SR_DRIVER([ZEROPLUS Logic Cube], [zeroplus-logic-cube], [libusb])
 324 SR_DRIVER([ZKETECH EBD-USB], [zketech-ebd-usb], [serial_comm])
 325
 326 ###############################
 327 ##  Language bindings setup  ##
 328 ###############################
 329
 330 AC_LANG([C++])
 331 SR_ARG_ENABLE_WARNINGS([SR_WXXFLAGS], [-Wall], [-Wall -Wextra])
 332
 333 AC_ARG_ENABLE([bindings],
 334         [AS_HELP_STRING([--enable-bindings], [build language bindings [default=yes]])],
 335         [], [enable_bindings=yes])
 336
 337 AC_ARG_ENABLE([cxx],
 338         [AS_HELP_STRING([--enable-cxx], [build C++ bindings [default=yes]])],
 339         [], [enable_cxx=$enable_bindings])
 340
 341 AC_ARG_ENABLE([python],
 342         [AS_HELP_STRING([--enable-python], [build Python bindings [default=yes]])],
 343         [], [enable_python=$enable_bindings])
 344
 345 AC_ARG_ENABLE([ruby],
 346         [AS_HELP_STRING([--enable-ruby], [build Ruby bindings [default=no]])],
 347         [], [enable_ruby=no])
 348
 349 AC_ARG_ENABLE([java],
 350         [AS_HELP_STRING([--enable-java], [build Java bindings [default=yes]])],
 351         [], [enable_java=$enable_bindings])
 352
 353 ####################
 354 ##  C++ bindings  ##
 355 ####################
 356
 357 sr_cxx_missing=
 358
 359 # Check if the C++ compiler supports the C++11 standard.
 360 AX_CXX_COMPILE_STDCXX([11], [noext], [optional])
 361 AS_IF([test "x$HAVE_CXX11" != x1],
 362         [SR_APPEND([sr_cxx_missing], [', '], ['C++11'])])
 363
 364 # The C++ bindings need glibmm.
 365 SR_PKG_CHECK([glibmm], [SR_PKGLIBS_CXX], [glibmm-2.4 >= 2.32.0])
 366 AS_IF([test "x$sr_have_glibmm" != xyes],
 367         [SR_APPEND([sr_cxx_missing], [', '], [glibmm])])
 368
 369 # The C++ bindings use Doxygen to parse libsigrok symbols.
 370 AC_CHECK_PROG([HAVE_DOXYGEN], [doxygen], [yes], [no])
 371 AS_IF([test "x$HAVE_DOXYGEN" != xyes],
 372         [SR_APPEND([sr_cxx_missing], [', '], [Doxygen])])
 373
 374 # Link C++ code with gnustl_shared if it exists (Android)
 375 SR_SEARCH_LIBS([SR_EXTRA_CXX_LIBS], [__cxa_throw], [gnustl_shared])
 376
 377 # Python is needed for the C++ bindings.
 378 AM_PATH_PYTHON([2.7],
 379         [HAVE_PYTHON=yes],
 380         [HAVE_PYTHON=no
 381         SR_APPEND([sr_cxx_missing], [', '], [Python])])
 382
 383 AS_IF([test -z "$sr_cxx_missing"],
 384         [BINDINGS_CXX=$enable_cxx], [BINDINGS_CXX=no])
 385 AM_CONDITIONAL([BINDINGS_CXX], [test "x$BINDINGS_CXX" = xyes])
 386
 387 # C++ bindings want stoi and stod.
 388 AM_COND_IF([BINDINGS_CXX], [
 389         AC_CACHE_CHECK([for stoi and stod], [sr_cv_have_stoi_stod],
 390                 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <string>]],
 391                                 [[(void) std::stoi("1"); (void) std::stod("1.0");]])],
 392                         [sr_cv_have_stoi_stod=yes], [sr_cv_have_stoi_stod=no])])
 393         AS_IF([test "x$sr_cv_have_stoi_stod" = xyes],
 394                 [AC_DEFINE([HAVE_STOI_STOD], [1],
 395                         [Specifies whether we have the stoi and stod functions.])])
 396 ])
 397
 398 #######################
 399 ##  Python bindings  ##
 400 #######################
 401
 402 AS_IF([test "x$BINDINGS_CXX" = xyes],
 403         [sr_python_missing=],
 404         [sr_python_missing='C++ bindings'])
 405
 406 # Extract major and minor version number of the Python interpreter.
 407 sr_pymajor=${PYTHON_VERSION%%.*}
 408 sr_pyminor=${PYTHON_VERSION#*.}
 409
 410 # The Python bindings need Python development files. Check for either
 411 # Python 3 or Python 2 headers depending on the interpreter version.
 412 SR_PKG_CHECK([python_dev], [SR_PKGLIBS_PYTHON],
 413         [python = $PYTHON_VERSION],
 414         [python$sr_pymajor = $PYTHON_VERSION],
 415         [python$sr_pymajor$sr_pyminor = $PYTHON_VERSION],
 416         [python-$PYTHON_VERSION = $PYTHON_VERSION])
 417
 418 AS_IF([test "x$sr_have_python_dev" != xyes],
 419         [SR_APPEND([sr_python_missing], [', '], [Headers])])
 420
 421 # PyGObject is needed for the Python bindings.
 422 SR_PKG_CHECK([pygobject], [SR_PKGLIBS_PYTHON], [pygobject-3.0 >= 3.0.0])
 423 AS_IF([test "x$sr_have_pygobject" != xyes],
 424         [SR_APPEND([sr_python_missing], [', '], [PyGObject])])
 425
 426 PKG_CHECK_EXISTS([pygobject-3.0 < 3.7.91],
 427         [AC_DEFINE([PYGOBJECT_FLAGS_SIGNED], [1],
 428                 [Whether last argument to pyg_flags_get_value() is signed.])])
 429
 430 # The Python bindings need the setuptools and numpy Python modules.
 431 # We'll let it go through even if the AX macro wasn't found, as the
 432 # Python modules may still be there.
 433 m4_ifdef([AX_PYTHON_MODULE], [
 434         AX_PYTHON_MODULE([setuptools])
 435         AX_PYTHON_MODULE([numpy])
 436 ], [
 437         HAVE_PYMOD_SETUPTOOLS=yes
 438         HAVE_PYMOD_NUMPY=yes
 439         m4_warn([unsupported],
 440                 [Missing macro AX_PYTHON_MODULE: no check for setuptools and numpy])
 441 ])
 442 AS_IF([test "x$HAVE_PYMOD_SETUPTOOLS" != xyes],
 443         [SR_APPEND([sr_python_missing], [', '], [setuptools])])
 444 AS_IF([test "x$HAVE_PYMOD_NUMPY" != xyes],
 445         [SR_APPEND([sr_python_missing], [', '], [numpy])])
 446
 447 # The Python bindings use SWIG to generate code.
 448 AC_CHECK_PROGS([SWIG], [swig swig4.0 swig3.0 swig2.0])
 449 AS_IF([test "x$SWIG" != x],
 450     AC_MSG_CHECKING([for $SWIG version])
 451     [SWIG_VERSION=`$SWIG -version 2>&1 | sed -n 's/SWIG Version //p'`]
 452     AC_MSG_RESULT([$SWIG_VERSION]))
 453 AS_IF([test "x$SWIG" = x],
 454         [SR_APPEND([sr_python_missing], [', '], [SWIG])])
 455
 456 AS_IF([test -z "$sr_python_missing"],
 457         [BINDINGS_PYTHON=$enable_python], [BINDINGS_PYTHON=no])
 458 AM_CONDITIONAL([BINDINGS_PYTHON], [test "x$BINDINGS_PYTHON" = xyes])
 459
 460 #####################
 461 ##  Ruby bindings  ##
 462 #####################
 463
 464 AS_IF([test "x$BINDINGS_CXX" = xyes],
 465         [sr_ruby_missing=],
 466         [sr_ruby_missing='C++ bindings'])
 467
 468 AC_PATH_PROGS(RUBY, ["${RUBY-ruby}"], [])
 469 AS_IF([test "x$RUBY" != x],
 470         AC_MSG_CHECKING([for Ruby version])
 471     [RUBY_VERSION=`$RUBY -e 'puts RUBY_VERSION'`]
 472     AC_MSG_RESULT([$RUBY_VERSION])
 473     [RUBY_DLEXT=`$RUBY -rrbconfig -e 'puts RbConfig::CONFIG[["DLEXT"]]'`]
 474     AC_SUBST(RUBY_DLEXT))
 475
 476 AS_IF([test "x$RUBY" = x],
 477         [SR_APPEND([sr_ruby_missing], [', '], [Ruby])])
 478
 479 # Extract major and minor version number of the Ruby interpreter.
 480 sr_rbmajor=${RUBY_VERSION%%.*}
 481 sr_rbminor=${RUBY_VERSION#*.}
 482 sr_rbminor=${sr_rbminor%%.*}
 483
 484 # The Ruby bindings need Ruby development files.
 485 SR_PKG_CHECK([ruby_dev], [SR_PKGLIBS_RUBY],
 486         [ruby],
 487         [ruby-$sr_rbmajor.$sr_rbminor])
 488
 489 AS_IF([test "x$sr_have_ruby_dev" != xyes],
 490         [SR_APPEND([sr_ruby_missing], [', '], [Headers])])
 491
 492 # The Ruby bindings use SWIG >= 3.0.8 to generate code.
 493 AS_IF([test "x$SWIG" = x],
 494         [SR_APPEND([sr_ruby_missing], [', '], [SWIG])],
 495         [AS_VERSION_COMPARE($SWIG_VERSION, "3.0.8",
 496                 [SR_APPEND([sr_ruby_missing], [', '], ['SWIG >= 3.0.8'])])])
 497
 498 AS_IF([test -z "$sr_ruby_missing"],
 499         [BINDINGS_RUBY=$enable_ruby], [BINDINGS_RUBY=no])
 500 AM_CONDITIONAL([BINDINGS_RUBY], [test "x$BINDINGS_RUBY" = xyes])
 501
 502 ####################
 503 ##  Java bindings ##
 504 ####################
 505
 506 AS_IF([test "x$BINDINGS_CXX" = xyes],
 507         [sr_java_missing=],
 508         [sr_java_missing='C++ bindings'])
 509
 510 # The Java bindings use SWIG to generate code.
 511 AS_IF([test "x$SWIG" = x],
 512         [SR_APPEND([sr_java_missing], [', '], [SWIG])])
 513
 514 # Find Java compiler and JNI includes for Java bindings.
 515 AC_CHECK_PROG([HAVE_JAVAC], [javac], [yes], [no])
 516 AS_IF([test "x$HAVE_JAVAC" = xno],
 517         [SR_APPEND([sr_java_missing], [', '], [JavaC])])
 518
 519 AC_ARG_WITH([jni-include-path],
 520         [AS_HELP_STRING([[--with-jni-include-path=DIR-LIST (space-separated)]],
 521                 [specify JNI include directories [default=detect]])],
 522         [JNI_INCLUDE_DIRS=" $withval"], [JNI_INCLUDE_DIRS=])
 523
 524 JNI_CPPFLAGS=
 525 AS_IF([test "x$enable_java$HAVE_JAVAC" = xyesyes], [
 526         AX_PROG_JAVAC
 527         AS_IF([test -z "$JNI_INCLUDE_DIRS" && test "x$cross_compiling" != xyes], [
 528                 ## Work around the totally broken logic in AX_JNI_INCLUDE_DIR:
 529                 ## If we can find jni.h without any special search path, skip
 530                 ## the execution of the broken macro to increase our chances of
 531                 ## success.
 532                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <jni.h>]], [])],,
 533                         [AX_JNI_INCLUDE_DIR])
 534         ])
 535 ])
 536 for sr_dir in $JNI_INCLUDE_DIRS
 537 do
 538         SR_APPEND([JNI_CPPFLAGS], ["-I$sr_dir"])
 539 done
 540 AC_SUBST([JNI_CPPFLAGS])
 541
 542 sr_save_cppflags=$CPPFLAGS
 543 SR_APPEND([CPPFLAGS], [$JNI_CPPFLAGS])
 544 AC_CHECK_HEADER([jni.h],,
 545         [SR_APPEND([sr_java_missing], [', '], ['JNI headers'])])
 546 CPPFLAGS=$sr_save_cppflags
 547
 548 AS_IF([test -z "$sr_java_missing"],
 549         [BINDINGS_JAVA=$enable_java], [BINDINGS_JAVA=no])
 550 AM_CONDITIONAL([BINDINGS_JAVA], [test "x$BINDINGS_JAVA" = xyes])
 551
 552 ##############################
 553 ##  Finalize configuration  ##
 554 ##############################
 555
 556 # Add mandatory dependencies to module list.
 557 SR_APPEND([SR_PKGLIBS], ['libzip >= 0.10'])
 558 AC_SUBST([SR_PKGLIBS])
 559
 560 # Retrieve the compile and link flags for all modules combined.
 561 # Also, bail out at this point if any module dependency is not met.
 562 PKG_CHECK_MODULES([LIBSIGROK], [glib-2.0 >= 2.32.0 $SR_PKGLIBS])
 563 PKG_CHECK_MODULES([TESTS], [$SR_PKGLIBS_TESTS glib-2.0 $SR_PKGLIBS])
 564
 565 # SR_PKGLIBS_CXX may be empty, so only invoke these checks when
 566 # the C++ bindings are enabled.
 567 AM_COND_IF([BINDINGS_CXX], [
 568         PKG_CHECK_MODULES([LIBSIGROKCXX], [$SR_PKGLIBS_CXX])
 569         PKG_CHECK_MODULES([PYSIGROK], [$SR_PKGLIBS_PYTHON $SR_PKGLIBS_CXX])
 570         PKG_CHECK_MODULES([RBSIGROK], [$SR_PKGLIBS_RUBY $SR_PKGLIBS_CXX], [AC_SUBST(RBSIGROK_EXTDIR, "lib/$($PKG_CONFIG --variable=sitearch $SR_PKGLIBS_RUBY)/$($PKG_CONFIG --variable=RUBY_BASE_NAME $SR_PKGLIBS_RUBY)/vendor_ruby/$($PKG_CONFIG --variable=ruby_version $SR_PKGLIBS_RUBY)")])
 571 ])
 572
 573 # Check for specific libusb features, now that we know the CFLAGS.
 574 AC_LANG([C])
 575 sr_save_cflags=$CFLAGS
 576 sr_save_libs=$LIBS
 577 CFLAGS="$LIBSIGROK_CFLAGS $CFLAGS"
 578 LIBS="$LIBSIGROK_LIBS $LIBS"
 579 AC_CHECK_TYPES([libusb_os_handle],
 580         [sr_have_libusb_os_handle=yes], [sr_have_libusb_os_handle=no],
 581         [[#include <libusb.h>]])
 582 AC_CHECK_FUNCS([zip_discard])
 583 LIBS=$sr_save_libs
 584 CFLAGS=$sr_save_cflags
 585
 586 AM_COND_IF([NEED_USB], [AS_CASE([$sr_have_libusb_os_handle:$host_os], [no:mingw*],
 587         [AC_MSG_ERROR([Windows builds require the event-abstraction branch of libusb])])])
 588
 589 sr_glib_version=`$PKG_CONFIG --modversion glib-2.0 2>&AS_MESSAGE_LOG_FD`
 590 sr_libzip_version=`$PKG_CONFIG --modversion libzip 2>&AS_MESSAGE_LOG_FD`
 591
 592 AC_DEFINE_UNQUOTED([CONF_LIBZIP_VERSION], ["$sr_libzip_version"],
 593         [Build-time version of libzip.])
 594 AC_DEFINE_UNQUOTED([CONF_HOST], ["$host"],
 595         [The canonical host libsigrok will run on.])
 596
 597 AC_CONFIG_FILES([Makefile libsigrok.pc bindings/cxx/libsigrokcxx.pc])
 598
 599 AC_OUTPUT
 600
 601 # Prepare bindings report messages.
 602 m4_define([SR_PREPARE_BINDING_REPORT], [
 603         sr_report_$1=
 604         test -z "$sr_$1_missing" || sr_report_$1=" (missing: $sr_$1_missing)"
 605         test "x$enable_$1" = xyes || sr_report_$1=' (disabled)'
 606 ])
 607 m4_map_args([SR_PREPARE_BINDING_REPORT], [cxx], [python], [ruby], [java])
 608
 609 cat >&AS_MESSAGE_FD <<_EOF
 610
 611 libsigrok configuration summary:
 612  - Package version................. $SR_PACKAGE_VERSION
 613  - Library ABI version............. $SR_LIB_VERSION
 614  - Prefix.......................... $prefix
 615  - Building on..................... $build
 616  - Building for.................... $host
 617  - Building shared / static........ $enable_shared / $enable_static
 618
 619 Compile configuration:
 620  - C compiler...................... $CC
 621  - C compiler version.............. $sr_cc_version
 622  - C compiler flags................ $CFLAGS
 623  - Additional C compiler flags..... $SR_EXTRA_CFLAGS
 624  - C compiler warnings............. $SR_WFLAGS
 625  - C++ compiler.................... $CXX
 626  - C++ compiler version............ $sr_cxx_version
 627  - C++ compiler flags.............. $CXXFLAGS
 628  - C++ compiler warnings........... $SR_WXXFLAGS
 629  - Linker flags.................... $LDFLAGS
 630
 631 Detected libraries (required):
 632  - glib-2.0 >= 2.32.0.............. $sr_glib_version
 633  - libzip >= 0.10.................. $sr_libzip_version
 634
 635 Detected libraries (optional):
 636 $sr_pkglibs_summary
 637 Enabled hardware drivers:
 638 $sr_driver_summary
 639 Enabled serial communication transports:
 640   - serial comm ................... $sr_have_serial_comm
 641   - libserialport ................. $sr_have_libserialport
 642   - hidapi ........................ $sr_have_libhidapi
 643   - bluetooth ..................... $sr_have_bluetooth
 644   - bluez ......................... $sr_have_libbluez
 645
 646 Enabled SCPI backends:
 647  - TCP............................. yes
 648  - RPC............................. $sr_cv_have_rpc
 649  - serial.......................... $sr_have_serial_comm
 650  - VISA............................ $sr_have_librevisa
 651  - GPIB............................ $sr_have_libgpib
 652  - USBTMC.......................... $sr_have_libusb
 653
 654 Enabled language bindings:
 655  - C++............................. $BINDINGS_CXX$sr_report_cxx
 656  - Python.......................... $BINDINGS_PYTHON$sr_report_python
 657  - Ruby............................ $BINDINGS_RUBY$sr_report_ruby
 658  - Java............................ $BINDINGS_JAVA$sr_report_java
 659
 660 _EOF
 661
 662 # Emit a warning if the C++ bindings are not being built.
 663 AM_COND_IF([BINDINGS_CXX], [], [
 664 cat >&AS_MESSAGE_FD <<_EOF
 665 ===============================================================================
 666 WARNING WARNING WARNING WARNING WARNING WARNING WARNING WARNING WARNING WARNING
 667 ===============================================================================
 668 ===                                                                         ===
 669 ===         The libsigrok C++ bindings are not being built since you        ===
 670 ===             are missing one or more dependencies (see above)!           ===
 671 ===                                                                         ===
 672 ===      This means you won't be able to compile frontends that require     ===
 673 ===  the C++ bindings (such as PulseView)! You also won't be able to build  ===
 674 ===     other bindings and frontends using those (such as sigrok-meter)!    ===
 675 ===                                                                         ===
 676 ===============================================================================
 677 WARNING WARNING WARNING WARNING WARNING WARNING WARNING WARNING WARNING WARNING
 678 ===============================================================================
 679
 680 _EOF
 681 ])