sigrok.org Git - libsigrok.git/blob

1 ##

2 ## This file is part of the libsigrok project.

3 ##

6 ##

7 ## This program is free software: you can redistribute it and/or modify

8 ## it under the terms of the GNU General Public License as published by

9 ## the Free Software Foundation, either version 3 of the License, or

10 ## (at your option) any later version.

11 ##

12 ## This program is distributed in the hope that it will be useful,

13 ## but WITHOUT ANY WARRANTY; without even the implied warranty of

14 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the

15 ## GNU General Public License for more details.

16 ##

17 ## You should have received a copy of the GNU General Public License

18 ## along with this program. If not, see <http://www.gnu.org/licenses/>.

19 ##

20

21 # We require at least autoconf 2.63 (AC_INIT format changed there).

22 AC_PREREQ([2.63])

23

24 AC_INIT([libsigrok], [0.6.0],

25 [sigrok-devel@lists.sourceforge.net],

26 [libsigrok], [http://www.sigrok.org])

27 AC_CONFIG_MACRO_DIR([m4])

28 AC_CONFIG_AUX_DIR([autostuff])

29 AC_CONFIG_HEADERS([config.h include/libsigrok/version.h])

30

31 # We require at least automake 1.11 (needed for 'silent rules').

32 AM_INIT_AUTOMAKE([1.11 -Wall -Werror no-define nostdinc subdir-objects check-news color-tests])

33 AM_SILENT_RULES([yes])

34 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])

35

36 AC_CANONICAL_HOST

37

38 # Checks for programs.

39 AC_PROG_CC

40 AC_PROG_CXX

41 AC_PROG_INSTALL

42 AC_PROG_LN_S

43

44 # Required for per-target flags or subdir-objects with C sources.

45 AM_PROG_CC_C_O

46

47 # Set the standard the C library headers should conform to.

48 AH_VERBATIM([_POSIX_C_SOURCE], [/* The targeted POSIX standard. */

49 #ifndef _POSIX_C_SOURCE

50 # define _POSIX_C_SOURCE 200112L

51 #endif])

52

53 # Get compiler versions.

54 SR_PROG_VERSION([$CC], [sr_cc_version])

55 SR_PROG_VERSION([$CXX], [sr_cxx_version])

56

57 # Check for optional make features.

58 SR_PROG_MAKE_ORDER_ONLY

59

60 # Initialize libtool.

61 LT_INIT

62

63 # Set up the libsigrok version defines.

64 SR_PKG_VERSION_SET([SR_PACKAGE_VERSION], [AC_PACKAGE_VERSION])

65

66 # Library version for libsigrok (NOT the same as the package version).

67 # Carefully read the libtool docs before updating these numbers!

68 # The algorithm for determining which number to change (and how) is nontrivial!

69 # http://www.gnu.org/software/libtool/manual/libtool.html#Updating-version-info

70 # Format: current:revision:age.

71 SR_LIB_VERSION_SET([SR_LIB_VERSION], [4:0:0])

72

73 AM_CONDITIONAL([WIN32], [test -z "${host_os##mingw*}" || test -z "${host_os##cygwin*}"])

74

75 #############################

76 ## Optional dependencies ##

77 #############################

78

79 AC_LANG([C])

80

81 # Initialize pkg-config.

82 # We require at least 0.22, as "Requires.private" behaviour changed there.

83 PKG_PROG_PKG_CONFIG([0.22])

84

85 # Keep track of all checked modules so we can list them at the end.

86 SR_PKG_CHECK_SUMMARY([sr_pkglibs_summary])

87

88 # Collect the pkg-config module names of all dependencies in SR_PKGLIBS.

89 # These are used to derive the compiler flags and for the "Requires.private"

90 # field in the generated libsigrok.pc file.

91 SR_VAR_OPT_PKG([SR_PKGLIBS], [sr_deps_avail])

92 SR_PKGLIBS_TESTS=

93 SR_PKGLIBS_CXX=

94 SR_PKGLIBS_PYTHON=

95 SR_PKGLIBS_RUBY=

96 SR_EXTRA_LIBS=

97 SR_EXTRA_CXX_LIBS=

98

99 SR_ARG_OPT_PKG([zlib], [ZLIB], , [zlib])

100 AM_CONDITIONAL([HAVE_ZLIB], [test "x$sr_have_zlib" = xyes])

101 AM_COND_IF([HAVE_ZLIB], [

102 SR_APPEND([sr_deps_avail], ['crc32 zlib'])

103 SR_PREPEND([SR_EXTRA_LIBS], [-lz])

104 ])

105

106 AM_CONDITIONAL([HAVE_INPUT_STF], [test "x$sr_have_zlib" = xyes])

107 AM_COND_IF([HAVE_INPUT_STF], [

108 AC_DEFINE([HAVE_INPUT_STF], [1], [Is the STF input module supported?])

109 ])

110

111 SR_ARG_OPT_PKG([libserialport], [LIBSERIALPORT], ,

112 [libserialport >= 0.1.1])

113

114 SR_ARG_OPT_PKG([libftdi], [LIBFTDI], , [libftdi1 >= 1.0])

115

116 # pkg-config file names: MinGW/MacOSX: hidapi; Linux: hidapi-hidraw/-libusb

117 SR_ARG_OPT_PKG([libhidapi], [LIBHIDAPI], ,

118 [hidapi >= 0.8.0], [hidapi-hidraw >= 0.8.0], [hidapi-libusb >= 0.8.0])

119

120 SR_ARG_OPT_PKG([libbluez], [LIBBLUEZ], , [bluez >= 4.0])

121

122 SR_ARG_OPT_PKG([libnettle], [LIBNETTLE], , [nettle])

123

124 # FreeBSD comes with an "integrated" libusb-1.0-style USB API.

125 # This means libusb-1.0 is always available; no need to check for it.

126 # On Windows, require the latest version we can get our hands on,

127 # until the new generic event handling has seen an official release.

128 AS_CASE([$host_os],

129 [freebsd*], [sr_libusb_req='libusb-1.0' sr_have_libusb=yes],

130 [mingw*], [sr_libusb_req='libusb-1.0 >= 1.0.20'],

131 [sr_libusb_req='libusb-1.0 >= 1.0.16'])

132

133 SR_ARG_OPT_PKG([libusb], [LIBUSB_1_0], [NEED_USB],

134 [$sr_libusb_req])

135

136 SR_ARG_OPT_PKG([librevisa], [LIBREVISA], [NEED_VISA],

137 [librevisa >= 0.0.20130412])

138

139 SR_ARG_OPT_PKG([libgpib], [LIBGPIB], [NEED_GPIB],

140 [libgpib])

141

142 SR_ARG_OPT_CHECK([libieee1284], [LIBIEEE1284],, [

143 sr_save_LIBS=$LIBS

144 LIBS="-lieee1284 $LIBS"

145 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <ieee1284.h>]],

146 [[(void) ieee1284_open(0, 0, 0);]])],

