configure.ac

   1 ##
   2 ## This file is part of the libsigrok project.
   3 ##
   4 ## Copyright (C) 2010-2012 Bert Vermeulen <bert@biot.com>
   5 ## Copyright (C) 2012 Alexandru Gagniuc <mr.nuke.me@gmail.com>
   6 ##
   7 ## This program is free software: you can redistribute it and/or modify
   8 ## it under the terms of the GNU General Public License as published by
   9 ## the Free Software Foundation, either version 3 of the License, or
  10 ## (at your option) any later version.
  11 ##
  12 ## This program is distributed in the hope that it will be useful,
  13 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ## GNU General Public License for more details.
  16 ##
  17 ## You should have received a copy of the GNU General Public License
  18 ## along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19 ##
  20
  21 # We require at least autoconf 2.63 (AC_INIT format changed there).
  22 AC_PREREQ([2.63])
  23
  24 AC_INIT([libsigrok], [0.6.0],
  25         [sigrok-devel@lists.sourceforge.net],
  26         [libsigrok], [http://www.sigrok.org])
  27 AC_CONFIG_MACRO_DIR([m4])
  28 AC_CONFIG_AUX_DIR([autostuff])
  29 AC_CONFIG_HEADERS([config.h include/libsigrok/version.h])
  30
  31 # We require at least automake 1.11 (needed for 'silent rules').
  32 AM_INIT_AUTOMAKE([1.11 -Wall -Werror no-define nostdinc subdir-objects check-news color-tests])
  33 AM_SILENT_RULES([yes])
  34 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  35
  36 AC_CANONICAL_HOST
  37
  38 # Checks for programs.
  39 AC_PROG_CC
  40 AC_PROG_CXX
  41 AC_PROG_INSTALL
  42 AC_PROG_LN_S
  43
  44 # Required for per-target flags or subdir-objects with C sources.
  45 AM_PROG_CC_C_O
  46
  47 # Set the standard the C library headers should conform to.
  48 AH_VERBATIM([_POSIX_C_SOURCE], [/* The targeted POSIX standard. */
  49 #ifndef _POSIX_C_SOURCE
  50 # define _POSIX_C_SOURCE 200112L
  51 #endif])
  52
  53 # Get compiler versions.
  54 SR_PROG_VERSION([$CC], [sr_cc_version])
  55 SR_PROG_VERSION([$CXX], [sr_cxx_version])
  56
  57 # Check for optional make features.
  58 SR_PROG_MAKE_ORDER_ONLY
  59
  60 # Initialize libtool.
  61 LT_INIT
  62
  63 # Set up the libsigrok version defines.
  64 SR_PKG_VERSION_SET([SR_PACKAGE_VERSION], [AC_PACKAGE_VERSION])
  65
  66 # Library version for libsigrok (NOT the same as the package version).
  67 # Carefully read the libtool docs before updating these numbers!
  68 # The algorithm for determining which number to change (and how) is nontrivial!
  69 # http://www.gnu.org/software/libtool/manual/libtool.html#Updating-version-info
  70 # Format: current:revision:age.
  71 SR_LIB_VERSION_SET([SR_LIB_VERSION], [4:0:0])
  72
  73 AM_CONDITIONAL([WIN32], [test -z "${host_os##mingw*}" || test -z "${host_os##cygwin*}"])
  74
  75 #############################
  76 ##  Optional dependencies  ##
  77 #############################
  78
  79 AC_LANG([C])
  80
  81 # Initialize pkg-config.
  82 # We require at least 0.22, as "Requires.private" behaviour changed there.
  83 PKG_PROG_PKG_CONFIG([0.22])
  84
  85 # Keep track of all checked modules so we can list them at the end.
  86 SR_PKG_CHECK_SUMMARY([sr_pkglibs_summary])
  87
  88 # Collect the pkg-config module names of all dependencies in SR_PKGLIBS.
  89 # These are used to derive the compiler flags and for the "Requires.private"
  90 # field in the generated libsigrok.pc file.
  91 SR_VAR_OPT_PKG([SR_PKGLIBS], [sr_deps_avail])
  92 SR_PKGLIBS_TESTS=
  93 SR_PKGLIBS_CXX=
  94 SR_PKGLIBS_PYTHON=
  95 SR_PKGLIBS_RUBY=
  96 SR_EXTRA_LIBS=
  97 SR_EXTRA_CXX_LIBS=
  98
  99 SR_ARG_OPT_PKG([libserialport], [LIBSERIALPORT], ,
 100         [libserialport >= 0.1.1])
 101
 102 SR_ARG_OPT_PKG([libftdi], [LIBFTDI], , [libftdi1 >= 1.0])
 103
 104 # pkg-config file names: MinGW/MacOSX: hidapi; Linux: hidapi-hidraw/-libusb
 105 SR_ARG_OPT_PKG([libhidapi], [LIBHIDAPI], ,
 106         [hidapi >= 0.8.0], [hidapi-hidraw >= 0.8.0], [hidapi-libusb >= 0.8.0])
 107
 108 SR_ARG_OPT_PKG([libbluez], [LIBBLUEZ], , [bluez >= 4.0])
 109
 110 SR_ARG_OPT_PKG([libnettle], [LIBNETTLE], , [nettle])
 111
 112 # FreeBSD comes with an "integrated" libusb-1.0-style USB API.
 113 # This means libusb-1.0 is always available; no need to check for it.
 114 # On Windows, require the latest version we can get our hands on,
 115 # until the new generic event handling has seen an official release.
 116 AS_CASE([$host_os],
 117         [freebsd*], [sr_libusb_req='libusb-1.0' sr_have_libusb=yes],
 118         [mingw*], [sr_libusb_req='libusb-1.0 >= 1.0.20'],
 119         [sr_libusb_req='libusb-1.0 >= 1.0.16'])
 120
 121 SR_ARG_OPT_PKG([libusb], [LIBUSB_1_0], [NEED_USB],
 122         [$sr_libusb_req])
 123
 124 SR_ARG_OPT_PKG([librevisa], [LIBREVISA], [NEED_VISA],
 125         [librevisa >= 0.0.20130412])
 126
 127 SR_ARG_OPT_PKG([libgpib], [LIBGPIB], [NEED_GPIB],
 128         [libgpib])
 129
 130 SR_ARG_OPT_CHECK([libieee1284], [LIBIEEE1284],, [
 131         sr_save_LIBS=$LIBS
 132         LIBS="-lieee1284 $LIBS"
 133         AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <ieee1284.h>]],
 134                                 [[(void) ieee1284_open(0, 0, 0);]])],
 135                 [sr_have_libieee1284=yes], [sr_have_libieee1284=no])
 136         LIBS=$sr_save_LIBS
 137 ])
 138 AS_IF([test "x$sr_have_libieee1284" = xyes],
 139         [SR_PREPEND([SR_EXTRA_LIBS], [-lieee1284])])
 140
 141 SR_ARG_OPT_PKG([libgio], [LIBGIO], , [gio-2.0 >= 2.24.0])
 142
 143 # See if any of the (potentially platform specific) libs are available
 144 # which provide some means of Bluetooth communication.
 145 AS_IF([test "x$sr_have_libbluez" = xyes],
 146         sr_have_bluetooth=yes, sr_have_bluetooth=no)
 147 AS_IF([test "x$sr_have_bluetooth" = xyes],
 148         [AC_DEFINE([HAVE_BLUETOOTH], [1], [Specifies whether Bluetooth communication is supported.])])
 149 AS_IF([test "x$sr_have_bluetooth" = xyes],
 150         [SR_APPEND([sr_deps_avail], [bluetooth_comm])])
 151
 152 AS_IF([test "x$sr_have_libserialport" = xyes -o "x$sr_have_libhidapi" = xyes -o "x$sr_have_bluetooth" = xyes],
 153         sr_have_serial_comm=yes, sr_have_serial_comm=no)
 154 AS_IF([test "x$sr_have_serial_comm" = xyes],
 155         [AC_DEFINE([HAVE_SERIAL_COMM], [1], [Specifies whether serial communication is supported.])])
 156 AS_IF([test "x$sr_have_serial_comm" = xyes],
 157         [SR_APPEND([sr_deps_avail], [serial_comm])])
 158 AM_CONDITIONAL([NEED_SERIAL], [test "x$sr_have_serial_comm" = xyes])
 159
 160 ######################
 161 ##  Feature checks  ##
 162 ######################
 163
 164 # The Check unit testing framework is optional. Disable if not found.
 165 SR_PKG_CHECK([check], [SR_PKGLIBS_TESTS], [check >= 0.9.4])
 166 AM_CONDITIONAL([HAVE_CHECK], [test "x$sr_have_check" = xyes])
 167
 168 # Enable the C99 standard if possible, and enforce the use
 169 # of SR_API to explicitly mark all public API functions.
 170 SR_EXTRA_CFLAGS=
 171 SR_CHECK_COMPILE_FLAGS([SR_EXTRA_CFLAGS], [C99], [-std=c99 -c99 -AC99 -qlanglvl=extc99])
 172 SR_CHECK_COMPILE_FLAGS([SR_EXTRA_CFLAGS], [visibility], [-fvisibility=hidden])
 173
 174 SR_ARG_ENABLE_WARNINGS([SR_WFLAGS], [-Wall], [-Wall -Wextra -Wmissing-prototypes])
 175
 176 # Check host characteristics.
 177 AC_SYS_LARGEFILE
 178 AC_C_BIGENDIAN
 179
 180 AC_CHECK_HEADERS([sys/mman.h], [SR_APPEND([sr_deps_avail], [sys_mman_h])])
 181 AC_CHECK_HEADERS([sys/ioctl.h], [SR_APPEND([sr_deps_avail], [sys_ioctl_h])])
 182 AC_CHECK_HEADERS([sys/timerfd.h], [SR_APPEND([sr_deps_avail], [sys_timerfd_h])])
 183
 184 # We need to link against the Winsock2 library for SCPI over TCP.
 185 AS_CASE([$host_os], [mingw*], [SR_PREPEND([SR_EXTRA_LIBS], [-lws2_32])])
 186
 187 # libm (the standard math library) is always needed.
 188 SR_SEARCH_LIBS([SR_EXTRA_LIBS], [pow], [m])
 189
 190 # RPC is only needed for VXI support.
 191 AC_CACHE_CHECK([for SunRPC support], [sr_cv_have_sunrpc],
 192         [AC_LINK_IFELSE([AC_LANG_PROGRAM(
 193                         [[#include <rpc/rpc.h>]m4_newline[CLIENT *rpc_test(void);]],
 194                         [[(void) clnt_create("", 0, 0, "");]])],
 195                 [RPC_CFLAGS=""; RPC_LIBS=""; sr_cv_have_sunrpc=yes],
 196                 [sr_cv_have_sunrpc=no])])
 197 PKG_CHECK_MODULES([TIRPC],
 198         [libtirpc],
 199         [RPC_CFLAGS=$TIRPC_CFLAGS; SR_PREPEND([SR_EXTRA_LIBS], [$TIRPC_LIBS]); sr_cv_have_tirpc=yes],
 200         [sr_cv_have_tirpc=no])
 201 AS_IF([test "x$sr_cv_have_sunrpc" = xyes -o "x$sr_cv_have_tirpc" = xyes],
 202         [sr_cv_have_rpc=yes], [sr_cv_have_rpc=no])
 203
 204 AC_SUBST(RPC_CFLAGS)
 205 AC_SUBST(RPC_LIBS)
 206
 207 AS_IF([test "x$sr_cv_have_rpc" = xyes],
 208         [AC_DEFINE([HAVE_RPC], [1], [Specifies whether we have RPC support (either by SunRPC or libtirpc).])])
 209
 210 # VXI support is only compiled if RPC support was found.
 211 AM_CONDITIONAL([NEED_RPC], [test "x$sr_cv_have_rpc" = xyes])
 212
 213 # Check for compiler support of 128 bit integers
 214 AC_CHECK_TYPES([__int128_t, __uint128_t], [], [], [])
 215
 216 ########################
 217 ##  Hardware drivers  ##
 218 ########################
 219
 220 # Keep track of all drivers so we can list them at the end.
 221 SR_VAR_SUMMARY([sr_driver_summary])
 222
 223 # Check whether the sr_deps_avail list contains all of the arguments.
 224 # Unavailable dependencies are collected in sr_deps_missing.
 225 sr_check_driver_deps() {
 226         sr_deps_missing=
 227         for sr_dep
 228         do
 229                 AS_CASE([" $sr_deps_avail "], [*" $sr_dep "*],,
 230                         [SR_APPEND([sr_deps_missing], [', '], [$sr_dep])])
 231         done
 232         test -z "$sr_deps_missing" || return 1
 233 }
 234
 235 AC_ARG_ENABLE([all-drivers],
 236         [AS_HELP_STRING([--enable-all-drivers],
 237                         [enable all drivers by default [default=yes]])],
 238         [], [enable_all_drivers=yes])
 239
 240 ## _SR_DRIVER(Device name, driver-name, var-name, [dependencies...])
 241 m4_define([_SR_DRIVER], [
 242         AC_ARG_ENABLE([$2],
 243                 [AS_HELP_STRING([--enable-$2], [enable $1 support])],
 244                 [$3=$enableval], [$3=$enable_all_drivers])
 245
 246         AS_IF([test "x[$]$3" = xyes], [sr_hw_info=yes[]m4_ifval([$4], [
 247                 sr_check_driver_deps $4 \
 248                         || $3=no sr_hw_info="no (missing: $sr_deps_missing)"
 249         ])], [sr_hw_info='no (disabled)'])
 250         sr_driver_summary_append "$2" "$sr_hw_info"
 251
 252         AM_CONDITIONAL([$3], [test "x[$]$3" = xyes])
 253         AM_COND_IF([$3], [AC_DEFINE([HAVE_$3], [1], [Whether to support $1 device.]) AC_DEFINE([HAVE_DRIVERS], [1], [Whether at least one driver is enabled.])])
 254 ])
 255
 256 ## SR_DRIVER(Device name, driver-name, [dependencies...])
 257 m4_define([SR_DRIVER],
 258         [_SR_DRIVER([$1], [$2], m4_expand([AS_TR_CPP([HW_$2])]), [$3])])
 259
 260 SR_DRIVER([Agilent DMM], [agilent-dmm], [serial_comm])
 261 SR_DRIVER([Appa 55II], [appa-55ii], [serial_comm])
 262 SR_DRIVER([Arachnid Labs Re:load Pro], [arachnid-labs-re-load-pro], [serial_comm])
 263 SR_DRIVER([ASIX SIGMA/SIGMA2], [asix-sigma], [libftdi])
 264 SR_DRIVER([Atten PPS3xxx], [atten-pps3xxx], [serial_comm])
 265 SR_DRIVER([BayLibre ACME], [baylibre-acme], [sys_timerfd_h])
 266 SR_DRIVER([BeagleLogic], [beaglelogic], [sys_mman_h sys_ioctl_h])
 267 SR_DRIVER([CEM DT-885x], [cem-dt-885x], [serial_comm])
 268 SR_DRIVER([Center 3xx], [center-3xx], [serial_comm])
 269 SR_DRIVER([ChronoVu LA], [chronovu-la], [libusb libftdi])
 270 SR_DRIVER([Colead SLM], [colead-slm], [serial_comm])
 271 SR_DRIVER([Conrad DIGI 35 CPU], [conrad-digi-35-cpu], [serial_comm])
 272 SR_DRIVER([demo], [demo])
 273 SR_DRIVER([DreamSourceLab DSLogic], [dreamsourcelab-dslogic], [libusb])
 274 SR_DRIVER([Fluke 45], [fluke-45])
 275 SR_DRIVER([Fluke DMM], [fluke-dmm], [serial_comm])
 276 SR_DRIVER([FTDI LA], [ftdi-la], [libusb libftdi])
 277 SR_DRIVER([fx2lafw], [fx2lafw], [libusb])
 278 SR_DRIVER([GMC MH 1x/2x], [gmc-mh-1x-2x], [serial_comm])
 279 SR_DRIVER([GW Instek GDS-800], [gwinstek-gds-800], [serial_comm])
 280 SR_DRIVER([GW Instek GPD], [gwinstek-gpd], [serial_comm])
 281 SR_DRIVER([Hameg HMO], [hameg-hmo], [serial_comm])
 282 SR_DRIVER([Hantek 4032L], [hantek-4032l], [libusb])
 283 SR_DRIVER([Hantek 6xxx], [hantek-6xxx], [libusb])
 284 SR_DRIVER([Hantek DSO], [hantek-dso], [libusb])
 285 SR_DRIVER([HP 3457A], [hp-3457a])
 286 SR_DRIVER([HP 3478A], [hp-3478a], [libgpib])
 287 SR_DRIVER([Hung-Chang DSO-2100], [hung-chang-dso-2100], [libieee1284])
 288 SR_DRIVER([Ikalogic Scanalogic-2], [ikalogic-scanalogic2], [libusb])
 289 SR_DRIVER([Ikalogic Scanaplus], [ikalogic-scanaplus], [libftdi])
 290 SR_DRIVER([IPDBG LA], [ipdbg-la])
 291 SR_DRIVER([ITECH IT8500], [itech-it8500], [serial_comm])
 292 SR_DRIVER([Kecheng KC-330B], [kecheng-kc-330b], [libusb])
 293 SR_DRIVER([KERN scale], [kern-scale], [serial_comm])
 294 SR_DRIVER([Kingst LA2016], [kingst-la2016], [libusb])
 295 SR_DRIVER([Korad KAxxxxP], [korad-kaxxxxp], [serial_comm])
 296 SR_DRIVER([Lascar EL-USB], [lascar-el-usb], [libusb])
 297 SR_DRIVER([LeCroy LogicStudio], [lecroy-logicstudio], [libusb])
 298 SR_DRIVER([LeCroy X-Stream], [lecroy-xstream])
 299 SR_DRIVER([Manson HCS-3xxx], [manson-hcs-3xxx], [serial_comm])
 300 SR_DRIVER([Mastech MS6514], [mastech-ms6514], [serial_comm])
 301 SR_DRIVER([maynuo-m97], [maynuo-m97])
 302 SR_DRIVER([MIC 985xx], [mic-985xx], [serial_comm])
 303 SR_DRIVER([Microchip PICkit2], [microchip-pickit2], [libusb])
 304 SR_DRIVER([Mooshimeter DMM], [mooshimeter-dmm], [bluetooth_comm libgio])
 305 SR_DRIVER([Motech LPS 30x], [motech-lps-30x], [serial_comm])
 306 SR_DRIVER([Norma DMM], [norma-dmm], [serial_comm])
 307 SR_DRIVER([OpenBench Logic Sniffer], [openbench-logic-sniffer], [serial_comm])
 308 SR_DRIVER([PCE PCE-322A], [pce-322a], [serial_comm])
 309 SR_DRIVER([Pipistrello-OLS], [pipistrello-ols], [libftdi])
 310 SR_DRIVER([RDTech DPSxxxx/DPHxxxx], [rdtech-dps], [serial_comm])
 311 SR_DRIVER([RDTech UMXX], [rdtech-um], [serial_comm])
 312 SR_DRIVER([RDTech TCXX], [rdtech-tc], [serial_comm libnettle])
 313 SR_DRIVER([Rigol DS], [rigol-ds])
 314 SR_DRIVER([Rigol DG], [rigol-dg])
 315 SR_DRIVER([Rohde&Schwarz SME-0x], [rohde-schwarz-sme-0x], [serial_comm])
 316 SR_DRIVER([Saleae Logic16], [saleae-logic16], [libusb])
 317 SR_DRIVER([Saleae Logic Pro], [saleae-logic-pro], [libusb])
 318 SR_DRIVER([SCPI DMM], [scpi-dmm])
 319 SR_DRIVER([SCPI PPS], [scpi-pps])
 320 SR_DRIVER([serial DMM], [serial-dmm], [serial_comm])
 321 SR_DRIVER([serial LCR], [serial-lcr], [serial_comm])
 322 SR_DRIVER([Siglent SDS], [siglent-sds])
 323 SR_DRIVER([Sysclk LWLA], [sysclk-lwla], [libusb])
 324 SR_DRIVER([Sysclk SLA5032], [sysclk-sla5032], [libusb])
 325 SR_DRIVER([Teleinfo], [teleinfo], [serial_comm])
 326 SR_DRIVER([Testo], [testo], [libusb])
 327 SR_DRIVER([Tondaj SL-814], [tondaj-sl-814], [serial_comm])
 328 SR_DRIVER([UNI-T DMM], [uni-t-dmm], [libusb])
 329 SR_DRIVER([UNI-T UT181A], [uni-t-ut181a], [serial_comm])
 330 SR_DRIVER([UNI-T UT32x], [uni-t-ut32x], [serial_comm])
 331 SR_DRIVER([Yokogawa DL/DLM], [yokogawa-dlm])
 332 SR_DRIVER([ZEROPLUS Logic Cube], [zeroplus-logic-cube], [libusb])
 333 SR_DRIVER([ZKETECH EBD-USB], [zketech-ebd-usb], [serial_comm])
 334
 335 ###############################
 336 ##  Language bindings setup  ##
 337 ###############################
 338
 339 AC_LANG([C++])
 340 SR_ARG_ENABLE_WARNINGS([SR_WXXFLAGS], [-Wall], [-Wall -Wextra])
 341
 342 AC_ARG_ENABLE([bindings],
 343         [AS_HELP_STRING([--enable-bindings], [build language bindings [default=yes]])],
 344         [], [enable_bindings=yes])
 345
 346 AC_ARG_ENABLE([cxx],
 347         [AS_HELP_STRING([--enable-cxx], [build C++ bindings [default=yes]])],
 348         [], [enable_cxx=$enable_bindings])
 349
 350 AC_ARG_ENABLE([python],
 351         [AS_HELP_STRING([--enable-python], [build Python bindings [default=yes]])],
 352         [], [enable_python=$enable_bindings])
 353
 354 AC_ARG_ENABLE([ruby],
 355         [AS_HELP_STRING([--enable-ruby], [build Ruby bindings [default=yes]])],
 356         [], [enable_ruby=$enable_bindings])
 357
 358 AC_ARG_ENABLE([java],
 359         [AS_HELP_STRING([--enable-java], [build Java bindings [default=yes]])],
 360         [], [enable_java=$enable_bindings])
 361
 362 ####################
 363 ##  C++ bindings  ##
 364 ####################
 365
 366 sr_cxx_missing=
 367
 368 # Check if the C++ compiler supports the C++11 standard.
 369 AX_CXX_COMPILE_STDCXX([11], [noext], [optional])
 370 AS_IF([test "x$HAVE_CXX11" != x1],
 371         [SR_APPEND([sr_cxx_missing], [', '], ['C++11'])])
 372
 373 # The C++ bindings need glibmm.
 374 SR_PKG_CHECK([glibmm], [SR_PKGLIBS_CXX], [glibmm-2.4 >= 2.32.0])
 375 AS_IF([test "x$sr_have_glibmm" != xyes],
 376         [SR_APPEND([sr_cxx_missing], [', '], [glibmm])])
 377
 378 # The C++ bindings use Doxygen to parse libsigrok symbols.
 379 AC_CHECK_PROG([HAVE_DOXYGEN], [doxygen], [yes], [no])
 380 AS_IF([test "x$HAVE_DOXYGEN" != xyes],
 381         [SR_APPEND([sr_cxx_missing], [', '], [Doxygen])])
 382
 383 # Link C++ code with gnustl_shared if it exists (Android)
 384 SR_SEARCH_LIBS([SR_EXTRA_CXX_LIBS], [__cxa_throw], [gnustl_shared])
 385
 386 # Python is needed for the C++ bindings.
 387 AM_PATH_PYTHON([2.7],
 388         [HAVE_PYTHON=yes],
 389         [HAVE_PYTHON=no
 390         SR_APPEND([sr_cxx_missing], [', '], [Python])])
 391
 392 AS_IF([test -z "$sr_cxx_missing"],
 393         [BINDINGS_CXX=$enable_cxx], [BINDINGS_CXX=no])
 394 AM_CONDITIONAL([BINDINGS_CXX], [test "x$BINDINGS_CXX" = xyes])
 395
 396 # C++ bindings want stoi and stod.
 397 AM_COND_IF([BINDINGS_CXX], [
 398         AC_CACHE_CHECK([for stoi and stod], [sr_cv_have_stoi_stod],
 399                 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <string>]],
 400                                 [[(void) std::stoi("1"); (void) std::stod("1.0");]])],
 401                         [sr_cv_have_stoi_stod=yes], [sr_cv_have_stoi_stod=no])])
 402         AS_IF([test "x$sr_cv_have_stoi_stod" = xyes],
 403                 [AC_DEFINE([HAVE_STOI_STOD], [1],
 404                         [Specifies whether we have the stoi and stod functions.])])
 405 ])
 406
 407 #######################
 408 ##  Python bindings  ##
 409 #######################
 410
 411 AS_IF([test "x$BINDINGS_CXX" = xyes],
 412         [sr_python_missing=],
 413         [sr_python_missing='C++ bindings'])
 414
 415 # Extract major and minor version number of the Python interpreter.
 416 sr_pymajor=${PYTHON_VERSION%%.*}
 417 sr_pyminor=${PYTHON_VERSION#*.}
 418
 419 # The Python bindings need Python development files. Check for either
 420 # Python 3 or Python 2 headers depending on the interpreter version.
 421 SR_PKG_CHECK([python_dev], [SR_PKGLIBS_PYTHON],
 422         [python = $PYTHON_VERSION],
 423         [python$sr_pymajor = $PYTHON_VERSION],
 424         [python$sr_pymajor$sr_pyminor = $PYTHON_VERSION],
 425         [python-$PYTHON_VERSION = $PYTHON_VERSION])
 426
 427 AS_IF([test "x$sr_have_python_dev" != xyes],
 428         [SR_APPEND([sr_python_missing], [', '], [Headers])])
 429
 430 # PyGObject is needed for the Python bindings.
 431 SR_PKG_CHECK([pygobject], [SR_PKGLIBS_PYTHON], [pygobject-3.0 >= 3.0.0])
 432 AS_IF([test "x$sr_have_pygobject" != xyes],
 433         [SR_APPEND([sr_python_missing], [', '], [PyGObject])])
 434
 435 PKG_CHECK_EXISTS([pygobject-3.0 < 3.7.91],
 436         [AC_DEFINE([PYGOBJECT_FLAGS_SIGNED], [1],
 437                 [Whether last argument to pyg_flags_get_value() is signed.])])
 438
 439 # The Python bindings need the setuptools and numpy Python modules.
 440 # We'll let it go through even if the AX macro wasn't found, as the
 441 # Python modules may still be there.
 442 m4_ifdef([AX_PYTHON_MODULE], [
 443         AX_PYTHON_MODULE([setuptools])
 444         AX_PYTHON_MODULE([numpy])
 445 ], [
 446         HAVE_PYMOD_SETUPTOOLS=yes
 447         HAVE_PYMOD_NUMPY=yes
 448         m4_warn([unsupported],
 449                 [Missing macro AX_PYTHON_MODULE: no check for setuptools and numpy])
 450 ])
 451 AS_IF([test "x$HAVE_PYMOD_SETUPTOOLS" != xyes],
 452         [SR_APPEND([sr_python_missing], [', '], [setuptools])])
 453 AS_IF([test "x$HAVE_PYMOD_NUMPY" != xyes],
 454         [SR_APPEND([sr_python_missing], [', '], [numpy])])
 455
 456 # The Python bindings use SWIG to generate code.
 457 AC_CHECK_PROGS([SWIG], [swig swig4.0 swig3.0 swig2.0])
 458 AS_IF([test "x$SWIG" != x],
 459     AC_MSG_CHECKING([for $SWIG version])
 460     [SWIG_VERSION=`$SWIG -version 2>&1 | sed -n 's/SWIG Version //p'`]
 461     AC_MSG_RESULT([$SWIG_VERSION]))
 462 AS_IF([test "x$SWIG" = x],
 463         [SR_APPEND([sr_python_missing], [', '], [SWIG])])
 464
 465 AS_IF([test -z "$sr_python_missing"],
 466         [BINDINGS_PYTHON=$enable_python], [BINDINGS_PYTHON=no])
 467 AM_CONDITIONAL([BINDINGS_PYTHON], [test "x$BINDINGS_PYTHON" = xyes])
 468
 469 #####################
 470 ##  Ruby bindings  ##
 471 #####################
 472
 473 AS_IF([test "x$BINDINGS_CXX" = xyes],
 474         [sr_ruby_missing=],
 475         [sr_ruby_missing='C++ bindings'])
 476
 477 AC_PATH_PROGS(RUBY, ["${RUBY-ruby}"], [])
 478 AS_IF([test "x$RUBY" != x],
 479         AC_MSG_CHECKING([for Ruby version])
 480     [RUBY_VERSION=`$RUBY -e 'puts RUBY_VERSION'`]
 481     AC_MSG_RESULT([$RUBY_VERSION])
 482     [RUBY_DLEXT=`$RUBY -rrbconfig -e 'puts RbConfig::CONFIG[["DLEXT"]]'`]
 483     AC_SUBST(RUBY_DLEXT))
 484
 485 AS_IF([test "x$RUBY" = x],
 486         [SR_APPEND([sr_ruby_missing], [', '], [Ruby])])
 487
 488 # Extract major and minor version number of the Ruby interpreter.
 489 sr_rbmajor=${RUBY_VERSION%%.*}
 490 sr_rbminor=${RUBY_VERSION#*.}
 491 sr_rbminor=${sr_rbminor%%.*}
 492
 493 # The Ruby bindings need Ruby development files.
 494 SR_PKG_CHECK([ruby_dev], [SR_PKGLIBS_RUBY],
 495         [ruby >= 2.5.0],
 496         [ruby-$sr_rbmajor.$sr_rbminor >= 2.5.0])
 497
 498 AS_IF([test "x$sr_have_ruby_dev" != xyes],
 499         [SR_APPEND([sr_ruby_missing], [', '], [Headers])])
 500
 501 # The Ruby bindings use SWIG >= 3.0.8 to generate code.
 502 AS_IF([test "x$SWIG" = x],
 503         [SR_APPEND([sr_ruby_missing], [', '], [SWIG])],
 504         [AS_VERSION_COMPARE($SWIG_VERSION, "3.0.8",
 505                 [SR_APPEND([sr_ruby_missing], [', '], ['SWIG >= 3.0.8'])])])
 506
 507 AS_IF([test -z "$sr_ruby_missing"],
 508         [BINDINGS_RUBY=$enable_ruby], [BINDINGS_RUBY=no])
 509 AM_CONDITIONAL([BINDINGS_RUBY], [test "x$BINDINGS_RUBY" = xyes])
 510
 511 ####################
 512 ##  Java bindings ##
 513 ####################
 514
 515 AS_IF([test "x$BINDINGS_CXX" = xyes],
 516         [sr_java_missing=],
 517         [sr_java_missing='C++ bindings'])
 518
 519 # The Java bindings use SWIG to generate code.
 520 AS_IF([test "x$SWIG" = x],
 521         [SR_APPEND([sr_java_missing], [', '], [SWIG])])
 522
 523 # Find Java compiler and JNI includes for Java bindings.
 524 AC_CHECK_PROG([HAVE_JAVAC], [javac], [yes], [no])
 525 AS_IF([test "x$HAVE_JAVAC" = xno],
 526         [SR_APPEND([sr_java_missing], [', '], [JavaC])])
 527
 528 AC_ARG_WITH([jni-include-path],
 529         [AS_HELP_STRING([[--with-jni-include-path=DIR-LIST (space-separated)]],
 530                 [specify JNI include directories [default=detect]])],
 531         [JNI_INCLUDE_DIRS=" $withval"], [JNI_INCLUDE_DIRS=])
 532
 533 JNI_CPPFLAGS=
 534 AS_IF([test "x$enable_java$HAVE_JAVAC" = xyesyes], [
 535         AX_PROG_JAVAC
 536         AS_IF([test -z "$JNI_INCLUDE_DIRS" && test "x$cross_compiling" != xyes], [
 537                 ## Work around the totally broken logic in AX_JNI_INCLUDE_DIR:
 538                 ## If we can find jni.h without any special search path, skip
 539                 ## the execution of the broken macro to increase our chances of
 540                 ## success.
 541                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <jni.h>]], [])],,
 542                         [AX_JNI_INCLUDE_DIR])
 543         ])
 544 ])
 545 for sr_dir in $JNI_INCLUDE_DIRS
 546 do
 547         SR_APPEND([JNI_CPPFLAGS], ["-I$sr_dir"])
 548 done
 549 AC_SUBST([JNI_CPPFLAGS])
 550
 551 sr_save_cppflags=$CPPFLAGS
 552 SR_APPEND([CPPFLAGS], [$JNI_CPPFLAGS])
 553 AC_CHECK_HEADER([jni.h],,
 554         [SR_APPEND([sr_java_missing], [', '], ['JNI headers'])])
 555 CPPFLAGS=$sr_save_cppflags
 556
 557 AS_IF([test -z "$sr_java_missing"],
 558         [BINDINGS_JAVA=$enable_java], [BINDINGS_JAVA=no])
 559 AM_CONDITIONAL([BINDINGS_JAVA], [test "x$BINDINGS_JAVA" = xyes])
 560
 561 ##############################
 562 ##  Finalize configuration  ##
 563 ##############################
 564
 565 # Add mandatory dependencies to module list.
 566 SR_APPEND([SR_PKGLIBS], ['libzip >= 0.10'])
 567 AC_SUBST([SR_PKGLIBS])
 568
 569 # Retrieve the compile and link flags for all modules combined.
 570 # Also, bail out at this point if any module dependency is not met.
 571 PKG_CHECK_MODULES([LIBSIGROK], [glib-2.0 >= 2.32.0 $SR_PKGLIBS])
 572 PKG_CHECK_MODULES([TESTS], [$SR_PKGLIBS_TESTS glib-2.0 $SR_PKGLIBS])
 573
 574 # SR_PKGLIBS_CXX may be empty, so only invoke these checks when
 575 # the C++ bindings are enabled.
 576 AM_COND_IF([BINDINGS_CXX], [
 577         PKG_CHECK_MODULES([LIBSIGROKCXX], [$SR_PKGLIBS_CXX])
 578         PKG_CHECK_MODULES([PYSIGROK], [$SR_PKGLIBS_PYTHON $SR_PKGLIBS_CXX])
 579         PKG_CHECK_MODULES([RBSIGROK], [$SR_PKGLIBS_RUBY $SR_PKGLIBS_CXX], [AC_SUBST(RBSIGROK_EXTDIR, "lib/$($PKG_CONFIG --variable=sitearch $SR_PKGLIBS_RUBY)/$($PKG_CONFIG --variable=RUBY_BASE_NAME $SR_PKGLIBS_RUBY)/vendor_ruby/$($PKG_CONFIG --variable=ruby_version $SR_PKGLIBS_RUBY)")])
 580 ])
 581
 582 # Check for specific libusb features, now that we know the CFLAGS.
 583 AC_LANG([C])
 584 sr_save_cflags=$CFLAGS
 585 sr_save_libs=$LIBS
 586 CFLAGS="$LIBSIGROK_CFLAGS $CFLAGS"
 587 LIBS="$LIBSIGROK_LIBS $LIBS"
 588 AC_CHECK_TYPES([libusb_os_handle],
 589         [sr_have_libusb_os_handle=yes], [sr_have_libusb_os_handle=no],
 590         [[#include <libusb.h>]])
 591 AC_CHECK_FUNCS([zip_discard])
 592 LIBS=$sr_save_libs
 593 CFLAGS=$sr_save_cflags
 594
 595 AM_COND_IF([NEED_USB], [AS_CASE([$sr_have_libusb_os_handle:$host_os], [no:mingw*],
 596         [AC_MSG_ERROR([Windows builds require the event-abstraction branch of libusb])])])
 597
 598 sr_glib_version=`$PKG_CONFIG --modversion glib-2.0 2>&AS_MESSAGE_LOG_FD`
 599 sr_libzip_version=`$PKG_CONFIG --modversion libzip 2>&AS_MESSAGE_LOG_FD`
 600
 601 AC_DEFINE_UNQUOTED([CONF_LIBZIP_VERSION], ["$sr_libzip_version"],
 602         [Build-time version of libzip.])
 603 AC_DEFINE_UNQUOTED([CONF_HOST], ["$host"],
 604         [The canonical host libsigrok will run on.])
 605
 606 AC_CONFIG_FILES([Makefile libsigrok.pc bindings/cxx/libsigrokcxx.pc])
 607
 608 AC_OUTPUT
 609
 610 # Prepare bindings report messages.
 611 m4_define([SR_PREPARE_BINDING_REPORT], [
 612         sr_report_$1=
 613         test -z "$sr_$1_missing" || sr_report_$1=" (missing: $sr_$1_missing)"
 614         test "x$enable_$1" = xyes || sr_report_$1=' (disabled)'
 615 ])
 616 m4_map_args([SR_PREPARE_BINDING_REPORT], [cxx], [python], [ruby], [java])
 617
 618 cat >&AS_MESSAGE_FD <<_EOF
 619
 620 libsigrok configuration summary:
 621  - Package version................. $SR_PACKAGE_VERSION
 622  - Library ABI version............. $SR_LIB_VERSION
 623  - Prefix.......................... $prefix
 624  - Building on..................... $build
 625  - Building for.................... $host
 626  - Building shared / static........ $enable_shared / $enable_static
 627
 628 Compile configuration:
 629  - C compiler...................... $CC
 630  - C compiler version.............. $sr_cc_version
 631  - C compiler flags................ $CFLAGS
 632  - Additional C compiler flags..... $SR_EXTRA_CFLAGS
 633  - C compiler warnings............. $SR_WFLAGS
 634  - C++ compiler.................... $CXX
 635  - C++ compiler version............ $sr_cxx_version
 636  - C++ compiler flags.............. $CXXFLAGS
 637  - C++ compiler warnings........... $SR_WXXFLAGS
 638  - Linker flags.................... $LDFLAGS
 639
 640 Detected libraries (required):
 641  - glib-2.0 >= 2.32.0.............. $sr_glib_version
 642  - libzip >= 0.10.................. $sr_libzip_version
 643
 644 Detected libraries (optional):
 645 $sr_pkglibs_summary
 646 Enabled hardware drivers:
 647 $sr_driver_summary
 648 Enabled serial communication transports:
 649   - serial comm ................... $sr_have_serial_comm
 650   - libserialport ................. $sr_have_libserialport
 651   - hidapi ........................ $sr_have_libhidapi
 652   - bluetooth ..................... $sr_have_bluetooth
 653   - bluez ......................... $sr_have_libbluez
 654
 655 Enabled SCPI backends:
 656  - TCP............................. yes
 657  - SunRPC ......................... $sr_cv_have_sunrpc
 658  - TI-RPC ......................... $sr_cv_have_tirpc
 659  - RPC............................. $sr_cv_have_rpc
 660  - serial.......................... $sr_have_serial_comm
 661  - VISA............................ $sr_have_librevisa
 662  - GPIB............................ $sr_have_libgpib
 663  - USBTMC.......................... $sr_have_libusb
 664
 665 Enabled language bindings:
 666  - C++............................. $BINDINGS_CXX$sr_report_cxx
 667  - Python.......................... $BINDINGS_PYTHON$sr_report_python
 668  - Ruby............................ $BINDINGS_RUBY$sr_report_ruby
 669  - Java............................ $BINDINGS_JAVA$sr_report_java
 670
 671 _EOF
 672
 673 # Emit a warning if the C++ bindings are not being built.
 674 AM_COND_IF([BINDINGS_CXX], [], [
 675 cat >&AS_MESSAGE_FD <<_EOF
 676 ===============================================================================
 677 WARNING WARNING WARNING WARNING WARNING WARNING WARNING WARNING WARNING WARNING
 678 ===============================================================================
 679 ===                                                                         ===
 680 ===         The libsigrok C++ bindings are not being built since you        ===
 681 ===             are missing one or more dependencies (see above)!           ===
 682 ===                                                                         ===
 683 ===      This means you won't be able to compile frontends that require     ===
 684 ===  the C++ bindings (such as PulseView)! You also won't be able to build  ===
 685 ===     other bindings and frontends using those (such as sigrok-meter)!    ===
 686 ===                                                                         ===
 687 ===============================================================================
 688 WARNING WARNING WARNING WARNING WARNING WARNING WARNING WARNING WARNING WARNING
 689 ===============================================================================
 690
 691 _EOF
 692 ])