configure.ac

   1 ##
   2 ## This file is part of the libsigrok project.
   3 ##
   4 ## Copyright (C) 2010-2012 Bert Vermeulen <bert@biot.com>
   5 ## Copyright (C) 2012 Alexandru Gagniuc <mr.nuke.me@gmail.com>
   6 ##
   7 ## This program is free software: you can redistribute it and/or modify
   8 ## it under the terms of the GNU General Public License as published by
   9 ## the Free Software Foundation, either version 3 of the License, or
  10 ## (at your option) any later version.
  11 ##
  12 ## This program is distributed in the hope that it will be useful,
  13 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ## GNU General Public License for more details.
  16 ##
  17 ## You should have received a copy of the GNU General Public License
  18 ## along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19 ##
  20
  21 # We require at least autoconf 2.63 (AC_INIT format changed there).
  22 AC_PREREQ([2.63])
  23
  24 AC_INIT([libsigrok], [0.6.0],
  25         [sigrok-devel@lists.sourceforge.net],
  26         [libsigrok], [http://www.sigrok.org])
  27 AC_CONFIG_MACRO_DIR([m4])
  28 AC_CONFIG_AUX_DIR([autostuff])
  29 AC_CONFIG_HEADERS([config.h include/libsigrok/version.h])
  30
  31 # We require at least automake 1.11 (needed for 'silent rules').
  32 AM_INIT_AUTOMAKE([1.11 -Wall -Werror no-define nostdinc subdir-objects check-news color-tests])
  33 AM_SILENT_RULES([yes])
  34 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  35
  36 AC_CANONICAL_HOST
  37
  38 # Checks for programs.
  39 AC_PROG_CC
  40 AC_PROG_CXX
  41 AC_PROG_INSTALL
  42 AC_PROG_LN_S
  43
  44 # Required for per-target flags or subdir-objects with C sources.
  45 AM_PROG_CC_C_O
  46
  47 # Set the standard the C library headers should conform to.
  48 AH_VERBATIM([_POSIX_C_SOURCE], [/* The targeted POSIX standard. */
  49 #ifndef _POSIX_C_SOURCE
  50 # define _POSIX_C_SOURCE 200112L
  51 #endif])
  52
  53 # Get compiler versions.
  54 SR_PROG_VERSION([$CC], [sr_cc_version])
  55 SR_PROG_VERSION([$CXX], [sr_cxx_version])
  56
  57 # Check for optional make features.
  58 SR_PROG_MAKE_ORDER_ONLY
  59
  60 # Initialize libtool.
  61 LT_INIT
  62
  63 # Set up the libsigrok version defines.
  64 SR_PKG_VERSION_SET([SR_PACKAGE_VERSION], [AC_PACKAGE_VERSION])
  65
  66 # Library version for libsigrok (NOT the same as the package version).
  67 # Carefully read the libtool docs before updating these numbers!
  68 # The algorithm for determining which number to change (and how) is nontrivial!
  69 # http://www.gnu.org/software/libtool/manual/libtool.html#Updating-version-info
  70 # Format: current:revision:age.
  71 SR_LIB_VERSION_SET([SR_LIB_VERSION], [4:0:0])
  72
  73 AM_CONDITIONAL([WIN32], [test -z "${host_os##mingw*}" || test -z "${host_os##cygwin*}"])
  74
  75 #############################
  76 ##  Optional dependencies  ##
  77 #############################
  78
  79 AC_LANG([C])
  80
  81 # Initialize pkg-config.
  82 # We require at least 0.22, as "Requires.private" behaviour changed there.
  83 PKG_PROG_PKG_CONFIG([0.22])
  84
  85 # Keep track of all checked modules so we can list them at the end.
  86 SR_PKG_CHECK_SUMMARY([sr_pkglibs_summary])
  87
  88 # Collect the pkg-config module names of all dependencies in SR_PKGLIBS.
  89 # These are used to derive the compiler flags and for the "Requires.private"
  90 # field in the generated libsigrok.pc file.
  91 SR_VAR_OPT_PKG([SR_PKGLIBS], [sr_deps_avail])
  92 SR_PKGLIBS_TESTS=
  93 SR_PKGLIBS_CXX=
  94 SR_PKGLIBS_PYTHON=
  95 SR_PKGLIBS_RUBY=
  96 SR_EXTRA_LIBS=
  97 SR_EXTRA_CXX_LIBS=
  98
  99 SR_ARG_OPT_PKG([zlib], [ZLIB], , [zlib])
 100 AM_CONDITIONAL([HAVE_ZLIB], [test "x$sr_have_zlib" = xyes])
 101 AM_COND_IF([HAVE_ZLIB], [
 102         SR_APPEND([sr_deps_avail], [crc32 zlib])
 103         SR_PREPEND([SR_EXTRA_LIBS], [-lz])
 104 ])
 105
 106 AM_CONDITIONAL([HAVE_INPUT_STF], [test "x$sr_have_zlib" = xyes])
 107 AM_COND_IF([HAVE_INPUT_STF], [
 108         AC_DEFINE([HAVE_INPUT_STF], [1], [Is the STF input module supported?])
 109 ])
 110
 111 SR_ARG_OPT_PKG([libserialport], [LIBSERIALPORT], ,
 112         [libserialport >= 0.1.1])
 113
 114 SR_ARG_OPT_PKG([libftdi], [LIBFTDI], , [libftdi1 >= 1.0])
 115
 116 # pkg-config file names: MinGW/MacOSX: hidapi; Linux: hidapi-hidraw/-libusb
 117 SR_ARG_OPT_PKG([libhidapi], [LIBHIDAPI], ,
 118         [hidapi >= 0.8.0], [hidapi-hidraw >= 0.8.0], [hidapi-libusb >= 0.8.0])
 119
 120 SR_ARG_OPT_PKG([libbluez], [LIBBLUEZ], , [bluez >= 4.0])
 121
 122 SR_ARG_OPT_PKG([libnettle], [LIBNETTLE], , [nettle])
 123
 124 # FreeBSD comes with an "integrated" libusb-1.0-style USB API.
 125 # This means libusb-1.0 is always available; no need to check for it.
 126 # On Windows, require the latest version we can get our hands on,
 127 # until the new generic event handling has seen an official release.
 128 AS_CASE([$host_os],
 129         [freebsd*], [sr_libusb_req='libusb-1.0' sr_have_libusb=yes],
 130         [mingw*], [sr_libusb_req='libusb-1.0 >= 1.0.20'],
 131         [sr_libusb_req='libusb-1.0 >= 1.0.16'])
 132
 133 SR_ARG_OPT_PKG([libusb], [LIBUSB_1_0], [NEED_USB],
 134         [$sr_libusb_req])
 135
 136 SR_ARG_OPT_PKG([librevisa], [LIBREVISA], [NEED_VISA],
 137         [librevisa >= 0.0.20130412])
 138
 139 SR_ARG_OPT_PKG([libgpib], [LIBGPIB], [NEED_GPIB],
 140         [libgpib])
 141
 142 SR_ARG_OPT_CHECK([libieee1284], [LIBIEEE1284],, [
 143         sr_save_LIBS=$LIBS
 144         LIBS="-lieee1284 $LIBS"
 145         AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <ieee1284.h>]],
 146                                 [[(void) ieee1284_open(0, 0, 0);]])],
 147                 [sr_have_libieee1284=yes], [sr_have_libieee1284=no])
 148         LIBS=$sr_save_LIBS
 149 ])
 150 AS_IF([test "x$sr_have_libieee1284" = xyes],
 151         [SR_PREPEND([SR_EXTRA_LIBS], [-lieee1284])])
 152
 153 SR_ARG_OPT_PKG([libgio], [LIBGIO], , [gio-2.0 >= 2.24.0])
 154
 155 # See if any of the (potentially platform specific) libs are available
 156 # which provide some means of Bluetooth communication.
 157 AS_IF([test "x$sr_have_libbluez" = xyes],
 158         sr_have_bluetooth=yes, sr_have_bluetooth=no)
 159 AS_IF([test "x$sr_have_bluetooth" = xyes],
 160         [AC_DEFINE([HAVE_BLUETOOTH], [1], [Specifies whether Bluetooth communication is supported.])])
 161 AS_IF([test "x$sr_have_bluetooth" = xyes],
 162         [SR_APPEND([sr_deps_avail], [bluetooth_comm])])
 163
 164 AS_IF([test "x$sr_have_libserialport" = xyes -o "x$sr_have_libhidapi" = xyes -o "x$sr_have_bluetooth" = xyes],
 165         sr_have_serial_comm=yes, sr_have_serial_comm=no)
 166 AS_IF([test "x$sr_have_serial_comm" = xyes],
 167         [AC_DEFINE([HAVE_SERIAL_COMM], [1], [Specifies whether serial communication is supported.])])
 168 AS_IF([test "x$sr_have_serial_comm" = xyes],
 169         [SR_APPEND([sr_deps_avail], [serial_comm])])
 170 AM_CONDITIONAL([NEED_SERIAL], [test "x$sr_have_serial_comm" = xyes])
 171
 172 ######################
 173 ##  Feature checks  ##
 174 ######################
 175
 176 # The Check unit testing framework is optional. Disable if not found.
 177 SR_PKG_CHECK([check], [SR_PKGLIBS_TESTS], [check >= 0.9.4])
 178 AM_CONDITIONAL([HAVE_CHECK], [test "x$sr_have_check" = xyes])
 179
 180 # Enable the C99 standard if possible, and enforce the use
 181 # of SR_API to explicitly mark all public API functions.
 182 SR_EXTRA_CFLAGS=
 183 SR_CHECK_COMPILE_FLAGS([SR_EXTRA_CFLAGS], [C99], [-std=c99 -c99 -AC99 -qlanglvl=extc99])
 184 SR_CHECK_COMPILE_FLAGS([SR_EXTRA_CFLAGS], [visibility], [-fvisibility=hidden])
 185
 186 SR_ARG_ENABLE_WARNINGS([SR_WFLAGS], [-Wall], [-Wall -Wextra -Wmissing-prototypes])
 187
 188 # Check host characteristics.
 189 AC_SYS_LARGEFILE
 190 AC_C_BIGENDIAN
 191
 192 AC_CHECK_HEADERS([sys/mman.h], [SR_APPEND([sr_deps_avail], [sys_mman_h])])
 193 AC_CHECK_HEADERS([sys/ioctl.h], [SR_APPEND([sr_deps_avail], [sys_ioctl_h])])
 194 AC_CHECK_HEADERS([sys/timerfd.h], [SR_APPEND([sr_deps_avail], [sys_timerfd_h])])
 195
 196 # We need to link against the Winsock2 library for SCPI over TCP.
 197 AS_CASE([$host_os], [mingw*], [SR_PREPEND([SR_EXTRA_LIBS], [-lws2_32])])
 198
 199 # libm (the standard math library) is always needed.
 200 SR_SEARCH_LIBS([SR_EXTRA_LIBS], [pow], [m])
 201
 202 # RPC is only needed for VXI support.
 203 AC_CACHE_CHECK([for SunRPC support], [sr_cv_have_sunrpc],
 204         [AC_LINK_IFELSE([AC_LANG_PROGRAM(
 205                         [[#include <rpc/rpc.h>]m4_newline[CLIENT *rpc_test(void);]],
 206                         [[(void) clnt_create("", 0, 0, "");]])],
 207                 [RPC_CFLAGS=""; RPC_LIBS=""; sr_cv_have_sunrpc=yes],
 208                 [sr_cv_have_sunrpc=no])])
 209 PKG_CHECK_MODULES([TIRPC],
 210         [libtirpc],
 211         [RPC_CFLAGS=$TIRPC_CFLAGS; SR_PREPEND([SR_EXTRA_LIBS], [$TIRPC_LIBS]); sr_cv_have_tirpc=yes],
 212         [sr_cv_have_tirpc=no])
 213 AS_IF([test "x$sr_cv_have_sunrpc" = xyes -o "x$sr_cv_have_tirpc" = xyes],
 214         [sr_cv_have_rpc=yes], [sr_cv_have_rpc=no])
 215
 216 AC_SUBST(RPC_CFLAGS)
 217 AC_SUBST(RPC_LIBS)
 218
 219 AS_IF([test "x$sr_cv_have_rpc" = xyes],
 220         [AC_DEFINE([HAVE_RPC], [1], [Specifies whether we have RPC support (either by SunRPC or libtirpc).])])
 221
 222 # VXI support is only compiled if RPC support was found.
 223 AM_CONDITIONAL([NEED_RPC], [test "x$sr_cv_have_rpc" = xyes])
 224
 225 # Check for compiler support of 128 bit integers
 226 AC_CHECK_TYPES([__int128_t, __uint128_t], [], [], [])
 227
 228
 229 #######################
 230 ##  miniLZO related  ##
 231 #######################
 232 # These were taken from the README.LZO file in the miniLZO archive.
 233
 234 AC_CHECK_TYPE(ptrdiff_t,long)
 235 AC_TYPE_SIZE_T
 236 AC_CHECK_SIZEOF(short)
 237 AC_CHECK_SIZEOF(int)
 238 AC_CHECK_SIZEOF(long)
 239 AC_CHECK_SIZEOF(long long)
 240 AC_CHECK_SIZEOF(__int64)
 241 AC_CHECK_SIZEOF(void *)
 242 AC_CHECK_SIZEOF(size_t)
 243 AC_CHECK_SIZEOF(ptrdiff_t)
 244
 245 AC_C_CONST
 246
 247 AC_CHECK_FUNCS(memcmp memcpy memmove memset)
 248
 249 ########################
 250 ##  Hardware drivers  ##
 251 ########################
 252
 253 # Keep track of all drivers so we can list them at the end.
 254 SR_VAR_SUMMARY([sr_driver_summary])
 255
 256 # Check whether the sr_deps_avail list contains all of the arguments.
 257 # Unavailable dependencies are collected in sr_deps_missing.
 258 sr_check_driver_deps() {
 259         sr_deps_missing=
 260         for sr_dep
 261         do
 262                 AS_CASE([" $sr_deps_avail "], [*" $sr_dep "*],,
 263                         [SR_APPEND([sr_deps_missing], [', '], [$sr_dep])])
 264         done
 265         test -z "$sr_deps_missing" || return 1
 266 }
 267
 268 AC_ARG_ENABLE([all-drivers],
 269         [AS_HELP_STRING([--enable-all-drivers],
 270                         [enable all drivers by default [default=yes]])],
 271         [], [enable_all_drivers=yes])
 272
 273 ## _SR_DRIVER(Device name, driver-name, var-name, [dependencies...])
 274 m4_define([_SR_DRIVER], [
 275         AC_ARG_ENABLE([$2],
 276                 [AS_HELP_STRING([--enable-$2], [enable $1 support])],
 277                 [$3=$enableval], [$3=$enable_all_drivers])
 278
 279         AS_IF([test "x[$]$3" = xyes], [sr_hw_info=yes[]m4_ifval([$4], [
 280                 sr_check_driver_deps $4 \
 281                         || $3=no sr_hw_info="no (missing: $sr_deps_missing)"
 282         ])], [sr_hw_info='no (disabled)'])
 283         sr_driver_summary_append "$2" "$sr_hw_info"
 284
 285         AM_CONDITIONAL([$3], [test "x[$]$3" = xyes])
 286         AM_COND_IF([$3], [AC_DEFINE([HAVE_$3], [1], [Whether to support $1 device.]) AC_DEFINE([HAVE_DRIVERS], [1], [Whether at least one driver is enabled.])])
 287 ])
 288
 289 ## SR_DRIVER(Device name, driver-name, [dependencies...])
 290 m4_define([SR_DRIVER],
 291         [_SR_DRIVER([$1], [$2], m4_expand([AS_TR_CPP([HW_$2])]), [$3])])
 292
 293 SR_DRIVER([Agilent DMM], [agilent-dmm], [serial_comm])
 294 SR_DRIVER([Appa 55II], [appa-55ii], [serial_comm])
 295 SR_DRIVER([Arachnid Labs Re:load Pro], [arachnid-labs-re-load-pro], [serial_comm])
 296 SR_DRIVER([ASIX SIGMA/SIGMA2], [asix-sigma], [libftdi])
 297 SR_DRIVER([ASIX OMEGA RTM CLI], [asix-omega-rtm-cli])
 298 SR_DRIVER([Atten PPS3xxx], [atten-pps3xxx], [serial_comm])
 299 SR_DRIVER([BayLibre ACME], [baylibre-acme], [sys_timerfd_h])
 300 SR_DRIVER([BeagleLogic], [beaglelogic], [sys_mman_h sys_ioctl_h])
 301 SR_DRIVER([CEM DT-885x], [cem-dt-885x], [serial_comm])
 302 SR_DRIVER([Center 3xx], [center-3xx], [serial_comm])
 303 SR_DRIVER([ChronoVu LA], [chronovu-la], [libusb libftdi])
 304 SR_DRIVER([Colead SLM], [colead-slm], [serial_comm])
 305 SR_DRIVER([Conrad DIGI 35 CPU], [conrad-digi-35-cpu], [serial_comm])
 306 SR_DRIVER([dcttech usbrelay], [dcttech-usbrelay], [libhidapi])
 307 SR_DRIVER([demo], [demo])
 308 SR_DRIVER([DreamSourceLab DSLogic], [dreamsourcelab-dslogic], [libusb])
 309 SR_DRIVER([Fluke 45], [fluke-45])
 310 SR_DRIVER([Fluke DMM], [fluke-dmm], [serial_comm])
 311 SR_DRIVER([FTDI LA], [ftdi-la], [libusb libftdi])
 312 SR_DRIVER([fx2lafw], [fx2lafw], [libusb])
 313 SR_DRIVER([GMC MH 1x/2x], [gmc-mh-1x-2x], [serial_comm])
 314 SR_DRIVER([GW Instek GDS-800], [gwinstek-gds-800], [serial_comm])
 315 SR_DRIVER([GW Instek GPD], [gwinstek-gpd], [serial_comm])
 316 SR_DRIVER([Hameg HMO], [hameg-hmo])
 317 SR_DRIVER([Hantek 4032L], [hantek-4032l], [libusb])
 318 SR_DRIVER([Hantek 6xxx], [hantek-6xxx], [libusb])
 319 SR_DRIVER([Hantek DSO], [hantek-dso], [libusb])
 320 SR_DRIVER([HP 3457A], [hp-3457a])
 321 SR_DRIVER([HP 3478A], [hp-3478a], [libgpib])
 322 SR_DRIVER([hp-59306a], [hp-59306a])
 323 SR_DRIVER([Hung-Chang DSO-2100], [hung-chang-dso-2100], [libieee1284])
 324 SR_DRIVER([Ikalogic Scanalogic-2], [ikalogic-scanalogic2], [libusb])
 325 SR_DRIVER([Ikalogic Scanaplus], [ikalogic-scanaplus], [libftdi])
 326 SR_DRIVER([IPDBG LA], [ipdbg-la])
 327 SR_DRIVER([ITECH IT8500], [itech-it8500], [serial_comm])
 328 SR_DRIVER([Kecheng KC-330B], [kecheng-kc-330b], [libusb])
 329 SR_DRIVER([KERN scale], [kern-scale], [serial_comm])
 330 SR_DRIVER([Kingst LA2016], [kingst-la2016], [libusb])
 331 SR_DRIVER([Korad KAxxxxP], [korad-kaxxxxp], [serial_comm])
 332 SR_DRIVER([Lascar EL-USB], [lascar-el-usb], [libusb])
 333 SR_DRIVER([LeCroy LogicStudio], [lecroy-logicstudio], [libusb])
 334 SR_DRIVER([LeCroy X-Stream], [lecroy-xstream])
 335 SR_DRIVER([Manson HCS-3xxx], [manson-hcs-3xxx], [serial_comm])
 336 SR_DRIVER([Mastech MS6514], [mastech-ms6514], [serial_comm])
 337 SR_DRIVER([maynuo-m97], [maynuo-m97])
 338 SR_DRIVER([MIC 985xx], [mic-985xx], [serial_comm])
 339 SR_DRIVER([Microchip PICkit2], [microchip-pickit2], [libusb])
 340 SR_DRIVER([Mooshimeter DMM], [mooshimeter-dmm], [bluetooth_comm libgio])
 341 SR_DRIVER([Motech LPS 30x], [motech-lps-30x], [serial_comm])
 342 SR_DRIVER([Norma DMM], [norma-dmm], [serial_comm])
 343 SR_DRIVER([OpenBench Logic Sniffer], [openbench-logic-sniffer], [serial_comm])
 344 SR_DRIVER([PCE PCE-322A], [pce-322a], [serial_comm])
 345 SR_DRIVER([Pipistrello-OLS], [pipistrello-ols], [libftdi])
 346 SR_DRIVER([RDTech DPSxxxx/DPHxxxx], [rdtech-dps], [serial_comm])
 347 SR_DRIVER([RDTech UMXX], [rdtech-um], [serial_comm])
 348 SR_DRIVER([RDTech TCXX], [rdtech-tc], [serial_comm libnettle])
 349 SR_DRIVER([Rigol DS], [rigol-ds])
 350 SR_DRIVER([Rigol DG], [rigol-dg])
 351 SR_DRIVER([Rohde&Schwarz SME-0x], [rohde-schwarz-sme-0x], [serial_comm])
 352 SR_DRIVER([Saleae Logic16], [saleae-logic16], [libusb])
 353 SR_DRIVER([Saleae Logic Pro], [saleae-logic-pro], [libusb])
 354 SR_DRIVER([SCPI DMM], [scpi-dmm])
 355 SR_DRIVER([SCPI PPS], [scpi-pps])
 356 SR_DRIVER([serial DMM], [serial-dmm], [serial_comm])
 357 SR_DRIVER([serial LCR], [serial-lcr], [serial_comm])
 358 SR_DRIVER([Siglent SDS], [siglent-sds])
 359 SR_DRIVER([Sysclk LWLA], [sysclk-lwla], [libusb])
 360 SR_DRIVER([Sysclk SLA5032], [sysclk-sla5032], [libusb])
 361 SR_DRIVER([Teleinfo], [teleinfo], [serial_comm])
 362 SR_DRIVER([Testo], [testo], [libusb])
 363 SR_DRIVER([Tondaj SL-814], [tondaj-sl-814], [serial_comm])
 364 SR_DRIVER([UNI-T DMM], [uni-t-dmm], [libusb])
 365 SR_DRIVER([UNI-T UT181A], [uni-t-ut181a], [serial_comm])
 366 SR_DRIVER([UNI-T UT32x], [uni-t-ut32x], [serial_comm])
 367 SR_DRIVER([Yokogawa DL/DLM], [yokogawa-dlm])
 368 SR_DRIVER([ZEROPLUS Logic Cube], [zeroplus-logic-cube], [libusb])
 369 SR_DRIVER([ZKETECH EBD-USB], [zketech-ebd-usb], [serial_comm])
 370
 371 ###############################
 372 ##  Language bindings setup  ##
 373 ###############################
 374
 375 AC_LANG([C++])
 376 SR_ARG_ENABLE_WARNINGS([SR_WXXFLAGS], [-Wall], [-Wall -Wextra])
 377
 378 AC_ARG_ENABLE([bindings],
 379         [AS_HELP_STRING([--enable-bindings], [build language bindings [default=yes]])],
 380         [], [enable_bindings=yes])
 381
 382 AC_ARG_ENABLE([cxx],
 383         [AS_HELP_STRING([--enable-cxx], [build C++ bindings [default=yes]])],
 384         [], [enable_cxx=$enable_bindings])
 385
 386 AC_ARG_ENABLE([python],
 387         [AS_HELP_STRING([--enable-python], [build Python bindings [default=yes]])],
 388         [], [enable_python=$enable_bindings])
 389
 390 AC_ARG_ENABLE([ruby],
 391         [AS_HELP_STRING([--enable-ruby], [build Ruby bindings [default=yes]])],
 392         [], [enable_ruby=$enable_bindings])
 393
 394 AC_ARG_ENABLE([java],
 395         [AS_HELP_STRING([--enable-java], [build Java bindings [default=yes]])],
 396         [], [enable_java=$enable_bindings])
 397
 398 ####################
 399 ##  C++ bindings  ##
 400 ####################
 401
 402 sr_cxx_missing=
 403
 404 # Check if the C++ compiler supports the C++11 standard.
 405 AX_CXX_COMPILE_STDCXX([11], [noext], [optional])
 406 AS_IF([test "x$HAVE_CXX11" != x1],
 407         [SR_APPEND([sr_cxx_missing], [', '], ['C++11'])])
 408
 409 # The C++ bindings need glibmm.
 410 SR_PKG_CHECK([glibmm], [SR_PKGLIBS_CXX], [glibmm-2.4 >= 2.32.0])
 411 AS_IF([test "x$sr_have_glibmm" != xyes],
 412         [SR_APPEND([sr_cxx_missing], [', '], [glibmm])])
 413
 414 # The C++ bindings use Doxygen to parse libsigrok symbols.
 415 AC_CHECK_PROG([HAVE_DOXYGEN], [doxygen], [yes], [no])
 416 AS_IF([test "x$HAVE_DOXYGEN" != xyes],
 417         [SR_APPEND([sr_cxx_missing], [', '], [Doxygen])])
 418
 419 # Link C++ code with gnustl_shared if it exists (Android)
 420 SR_SEARCH_LIBS([SR_EXTRA_CXX_LIBS], [__cxa_throw], [gnustl_shared])
 421
 422 # Python is needed for the C++ bindings.
 423 AM_PATH_PYTHON([2.7],
 424         [HAVE_PYTHON=yes],
 425         [HAVE_PYTHON=no
 426         SR_APPEND([sr_cxx_missing], [', '], [Python])])
 427
 428 AS_IF([test -z "$sr_cxx_missing"],
 429         [BINDINGS_CXX=$enable_cxx], [BINDINGS_CXX=no])
 430 AM_CONDITIONAL([BINDINGS_CXX], [test "x$BINDINGS_CXX" = xyes])
 431
 432 # C++ bindings want stoi and stod.
 433 AM_COND_IF([BINDINGS_CXX], [
 434         AC_CACHE_CHECK([for stoi and stod], [sr_cv_have_stoi_stod],
 435                 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <string>]],
 436                                 [[(void) std::stoi("1"); (void) std::stod("1.0");]])],
 437                         [sr_cv_have_stoi_stod=yes], [sr_cv_have_stoi_stod=no])])
 438         AS_IF([test "x$sr_cv_have_stoi_stod" = xyes],
 439                 [AC_DEFINE([HAVE_STOI_STOD], [1],
 440                         [Specifies whether we have the stoi and stod functions.])])
 441 ])
 442
 443 #######################
 444 ##  Python bindings  ##
 445 #######################
 446
 447 AS_IF([test "x$BINDINGS_CXX" = xyes],
 448         [sr_python_missing=],
 449         [sr_python_missing='C++ bindings'])
 450
 451 # Extract major and minor version number of the Python interpreter.
 452 sr_pymajor=${PYTHON_VERSION%%.*}
 453 sr_pyminor=${PYTHON_VERSION#*.}
 454
 455 # The Python bindings need Python development files. Check for either
 456 # Python 3 or Python 2 headers depending on the interpreter version.
 457 SR_PKG_CHECK([python_dev], [SR_PKGLIBS_PYTHON],
 458         [python = $PYTHON_VERSION],
 459         [python$sr_pymajor = $PYTHON_VERSION],
 460         [python$sr_pymajor$sr_pyminor = $PYTHON_VERSION],
 461         [python-$PYTHON_VERSION = $PYTHON_VERSION])
 462
 463 AS_IF([test "x$sr_have_python_dev" != xyes],
 464         [SR_APPEND([sr_python_missing], [', '], [Headers])])
 465
 466 # PyGObject is needed for the Python bindings.
 467 SR_PKG_CHECK([pygobject], [SR_PKGLIBS_PYTHON], [pygobject-3.0 >= 3.0.0])
 468 AS_IF([test "x$sr_have_pygobject" != xyes],
 469         [SR_APPEND([sr_python_missing], [', '], [PyGObject])])
 470
 471 PKG_CHECK_EXISTS([pygobject-3.0 < 3.7.91],
 472         [AC_DEFINE([PYGOBJECT_FLAGS_SIGNED], [1],
 473                 [Whether last argument to pyg_flags_get_value() is signed.])])
 474
 475 # The Python bindings need the setuptools and numpy Python modules.
 476 # We'll let it go through even if the AX macro wasn't found, as the
 477 # Python modules may still be there.
 478 m4_ifdef([AX_PYTHON_MODULE], [
 479         AX_PYTHON_MODULE([setuptools])
 480         AX_PYTHON_MODULE([numpy])
 481 ], [
 482         HAVE_PYMOD_SETUPTOOLS=yes
 483         HAVE_PYMOD_NUMPY=yes
 484         m4_warn([unsupported],
 485                 [Missing macro AX_PYTHON_MODULE: no check for setuptools and numpy])
 486 ])
 487 AS_IF([test "x$HAVE_PYMOD_SETUPTOOLS" != xyes],
 488         [SR_APPEND([sr_python_missing], [', '], [setuptools])])
 489 AS_IF([test "x$HAVE_PYMOD_NUMPY" != xyes],
 490         [SR_APPEND([sr_python_missing], [', '], [numpy])])
 491
 492 # The Python bindings use SWIG to generate code.
 493 AC_CHECK_PROGS([SWIG], [swig swig4.0 swig3.0 swig2.0])
 494 AS_IF([test "x$SWIG" != x],
 495     AC_MSG_CHECKING([for $SWIG version])
 496     [SWIG_VERSION=`$SWIG -version 2>&1 | sed -n 's/SWIG Version //p'`]
 497     AC_MSG_RESULT([$SWIG_VERSION]))
 498 AS_IF([test "x$SWIG" = x],
 499         [SR_APPEND([sr_python_missing], [', '], [SWIG])])
 500
 501 AS_IF([test -z "$sr_python_missing"],
 502         [BINDINGS_PYTHON=$enable_python], [BINDINGS_PYTHON=no])
 503 AM_CONDITIONAL([BINDINGS_PYTHON], [test "x$BINDINGS_PYTHON" = xyes])
 504
 505 #####################
 506 ##  Ruby bindings  ##
 507 #####################
 508
 509 AS_IF([test "x$BINDINGS_CXX" = xyes],
 510         [sr_ruby_missing=],
 511         [sr_ruby_missing='C++ bindings'])
 512
 513 AC_PATH_PROGS(RUBY, ["${RUBY-ruby}"], [])
 514 AS_IF([test "x$RUBY" != x],
 515         AC_MSG_CHECKING([for Ruby version])
 516     [RUBY_VERSION=`$RUBY -e 'puts RUBY_VERSION'`]
 517     AC_MSG_RESULT([$RUBY_VERSION])
 518     [RUBY_DLEXT=`$RUBY -rrbconfig -e 'puts RbConfig::CONFIG[["DLEXT"]]'`]
 519     AC_SUBST(RUBY_DLEXT))
 520
 521 AS_IF([test "x$RUBY" = x],
 522         [SR_APPEND([sr_ruby_missing], [', '], [Ruby])])
 523
 524 # Extract major and minor version number of the Ruby interpreter.
 525 sr_rbmajor=${RUBY_VERSION%%.*}
 526 sr_rbminor=${RUBY_VERSION#*.}
 527 sr_rbminor=${sr_rbminor%%.*}
 528
 529 # The Ruby bindings need Ruby development files.
 530 SR_PKG_CHECK([ruby_dev], [SR_PKGLIBS_RUBY],
 531         [ruby >= 2.5.0],
 532         [ruby-$sr_rbmajor.$sr_rbminor >= 2.5.0])
 533
 534 AS_IF([test "x$sr_have_ruby_dev" != xyes],
 535         [SR_APPEND([sr_ruby_missing], [', '], [Headers])])
 536
 537 # The Ruby bindings use SWIG >= 3.0.8 to generate code.
 538 AS_IF([test "x$SWIG" = x],
 539         [SR_APPEND([sr_ruby_missing], [', '], [SWIG])],
 540         [AS_VERSION_COMPARE($SWIG_VERSION, "3.0.8",
 541                 [SR_APPEND([sr_ruby_missing], [', '], ['SWIG >= 3.0.8'])])])
 542
 543 AS_IF([test -z "$sr_ruby_missing"],
 544         [BINDINGS_RUBY=$enable_ruby], [BINDINGS_RUBY=no])
 545 AM_CONDITIONAL([BINDINGS_RUBY], [test "x$BINDINGS_RUBY" = xyes])
 546
 547 ####################
 548 ##  Java bindings ##
 549 ####################
 550
 551 AS_IF([test "x$BINDINGS_CXX" = xyes],
 552         [sr_java_missing=],
 553         [sr_java_missing='C++ bindings'])
 554
 555 # The Java bindings use SWIG to generate code.
 556 AS_IF([test "x$SWIG" = x],
 557         [SR_APPEND([sr_java_missing], [', '], [SWIG])])
 558
 559 # Find Java compiler and JNI includes for Java bindings.
 560 AC_CHECK_PROG([HAVE_JAVAC], [javac], [yes], [no])
 561 AS_IF([test "x$HAVE_JAVAC" = xno],
 562         [SR_APPEND([sr_java_missing], [', '], [JavaC])])
 563
 564 AC_ARG_WITH([jni-include-path],
 565         [AS_HELP_STRING([[--with-jni-include-path=DIR-LIST (space-separated)]],
 566                 [specify JNI include directories [default=detect]])],
 567         [JNI_INCLUDE_DIRS=" $withval"], [JNI_INCLUDE_DIRS=])
 568
 569 JNI_CPPFLAGS=
 570 AS_IF([test "x$enable_java$HAVE_JAVAC" = xyesyes], [
 571         AX_PROG_JAVAC
 572         AS_IF([test -z "$JNI_INCLUDE_DIRS" && test "x$cross_compiling" != xyes], [
 573                 ## Work around the totally broken logic in AX_JNI_INCLUDE_DIR:
 574                 ## If we can find jni.h without any special search path, skip
 575                 ## the execution of the broken macro to increase our chances of
 576                 ## success.
 577                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <jni.h>]], [])],,
 578                         [AX_JNI_INCLUDE_DIR])
 579         ])
 580 ])
 581 for sr_dir in $JNI_INCLUDE_DIRS
 582 do
 583         SR_APPEND([JNI_CPPFLAGS], ["-I$sr_dir"])
 584 done
 585 AC_SUBST([JNI_CPPFLAGS])
 586
 587 sr_save_cppflags=$CPPFLAGS
 588 SR_APPEND([CPPFLAGS], [$JNI_CPPFLAGS])
 589 AC_CHECK_HEADER([jni.h],,
 590         [SR_APPEND([sr_java_missing], [', '], ['JNI headers'])])
 591 CPPFLAGS=$sr_save_cppflags
 592
 593 AS_IF([test -z "$sr_java_missing"],
 594         [BINDINGS_JAVA=$enable_java], [BINDINGS_JAVA=no])
 595 AM_CONDITIONAL([BINDINGS_JAVA], [test "x$BINDINGS_JAVA" = xyes])
 596
 597 ##############################
 598 ##  Finalize configuration  ##
 599 ##############################
 600
 601 # Add mandatory dependencies to module list.
 602 SR_APPEND([SR_PKGLIBS], ['libzip >= 0.10'])
 603 AC_SUBST([SR_PKGLIBS])
 604
 605 # Retrieve the compile and link flags for all modules combined.
 606 # Also, bail out at this point if any module dependency is not met.
 607 PKG_CHECK_MODULES([LIBSIGROK], [glib-2.0 >= 2.32.0 $SR_PKGLIBS])
 608 PKG_CHECK_MODULES([TESTS], [$SR_PKGLIBS_TESTS glib-2.0 $SR_PKGLIBS])
 609
 610 # SR_PKGLIBS_CXX may be empty, so only invoke these checks when
 611 # the C++ bindings are enabled.
 612 AM_COND_IF([BINDINGS_CXX], [
 613         PKG_CHECK_MODULES([LIBSIGROKCXX], [$SR_PKGLIBS_CXX])
 614         PKG_CHECK_MODULES([PYSIGROK], [$SR_PKGLIBS_PYTHON $SR_PKGLIBS_CXX])
 615         PKG_CHECK_MODULES([RBSIGROK], [$SR_PKGLIBS_RUBY $SR_PKGLIBS_CXX], [AC_SUBST(RBSIGROK_EXTDIR, "lib/$($PKG_CONFIG --variable=sitearch $SR_PKGLIBS_RUBY)/$($PKG_CONFIG --variable=RUBY_BASE_NAME $SR_PKGLIBS_RUBY)/vendor_ruby/$($PKG_CONFIG --variable=ruby_version $SR_PKGLIBS_RUBY)")])
 616 ])
 617
 618 # Check for specific libusb features, now that we know the CFLAGS.
 619 AC_LANG([C])
 620 sr_save_cflags=$CFLAGS
 621 sr_save_libs=$LIBS
 622 CFLAGS="$LIBSIGROK_CFLAGS $CFLAGS"
 623 LIBS="$LIBSIGROK_LIBS $LIBS"
 624 AC_CHECK_TYPES([libusb_os_handle],
 625         [sr_have_libusb_os_handle=yes], [sr_have_libusb_os_handle=no],
 626         [[#include <libusb.h>]])
 627 AC_CHECK_FUNCS([zip_discard])
 628 LIBS=$sr_save_libs
 629 CFLAGS=$sr_save_cflags
 630
 631 AM_COND_IF([NEED_USB], [AS_CASE([$sr_have_libusb_os_handle:$host_os], [no:mingw*],
 632         [AC_MSG_ERROR([Windows builds require the event-abstraction branch of libusb])])])
 633
 634 sr_glib_version=`$PKG_CONFIG --modversion glib-2.0 2>&AS_MESSAGE_LOG_FD`
 635 sr_libzip_version=`$PKG_CONFIG --modversion libzip 2>&AS_MESSAGE_LOG_FD`
 636 sr_zlib_version=`$PKG_CONFIG --modversion zlib 2>&AS_MESSAGE_LOG_FD`
 637
 638 AC_DEFINE_UNQUOTED([CONF_LIBZIP_VERSION], ["$sr_libzip_version"],
 639         [Build-time version of libzip.])
 640 AC_DEFINE_UNQUOTED([CONF_ZLIB_VERSION], ["$sr_zlib_version"],
 641         [Build-time version of zlib.])
 642 AC_DEFINE_UNQUOTED([CONF_HOST], ["$host"],
 643         [The canonical host libsigrok will run on.])
 644
 645 AC_CONFIG_FILES([Makefile libsigrok.pc bindings/cxx/libsigrokcxx.pc])
 646
 647 AC_OUTPUT
 648
 649 # Prepare bindings report messages.
 650 m4_define([SR_PREPARE_BINDING_REPORT], [
 651         sr_report_$1=
 652         test -z "$sr_$1_missing" || sr_report_$1=" (missing: $sr_$1_missing)"
 653         test "x$enable_$1" = xyes || sr_report_$1=' (disabled)'
 654 ])
 655 m4_map_args([SR_PREPARE_BINDING_REPORT], [cxx], [python], [ruby], [java])
 656
 657 cat >&AS_MESSAGE_FD <<_EOF
 658
 659 libsigrok configuration summary:
 660  - Package version................. $SR_PACKAGE_VERSION
 661  - Library ABI version............. $SR_LIB_VERSION
 662  - Prefix.......................... $prefix
 663  - Building on..................... $build
 664  - Building for.................... $host
 665  - Building shared / static........ $enable_shared / $enable_static
 666
 667 Compile configuration:
 668  - C compiler...................... $CC
 669  - C compiler version.............. $sr_cc_version
 670  - C compiler flags................ $CFLAGS
 671  - Additional C compiler flags..... $SR_EXTRA_CFLAGS
 672  - C compiler warnings............. $SR_WFLAGS
 673  - C++ compiler.................... $CXX
 674  - C++ compiler version............ $sr_cxx_version
 675  - C++ compiler flags.............. $CXXFLAGS
 676  - C++ compiler warnings........... $SR_WXXFLAGS
 677  - Linker flags.................... $LDFLAGS
 678
 679 Detected libraries (required):
 680  - glib-2.0 >= 2.32.0.............. $sr_glib_version
 681  - libzip >= 0.10.................. $sr_libzip_version
 682
 683 Detected libraries (optional):
 684 $sr_pkglibs_summary
 685 Enabled hardware drivers:
 686 $sr_driver_summary
 687 Enabled serial communication transports:
 688   - serial comm ................... $sr_have_serial_comm
 689   - libserialport ................. $sr_have_libserialport
 690   - hidapi ........................ $sr_have_libhidapi
 691   - bluetooth ..................... $sr_have_bluetooth
 692   - bluez ......................... $sr_have_libbluez
 693
 694 Enabled SCPI backends:
 695  - TCP............................. yes
 696  - SunRPC ......................... $sr_cv_have_sunrpc
 697  - TI-RPC ......................... $sr_cv_have_tirpc
 698  - RPC............................. $sr_cv_have_rpc
 699  - serial.......................... $sr_have_serial_comm
 700  - VISA............................ $sr_have_librevisa
 701  - GPIB............................ $sr_have_libgpib
 702  - USBTMC.......................... $sr_have_libusb
 703
 704 Enabled language bindings:
 705  - C++............................. $BINDINGS_CXX$sr_report_cxx
 706  - Python.......................... $BINDINGS_PYTHON$sr_report_python
 707  - Ruby............................ $BINDINGS_RUBY$sr_report_ruby
 708  - Java............................ $BINDINGS_JAVA$sr_report_java
 709
 710 _EOF
 711
 712 # Emit a warning if the C++ bindings are not being built.
 713 AM_COND_IF([BINDINGS_CXX], [], [
 714 cat >&AS_MESSAGE_FD <<_EOF
 715 ===============================================================================
 716 WARNING WARNING WARNING WARNING WARNING WARNING WARNING WARNING WARNING WARNING
 717 ===============================================================================
 718 ===                                                                         ===
 719 ===         The libsigrok C++ bindings are not being built since you        ===
 720 ===             are missing one or more dependencies (see above)!           ===
 721 ===                                                                         ===
 722 ===      This means you won't be able to compile frontends that require     ===
 723 ===  the C++ bindings (such as PulseView)! You also won't be able to build  ===
 724 ===     other bindings and frontends using those (such as sigrok-meter)!    ===
 725 ===                                                                         ===
 726 ===============================================================================
 727 WARNING WARNING WARNING WARNING WARNING WARNING WARNING WARNING WARNING WARNING
 728 ===============================================================================
 729
 730 _EOF
 731 ])