147 [sr_have_libieee1284=yes], [sr_have_libieee1284=no])

148 LIBS=$sr_save_LIBS

149 ])

150 AS_IF([test "x$sr_have_libieee1284" = xyes],

151 [SR_PREPEND([SR_EXTRA_LIBS], [-lieee1284])])

152

153 SR_ARG_OPT_PKG([libgio], [LIBGIO], , [gio-2.0 >= 2.24.0])

154

155 # See if any of the (potentially platform specific) libs are available

156 # which provide some means of Bluetooth communication.

157 AS_IF([test "x$sr_have_libbluez" = xyes],

158 sr_have_bluetooth=yes, sr_have_bluetooth=no)

159 AS_IF([test "x$sr_have_bluetooth" = xyes],

160 [AC_DEFINE([HAVE_BLUETOOTH], [1], [Specifies whether Bluetooth communication is supported.])])

161 AS_IF([test "x$sr_have_bluetooth" = xyes],

162 [SR_APPEND([sr_deps_avail], [bluetooth_comm])])

163

164 AS_IF([test "x$sr_have_libserialport" = xyes -o "x$sr_have_libhidapi" = xyes -o "x$sr_have_bluetooth" = xyes],

165 sr_have_serial_comm=yes, sr_have_serial_comm=no)

166 AS_IF([test "x$sr_have_serial_comm" = xyes],

167 [AC_DEFINE([HAVE_SERIAL_COMM], [1], [Specifies whether serial communication is supported.])])

168 AS_IF([test "x$sr_have_serial_comm" = xyes],

169 [SR_APPEND([sr_deps_avail], [serial_comm])])

170 AM_CONDITIONAL([NEED_SERIAL], [test "x$sr_have_serial_comm" = xyes])

171

172 ######################

173 ## Feature checks ##

174 ######################

175

176 # The Check unit testing framework is optional. Disable if not found.

177 SR_PKG_CHECK([check], [SR_PKGLIBS_TESTS], [check >= 0.9.4])

178 AM_CONDITIONAL([HAVE_CHECK], [test "x$sr_have_check" = xyes])

179

180 # Enable the C99 standard if possible, and enforce the use

181 # of SR_API to explicitly mark all public API functions.

182 SR_EXTRA_CFLAGS=

183 SR_CHECK_COMPILE_FLAGS([SR_EXTRA_CFLAGS], [C99], [-std=c99 -c99 -AC99 -qlanglvl=extc99])

184 SR_CHECK_COMPILE_FLAGS([SR_EXTRA_CFLAGS], [visibility], [-fvisibility=hidden])

185

186 SR_ARG_ENABLE_WARNINGS([SR_WFLAGS], [-Wall], [-Wall -Wextra -Wmissing-prototypes])

187

188 # Check host characteristics.

189 AC_SYS_LARGEFILE

190 AC_C_BIGENDIAN

191

192 AC_CHECK_HEADERS([sys/mman.h], [SR_APPEND([sr_deps_avail], [sys_mman_h])])

193 AC_CHECK_HEADERS([sys/ioctl.h], [SR_APPEND([sr_deps_avail], [sys_ioctl_h])])

194 AC_CHECK_HEADERS([sys/timerfd.h], [SR_APPEND([sr_deps_avail], [sys_timerfd_h])])

195

196 # We need to link against the Winsock2 library for SCPI over TCP.

