configure.ac

   1 ##
   2 ## This file is part of the libsigrok project.
   3 ##
   4 ## Copyright (C) 2010-2012 Bert Vermeulen <bert@biot.com>
   5 ## Copyright (C) 2012 Alexandru Gagniuc <mr.nuke.me@gmail.com>
   6 ##
   7 ## This program is free software: you can redistribute it and/or modify
   8 ## it under the terms of the GNU General Public License as published by
   9 ## the Free Software Foundation, either version 3 of the License, or
  10 ## (at your option) any later version.
  11 ##
  12 ## This program is distributed in the hope that it will be useful,
  13 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ## GNU General Public License for more details.
  16 ##
  17 ## You should have received a copy of the GNU General Public License
  18 ## along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19 ##
  20
  21 # We require at least autoconf 2.63 (AC_INIT format changed there).
  22 AC_PREREQ([2.63])
  23
  24 # libsigrok package version number (NOT the same as shared lib version!).
  25 m4_define([sr_package_version_major], [0])
  26 m4_define([sr_package_version_minor], [3])
  27 m4_define([sr_package_version_micro], [0])
  28 m4_define([sr_package_version], [sr_package_version_major.sr_package_version_minor.sr_package_version_micro])
  29
  30 AC_INIT([libsigrok], [sr_package_version], [sigrok-devel@lists.sourceforge.net],
  31         [libsigrok], [http://www.sigrok.org])
  32 AC_CONFIG_HEADER([config.h])
  33 AC_CONFIG_MACRO_DIR([autostuff])
  34 AC_CONFIG_AUX_DIR([autostuff])
  35
  36 # We require at least automake 1.11 (needed for 'silent rules').
  37 AM_INIT_AUTOMAKE([1.11 -Wall -Werror subdir-objects check-news color-tests])
  38 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  39 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  40
  41 AH_TOP([#ifndef SR_CONFIG_H
  42 #define SR_CONFIG_H    /* To stop multiple inclusions. */])
  43 AH_BOTTOM([#endif /* SR_CONFIG_H */])
  44
  45 # Enable more compiler warnings via -Wall and -Wextra. Add -fvisibility=hidden
  46 # and enforce use of SR_API to explicitly mark all public API functions.
  47 COMMON_FLAGS="$CFLAGS -Wall -Wextra -fvisibility=hidden"
  48 CFLAGS="$COMMON_FLAGS -Wmissing-prototypes"
  49 CXXFLAGS="-std=c++11 $COMMON_FLAGS"
  50
  51 # Checks for programs.
  52 AC_PROG_CC
  53 AC_PROG_CPP
  54 AC_PROG_CXX
  55 AC_PROG_INSTALL
  56 AC_PROG_LN_S
  57
  58 # Required for per-target flags or subdir-objects with C sources.
  59 AM_PROG_CC_C_O
  60
  61 # Initialize libtool.
  62 LT_INIT
  63
  64 # Initialize pkg-config.
  65 # We require at least 0.22, as "Requires.private" behaviour changed there.
  66 PKG_PROG_PKG_CONFIG([0.22])
  67
  68 # Library version for libsigrok (NOT the same as the package version).
  69 # Carefully read the libtool docs before updating these numbers!
  70 # The algorithm for determining which number to change (and how) is nontrivial!
  71 # http://www.gnu.org/software/libtool/manual/libtool.html#Updating-version-info
  72 SR_LIB_VERSION_CURRENT=2
  73 SR_LIB_VERSION_REVISION=0
  74 SR_LIB_VERSION_AGE=0
  75 SR_LIB_VERSION="$SR_LIB_VERSION_CURRENT:$SR_LIB_VERSION_REVISION:$SR_LIB_VERSION_AGE"
  76 SR_LIB_LDFLAGS="-version-info $SR_LIB_VERSION"
  77 AC_SUBST(SR_LIB_VERSION_CURRENT)
  78 AC_SUBST(SR_LIB_VERSION_REVISION)
  79 AC_SUBST(SR_LIB_VERSION_AGE)
  80 AC_SUBST(SR_LIB_VERSION)
  81 AC_SUBST(SR_LIB_LDFLAGS)
  82
  83 AC_ARG_ENABLE(all-drivers, AC_HELP_STRING([--enable-all-drivers],
  84         [enable all drivers by default [default=yes]]),
  85         [HW_ENABLED_DEFAULT="$enableval"],
  86         [HW_ENABLED_DEFAULT="yes"])
  87
  88 # Usage: DRIVER([Device name], [driver-name])
  89 # An optional third argument [no] disables that driver.
  90 m4_define([driverize], [m4_tolower(m4_bpatsubst([$1], [[^0-9a-zA-Z-]+], [-]))])
  91 m4_define([upperize], [m4_toupper(m4_bpatsubst([$1], [[^0-9a-zA-Z_]+], [_]))])
  92 AC_DEFUN([DRIVER], [
  93         if test -z "$3"; then
  94                 default=$HW_ENABLED_DEFAULT
  95         else
  96                 default="$3"
  97         fi
  98         AC_ARG_ENABLE($2, AC_HELP_STRING([--enable-$2], [enable $1 support]),
  99                 [m4_join([], [HW_], upperize([$2]))="$enableval"],
 100                 [m4_join([], [HW_], upperize([$2]))=$default])
 101         dots=$(echo -n ".............................." | cut -c 1-$(expr 32 - $(echo -n $2|wc -c)))
 102         driver_summary="${driver_summary}  - $2${dots} \${m4_join([], [HW_], upperize([$2]))}@"
 103 ])
 104
 105 DRIVER([Agilent DMM], [agilent-dmm])
 106 DRIVER([Appa 55II], [appa-55ii])
 107 DRIVER([ASIX SIGMA/SIGMA2], [asix-sigma])
 108 DRIVER([Atten PPS3xxx], [atten-pps3xxx])
 109 DRIVER([BeagleLogic], [beaglelogic])
 110 DRIVER([Brymen BM86x], [brymen-bm86x])
 111 DRIVER([Brymen DMM], [brymen-dmm])
 112 DRIVER([CEM DT-885x], [cem-dt-885x])
 113 DRIVER([Center 3xx], [center-3xx])
 114 DRIVER([ChronoVu LA], [chronovu-la])
 115 DRIVER([Colead SLM], [colead-slm])
 116 DRIVER([Conrad DIGI 35 CPU], [conrad-digi-35-cpu])
 117 DRIVER([demo], [demo])
 118 DRIVER([Fluke DMM], [fluke-dmm])
 119 DRIVER([fx2lafw], [fx2lafw])
 120 DRIVER([GMC MH 1x/2x], [gmc-mh-1x-2x])
 121 DRIVER([Hameg HMO], [hameg-hmo])
 122 DRIVER([Hantek DSO], [hantek-dso])
 123 DRIVER([Ikalogic Scanalogic-2], [ikalogic-scanalogic2])
 124 DRIVER([Ikalogic Scanaplus], [ikalogic-scanaplus])
 125 DRIVER([Kecheng KC-330B], [kecheng-kc-330b])
 126 DRIVER([Lascar EL-USB], [lascar-el-usb])
 127 DRIVER([Manson HCS-3xxx], [manson-hcs-3xxx])
 128 DRIVER([MIC 985xx], [mic-985xx])
 129 DRIVER([Motech LPS 30x], [motech-lps-30x])
 130 DRIVER([Norma DMM], [norma-dmm])
 131 DRIVER([OpenBench Logic Sniffer], [openbench-logic-sniffer])
 132 DRIVER([Pipistrello-OLS], [pipistrello-ols])
 133 DRIVER([Rigol DS], [rigol-ds])
 134 DRIVER([Saleae Logic16], [saleae-logic16])
 135 DRIVER([SCPI PPS], [scpi-pps])
 136 DRIVER([serial DMM], [serial-dmm])
 137 DRIVER([Sysclk LWLA], [sysclk-lwla])
 138 DRIVER([Teleinfo], [teleinfo])
 139 DRIVER([Testo], [testo])
 140 DRIVER([Tondaj SL-814], [tondaj-sl-814])
 141 DRIVER([UNI-T DMM], [uni-t-dmm])
 142 DRIVER([UNI-T UT32x], [uni-t-ut32x])
 143 DRIVER([Victor DMM], [victor-dmm])
 144 DRIVER([Yokogawa DL/DLM], [yokogawa-dlm])
 145 DRIVER([ZEROPLUS Logic Cube], [zeroplus-logic-cube])
 146
 147 AC_ARG_ENABLE(libserialport,
 148         AC_HELP_STRING([--disable-libserialport],
 149         [disable libserialport support [default=detect]]))
 150
 151 AC_ARG_ENABLE(libftdi,
 152         AC_HELP_STRING([--disable-libftdi],
 153         [disable libftdi support [default=detect]]))
 154
 155 AC_ARG_ENABLE(libusb,
 156         AC_HELP_STRING([--disable-libusb],
 157         [disable libusb support [default=detect]]))
 158
 159 # Language binding '--enable' options:
 160
 161 AC_ARG_ENABLE(bindings,
 162         AC_HELP_STRING([--enable-bindings],
 163         [build language bindings [default=yes]]),
 164         [BINDINGS_ALL="$enableval"], [BINDINGS_ALL="yes"])
 165
 166 AC_ARG_ENABLE(cxx,
 167         AC_HELP_STRING([--enable-cxx],
 168         [build C++ bindings [default=yes]]),
 169         [BINDINGS_CXX="$enableval"], [BINDINGS_CXX=$BINDINGS_ALL])
 170
 171 AC_ARG_ENABLE(python,
 172         AC_HELP_STRING([--enable-python],
 173         [build Python bindings [default=yes]]),
 174         [BINDINGS_PYTHON="$enableval"], [BINDINGS_PYTHON=$BINDINGS_ALL])
 175
 176 AC_ARG_ENABLE(java,
 177         AC_HELP_STRING([--enable-java],
 178         [build Java bindings [default=yes]]),
 179         [BINDINGS_JAVA="$enableval"], [BINDINGS_JAVA=$BINDINGS_ALL])
 180
 181 AC_ARG_WITH(jni-include-path,
 182         AC_HELP_STRING([--with-jni-include-path=path],
 183         [specify include path for JNI [default=autodetect]]),
 184         [JNI_INCLUDE_DIRS="$withval"], [JNI_INCLUDE_DIRS=auto])
 185
 186 # Check if the C++ compiler supports the C++11 standard.
 187
 188 m4_ifdef([AX_CXX_COMPILE_STDCXX_11], [AX_CXX_COMPILE_STDCXX_11(,[optional])],
 189         [AC_MSG_NOTICE([Missing macro m4_toupper(aX_CXX_COMPILE_STDCXX_11), no C++11 check])])
 190
 191 if test "x$HAVE_CXX11" != "x1"; then
 192         BINDINGS_CXX="no"; cxx_msg="C++11 compiler required"
 193 fi
 194
 195 # The C++ bindings use Doxygen to parse libsigrok symbols.
 196 AC_CHECK_PROG([HAVE_DOXYGEN], [doxygen], [yes])
 197 if test "x$HAVE_DOXYGEN" != "xyes"; then
 198         BINDINGS_CXX="no"; cxx_msg="Doxygen required"
 199 fi
 200
 201 # Python is needed for the C++ bindings.
 202 AM_PATH_PYTHON([2.7], [HAVE_PYTHON="yes"],
 203         [HAVE_PYTHON="no"; BINDINGS_CXX="no"; cxx_msg="Python required"])
 204
 205 # The Python bindings need Python development files.
 206 PKG_CHECK_MODULES([python], [python >= 2.7],
 207         [CXXFLAGS="$CXXFLAGS $python_CFLAGS";
 208         CXXLIBS="$CXXLIBS $python_LIBS"],
 209 [PKG_CHECK_MODULES([python27], [python-2.7 >= 2.7],
 210         [CXXFLAGS="$CXXFLAGS $python27_CFLAGS";
 211         CXXLIBS="$CXXLIBS $python27_LIBS"],
 212                 [BINDINGS_PYTHON="no"; python_msg="Python headers required"])])
 213
 214 # The Python bindings need the setuptools Python module.
 215 m4_ifdef([AX_PYTHON_MODULE], [AX_PYTHON_MODULE([setuptools])],
 216         # We'll let it go through even if the macro wasn't found, the Python
 217         # module may still be there.
 218         [HAVE_PYTHON_SETUPTOOLS="yes";
 219                 AC_MSG_NOTICE([Missing macro m4_toupper(aX_PYTHON_MODULE), no setuptools check])]
 220 )
 221 if test "x$HAVE_PYMOD_SETUPTOOLS" != "xyes"; then
 222         BINDINGS_PYTHON="no"; python_msg="Python setuptools module required"
 223 fi
 224
 225 # The Python and Java bindings use SWIG to generate code.
 226 AC_CHECK_PROG([HAVE_SWIG], [swig], [yes])
 227 if test "x$HAVE_SWIG" != "xyes"; then
 228         BINDINGS_PYTHON="no"; python_msg="SWIG required"
 229         BINDINGS_JAVA="no"; java_msg="SWIG required"
 230 fi
 231
 232 # Checks for libraries.
 233
 234 case "$host" in
 235 *mingw*)
 236         # We need to link against the Winsock2 library for SCPI over TCP.
 237         LIBS="$LIBS -lws2_32";;
 238 esac
 239
 240 # This variable collects the pkg-config names of all detected libs.
 241 # It is then used to construct the "Requires.private:" field in the
 242 # libsigrok.pc file.
 243 SR_PKGLIBS=""
 244
 245 # libm (the standard math library) is always needed.
 246 AC_SEARCH_LIBS([pow], [m])
 247
 248 # RPC is only needed for VXI support.
 249 AC_MSG_CHECKING([for RPC support])
 250 AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <rpc/rpc.h>],
 251                         [CLIENT *rpc_test(void)],
 252                         [{ return clnt_create("", 0, 0, ""); }])],
 253                 [AC_MSG_RESULT([yes]); have_rpc=1],
 254                 [AC_MSG_RESULT([no]);  have_rpc=0])
 255 # Define HAVE_RPC in config.h if we found RPC support.
 256 AC_DEFINE_UNQUOTED(HAVE_RPC, [$have_rpc], [Specifies whether we have RPC support.])
 257 # VXI support is only compiled if RPC support was found.
 258 AM_CONDITIONAL(NEED_RPC, test "x$have_rpc" != "x0")
 259
 260 # libglib-2.0 is always needed. Abort if it's not found.
 261 # Note: glib-2.0 is part of the libsigrok API (hard pkg-config requirement).
 262 # We require at least 2.32.0 due to e.g. g_variant_new_fixed_array().
 263 AM_PATH_GLIB_2_0([2.32.0],
 264         [LIB_CFLAGS="$LIB_CFLAGS $GLIB_CFLAGS"; LIBS="$LIBS $GLIB_LIBS"])
 265
 266 # libzip is always needed. Abort if it's not found.
 267 PKG_CHECK_MODULES([libzip], [libzip >= 0.10],
 268         [LIB_CFLAGS="$LIB_CFLAGS $libzip_CFLAGS"; LIBS="$LIBS $libzip_LIBS";
 269         SR_PKGLIBS="$SR_PKGLIBS libzip"])
 270
 271 # libserialport is only needed for some hardware drivers. Disable the
 272 # respective drivers if it is not found.
 273 if test "x$enable_libserialport" != "xno"; then
 274         PKG_CHECK_MODULES([libserialport], [libserialport >= 0.2.0],
 275                 [have_libserialport="yes"; LIB_CFLAGS="$LIB_CFLAGS $libserialport_CFLAGS";
 276                 LIBS="$LIBS $libserialport_LIBS";
 277                 SR_PKGLIBS="$SR_PKGLIBS libserialport"],
 278                 [have_libserialport="no"])
 279         if test "x$enable_libserialport$have_libserialport" = "xyesno"; then
 280                 AC_MSG_ERROR([libserialport support requested, but it was not found.])
 281         fi
 282 else
 283         have_libserialport="no"
 284 fi
 285 if test "x$have_libserialport" = "xno"; then
 286         HW_AGILENT_DMM="no"; HW_APPA_55II="no";
 287         HW_ATTEN_PPS3XXX="no"; HW_BRYMEN_DMM="no"; HW_CEM_DT_885X="no";
 288         HW_CENTER_3XX="no"; HW_COLEAD_SLM="no"; HW_CONRAD_DIGI_35_CPU="no";
 289         HW_FLUKE_DMM="no"; HW_GMC_MH_1X_2X="no"; HW_HAMEG_HMO="no";
 290         HW_MANSON_HCS_3XXX="no"; HW_MIC_985XX="no"; HW_MOTECH_LPS_30X="no";
 291         HW_NORMA_DMM="no"; HW_OPENBENCH_LOGIC_SNIFFER="no"; HW_SERIAL_DMM="no";
 292         HW_TELEINFO="no"; HW_TONDAJ_SL_814="no";
 293 else
 294         # Define HAVE_LIBSERIALPORT in config.h if we found libserialport.
 295         AC_DEFINE_UNQUOTED(HAVE_LIBSERIALPORT, [1],
 296                 [Specifies whether we have libserialport.])
 297 fi
 298
 299 # Serial port helper code is only compiled in if libserialport was found.
 300 AM_CONDITIONAL(NEED_SERIAL, test "x$have_libserialport" != xno)
 301
 302 # The VISA SCPI backend is only compiled in if librevisa was found.
 303 PKG_CHECK_MODULES([librevisa], [librevisa >= 0.0.20130812],
 304         [have_librevisa="yes"; LIB_CFLAGS="$LIB_CFLAGS $librevisa_CFLAGS";
 305         LIBS="$LIBS $librevisa_LIBS";
 306         SR_PKGLIBS="$SR_PKGLIBS librevisa"],
 307         [have_librevisa="no"])
 308 AM_CONDITIONAL(NEED_VISA, test "x$have_librevisa" != xno)
 309 if test "x$have_librevisa" != "xno"; then
 310         # Define HAVE_LIBREVISA in config.h if we found librevisa.
 311         AC_DEFINE_UNQUOTED(HAVE_LIBREVISA, [1],
 312                 [Specifies whether we have librevisa.])
 313 fi
 314
 315 # The GPIB SCPI backend is only compiled in if libgpib is found.
 316 PKG_CHECK_MODULES([libgpib], [libgpib],
 317         [have_libgpib="yes"; LIB_CFLAGS="$LIB_CFLAGS $libgpib_CFLAGS";
 318         LIBS="$LIBS $libgpib_LIBS";
 319         SR_PKGLIBS="$SR_PKGLIBS libgpib"],
 320         [have_libgpib="no"])
 321 AM_CONDITIONAL(NEED_GPIB, test "x$have_libgpib" != xno)
 322 if test "x$have_libgpib" != "xno"; then
 323         # Define HAVE_LIBGPIB in config.h if we found libgpib.
 324         AC_DEFINE_UNQUOTED(HAVE_LIBGPIB, [1],
 325                 [Specifies whether we have libgpib.])
 326 fi
 327
 328 # libusb-1.0 is only needed for some hardware drivers. Disable the respective
 329 # drivers if it is not found.
 330 if test "x$enable_libusb" != "xno"; then
 331         case "$host" in
 332         *freebsd*)
 333                 # FreeBSD comes with an "integrated" libusb-1.0-style USB API.
 334                 # This means libusb-1.0 is always available, no need to check for it,
 335                 # and no need to (potentially) disable any drivers if it's not found.
 336                 have_libusb1_0="yes"
 337                 ;;
 338         *)
 339                 PKG_CHECK_MODULES([libusb], [libusb-1.0 >= 1.0.16],
 340                         [have_libusb1_0="yes"; LIB_CFLAGS="$LIB_CFLAGS $libusb_CFLAGS";
 341                         LIBS="$LIBS $libusb_LIBS";
 342                         SR_PKGLIBS="$SR_PKGLIBS libusb-1.0"],
 343                         [have_libusb1_0="no"])
 344                 if test "x$enable_libusb$have_libusb1_0" = "xyesno"; then
 345                         AC_MSG_ERROR([libusb support requested, but it was not found.])
 346                 fi
 347                 ;;
 348         esac
 349 else
 350         have_libusb1_0="no"
 351 fi
 352 if test "x$have_libusb1_0" = "xno"; then
 353         HW_BRYMEN_BM86X="no"; HW_FX2LAFW="no";
 354         HW_HANTEK_DSO="no"; HW_IKALOGIC_SCANALOGIC2="no";
 355         HW_KECHENG_KC_330B="no"; HW_LASCAR_EL_USB="no";
 356         HW_SYSCLK_LWLA="no"; HW_TESTO="no"; HW_UNI_T_DMM="no";
 357         HW_UNI_T_UT32X="no"; HW_VICTOR_DMM="no";
 358         HW_ZEROPLUS_LOGIC_CUBE="no"; HW_SALEAE_LOGIC16="no";
 359 else
 360         # Define HAVE_LIBUSB_1_0 in config.h if we found libusb-1.0.
 361         AC_DEFINE_UNQUOTED(HAVE_LIBUSB_1_0, [1],
 362                 [Specifies whether we have libusb-1.0.])
 363 fi
 364
 365 # USB + FX2 firmware helper code is only compiled in if libusb-1.0 was found.
 366 AM_CONDITIONAL(NEED_USB, test "x$have_libusb1_0" != xno)
 367
 368 # libftdi is only needed for some hardware drivers. Disable them if not found.
 369 if test "x$enable_libftdi" != "xno"; then
 370         PKG_CHECK_MODULES([libftdi], [libftdi >= 0.16],
 371                 [have_libftdi="yes"; LIB_CFLAGS="$LIB_CFLAGS $libftdi_CFLAGS";
 372                 LIBS="$LIBS $libftdi_LIBS";
 373                 SR_PKGLIBS="$SR_PKGLIBS libftdi"],
 374                 [PKG_CHECK_MODULES([libftdi1], [libftdi1 >= 1.0],
 375                         [LIB_CFLAGS="$LIB_CFLAGS $libftdi1_CFLAGS";
 376                         LIBS="$LIBS $libftdi1_LIBS";
 377                         SR_PKGLIBS="$SR_PKGLIBS libftdi1"],
 378                         [have_libftdi="no"])])
 379         if test "x$enable_libftdi$have_libftdi" = "xyesno"; then
 380                 AC_MSG_ERROR([libftdi support requested, but it was not found.])
 381         fi
 382 else
 383         have_libftdi="no"
 384 fi
 385 if test "x$have_libftdi" = "xno"; then
 386         HW_ASIX_SIGMA="no"; HW_CHRONOVU_LA="no"; HW_IKALOGIC_SCANAPLUS="no";
 387         HW_PIPISTRELLO_OLS="no";
 388 fi
 389
 390 # glibmm-2.4 is needed for the C++ bindings.
 391 PKG_CHECK_MODULES([glibmm], [glibmm-2.4 >= 2.32.0],
 392         [CXXFLAGS="$CXXFLAGS $glibmm_CFLAGS";
 393         CXXLIBS="$CXXLIBS $glibmm_LIBS"],
 394         [BINDINGS_CXX="no"; cxx_msg="glibmm required"])
 395
 396 # C++ bindings want stoi and stod.
 397 if test "x$BINDINGS_CXX" == "xyes"; then
 398         AC_LANG_PUSH([C++])
 399         AC_MSG_CHECKING([for stoi and stod])
 400         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <string>],
 401                 [{ return std::stoi("1") + std::stod("1.0"); }])],
 402                 [AC_MSG_RESULT([yes]);
 403                 AC_DEFINE_UNQUOTED(HAVE_STOI_STOD, [1],
 404                 [Specifies whether we have the stoi and stod functions.])],
 405                 [AC_MSG_RESULT([no])])
 406         AC_LANG_POP([C++])
 407 fi
 408
 409 # PyGObject is needed for the Python bindings.
 410 PKG_CHECK_MODULES([pygobject], [pygobject-3.0 >= 3.0.0],
 411         [CXXFLAGS="$CXXFLAGS $pygobject_CFLAGS";
 412         CXXLIBS="$CXXLIBS $pygobject_LIBS";
 413         PKG_CHECK_MODULES([pygobject_3_7_91], [pygobject-3.0 >= 3.7.91],
 414                 [pyg_flags_signed=0], [pyg_flags_signed=1]);
 415         AC_DEFINE_UNQUOTED(PYGOBJECT_FLAGS_SIGNED, [$pyg_flags_signed],
 416                 [Whether last argument to pyg_flags_get_value() is signed.])],
 417         [BINDINGS_PYTHON="no"; python_msg="Python pygobject module required"])
 418
 419 # The Check unit testing framework is optional. Disable if not found.
 420 PKG_CHECK_MODULES([check], [check >= 0.9.4],
 421         [have_check="yes"], [have_check="no"])
 422 AM_CONDITIONAL(HAVE_CHECK, test x"$have_check" = "xyes")
 423
 424 # The OLS driver uses serial port file descriptors directly, and therefore
 425 # will not currently work on Windows.
 426 case "$host" in
 427 *mingw*)
 428         HW_OPENBENCH_LOGIC_SNIFFER="no"
 429         ;;
 430 esac
 431
 432 # The BeagleLogic driver needs sys/mman.h and sys/ioctl.h. Don't try to
 433 # build it if these headers aren't available.
 434 AC_CHECK_HEADERS([sys/mman.h sys/ioctl.h], [], [HW_BEAGLELOGIC="no"])
 435
 436 AC_SUBST(SR_PKGLIBS)
 437
 438 CFLAGS="$CFLAGS -Iinclude/libsigrok -I${srcdir}/include/libsigrok $LIB_CFLAGS"
 439 CXXFLAGS="$CXXFLAGS -Iinclude/libsigrok -I${srcdir}/include -Ibindings/cxx -Ibindings/cxx/include/libsigrok -I${srcdir}/bindings/cxx/include $LIB_CFLAGS"
 440
 441 # Find Java compiler and JNI includes for Java bindings.
 442 AC_CHECK_PROG([HAVE_JAVAC], [javac], [yes], [no])
 443 if test "x$HAVE_JAVAC" = "xyes"; then
 444         AX_PROG_JAVAC
 445         if test "x$JNI_INCLUDE_DIRS" = "xauto"; then
 446                 if test "x$cross_compiling" = "xyes"; then
 447                         JNI_INCLUDE_DIRS=
 448                 else
 449                         AX_JNI_INCLUDE_DIR
 450                 fi
 451         fi
 452         for JNI_INCLUDE_DIR in $JNI_INCLUDE_DIRS; do
 453                 CXXFLAGS="$CXXFLAGS -I$JNI_INCLUDE_DIR"
 454         done
 455         AC_LANG_PUSH([C++])
 456         AC_CHECK_HEADERS([jni.h], [], [BINDINGS_JAVA="no"; java_msg="Java JNI headers required"])
 457         AC_LANG_POP([C++])
 458 else
 459         BINDINGS_JAVA="no"; java_msg="Java compiler required"
 460 fi
 461
 462 # Python and Java bindings depend on C++ bindings.
 463 if test "x$BINDINGS_CXX" != "xyes"; then
 464         BINDINGS_PYTHON="no"; python_msg="C++ bindings required"
 465         BINDINGS_JAVA="no"; java_msg="C++ bindings required"
 466 fi
 467
 468 # Now set AM_CONDITIONALs and AC_DEFINEs for the enabled/disabled drivers.
 469
 470 AC_DEFUN([DRIVER2], [
 471         AM_CONDITIONAL($1, test "x$2" = "xyes")
 472         if test "x$2" = "xyes"; then AC_DEFINE($3, 1, [.]) fi
 473 ])
 474
 475 DRIVER2([HW_AGILENT_DMM], [$HW_AGILENT_DMM], [HAVE_HW_AGILENT_DMM])
 476 DRIVER2([HW_APPA_55II], [$HW_APPA_55II], [HAVE_HW_APPA_55II])
 477 DRIVER2([HW_ASIX_SIGMA], [$HW_ASIX_SIGMA], [HAVE_HW_ASIX_SIGMA])
 478 DRIVER2([HW_ATTEN_PPS3XXX], [$HW_ATTEN_PPS3XXX], [HAVE_HW_ATTEN_PPS3XXX])
 479 DRIVER2([HW_BEAGLELOGIC], [$HW_BEAGLELOGIC], [HAVE_HW_BEAGLELOGIC])
 480 DRIVER2([HW_BRYMEN_BM86X], [$HW_BRYMEN_BM86X], [HAVE_HW_BRYMEN_BM86X])
 481 DRIVER2([HW_BRYMEN_DMM], [$HW_BRYMEN_DMM], [HAVE_HW_BRYMEN_DMM])
 482 DRIVER2([HW_CEM_DT_885X], [$HW_CEM_DT_885X], [HAVE_HW_CEM_DT_885X])
 483 DRIVER2([HW_CENTER_3XX], [$HW_CENTER_3XX], [HAVE_HW_CENTER_3XX])
 484 DRIVER2([HW_CHRONOVU_LA], [$HW_CHRONOVU_LA], [HAVE_HW_CHRONOVU_LA])
 485 DRIVER2([HW_COLEAD_SLM], [$HW_COLEAD_SLM], [HAVE_HW_COLEAD_SLM])
 486 DRIVER2([HW_CONRAD_DIGI_35_CPU], [$HW_CONRAD_DIGI_35_CPU], [HAVE_HW_CONRAD_DIGI_35_CPU])
 487 DRIVER2([HW_DEMO], [$HW_DEMO], [HAVE_HW_DEMO])
 488 DRIVER2([HW_FLUKE_DMM], [$HW_FLUKE_DMM], [HAVE_HW_FLUKE_DMM])
 489 DRIVER2([HW_FX2LAFW], [$HW_FX2LAFW], [HAVE_HW_FX2LAFW])
 490 DRIVER2([HW_GMC_MH_1X_2X], [$HW_GMC_MH_1X_2X], [HAVE_HW_GMC_MH_1X_2X])
 491 DRIVER2([HW_HAMEG_HMO], [$HW_HAMEG_HMO], [HAVE_HW_HAMEG_HMO])
 492 DRIVER2([HW_HANTEK_DSO], [$HW_HANTEK_DSO], [HAVE_HW_HANTEK_DSO])
 493 DRIVER2([HW_IKALOGIC_SCANALOGIC2], [$HW_IKALOGIC_SCANALOGIC2], [HAVE_HW_IKALOGIC_SCANALOGIC2])
 494 DRIVER2([HW_IKALOGIC_SCANAPLUS], [$HW_IKALOGIC_SCANAPLUS], [HAVE_HW_IKALOGIC_SCANAPLUS])
 495 DRIVER2([HW_KECHENG_KC_330B], [$HW_KECHENG_KC_330B], [HAVE_HW_KECHENG_KC_330B])
 496 DRIVER2([HW_LASCAR_EL_USB], [$HW_LASCAR_EL_USB], [HAVE_HW_LASCAR_EL_USB])
 497 DRIVER2([HW_MANSON_HCS_3XXX], [$HW_MANSON_HCS_3XXX], [HAVE_HW_MANSON_HCS_3XXX])
 498 DRIVER2([HW_MIC_985XX], [$HW_MIC_985XX], [HAVE_HW_MIC_985XX])
 499 DRIVER2([HW_MOTECH_LPS_30X], [$HW_MOTECH_LPS_30X], [HAVE_HW_MOTECH_LPS_30X])
 500 DRIVER2([HW_NORMA_DMM], [$HW_NORMA_DMM], [HAVE_HW_NORMA_DMM])
 501 DRIVER2([HW_OPENBENCH_LOGIC_SNIFFER], [$HW_OPENBENCH_LOGIC_SNIFFER], [HAVE_HW_OPENBENCH_LOGIC_SNIFFER])
 502 DRIVER2([HW_PIPISTRELLO_OLS], [$HW_PIPISTRELLO_OLS], [HAVE_HW_PIPISTRELLO_OLS])
 503 DRIVER2([HW_RIGOL_DS], [$HW_RIGOL_DS], [HAVE_HW_RIGOL_DS])
 504 DRIVER2([HW_SALEAE_LOGIC16], [$HW_SALEAE_LOGIC16], [HAVE_HW_SALEAE_LOGIC16])
 505 DRIVER2([HW_SCPI_PPS], [$HW_SCPI_PPS], [HAVE_HW_SCPI_PPS])
 506 DRIVER2([HW_SERIAL_DMM], [$HW_SERIAL_DMM], [HAVE_HW_SERIAL_DMM])
 507 DRIVER2([HW_SYSCLK_LWLA], [$HW_SYSCLK_LWLA], [HAVE_HW_SYSCLK_LWLA])
 508 DRIVER2([HW_TELEINFO], [$HW_TELEINFO], [HAVE_HW_TELEINFO])
 509 DRIVER2([HW_TESTO], [$HW_TESTO], [HAVE_HW_TESTO])
 510 DRIVER2([HW_TONDAJ_SL_814], [$HW_TONDAJ_SL_814], [HAVE_HW_TONDAJ_SL_814])
 511 DRIVER2([HW_UNI_T_DMM], [$HW_UNI_T_DMM], [HAVE_HW_UNI_T_DMM])
 512 DRIVER2([HW_UNI_T_UT32X], [$HW_UNI_T_UT32X], [HAVE_HW_UNI_T_UT32X])
 513 DRIVER2([HW_VICTOR_DMM], [$HW_VICTOR_DMM], [HAVE_HW_VICTOR_DMM])
 514 DRIVER2([HW_YOKOGAWA_DLM], [$HW_YOKOGAWA_DLM], [HAVE_HW_YOKOGAWA_DLM])
 515 DRIVER2([HW_ZEROPLUS_LOGIC_CUBE], [$HW_ZEROPLUS_LOGIC_CUBE], [HAVE_HW_ZEROPLUS_LOGIC_CUBE])
 516
 517 AM_CONDITIONAL(BINDINGS_CXX, test x$BINDINGS_CXX = xyes)
 518
 519 AM_CONDITIONAL(BINDINGS_PYTHON, test x$BINDINGS_PYTHON = xyes)
 520
 521 AM_CONDITIONAL(BINDINGS_JAVA, test x$BINDINGS_JAVA = xyes)
 522
 523 # Checks for header files.
 524 # These are already implicitly checked: inttypes.h stdint.h stdlib.h string.h
 525 # unistd.h memory.h strings.h dlfcn.h sys/types.h sys/stat.h.
 526
 527 # Checks for typedefs, structures, and compiler characteristics.
 528 AC_C_BIGENDIAN
 529
 530 AC_SUBST(FIRMWARE_DIR, "$datadir/sigrok-firmware")
 531 AC_SUBST(MAKEFLAGS, '--no-print-directory')
 532 AC_SUBST(AM_LIBTOOLFLAGS, '--silent')
 533
 534 SR_PACKAGE_VERSION_MAJOR=sr_package_version_major
 535 SR_PACKAGE_VERSION_MINOR=sr_package_version_minor
 536 SR_PACKAGE_VERSION_MICRO=sr_package_version_micro
 537 SR_PACKAGE_VERSION=sr_package_version
 538
 539 AC_SUBST(SR_PACKAGE_VERSION_MAJOR)
 540 AC_SUBST(SR_PACKAGE_VERSION_MINOR)
 541 AC_SUBST(SR_PACKAGE_VERSION_MICRO)
 542 AC_SUBST(SR_PACKAGE_VERSION)
 543
 544 AC_CONFIG_FILES([Makefile include/libsigrok/version.h libsigrok.pc
 545         bindings/cxx/libsigrokxx.pc])
 546
 547 AC_OUTPUT
 548
 549 echo
 550 echo "libsigrok configuration summary:"
 551 echo
 552 echo "  - Package version (major.minor.micro):    $SR_PACKAGE_VERSION"
 553 echo "  - Library version (current:revision:age): $SR_LIB_VERSION"
 554 echo "  - Prefix: $prefix"
 555 echo "  - Building on: $build"
 556 echo "  - Building for: $host"
 557 echo
 558 echo "Detected libraries:"
 559 echo
 560
 561 # Note: This only works for libs with pkg-config integration.
 562 for lib in "glib-2.0 >= 2.32.0" "libzip >= 0.10" "libserialport >= 0.2.0" \
 563         "librevisa >= 0.0.20130812" "libusb-1.0 >= 1.0.16" "libftdi >= 0.16" \
 564         "libftdi1 >= 1.0" "libgpib" "glibmm-2.4 >= 2.32.0" \
 565         "pygobject-3.0 >= 3.0.0" "check >= 0.9.4"
 566 do
 567         optional="OPTIONAL"
 568         if test "x$lib" = "xglib-2.0 >= 2.32.0"; then optional="REQUIRED"; fi
 569         if test "x$lib" = "xlibzip >= 0.10"; then optional="REQUIRED"; fi
 570         if `$PKG_CONFIG --exists $lib`; then
 571                 ver=`$PKG_CONFIG --modversion $lib`
 572                 answer="yes ($ver)"
 573         else
 574                 answer="no"
 575         fi
 576         echo "  - ($optional) $lib: $answer"
 577 done
 578
 579 eval echo -e "@Enabled hardware drivers:@@${driver_summary}" | tr @ \\n
 580
 581 # Prepare final bindings report messages.
 582 final_cxx=""
 583 final_python=""
 584 final_java=""
 585 if test "$enable_bindings" = "no"; then
 586         final_cxx=" (disabled)"
 587         final_python=" (disabled)"
 588         final_java=" (disabled)"
 589 else
 590         if test "$enable_cxx" = "no"; then
 591                 final_cxx=" (disabled)"
 592         elif test "$BINDINGS_CXX" = "no"; then
 593                 final_cxx=" ($cxx_msg)"
 594         fi
 595         if test "$enable_python" = "no"; then
 596                 final_python=" (disabled)"
 597         elif test "$BINDINGS_PYTHON" = "no"; then
 598                 final_python=" ($python_msg)"
 599         fi
 600         if test "$enable_java" = "no"; then
 601                 final_java=" (disabled)"
 602         elif test "$BINDINGS_JAVA" = "no"; then
 603                 final_java=" ($java_msg)"
 604         fi
 605 fi
 606
 607 echo "Enabled SCPI backends:"
 608 echo " - TCP............................. yes"
 609 if test "x$have_rpc" = "x0"; then
 610 echo " - RPC............................. no"
 611 else
 612 echo " - RPC............................. yes"
 613 fi
 614 echo " - serial.......................... $have_libserialport"
 615 echo " - VISA............................ $have_librevisa"
 616 echo " - GPIB............................ $have_libgpib"
 617 echo " - USBTMC.......................... $have_libusb1_0"
 618 echo
 619
 620 echo "Enabled language bindings:"
 621 echo " - C++............................. $BINDINGS_CXX$final_cxx"
 622 echo " - Python.......................... $BINDINGS_PYTHON$final_python"
 623 echo " - Java............................ $BINDINGS_JAVA$final_java"
 624 echo