configure.ac

   1 ##
   2 ## This file is part of the libsigrok project.
   3 ##
   4 ## Copyright (C) 2010-2012 Bert Vermeulen <bert@biot.com>
   5 ## Copyright (C) 2012 Alexandru Gagniuc <mr.nuke.me@gmail.com>
   6 ##
   7 ## This program is free software: you can redistribute it and/or modify
   8 ## it under the terms of the GNU General Public License as published by
   9 ## the Free Software Foundation, either version 3 of the License, or
  10 ## (at your option) any later version.
  11 ##
  12 ## This program is distributed in the hope that it will be useful,
  13 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ## GNU General Public License for more details.
  16 ##
  17 ## You should have received a copy of the GNU General Public License
  18 ## along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19 ##
  20
  21 # We require at least autoconf 2.63 (AC_INIT format changed there).
  22 AC_PREREQ([2.63])
  23
  24 AC_INIT([libsigrok], [0.6.0],
  25         [sigrok-devel@lists.sourceforge.net],
  26         [libsigrok], [http://www.sigrok.org])
  27 AC_CONFIG_MACRO_DIR([m4])
  28 AC_CONFIG_AUX_DIR([autostuff])
  29 AC_CONFIG_HEADERS([config.h include/libsigrok/version.h])
  30
  31 # We require at least automake 1.11 (needed for 'silent rules').
  32 AM_INIT_AUTOMAKE([1.11 -Wall -Werror no-define nostdinc subdir-objects check-news color-tests])
  33 AM_SILENT_RULES([yes])
  34 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  35
  36 AC_CANONICAL_HOST
  37
  38 # Checks for programs.
  39 AC_PROG_CC
  40 AC_PROG_CXX
  41 AC_PROG_INSTALL
  42 AC_PROG_LN_S
  43
  44 # Required for per-target flags or subdir-objects with C sources.
  45 AM_PROG_CC_C_O
  46
  47 # Set the standard the C library headers should conform to.
  48 AH_VERBATIM([_POSIX_C_SOURCE], [/* The targeted POSIX standard. */
  49 #ifndef _POSIX_C_SOURCE
  50 # define _POSIX_C_SOURCE 200112L
  51 #endif])
  52
  53 # Get compiler versions.
  54 SR_PROG_VERSION([$CC], [sr_cc_version])
  55 SR_PROG_VERSION([$CXX], [sr_cxx_version])
  56
  57 # Check for optional make features.
  58 SR_PROG_MAKE_ORDER_ONLY
  59
  60 # Initialize libtool.
  61 LT_INIT
  62
  63 # Set up the libsigrok version defines.
  64 SR_PKG_VERSION_SET([SR_PACKAGE_VERSION], [AC_PACKAGE_VERSION])
  65
  66 # Library version for libsigrok (NOT the same as the package version).
  67 # Carefully read the libtool docs before updating these numbers!
  68 # The algorithm for determining which number to change (and how) is nontrivial!
  69 # http://www.gnu.org/software/libtool/manual/libtool.html#Updating-version-info
  70 # Format: current:revision:age.
  71 SR_LIB_VERSION_SET([SR_LIB_VERSION], [4:0:0])
  72
  73 AM_CONDITIONAL([WIN32], [test -z "${host_os##mingw*}" || test -z "${host_os##cygwin*}"])
  74
  75 #############################
  76 ##  Optional dependencies  ##
  77 #############################
  78
  79 AC_LANG([C])
  80
  81 # Initialize pkg-config.
  82 # We require at least 0.22, as "Requires.private" behaviour changed there.
  83 PKG_PROG_PKG_CONFIG([0.22])
  84
  85 # Keep track of all checked modules so we can list them at the end.
  86 SR_PKG_CHECK_SUMMARY([sr_pkglibs_summary])
  87
  88 # Collect the pkg-config module names of all dependencies in SR_PKGLIBS.
  89 # These are used to derive the compiler flags and for the "Requires.private"
  90 # field in the generated libsigrok.pc file.
  91 SR_VAR_OPT_PKG([SR_PKGLIBS], [sr_deps_avail])
  92 SR_PKGLIBS_TESTS=
  93 SR_PKGLIBS_CXX=
  94 SR_PKGLIBS_PYTHON=
  95 SR_PKGLIBS_RUBY=
  96 SR_EXTRA_LIBS=
  97 SR_EXTRA_CXX_LIBS=
  98
  99 SR_ARG_OPT_PKG([libserialport], [LIBSERIALPORT], ,
 100         [libserialport >= 0.1.1])
 101
 102 SR_ARG_OPT_PKG([libftdi], [LIBFTDI], , [libftdi1 >= 1.0])
 103
 104 # pkg-config file names: MinGW/MacOSX: hidapi; Linux: hidapi-hidraw/-libusb
 105 SR_ARG_OPT_PKG([libhidapi], [LIBHIDAPI], ,
 106         [hidapi >= 0.8.0], [hidapi-hidraw >= 0.8.0], [hidapi-libusb >= 0.8.0])
 107
 108 SR_ARG_OPT_PKG([libbluez], [LIBBLUEZ], , [bluez >= 4.0])
 109
 110 SR_ARG_OPT_PKG([libnettle], [LIBNETTLE], , [nettle])
 111
 112 # FreeBSD comes with an "integrated" libusb-1.0-style USB API.
 113 # This means libusb-1.0 is always available; no need to check for it.
 114 # On Windows, require the latest version we can get our hands on,
 115 # until the new generic event handling has seen an official release.
 116 AS_CASE([$host_os],
 117         [freebsd*], [sr_libusb_req='libusb-1.0' sr_have_libusb=yes],
 118         [mingw*], [sr_libusb_req='libusb-1.0 >= 1.0.20'],
 119         [sr_libusb_req='libusb-1.0 >= 1.0.16'])
 120
 121 SR_ARG_OPT_PKG([libusb], [LIBUSB_1_0], [NEED_USB],
 122         [$sr_libusb_req])
 123
 124 SR_ARG_OPT_PKG([librevisa], [LIBREVISA], [NEED_VISA],
 125         [librevisa >= 0.0.20130412])
 126
 127 SR_ARG_OPT_PKG([libgpib], [LIBGPIB], [NEED_GPIB],
 128         [libgpib])
 129
 130 SR_ARG_OPT_CHECK([libieee1284], [LIBIEEE1284],, [
 131         sr_save_LIBS=$LIBS
 132         LIBS="-lieee1284 $LIBS"
 133         AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <ieee1284.h>]],
 134                                 [[(void) ieee1284_open(0, 0, 0);]])],
 135                 [sr_have_libieee1284=yes], [sr_have_libieee1284=no])
 136         LIBS=$sr_save_LIBS
 137 ])
 138 AS_IF([test "x$sr_have_libieee1284" = xyes],
 139         [SR_PREPEND([SR_EXTRA_LIBS], [-lieee1284])])
 140
 141 SR_ARG_OPT_PKG([libgio], [LIBGIO], , [gio-2.0 >= 2.24.0])
 142
 143 # See if any of the (potentially platform specific) libs are available
 144 # which provide some means of Bluetooth communication.
 145 AS_IF([test "x$sr_have_libbluez" = xyes],
 146         sr_have_bluetooth=yes, sr_have_bluetooth=no)
 147 AS_IF([test "x$sr_have_bluetooth" = xyes],
 148         [AC_DEFINE([HAVE_BLUETOOTH], [1], [Specifies whether Bluetooth communication is supported.])])
 149 AS_IF([test "x$sr_have_bluetooth" = xyes],
 150         [SR_APPEND([sr_deps_avail], [bluetooth_comm])])
 151
 152 AS_IF([test "x$sr_have_libserialport" = xyes -o "x$sr_have_libhidapi" = xyes -o "x$sr_have_bluetooth" = xyes],
 153         sr_have_serial_comm=yes, sr_have_serial_comm=no)
 154 AS_IF([test "x$sr_have_serial_comm" = xyes],
 155         [AC_DEFINE([HAVE_SERIAL_COMM], [1], [Specifies whether serial communication is supported.])])
 156 AS_IF([test "x$sr_have_serial_comm" = xyes],
 157         [SR_APPEND([sr_deps_avail], [serial_comm])])
 158 AM_CONDITIONAL([NEED_SERIAL], [test "x$sr_have_serial_comm" = xyes])
 159
 160 ######################
 161 ##  Feature checks  ##
 162 ######################
 163
 164 # The Check unit testing framework is optional. Disable if not found.
 165 SR_PKG_CHECK([check], [SR_PKGLIBS_TESTS], [check >= 0.9.4])
 166 AM_CONDITIONAL([HAVE_CHECK], [test "x$sr_have_check" = xyes])
 167
 168 # Enable the C99 standard if possible, and enforce the use
 169 # of SR_API to explicitly mark all public API functions.
 170 SR_EXTRA_CFLAGS=
 171 SR_CHECK_COMPILE_FLAGS([SR_EXTRA_CFLAGS], [C99], [-std=c99 -c99 -AC99 -qlanglvl=extc99])
 172 SR_CHECK_COMPILE_FLAGS([SR_EXTRA_CFLAGS], [visibility], [-fvisibility=hidden])
 173
 174 SR_ARG_ENABLE_WARNINGS([SR_WFLAGS], [-Wall], [-Wall -Wextra -Wmissing-prototypes])
 175
 176 # Check host characteristics.
 177 AC_SYS_LARGEFILE
 178 AC_C_BIGENDIAN
 179
 180 AC_CHECK_HEADERS([sys/mman.h], [SR_APPEND([sr_deps_avail], [sys_mman_h])])
 181 AC_CHECK_HEADERS([sys/ioctl.h], [SR_APPEND([sr_deps_avail], [sys_ioctl_h])])
 182 AC_CHECK_HEADERS([sys/timerfd.h], [SR_APPEND([sr_deps_avail], [sys_timerfd_h])])
 183
 184 # We need to link against the Winsock2 library for SCPI over TCP.
 185 AS_CASE([$host_os], [mingw*], [SR_PREPEND([SR_EXTRA_LIBS], [-lws2_32])])
 186
 187 # libm (the standard math library) is always needed.
 188 SR_SEARCH_LIBS([SR_EXTRA_LIBS], [pow], [m])
 189
 190 # RPC is only needed for VXI support.
 191 AC_CACHE_CHECK([for RPC support], [sr_cv_have_rpc],
 192         [AC_LINK_IFELSE([AC_LANG_PROGRAM(
 193                         [[#include <rpc/rpc.h>]m4_newline[CLIENT *rpc_test(void);]],
 194                         [[(void) clnt_create("", 0, 0, "");]])],
 195                 [sr_cv_have_rpc=yes], [sr_cv_have_rpc=no])])
 196 AS_IF([test "x$sr_cv_have_rpc" = xyes],
 197         [AC_DEFINE([HAVE_RPC], [1], [Specifies whether we have RPC support.])])
 198 # VXI support is only compiled if RPC support was found.
 199 AM_CONDITIONAL([NEED_RPC], [test "x$sr_cv_have_rpc" = xyes])
 200
 201 # Check for compiler support of 128 bit integers
 202 AC_CHECK_TYPES([__int128_t, __uint128_t], [], [], [])
 203
 204 # Availability of bt_put_le16() depends on the bluez library version.
 205 AC_CACHE_CHECK([for bt_put_le16], [sr_cv_have_btputle16],
 206         [AC_LINK_IFELSE([AC_LANG_PROGRAM(
 207                         [[#include <bluetooth/bluetooth.h>]],
 208                         [[bt_put_le16(0, (void *)0);]])],
 209                 [sr_cv_have_btputle16=yes], [sr_cv_have_btputle16=no])])
 210 AS_IF([test "x$sr_cv_have_btputle16" = xyes],
 211         [AC_DEFINE([HAVE_BT_PUT_LE16], [1], [Specifies whether we have bt_put_le16().])])
 212
 213 ########################
 214 ##  Hardware drivers  ##
 215 ########################
 216
 217 # Keep track of all drivers so we can list them at the end.
 218 SR_VAR_SUMMARY([sr_driver_summary])
 219
 220 # Check whether the sr_deps_avail list contains all of the arguments.
 221 # Unavailable dependencies are collected in sr_deps_missing.
 222 sr_check_driver_deps() {
 223         sr_deps_missing=
 224         for sr_dep
 225         do
 226                 AS_CASE([" $sr_deps_avail "], [*" $sr_dep "*],,
 227                         [SR_APPEND([sr_deps_missing], [', '], [$sr_dep])])
 228         done
 229         test -z "$sr_deps_missing" || return 1
 230 }
 231
 232 AC_ARG_ENABLE([all-drivers],
 233         [AS_HELP_STRING([--enable-all-drivers],
 234                         [enable all drivers by default [default=yes]])],
 235         [], [enable_all_drivers=yes])
 236
 237 ## _SR_DRIVER(Device name, driver-name, var-name, [dependencies...])
 238 m4_define([_SR_DRIVER], [
 239         AC_ARG_ENABLE([$2],
 240                 [AS_HELP_STRING([--enable-$2], [enable $1 support])],
 241                 [$3=$enableval], [$3=$enable_all_drivers])
 242
 243         AS_IF([test "x[$]$3" = xyes], [sr_hw_info=yes[]m4_ifval([$4], [
 244                 sr_check_driver_deps $4 \
 245                         || $3=no sr_hw_info="no (missing: $sr_deps_missing)"
 246         ])], [sr_hw_info='no (disabled)'])
 247         sr_driver_summary_append "$2" "$sr_hw_info"
 248
 249         AM_CONDITIONAL([$3], [test "x[$]$3" = xyes])
 250         AM_COND_IF([$3], [AC_DEFINE([HAVE_$3], [1], [Whether to support $1 device.]) AC_DEFINE([HAVE_DRIVERS], [1], [Whether at least one driver is enabled.])])
 251 ])
 252
 253 ## SR_DRIVER(Device name, driver-name, [dependencies...])
 254 m4_define([SR_DRIVER],
 255         [_SR_DRIVER([$1], [$2], m4_expand([AS_TR_CPP([HW_$2])]), [$3])])
 256
 257 SR_DRIVER([Agilent DMM], [agilent-dmm], [serial_comm])
 258 SR_DRIVER([Appa 55II], [appa-55ii], [serial_comm])
 259 SR_DRIVER([Arachnid Labs Re:load Pro], [arachnid-labs-re-load-pro], [serial_comm])
 260 SR_DRIVER([ASIX SIGMA/SIGMA2], [asix-sigma], [libftdi])
 261 SR_DRIVER([Atten PPS3xxx], [atten-pps3xxx], [serial_comm])
 262 SR_DRIVER([BayLibre ACME], [baylibre-acme], [sys_timerfd_h])
 263 SR_DRIVER([BeagleLogic], [beaglelogic], [sys_mman_h sys_ioctl_h])
 264 SR_DRIVER([Brymen DMM], [brymen-dmm], [serial_comm])
 265 SR_DRIVER([CEM DT-885x], [cem-dt-885x], [serial_comm])
 266 SR_DRIVER([Center 3xx], [center-3xx], [serial_comm])
 267 SR_DRIVER([ChronoVu LA], [chronovu-la], [libusb libftdi])
 268 SR_DRIVER([Colead SLM], [colead-slm], [serial_comm])
 269 SR_DRIVER([Conrad DIGI 35 CPU], [conrad-digi-35-cpu], [serial_comm])
 270 SR_DRIVER([demo], [demo])
 271 SR_DRIVER([DreamSourceLab DSLogic], [dreamsourcelab-dslogic], [libusb])
 272 SR_DRIVER([Fluke 45], [fluke-45])
 273 SR_DRIVER([Fluke DMM], [fluke-dmm], [serial_comm])
 274 SR_DRIVER([FTDI LA], [ftdi-la], [libusb libftdi])
 275 SR_DRIVER([fx2lafw], [fx2lafw], [libusb])
 276 SR_DRIVER([GMC MH 1x/2x], [gmc-mh-1x-2x], [serial_comm])
 277 SR_DRIVER([GW Instek GDS-800], [gwinstek-gds-800], [serial_comm])
 278 SR_DRIVER([GW Instek GPD], [gwinstek-gpd], [serial_comm])
 279 SR_DRIVER([Hameg HMO], [hameg-hmo], [serial_comm])
 280 SR_DRIVER([Hantek 4032L], [hantek-4032l], [libusb])
 281 SR_DRIVER([Hantek 6xxx], [hantek-6xxx], [libusb])
 282 SR_DRIVER([Hantek DSO], [hantek-dso], [libusb])
 283 SR_DRIVER([HP 3457A], [hp-3457a])
 284 SR_DRIVER([HP 3478A], [hp-3478a], [libgpib])
 285 SR_DRIVER([Hung-Chang DSO-2100], [hung-chang-dso-2100], [libieee1284])
 286 SR_DRIVER([Ikalogic Scanalogic-2], [ikalogic-scanalogic2], [libusb])
 287 SR_DRIVER([Ikalogic Scanaplus], [ikalogic-scanaplus], [libftdi])
 288 SR_DRIVER([IPDBG LA], [ipdbg-la])
 289 SR_DRIVER([Kecheng KC-330B], [kecheng-kc-330b], [libusb])
 290 SR_DRIVER([KERN scale], [kern-scale], [serial_comm])
 291 SR_DRIVER([Kingst LA2016], [kingst-la2016], [libusb])
 292 SR_DRIVER([Korad KAxxxxP], [korad-kaxxxxp], [serial_comm])
 293 SR_DRIVER([Lascar EL-USB], [lascar-el-usb], [libusb])
 294 SR_DRIVER([LeCroy LogicStudio], [lecroy-logicstudio], [libusb])
 295 SR_DRIVER([LeCroy X-Stream], [lecroy-xstream])
 296 SR_DRIVER([Manson HCS-3xxx], [manson-hcs-3xxx], [serial_comm])
 297 SR_DRIVER([Mastech MS6514], [mastech-ms6514], [serial_comm])
 298 SR_DRIVER([maynuo-m97], [maynuo-m97])
 299 SR_DRIVER([MIC 985xx], [mic-985xx], [serial_comm])
 300 SR_DRIVER([Microchip PICkit2], [microchip-pickit2], [libusb])
 301 SR_DRIVER([Mooshimeter DMM], [mooshimeter-dmm], [bluetooth_comm libgio])
 302 SR_DRIVER([Motech LPS 30x], [motech-lps-30x], [serial_comm])
 303 SR_DRIVER([Norma DMM], [norma-dmm], [serial_comm])
 304 SR_DRIVER([OpenBench Logic Sniffer], [openbench-logic-sniffer], [serial_comm])
 305 SR_DRIVER([PCE PCE-322A], [pce-322a], [serial_comm])
 306 SR_DRIVER([Pipistrello-OLS], [pipistrello-ols], [libftdi])
 307 SR_DRIVER([RDTech DPSxxxx/DPHxxxx], [rdtech-dps], [serial_comm])
 308 SR_DRIVER([RDTech UMXX], [rdtech-um], [serial_comm])
 309 SR_DRIVER([RDTech TCXX], [rdtech-tc], [serial_comm libnettle])
 310 SR_DRIVER([Rigol DS], [rigol-ds])
 311 SR_DRIVER([Rohde&Schwarz SME-0x], [rohde-schwarz-sme-0x], [serial_comm])
 312 SR_DRIVER([Saleae Logic16], [saleae-logic16], [libusb])
 313 SR_DRIVER([Saleae Logic Pro], [saleae-logic-pro], [libusb])
 314 SR_DRIVER([SCPI DMM], [scpi-dmm])
 315 SR_DRIVER([SCPI PPS], [scpi-pps])
 316 SR_DRIVER([serial DMM], [serial-dmm], [serial_comm])
 317 SR_DRIVER([serial LCR], [serial-lcr], [serial_comm])
 318 SR_DRIVER([Siglent SDS], [siglent-sds])
 319 SR_DRIVER([Sysclk LWLA], [sysclk-lwla], [libusb])
 320 SR_DRIVER([Sysclk SLA5032], [sysclk-sla5032], [libusb])
 321 SR_DRIVER([Teleinfo], [teleinfo], [serial_comm])
 322 SR_DRIVER([Testo], [testo], [libusb])
 323 SR_DRIVER([Tondaj SL-814], [tondaj-sl-814], [serial_comm])
 324 SR_DRIVER([UNI-T DMM], [uni-t-dmm], [libusb])
 325 SR_DRIVER([UNI-T UT181A], [uni-t-ut181a], [serial_comm])
 326 SR_DRIVER([UNI-T UT32x], [uni-t-ut32x], [serial_comm])
 327 SR_DRIVER([Yokogawa DL/DLM], [yokogawa-dlm])
 328 SR_DRIVER([ZEROPLUS Logic Cube], [zeroplus-logic-cube], [libusb])
 329 SR_DRIVER([ZKETECH EBD-USB], [zketech-ebd-usb], [serial_comm])
 330
 331 ###############################
 332 ##  Language bindings setup  ##
 333 ###############################
 334
 335 AC_LANG([C++])
 336 SR_ARG_ENABLE_WARNINGS([SR_WXXFLAGS], [-Wall], [-Wall -Wextra])
 337
 338 AC_ARG_ENABLE([bindings],
 339         [AS_HELP_STRING([--enable-bindings], [build language bindings [default=yes]])],
 340         [], [enable_bindings=yes])
 341
 342 AC_ARG_ENABLE([cxx],
 343         [AS_HELP_STRING([--enable-cxx], [build C++ bindings [default=yes]])],
 344         [], [enable_cxx=$enable_bindings])
 345
 346 AC_ARG_ENABLE([python],
 347         [AS_HELP_STRING([--enable-python], [build Python bindings [default=yes]])],
 348         [], [enable_python=$enable_bindings])
 349
 350 AC_ARG_ENABLE([ruby],
 351         [AS_HELP_STRING([--enable-ruby], [build Ruby bindings [default=yes]])],
 352         [], [enable_ruby=$enable_bindings])
 353
 354 AC_ARG_ENABLE([java],
 355         [AS_HELP_STRING([--enable-java], [build Java bindings [default=yes]])],
 356         [], [enable_java=$enable_bindings])
 357
 358 ####################
 359 ##  C++ bindings  ##
 360 ####################
 361
 362 sr_cxx_missing=
 363
 364 # Check if the C++ compiler supports the C++11 standard.
 365 AX_CXX_COMPILE_STDCXX([11], [noext], [optional])
 366 AS_IF([test "x$HAVE_CXX11" != x1],
 367         [SR_APPEND([sr_cxx_missing], [', '], ['C++11'])])
 368
 369 # The C++ bindings need glibmm.
 370 SR_PKG_CHECK([glibmm], [SR_PKGLIBS_CXX], [glibmm-2.4 >= 2.32.0])
 371 AS_IF([test "x$sr_have_glibmm" != xyes],
 372         [SR_APPEND([sr_cxx_missing], [', '], [glibmm])])
 373
 374 # The C++ bindings use Doxygen to parse libsigrok symbols.
 375 AC_CHECK_PROG([HAVE_DOXYGEN], [doxygen], [yes], [no])
 376 AS_IF([test "x$HAVE_DOXYGEN" != xyes],
 377         [SR_APPEND([sr_cxx_missing], [', '], [Doxygen])])
 378
 379 # Link C++ code with gnustl_shared if it exists (Android)
 380 SR_SEARCH_LIBS([SR_EXTRA_CXX_LIBS], [__cxa_throw], [gnustl_shared])
 381
 382 # Python is needed for the C++ bindings.
 383 AM_PATH_PYTHON([2.7],
 384         [HAVE_PYTHON=yes],
 385         [HAVE_PYTHON=no
 386         SR_APPEND([sr_cxx_missing], [', '], [Python])])
 387
 388 AS_IF([test -z "$sr_cxx_missing"],
 389         [BINDINGS_CXX=$enable_cxx], [BINDINGS_CXX=no])
 390 AM_CONDITIONAL([BINDINGS_CXX], [test "x$BINDINGS_CXX" = xyes])
 391
 392 # C++ bindings want stoi and stod.
 393 AM_COND_IF([BINDINGS_CXX], [
 394         AC_CACHE_CHECK([for stoi and stod], [sr_cv_have_stoi_stod],
 395                 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <string>]],
 396                                 [[(void) std::stoi("1"); (void) std::stod("1.0");]])],
 397                         [sr_cv_have_stoi_stod=yes], [sr_cv_have_stoi_stod=no])])
 398         AS_IF([test "x$sr_cv_have_stoi_stod" = xyes],
 399                 [AC_DEFINE([HAVE_STOI_STOD], [1],
 400                         [Specifies whether we have the stoi and stod functions.])])
 401 ])
 402
 403 #######################
 404 ##  Python bindings  ##
 405 #######################
 406
 407 AS_IF([test "x$BINDINGS_CXX" = xyes],
 408         [sr_python_missing=],
 409         [sr_python_missing='C++ bindings'])
 410
 411 # Extract major and minor version number of the Python interpreter.
 412 sr_pymajor=${PYTHON_VERSION%%.*}
 413 sr_pyminor=${PYTHON_VERSION#*.}
 414
 415 # The Python bindings need Python development files. Check for either
 416 # Python 3 or Python 2 headers depending on the interpreter version.
 417 SR_PKG_CHECK([python_dev], [SR_PKGLIBS_PYTHON],
 418         [python = $PYTHON_VERSION],
 419         [python$sr_pymajor = $PYTHON_VERSION],
 420         [python$sr_pymajor$sr_pyminor = $PYTHON_VERSION],
 421         [python-$PYTHON_VERSION = $PYTHON_VERSION])
 422
 423 AS_IF([test "x$sr_have_python_dev" != xyes],
 424         [SR_APPEND([sr_python_missing], [', '], [Headers])])
 425
 426 # PyGObject is needed for the Python bindings.
 427 SR_PKG_CHECK([pygobject], [SR_PKGLIBS_PYTHON], [pygobject-3.0 >= 3.0.0])
 428 AS_IF([test "x$sr_have_pygobject" != xyes],
 429         [SR_APPEND([sr_python_missing], [', '], [PyGObject])])
 430
 431 PKG_CHECK_EXISTS([pygobject-3.0 < 3.7.91],
 432         [AC_DEFINE([PYGOBJECT_FLAGS_SIGNED], [1],
 433                 [Whether last argument to pyg_flags_get_value() is signed.])])
 434
 435 # The Python bindings need the setuptools and numpy Python modules.
 436 # We'll let it go through even if the AX macro wasn't found, as the
 437 # Python modules may still be there.
 438 m4_ifdef([AX_PYTHON_MODULE], [
 439         AX_PYTHON_MODULE([setuptools])
 440         AX_PYTHON_MODULE([numpy])
 441 ], [
 442         HAVE_PYMOD_SETUPTOOLS=yes
 443         HAVE_PYMOD_NUMPY=yes
 444         m4_warn([unsupported],
 445                 [Missing macro AX_PYTHON_MODULE: no check for setuptools and numpy])
 446 ])
 447 AS_IF([test "x$HAVE_PYMOD_SETUPTOOLS" != xyes],
 448         [SR_APPEND([sr_python_missing], [', '], [setuptools])])
 449 AS_IF([test "x$HAVE_PYMOD_NUMPY" != xyes],
 450         [SR_APPEND([sr_python_missing], [', '], [numpy])])
 451
 452 # The Python bindings use SWIG to generate code.
 453 AC_CHECK_PROGS([SWIG], [swig swig4.0 swig3.0 swig2.0])
 454 AS_IF([test "x$SWIG" != x],
 455     AC_MSG_CHECKING([for $SWIG version])
 456     [SWIG_VERSION=`$SWIG -version 2>&1 | sed -n 's/SWIG Version //p'`]
 457     AC_MSG_RESULT([$SWIG_VERSION]))
 458 AS_IF([test "x$SWIG" = x],
 459         [SR_APPEND([sr_python_missing], [', '], [SWIG])])
 460
 461 AS_IF([test -z "$sr_python_missing"],
 462         [BINDINGS_PYTHON=$enable_python], [BINDINGS_PYTHON=no])
 463 AM_CONDITIONAL([BINDINGS_PYTHON], [test "x$BINDINGS_PYTHON" = xyes])
 464
 465 #####################
 466 ##  Ruby bindings  ##
 467 #####################
 468
 469 AS_IF([test "x$BINDINGS_CXX" = xyes],
 470         [sr_ruby_missing=],
 471         [sr_ruby_missing='C++ bindings'])
 472
 473 AC_PATH_PROGS(RUBY, ["${RUBY-ruby}"], [])
 474 AS_IF([test "x$RUBY" != x],
 475         AC_MSG_CHECKING([for Ruby version])
 476     [RUBY_VERSION=`$RUBY -e 'puts RUBY_VERSION'`]
 477     AC_MSG_RESULT([$RUBY_VERSION])
 478     [RUBY_DLEXT=`$RUBY -rrbconfig -e 'puts RbConfig::CONFIG[["DLEXT"]]'`]
 479     AC_SUBST(RUBY_DLEXT))
 480
 481 AS_IF([test "x$RUBY" = x],
 482         [SR_APPEND([sr_ruby_missing], [', '], [Ruby])])
 483
 484 # Extract major and minor version number of the Ruby interpreter.
 485 sr_rbmajor=${RUBY_VERSION%%.*}
 486 sr_rbminor=${RUBY_VERSION#*.}
 487 sr_rbminor=${sr_rbminor%%.*}
 488
 489 # The Ruby bindings need Ruby development files.
 490 SR_PKG_CHECK([ruby_dev], [SR_PKGLIBS_RUBY],
 491         [ruby],
 492         [ruby-$sr_rbmajor.$sr_rbminor])
 493
 494 AS_IF([test "x$sr_have_ruby_dev" != xyes],
 495         [SR_APPEND([sr_ruby_missing], [', '], [Headers])])
 496
 497 # The Ruby bindings use SWIG >= 3.0.8 to generate code.
 498 AS_IF([test "x$SWIG" = x],
 499         [SR_APPEND([sr_ruby_missing], [', '], [SWIG])],
 500         [AS_VERSION_COMPARE($SWIG_VERSION, "3.0.8",
 501                 [SR_APPEND([sr_ruby_missing], [', '], ['SWIG >= 3.0.8'])])])
 502
 503 AS_IF([test -z "$sr_ruby_missing"],
 504         [BINDINGS_RUBY=$enable_ruby], [BINDINGS_RUBY=no])
 505 AM_CONDITIONAL([BINDINGS_RUBY], [test "x$BINDINGS_RUBY" = xyes])
 506
 507 ####################
 508 ##  Java bindings ##
 509 ####################
 510
 511 AS_IF([test "x$BINDINGS_CXX" = xyes],
 512         [sr_java_missing=],
 513         [sr_java_missing='C++ bindings'])
 514
 515 # The Java bindings use SWIG to generate code.
 516 AS_IF([test "x$SWIG" = x],
 517         [SR_APPEND([sr_java_missing], [', '], [SWIG])])
 518
 519 # Find Java compiler and JNI includes for Java bindings.
 520 AC_CHECK_PROG([HAVE_JAVAC], [javac], [yes], [no])
 521 AS_IF([test "x$HAVE_JAVAC" = xno],
 522         [SR_APPEND([sr_java_missing], [', '], [JavaC])])
 523
 524 AC_ARG_WITH([jni-include-path],
 525         [AS_HELP_STRING([[--with-jni-include-path=DIR-LIST (space-separated)]],
 526                 [specify JNI include directories [default=detect]])],
 527         [JNI_INCLUDE_DIRS=" $withval"], [JNI_INCLUDE_DIRS=])
 528
 529 JNI_CPPFLAGS=
 530 AS_IF([test "x$enable_java$HAVE_JAVAC" = xyesyes], [
 531         AX_PROG_JAVAC
 532         AS_IF([test -z "$JNI_INCLUDE_DIRS" && test "x$cross_compiling" != xyes], [
 533                 ## Work around the totally broken logic in AX_JNI_INCLUDE_DIR:
 534                 ## If we can find jni.h without any special search path, skip
 535                 ## the execution of the broken macro to increase our chances of
 536                 ## success.
 537                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <jni.h>]], [])],,
 538                         [AX_JNI_INCLUDE_DIR])
 539         ])
 540 ])
 541 for sr_dir in $JNI_INCLUDE_DIRS
 542 do
 543         SR_APPEND([JNI_CPPFLAGS], ["-I$sr_dir"])
 544 done
 545 AC_SUBST([JNI_CPPFLAGS])
 546
 547 sr_save_cppflags=$CPPFLAGS
 548 SR_APPEND([CPPFLAGS], [$JNI_CPPFLAGS])
 549 AC_CHECK_HEADER([jni.h],,
 550         [SR_APPEND([sr_java_missing], [', '], ['JNI headers'])])
 551 CPPFLAGS=$sr_save_cppflags
 552
 553 AS_IF([test -z "$sr_java_missing"],
 554         [BINDINGS_JAVA=$enable_java], [BINDINGS_JAVA=no])
 555 AM_CONDITIONAL([BINDINGS_JAVA], [test "x$BINDINGS_JAVA" = xyes])
 556
 557 ##############################
 558 ##  Finalize configuration  ##
 559 ##############################
 560
 561 # Add mandatory dependencies to module list.
 562 SR_APPEND([SR_PKGLIBS], ['libzip >= 0.10'])
 563 AC_SUBST([SR_PKGLIBS])
 564
 565 # Retrieve the compile and link flags for all modules combined.
 566 # Also, bail out at this point if any module dependency is not met.
 567 PKG_CHECK_MODULES([LIBSIGROK], [glib-2.0 >= 2.32.0 $SR_PKGLIBS])
 568 PKG_CHECK_MODULES([TESTS], [$SR_PKGLIBS_TESTS glib-2.0 $SR_PKGLIBS])
 569
 570 # SR_PKGLIBS_CXX may be empty, so only invoke these checks when
 571 # the C++ bindings are enabled.
 572 AM_COND_IF([BINDINGS_CXX], [
 573         PKG_CHECK_MODULES([LIBSIGROKCXX], [$SR_PKGLIBS_CXX])
 574         PKG_CHECK_MODULES([PYSIGROK], [$SR_PKGLIBS_PYTHON $SR_PKGLIBS_CXX])
 575         PKG_CHECK_MODULES([RBSIGROK], [$SR_PKGLIBS_RUBY $SR_PKGLIBS_CXX], [AC_SUBST(RBSIGROK_EXTDIR, "lib/$($PKG_CONFIG --variable=sitearch $SR_PKGLIBS_RUBY)/$($PKG_CONFIG --variable=RUBY_BASE_NAME $SR_PKGLIBS_RUBY)/vendor_ruby/$($PKG_CONFIG --variable=ruby_version $SR_PKGLIBS_RUBY)")])
 576 ])
 577
 578 # Check for specific libusb features, now that we know the CFLAGS.
 579 AC_LANG([C])
 580 sr_save_cflags=$CFLAGS
 581 sr_save_libs=$LIBS
 582 CFLAGS="$LIBSIGROK_CFLAGS $CFLAGS"
 583 LIBS="$LIBSIGROK_LIBS $LIBS"
 584 AC_CHECK_TYPES([libusb_os_handle],
 585         [sr_have_libusb_os_handle=yes], [sr_have_libusb_os_handle=no],
 586         [[#include <libusb.h>]])
 587 AC_CHECK_FUNCS([zip_discard])
 588 LIBS=$sr_save_libs
 589 CFLAGS=$sr_save_cflags
 590
 591 AM_COND_IF([NEED_USB], [AS_CASE([$sr_have_libusb_os_handle:$host_os], [no:mingw*],
 592         [AC_MSG_ERROR([Windows builds require the event-abstraction branch of libusb])])])
 593
 594 sr_glib_version=`$PKG_CONFIG --modversion glib-2.0 2>&AS_MESSAGE_LOG_FD`
 595 sr_libzip_version=`$PKG_CONFIG --modversion libzip 2>&AS_MESSAGE_LOG_FD`
 596
 597 AC_DEFINE_UNQUOTED([CONF_LIBZIP_VERSION], ["$sr_libzip_version"],
 598         [Build-time version of libzip.])
 599 AC_DEFINE_UNQUOTED([CONF_HOST], ["$host"],
 600         [The canonical host libsigrok will run on.])
 601
 602 AC_CONFIG_FILES([Makefile libsigrok.pc bindings/cxx/libsigrokcxx.pc])
 603
 604 AC_OUTPUT
 605
 606 # Prepare bindings report messages.
 607 m4_define([SR_PREPARE_BINDING_REPORT], [
 608         sr_report_$1=
 609         test -z "$sr_$1_missing" || sr_report_$1=" (missing: $sr_$1_missing)"
 610         test "x$enable_$1" = xyes || sr_report_$1=' (disabled)'
 611 ])
 612 m4_map_args([SR_PREPARE_BINDING_REPORT], [cxx], [python], [ruby], [java])
 613
 614 cat >&AS_MESSAGE_FD <<_EOF
 615
 616 libsigrok configuration summary:
 617  - Package version................. $SR_PACKAGE_VERSION
 618  - Library ABI version............. $SR_LIB_VERSION
 619  - Prefix.......................... $prefix
 620  - Building on..................... $build
 621  - Building for.................... $host
 622  - Building shared / static........ $enable_shared / $enable_static
 623
 624 Compile configuration:
 625  - C compiler...................... $CC
 626  - C compiler version.............. $sr_cc_version
 627  - C compiler flags................ $CFLAGS
 628  - Additional C compiler flags..... $SR_EXTRA_CFLAGS
 629  - C compiler warnings............. $SR_WFLAGS
 630  - C++ compiler.................... $CXX
 631  - C++ compiler version............ $sr_cxx_version
 632  - C++ compiler flags.............. $CXXFLAGS
 633  - C++ compiler warnings........... $SR_WXXFLAGS
 634  - Linker flags.................... $LDFLAGS
 635
 636 Detected libraries (required):
 637  - glib-2.0 >= 2.32.0.............. $sr_glib_version
 638  - libzip >= 0.10.................. $sr_libzip_version
 639
 640 Detected libraries (optional):
 641 $sr_pkglibs_summary
 642 Enabled hardware drivers:
 643 $sr_driver_summary
 644 Enabled serial communication transports:
 645   - serial comm ................... $sr_have_serial_comm
 646   - libserialport ................. $sr_have_libserialport
 647   - hidapi ........................ $sr_have_libhidapi
 648   - bluetooth ..................... $sr_have_bluetooth
 649   - bluez ......................... $sr_have_libbluez
 650
 651 Enabled SCPI backends:
 652  - TCP............................. yes
 653  - RPC............................. $sr_cv_have_rpc
 654  - serial.......................... $sr_have_serial_comm
 655  - VISA............................ $sr_have_librevisa
 656  - GPIB............................ $sr_have_libgpib
 657  - USBTMC.......................... $sr_have_libusb
 658
 659 Enabled language bindings:
 660  - C++............................. $BINDINGS_CXX$sr_report_cxx
 661  - Python.......................... $BINDINGS_PYTHON$sr_report_python
 662  - Ruby............................ $BINDINGS_RUBY$sr_report_ruby
 663  - Java............................ $BINDINGS_JAVA$sr_report_java
 664
 665 _EOF
 666
 667 # Emit a warning if the C++ bindings are not being built.
 668 AM_COND_IF([BINDINGS_CXX], [], [
 669 cat >&AS_MESSAGE_FD <<_EOF
 670 ===============================================================================
 671 WARNING WARNING WARNING WARNING WARNING WARNING WARNING WARNING WARNING WARNING
 672 ===============================================================================
 673 ===                                                                         ===
 674 ===         The libsigrok C++ bindings are not being built since you        ===
 675 ===             are missing one or more dependencies (see above)!           ===
 676 ===                                                                         ===
 677 ===      This means you won't be able to compile frontends that require     ===
 678 ===  the C++ bindings (such as PulseView)! You also won't be able to build  ===
 679 ===     other bindings and frontends using those (such as sigrok-meter)!    ===
 680 ===                                                                         ===
 681 ===============================================================================
 682 WARNING WARNING WARNING WARNING WARNING WARNING WARNING WARNING WARNING WARNING
 683 ===============================================================================
 684
 685 _EOF
 686 ])