197 AS_CASE([$host_os], [mingw*], [SR_PREPEND([SR_EXTRA_LIBS], [-lws2_32])])

198

199 # libm (the standard math library) is always needed.

200 SR_SEARCH_LIBS([SR_EXTRA_LIBS], [pow], [m])

201

202 # RPC is only needed for VXI support.

203 AC_CACHE_CHECK([for SunRPC support], [sr_cv_have_sunrpc],

204 [AC_LINK_IFELSE([AC_LANG_PROGRAM(

205 [[#include <rpc/rpc.h>]m4_newline[CLIENT *rpc_test(void);]],

206 [[(void) clnt_create("", 0, 0, "");]])],

207 [RPC_CFLAGS=""; RPC_LIBS=""; sr_cv_have_sunrpc=yes],

208 [sr_cv_have_sunrpc=no])])

209 PKG_CHECK_MODULES([TIRPC],

210 [libtirpc],

211 [RPC_CFLAGS=$TIRPC_CFLAGS; SR_PREPEND([SR_EXTRA_LIBS], [$TIRPC_LIBS]); sr_cv_have_tirpc=yes],

212 [sr_cv_have_tirpc=no])

213 AS_IF([test "x$sr_cv_have_sunrpc" = xyes -o "x$sr_cv_have_tirpc" = xyes],

214 [sr_cv_have_rpc=yes], [sr_cv_have_rpc=no])

215

216 AC_SUBST(RPC_CFLAGS)

217 AC_SUBST(RPC_LIBS)

218

219 AS_IF([test "x$sr_cv_have_rpc" = xyes],

220 [AC_DEFINE([HAVE_RPC], [1], [Specifies whether we have RPC support (either by SunRPC or libtirpc).])])

221

222 # VXI support is only compiled if RPC support was found.

223 AM_CONDITIONAL([NEED_RPC], [test "x$sr_cv_have_rpc" = xyes])

224

225 # Check for compiler support of 128 bit integers

226 AC_CHECK_TYPES([__int128_t, __uint128_t], [], [], [])

227

228 AC_CACHE_CHECK([for poll], [sr_cv_have_poll],

229 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <poll.h>]],

230 [[(void) poll(0, 0, -1);]])],

231 [sr_cv_have_poll=yes], [sr_cv_have_poll=no])])

232 AS_IF([test "x$sr_cv_have_poll" = xyes],

233 [AC_DEFINE([HAVE_POLL], [1],

234 [Specifies whether we have the poll(2) function.])])

235 AC_CACHE_CHECK([for select], [sr_cv_have_select],

236 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/select.h>]],

237 [[(void) select(0, 0, 0, 0, 0);]])],

238 [sr_cv_have_select=yes], [sr_cv_have_select=no])])

239 AS_IF([test "x$sr_cv_have_select" = xyes],

240 [AC_DEFINE([HAVE_SELECT], [1],

241 [Specifies whether we have the select(2) function.])])

242

243 #######################

244 ## miniLZO related ##

245 #######################

246 # These were taken from the README.LZO file in the miniLZO archive.

247

248 AC_CHECK_TYPE(ptrdiff_t,long)

249 AC_TYPE_SIZE_T

250 AC_CHECK_SIZEOF(short)

251 AC_CHECK_SIZEOF(int)

252 AC_CHECK_SIZEOF(long)

253 AC_CHECK_SIZEOF(long long)

254 AC_CHECK_SIZEOF(__int64)

255 AC_CHECK_SIZEOF(void *)

256 AC_CHECK_SIZEOF(size_t)

257 AC_CHECK_SIZEOF(ptrdiff_t)

258

259 AC_C_CONST

260

261 AC_CHECK_FUNCS(memcmp memcpy memmove memset)

262

263 ########################

264 ## Hardware drivers ##

265 ########################

266

267 # Keep track of all drivers so we can list them at the end.

268 SR_VAR_SUMMARY([sr_driver_summary])

269

270 # Check whether the sr_deps_avail list contains all of the arguments.

271 # Unavailable dependencies are collected in sr_deps_missing.

272 sr_check_driver_deps() {

273 sr_deps_missing=

274 for sr_dep

275 do

276 AS_CASE([" $sr_deps_avail "], [*" $sr_dep "*],,

277 [SR_APPEND([sr_deps_missing], [', '], [$sr_dep])])

278 done

279 test -z "$sr_deps_missing" || return 1

280 }

281

282 AC_ARG_ENABLE([all-drivers],

283 [AS_HELP_STRING([--enable-all-drivers],

284 [enable all drivers by default [default=check]])],

285 [], [enable_all_drivers=check])

286

287 ## _SR_DRIVER(Device name, driver-name, var-name, [dependencies...])

288 m4_define([_SR_DRIVER], [

289 AC_ARG_ENABLE([$2],

290 [AS_HELP_STRING([--enable-$2], [enable $1 support])],

291 [$3=$enableval], [$3=$enable_all_drivers])

292

293 AS_IF([test "x[$]$3" != xno],

294 [sr_hw_info=yes[]m4_ifval([$4], [

295 sr_check_driver_deps $4 \

296 || if test "x[$]$3" != xcheck; then

297 AC_MSG_ERROR([driver $2 is enabled, but these deps are missing: $sr_deps_missing. Either install the dependency or disable the driver with --disable-$2.])

298 else

299 $3=no sr_hw_info="no (missing: $sr_deps_missing)"

300 fi;

301 ])], [sr_hw_info='no (disabled)'])

302 sr_driver_summary_append "$2" "$sr_hw_info"

303

304 AM_CONDITIONAL([$3], [test "x[$]$3" = xyes])

305 AM_COND_IF([$3], [AC_DEFINE([HAVE_$3], [1], [Whether to support $1 device.]) AC_DEFINE([HAVE_DRIVERS], [1], [Whether at least one driver is enabled.])])

306 ])

307

308 ## SR_DRIVER(Device name, driver-name, [dependencies...])

309 m4_define([SR_DRIVER],

310 [_SR_DRIVER([$1], [$2], m4_expand([AS_TR_CPP([HW_$2])]), [$3])])

311

312 SR_DRIVER([Agilent DMM], [agilent-dmm], [serial_comm])

313 SR_DRIVER([Appa 55II], [appa-55ii], [serial_comm])

314 SR_DRIVER([Arachnid Labs Re:load Pro], [arachnid-labs-re-load-pro], [serial_comm])

315 SR_DRIVER([ASIX SIGMA/SIGMA2], [asix-sigma], [libftdi])

316 SR_DRIVER([ASIX OMEGA RTM CLI], [asix-omega-rtm-cli])

317 SR_DRIVER([Atorch], [atorch], [serial_comm])

318 SR_DRIVER([Atten PPS3xxx], [atten-pps3xxx], [serial_comm])

319 SR_DRIVER([BayLibre ACME], [baylibre-acme], [sys_timerfd_h])

320 SR_DRIVER([BeagleLogic], [beaglelogic], [sys_mman_h sys_ioctl_h])

321 SR_DRIVER([BK Precision 1856D], [bkprecision-1856d], [serial_comm])

322 SR_DRIVER([CEM DT-885x], [cem-dt-885x], [serial_comm])

323 SR_DRIVER([Center 3xx], [center-3xx], [serial_comm])

324 SR_DRIVER([ChronoVu LA], [chronovu-la], [libusb libftdi])

325 SR_DRIVER([Colead SLM], [colead-slm], [serial_comm])

326 SR_DRIVER([Conrad DIGI 35 CPU], [conrad-digi-35-cpu], [serial_comm])

327 SR_DRIVER([dcttech usbrelay], [dcttech-usbrelay], [libhidapi])

328 SR_DRIVER([demo], [demo])

329 SR_DRIVER([Devantech ETH008], [devantech-eth008], [serial_comm])

330 SR_DRIVER([DreamSourceLab DSLogic], [dreamsourcelab-dslogic], [libusb])

331 SR_DRIVER([Fluke 45], [fluke-45])

332 SR_DRIVER([Fluke DMM], [fluke-dmm], [serial_comm])

333 SR_DRIVER([FTDI LA], [ftdi-la], [libusb libftdi])

334 SR_DRIVER([fx2lafw], [fx2lafw], [libusb])

335 SR_DRIVER([GMC MH 1x/2x], [gmc-mh-1x-2x], [serial_comm])

336 SR_DRIVER([Great Scott Gadgets GreatFET One], [greatfet], [libusb])

337 SR_DRIVER([GW Instek GDS-800], [gwinstek-gds-800], [serial_comm])

338 SR_DRIVER([GW Instek GPD], [gwinstek-gpd], [serial_comm])

339 SR_DRIVER([GW Instek PSP], [gwinstek-psp])

340 SR_DRIVER([Hameg HMO], [hameg-hmo])

341 SR_DRIVER([Hantek 4032L], [hantek-4032l], [libusb])

342 SR_DRIVER([Hantek 6xxx], [hantek-6xxx], [libusb])

343 SR_DRIVER([Hantek DSO], [hantek-dso], [libusb])

344 SR_DRIVER([HP 3457A], [hp-3457a])

345 SR_DRIVER([HP 3478A], [hp-3478a], [libgpib])

346 SR_DRIVER([hp-59306a], [hp-59306a])

347 SR_DRIVER([Hung-Chang DSO-2100], [hung-chang-dso-2100], [libieee1284])

348 SR_DRIVER([ICStation USBRelay], [icstation-usbrelay], [serial_comm])

349 SR_DRIVER([Ikalogic Scanalogic-2], [ikalogic-scanalogic2], [libusb])

350 SR_DRIVER([Ikalogic Scanaplus], [ikalogic-scanaplus], [libftdi])

351 SR_DRIVER([IPDBG LA], [ipdbg-la])

352 SR_DRIVER([ITECH IT8500], [itech-it8500], [serial_comm])

353 SR_DRIVER([JUNTEK JDS6600], [juntek-jds6600], [serial_comm])

354 SR_DRIVER([Kecheng KC-330B], [kecheng-kc-330b], [libusb])

355 SR_DRIVER([KERN scale], [kern-scale], [serial_comm])

356 SR_DRIVER([Kingst LA2016], [kingst-la2016], [libusb])

357 SR_DRIVER([Korad KAxxxxP], [korad-kaxxxxp], [serial_comm])

358 SR_DRIVER([Lascar EL-USB], [lascar-el-usb], [libusb])

359 SR_DRIVER([LeCroy LogicStudio], [lecroy-logicstudio], [libusb])

360 SR_DRIVER([LeCroy X-Stream], [lecroy-xstream])

361 SR_DRIVER([Link Instruments MSO-19], [link-mso19], [libserialport])

362 SR_DRIVER([Manson HCS-3xxx], [manson-hcs-3xxx], [serial_comm])

363 SR_DRIVER([Mastech MS6514], [mastech-ms6514], [serial_comm])

364 SR_DRIVER([maynuo-m97], [maynuo-m97])

365 SR_DRIVER([MIC 985xx], [mic-985xx], [serial_comm])

366 SR_DRIVER([Microchip PICkit2], [microchip-pickit2], [libusb])

367 SR_DRIVER([Mooshimeter DMM], [mooshimeter-dmm], [bluetooth_comm libgio])

368 SR_DRIVER([Motech LPS 30x], [motech-lps-30x], [serial_comm])

369 SR_DRIVER([Norma DMM], [norma-dmm], [serial_comm])

370 SR_DRIVER([OpenBench Logic Sniffer], [openbench-logic-sniffer], [serial_comm])

371 SR_DRIVER([PCE PCE-322A], [pce-322a], [serial_comm])

372 SR_DRIVER([Pipistrello-OLS], [pipistrello-ols], [libftdi])

373 SR_DRIVER([RaspberryPI PICO], [raspberrypi-pico], [serial_comm])

374 SR_DRIVER([RDTech DPSxxxx/DPHxxxx], [rdtech-dps], [serial_comm])

375 SR_DRIVER([RDTech UMXX], [rdtech-um], [serial_comm])

376 SR_DRIVER([RDTech TCXX], [rdtech-tc], [serial_comm libnettle])

377 SR_DRIVER([Rigol DS], [rigol-ds])

378 SR_DRIVER([Rigol DG], [rigol-dg])

379 SR_DRIVER([Rohde&Schwarz SME-0x], [rohde-schwarz-sme-0x], [serial_comm])

380 SR_DRIVER([Saleae Logic16], [saleae-logic16], [libusb])

381 SR_DRIVER([Saleae Logic Pro], [saleae-logic-pro], [libusb])

382 SR_DRIVER([SCPI DMM], [scpi-dmm])

383 SR_DRIVER([SCPI PPS], [scpi-pps])

384 SR_DRIVER([serial DMM], [serial-dmm], [serial_comm])

385 SR_DRIVER([serial LCR], [serial-lcr], [serial_comm])

386 SR_DRIVER([SIGLENT SDL10x0], [siglent-sdl10x0])

387 SR_DRIVER([Siglent SDS], [siglent-sds])

388 SR_DRIVER([Sysclk LWLA], [sysclk-lwla], [libusb])

389 SR_DRIVER([Sysclk SLA5032], [sysclk-sla5032], [libusb])

390 SR_DRIVER([Teleinfo], [teleinfo], [serial_comm])

391 SR_DRIVER([Testo], [testo], [libusb])

392 SR_DRIVER([Tondaj SL-814], [tondaj-sl-814], [serial_comm])

393 SR_DRIVER([UNI-T DMM], [uni-t-dmm], [libusb])

394 SR_DRIVER([UNI-T UT181A], [uni-t-ut181a], [serial_comm])

395 SR_DRIVER([UNI-T UT32x], [uni-t-ut32x], [serial_comm])

396 SR_DRIVER([Yokogawa DL/DLM], [yokogawa-dlm])

397 SR_DRIVER([ZEROPLUS Logic Cube], [zeroplus-logic-cube], [libusb])

398 SR_DRIVER([ZKETECH EBD-USB], [zketech-ebd-usb], [serial_comm])

399

400 ###############################

401 ## Language bindings setup ##

402 ###############################

403

404 AC_LANG([C++])

405 SR_ARG_ENABLE_WARNINGS([SR_WXXFLAGS], [-Wall], [-Wall -Wextra])

406

407 AC_ARG_ENABLE([bindings],

408 [AS_HELP_STRING([--enable-bindings], [build language bindings [default=yes]])],

409 [], [enable_bindings=yes])

410

411 AC_ARG_ENABLE([cxx],

412 [AS_HELP_STRING([--enable-cxx], [build C++ bindings [default=yes]])],

413 [], [enable_cxx=$enable_bindings])

414

415 AC_ARG_ENABLE([python],

416 [AS_HELP_STRING([--enable-python], [build Python bindings [default=yes]])],

417 [], [enable_python=$enable_bindings])

418

419 AC_ARG_ENABLE([ruby],

420 [AS_HELP_STRING([--enable-ruby], [build Ruby bindings [default=yes]])],

421 [], [enable_ruby=$enable_bindings])

422

423 AC_ARG_ENABLE([java],

424 [AS_HELP_STRING([--enable-java], [build Java bindings [default=yes]])],

425 [], [enable_java=$enable_bindings])

426

427 ####################

428 ## C++ bindings ##

429 ####################

430

431 sr_cxx_missing=

432

433 # Check if the C++ compiler supports at least the C++11 standard.

434 # Get the highest of the available C++17/C++14/C++11 standards.

435 # This transparently amends CXXFLAGS to pick the detected standard.

436 HAVE_MODERN_CXX=

437 AS_IF([test "x$HAVE_MODERN_CXX" = x],

438 [AX_CXX_COMPILE_STDCXX([17], [noext], [optional])])

439 AS_IF([test "x$HAVE_CXX17" = x1],

440 [HAVE_MODERN_CXX=yes])

441 AS_IF([test "x$HAVE_MODERN_CXX" = x],

442 [AX_CXX_COMPILE_STDCXX([14], [noext], [optional])])

443 AS_IF([test "x$HAVE_CXX14" = x1],

444 [HAVE_MODERN_CXX=yes])

445 AS_IF([test "x$HAVE_MODERN_CXX" = x],

446 [AX_CXX_COMPILE_STDCXX([11], [noext], [optional])])

447 AS_IF([test "x$HAVE_CXX11" = x1],

448 [HAVE_MODERN_CXX=yes])

449 AS_IF([test "x$HAVE_MODERN_CXX" = x],

450 [SR_APPEND([sr_cxx_missing], [', '], ['C++11'])])

451

452 # The C++ bindings need glibmm.

453 # Prefer glibmm-2.4 for backwards compatibility.

454 # Accept glibmm-2.68 when glibmm-2.4 is not available.

455 sr_have_glibmm=no

456 AS_IF([test "x$sr_have_glibmm" != xyes],

457 [SR_PKG_CHECK([glibmm24], [SR_PKGLIBS_CXX], [glibmm-2.4 >= 2.32.0])])

458 AS_IF([test "x$sr_have_glibmm24" = xyes],

459 [SR_APPEND([SR_GLIBMM_REQUIRES], ['glibmm-2.4 >= 2.32.0'])

460 sr_have_glibmm=yes])

461 AS_IF([test "x$sr_have_glibmm" != xyes],

462 [SR_PKG_CHECK([glibmm268], [SR_PKGLIBS_CXX], [glibmm-2.68 >= 2.68.0])])

463 AS_IF([test "x$sr_have_glibmm268" = xyes],

464 [SR_APPEND([SR_GLIBMM_REQUIRES], ['glibmm-2.68 >= 2.68.0'])

465 sr_have_glibmm=yes])

466 AS_IF([test "x$sr_have_glibmm" = xyes],

467 [AC_SUBST(SR_GLIBMM_REQUIRES)],

468 [SR_APPEND([sr_cxx_missing], [', '], [glibmm])])

469

470 # The C++ bindings use Doxygen to parse libsigrok symbols.

471 AC_CHECK_PROG([HAVE_DOXYGEN], [doxygen], [yes], [no])

472 AS_IF([test "x$HAVE_DOXYGEN" != xyes],

473 [SR_APPEND([sr_cxx_missing], [', '], [Doxygen])])

474

475 # Link C++ code with gnustl_shared if it exists (Android)

476 SR_SEARCH_LIBS([SR_EXTRA_CXX_LIBS], [__cxa_throw], [gnustl_shared])

477

478 # Python is needed for the C++ bindings.

479 AM_PATH_PYTHON([2.7],

480 [HAVE_PYTHON=yes],

481 [HAVE_PYTHON=no

482 SR_APPEND([sr_cxx_missing], [', '], [Python])])

483

484 AS_IF([test -z "$sr_cxx_missing"],

485 [BINDINGS_CXX=$enable_cxx], [BINDINGS_CXX=no])

486 AM_CONDITIONAL([BINDINGS_CXX], [test "x$BINDINGS_CXX" = xyes])

487

488 # C++ bindings want stoi and stod.

489 AM_COND_IF([BINDINGS_CXX], [

490 AC_CACHE_CHECK([for stoi and stod], [sr_cv_have_stoi_stod],

491 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <string>]],

492 [[(void) std::stoi("1"); (void) std::stod("1.0");]])],

493 [sr_cv_have_stoi_stod=yes], [sr_cv_have_stoi_stod=no])])

494 AS_IF([test "x$sr_cv_have_stoi_stod" = xyes],

495 [AC_DEFINE([HAVE_STOI_STOD], [1],

496 [Specifies whether we have the stoi and stod functions.])])

497 # In theory std::stoul() should have identical availability

498 # as std::stoi() and std::stod() have. All of them are C++11.

499 # But we play it safe here, and check support individually.

500 AC_CACHE_CHECK([for stoul], [sr_cv_have_stoul],

501 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <string>]],

502 [[(void) std::stoul("1");]])],

503 [sr_cv_have_stoul=yes], [sr_cv_have_stoul=no])])

504 AS_IF([test "x$sr_cv_have_stoul" = xyes],

505 [AC_DEFINE([HAVE_STOUL], [1],

506 [Specifies whether we have the std::stoul function.])])

507 ])

508

509 #######################

510 ## Python bindings ##

511 #######################

512

513 AS_IF([test "x$BINDINGS_CXX" = xyes],

514 [sr_python_missing=],

515 [sr_python_missing='C++ bindings'])

516

517 # Extract major and minor version number of the Python interpreter.

518 sr_pymajor=${PYTHON_VERSION%%.*}

519 sr_pyminor=${PYTHON_VERSION#*.}

520

521 # The Python bindings need Python development files. Check for either

522 # Python 3 or Python 2 headers depending on the interpreter version.

523 SR_PKG_CHECK([python_dev], [SR_PKGLIBS_PYTHON],

524 [python = $PYTHON_VERSION],

525 [python$sr_pymajor = $PYTHON_VERSION],

526 [python$sr_pymajor$sr_pyminor = $PYTHON_VERSION],

527 [python-$PYTHON_VERSION = $PYTHON_VERSION])

528

529 AS_IF([test "x$sr_have_python_dev" != xyes],

530 [SR_APPEND([sr_python_missing], [', '], [Headers])])

531

532 # PyGObject is needed for the Python bindings.

533 SR_PKG_CHECK([pygobject], [SR_PKGLIBS_PYTHON], [pygobject-3.0 >= 3.0.0])

534 AS_IF([test "x$sr_have_pygobject" != xyes],

535 [SR_APPEND([sr_python_missing], [', '], [PyGObject])])

536

537 PKG_CHECK_EXISTS([pygobject-3.0 < 3.7.91],

538 [AC_DEFINE([PYGOBJECT_FLAGS_SIGNED], [1],

539 [Whether last argument to pyg_flags_get_value() is signed.])])

540

541 # The Python bindings need the setuptools and numpy Python modules.

542 # We'll let it go through even if the AX macro wasn't found, as the

543 # Python modules may still be there.

544 m4_ifdef([AX_PYTHON_MODULE], [

545 AX_PYTHON_MODULE([setuptools])

546 AX_PYTHON_MODULE([numpy])

547 ], [

548 HAVE_PYMOD_SETUPTOOLS=yes

549 HAVE_PYMOD_NUMPY=yes

550 m4_warn([unsupported],

551 [Missing macro AX_PYTHON_MODULE: no check for setuptools and numpy])

552 ])

553 AS_IF([test "x$HAVE_PYMOD_SETUPTOOLS" != xyes],

554 [SR_APPEND([sr_python_missing], [', '], [setuptools])])

555 AS_IF([test "x$HAVE_PYMOD_NUMPY" != xyes],

556 [SR_APPEND([sr_python_missing], [', '], [numpy])])

557

558 # The Python bindings use SWIG to generate code.

559 AC_CHECK_PROGS([SWIG], [swig swig4.0 swig3.0 swig2.0])

560 AS_IF([test "x$SWIG" != x],

561 AC_MSG_CHECKING([for $SWIG version])

562 [SWIG_VERSION=`$SWIG -version 2>&1 | sed -n 's/SWIG Version //p'`]

563 AC_MSG_RESULT([$SWIG_VERSION]))

564 AS_IF([test "x$SWIG" = x],

565 [SR_APPEND([sr_python_missing], [', '], [SWIG])])

566

567 AS_IF([test -z "$sr_python_missing"],

568 [BINDINGS_PYTHON=$enable_python], [BINDINGS_PYTHON=no])

569 AM_CONDITIONAL([BINDINGS_PYTHON], [test "x$BINDINGS_PYTHON" = xyes])

570

571 #####################

572 ## Ruby bindings ##

573 #####################

574

575 AS_IF([test "x$BINDINGS_CXX" = xyes],

576 [sr_ruby_missing=],

577 [sr_ruby_missing='C++ bindings'])

578

579 AC_PATH_PROGS(RUBY, ["${RUBY-ruby}"], [])

580 AS_IF([test "x$RUBY" != x],

581 AC_MSG_CHECKING([for Ruby version])

582 [RUBY_VERSION=`$RUBY -e 'puts RUBY_VERSION'`]

583 AC_MSG_RESULT([$RUBY_VERSION])

584 [RUBY_DLEXT=`$RUBY -rrbconfig -e 'puts RbConfig::CONFIG[["DLEXT"]]'`]

585 AC_SUBST(RUBY_DLEXT))

586

587 AS_IF([test "x$RUBY" = x],

588 [SR_APPEND([sr_ruby_missing], [', '], [Ruby])])

589

590 # Extract major and minor version number of the Ruby interpreter.

591 sr_rbmajor=${RUBY_VERSION%%.*}

592 sr_rbminor=${RUBY_VERSION#*.}

593 sr_rbminor=${sr_rbminor%%.*}

594

595 # The Ruby bindings need Ruby development files.

596 SR_PKG_CHECK([ruby_dev], [SR_PKGLIBS_RUBY],

597 [ruby >= 2.5.0],

598 [ruby-$sr_rbmajor.$sr_rbminor >= 2.5.0])

599

600 AS_IF([test "x$sr_have_ruby_dev" != xyes],

601 [SR_APPEND([sr_ruby_missing], [', '], [Headers])])

602

603 # The Ruby bindings use SWIG >= 3.0.8 to generate code.

604 AS_IF([test "x$SWIG" = x],

605 [SR_APPEND([sr_ruby_missing], [', '], [SWIG])],

606 [AS_VERSION_COMPARE($SWIG_VERSION, "3.0.8",

607 [SR_APPEND([sr_ruby_missing], [', '], ['SWIG >= 3.0.8'])])])

608

609 AS_IF([test -z "$sr_ruby_missing"],

610 [BINDINGS_RUBY=$enable_ruby], [BINDINGS_RUBY=no])

611 AM_CONDITIONAL([BINDINGS_RUBY], [test "x$BINDINGS_RUBY" = xyes])

612

613 ####################

614 ## Java bindings ##

615 ####################

616

617 AS_IF([test "x$BINDINGS_CXX" = xyes],

618 [sr_java_missing=],

619 [sr_java_missing='C++ bindings'])

620

621 # The Java bindings use SWIG to generate code.

622 AS_IF([test "x$SWIG" = x],

623 [SR_APPEND([sr_java_missing], [', '], [SWIG])])

624

625 # Find Java compiler and JNI includes for Java bindings.

626 AC_CHECK_PROG([HAVE_JAVAC], [javac], [yes], [no])

627 AS_IF([test "x$HAVE_JAVAC" = xno],

628 [SR_APPEND([sr_java_missing], [', '], [JavaC])])

629

630 AC_ARG_WITH([jni-include-path],

631 [AS_HELP_STRING([[--with-jni-include-path=DIR-LIST (space-separated)]],

632 [specify JNI include directories [default=detect]])],

633 [JNI_INCLUDE_DIRS=" $withval"], [JNI_INCLUDE_DIRS=])

634

635 JNI_CPPFLAGS=

636 AS_IF([test "x$enable_java$HAVE_JAVAC" = xyesyes], [

637 AX_PROG_JAVAC

638 AS_IF([test -z "$JNI_INCLUDE_DIRS" && test "x$cross_compiling" != xyes], [

639 ## Work around the totally broken logic in AX_JNI_INCLUDE_DIR:

640 ## If we can find jni.h without any special search path, skip

641 ## the execution of the broken macro to increase our chances of

642 ## success.

643 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <jni.h>]], [])],,

644 [AX_JNI_INCLUDE_DIR])

645 ])

646 ])

647 for sr_dir in $JNI_INCLUDE_DIRS

648 do

649 SR_APPEND([JNI_CPPFLAGS], ["-I$sr_dir"])

650 done

651 AC_SUBST([JNI_CPPFLAGS])

652

653 sr_save_cppflags=$CPPFLAGS

654 SR_APPEND([CPPFLAGS], [$JNI_CPPFLAGS])

655 AC_CHECK_HEADER([jni.h],,

656 [SR_APPEND([sr_java_missing], [', '], ['JNI headers'])])

657 CPPFLAGS=$sr_save_cppflags

658

659 AS_IF([test -z "$sr_java_missing"],

660 [BINDINGS_JAVA=$enable_java], [BINDINGS_JAVA=no])

661 AM_CONDITIONAL([BINDINGS_JAVA], [test "x$BINDINGS_JAVA" = xyes])

662

663 ##############################

664 ## Finalize configuration ##

665 ##############################

666

667 # Add mandatory dependencies to module list.

668 SR_APPEND([SR_PKGLIBS], ['libzip >= 0.10'])

669 AC_SUBST([SR_PKGLIBS])

670

671 # Retrieve the compile and link flags for all modules combined.

672 # Also, bail out at this point if any module dependency is not met.

673 PKG_CHECK_MODULES([LIBSIGROK], [glib-2.0 >= 2.32.0 $SR_PKGLIBS])

674 PKG_CHECK_MODULES([TESTS], [$SR_PKGLIBS_TESTS glib-2.0 $SR_PKGLIBS])

675

676 # SR_PKGLIBS_CXX may be empty, so only invoke these checks when

677 # the C++ bindings are enabled.

678 AM_COND_IF([BINDINGS_CXX], [

679 PKG_CHECK_MODULES([LIBSIGROKCXX], [$SR_PKGLIBS_CXX])

680 PKG_CHECK_MODULES([PYSIGROK], [$SR_PKGLIBS_PYTHON $SR_PKGLIBS_CXX])

681 PKG_CHECK_MODULES([RBSIGROK], [$SR_PKGLIBS_RUBY $SR_PKGLIBS_CXX], [AC_SUBST(RBSIGROK_EXTDIR, "lib/$($PKG_CONFIG --variable=sitearch $SR_PKGLIBS_RUBY)/$($PKG_CONFIG --variable=RUBY_BASE_NAME $SR_PKGLIBS_RUBY)/vendor_ruby/$($PKG_CONFIG --variable=ruby_version $SR_PKGLIBS_RUBY)")])

682 ])

683

684 # Check for specific libusb features, now that we know the CFLAGS.

685 # Also check for version dependent libftdi features.

686 AC_LANG([C])

687 sr_save_cflags=$CFLAGS

688 sr_save_libs=$LIBS

689 CFLAGS="$LIBSIGROK_CFLAGS $CFLAGS"

690 LIBS="$LIBSIGROK_LIBS $LIBS"

691 AC_CHECK_TYPES([libusb_os_handle],

692 [sr_have_libusb_os_handle=yes], [sr_have_libusb_os_handle=no],

693 [[#include <libusb.h>]])