configure.ac

   1 ##
   2 ## This file is part of the libsigrok project.
   3 ##
   4 ## Copyright (C) 2010-2012 Bert Vermeulen <bert@biot.com>
   5 ## Copyright (C) 2012 Alexandru Gagniuc <mr.nuke.me@gmail.com>
   6 ##
   7 ## This program is free software: you can redistribute it and/or modify
   8 ## it under the terms of the GNU General Public License as published by
   9 ## the Free Software Foundation, either version 3 of the License, or
  10 ## (at your option) any later version.
  11 ##
  12 ## This program is distributed in the hope that it will be useful,
  13 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ## GNU General Public License for more details.
  16 ##
  17 ## You should have received a copy of the GNU General Public License
  18 ## along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19 ##
  20
  21 # We require at least autoconf 2.63 (AC_INIT format changed there).
  22 AC_PREREQ([2.63])
  23
  24 # libsigrok package version number (NOT the same as shared lib version!).
  25 m4_define([sr_package_version_major], [0])
  26 m4_define([sr_package_version_minor], [3])
  27 m4_define([sr_package_version_micro], [0])
  28 m4_define([sr_package_version], [sr_package_version_major.sr_package_version_minor.sr_package_version_micro])
  29
  30 AC_INIT([libsigrok], [sr_package_version], [sigrok-devel@lists.sourceforge.net],
  31         [libsigrok], [http://www.sigrok.org])
  32 AC_CONFIG_HEADER([config.h])
  33 AC_CONFIG_MACRO_DIR([autostuff])
  34 AC_CONFIG_AUX_DIR([autostuff])
  35
  36 # We require at least automake 1.11 (needed for 'silent rules').
  37 AM_INIT_AUTOMAKE([1.11 -Wall -Werror subdir-objects check-news color-tests])
  38 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  39 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  40
  41 AH_TOP([#ifndef SR_CONFIG_H
  42 #define SR_CONFIG_H    /* To stop multiple inclusions. */])
  43 AH_BOTTOM([#endif /* SR_CONFIG_H */])
  44
  45 # Enable more compiler warnings via -Wall and -Wextra. Add -fvisibility=hidden
  46 # and enforce use of SR_API to explicitly mark all public API functions.
  47 COMMON_FLAGS="$CFLAGS -Wall -Wextra -fvisibility=hidden"
  48 CFLAGS="$COMMON_FLAGS -std=c11 -D_POSIX_C_SOURCE=200112L -Wmissing-prototypes"
  49 CXXFLAGS="-std=c++11 $COMMON_FLAGS"
  50
  51 # Checks for programs.
  52 AC_PROG_CC
  53 AC_PROG_CPP
  54 AC_PROG_CXX
  55 AC_PROG_INSTALL
  56 AC_PROG_LN_S
  57
  58 # Required for per-target flags or subdir-objects with C sources.
  59 AM_PROG_CC_C_O
  60
  61 # Initialize libtool.
  62 LT_INIT
  63
  64 # Initialize pkg-config.
  65 # We require at least 0.22, as "Requires.private" behaviour changed there.
  66 PKG_PROG_PKG_CONFIG([0.22])
  67
  68 # Library version for libsigrok (NOT the same as the package version).
  69 # Carefully read the libtool docs before updating these numbers!
  70 # The algorithm for determining which number to change (and how) is nontrivial!
  71 # http://www.gnu.org/software/libtool/manual/libtool.html#Updating-version-info
  72 SR_LIB_VERSION_CURRENT=2
  73 SR_LIB_VERSION_REVISION=0
  74 SR_LIB_VERSION_AGE=0
  75 SR_LIB_VERSION="$SR_LIB_VERSION_CURRENT:$SR_LIB_VERSION_REVISION:$SR_LIB_VERSION_AGE"
  76 SR_LIB_LDFLAGS="-version-info $SR_LIB_VERSION"
  77 AC_SUBST(SR_LIB_VERSION_CURRENT)
  78 AC_SUBST(SR_LIB_VERSION_REVISION)
  79 AC_SUBST(SR_LIB_VERSION_AGE)
  80 AC_SUBST(SR_LIB_VERSION)
  81 AC_SUBST(SR_LIB_LDFLAGS)
  82
  83 AC_ARG_ENABLE(all-drivers, AC_HELP_STRING([--enable-all-drivers],
  84         [enable all drivers by default [default=yes]]),
  85         [HW_ENABLED_DEFAULT="$enableval"],
  86         [HW_ENABLED_DEFAULT="yes"])
  87
  88 # Usage: DRIVER([Device name], [driver-name])
  89 # An optional third argument [no] disables that driver.
  90 m4_define([driverize], [m4_tolower(m4_bpatsubst([$1], [[^0-9a-zA-Z-]+], [-]))])
  91 m4_define([upperize], [m4_toupper(m4_bpatsubst([$1], [[^0-9a-zA-Z_]+], [_]))])
  92 AC_DEFUN([DRIVER], [
  93         if test -z "$3"; then
  94                 default=$HW_ENABLED_DEFAULT
  95         else
  96                 default="$3"
  97         fi
  98         AC_ARG_ENABLE($2, AC_HELP_STRING([--enable-$2], [enable $1 support]),
  99                 [m4_join([], [HW_], upperize([$2]))="$enableval"],
 100                 [m4_join([], [HW_], upperize([$2]))=$default])
 101         dots=$(echo -n ".............................." | cut -c 1-$(expr 32 - $(echo -n $2|wc -c)))
 102         driver_summary="${driver_summary}  - $2${dots} \${m4_join([], [HW_], upperize([$2]))}@"
 103 ])
 104
 105 DRIVER([Agilent DMM], [agilent-dmm])
 106 DRIVER([Appa 55II], [appa-55ii])
 107 DRIVER([ASIX SIGMA/SIGMA2], [asix-sigma])
 108 DRIVER([Atten PPS3xxx], [atten-pps3xxx])
 109 DRIVER([BayLibre ACME], [baylibre-acme])
 110 DRIVER([BeagleLogic], [beaglelogic])
 111 DRIVER([Brymen BM86x], [brymen-bm86x])
 112 DRIVER([Brymen DMM], [brymen-dmm])
 113 DRIVER([CEM DT-885x], [cem-dt-885x])
 114 DRIVER([Center 3xx], [center-3xx])
 115 DRIVER([ChronoVu LA], [chronovu-la])
 116 DRIVER([Colead SLM], [colead-slm])
 117 DRIVER([Conrad DIGI 35 CPU], [conrad-digi-35-cpu])
 118 DRIVER([DER EE DE-5000], [deree-de5000])
 119 DRIVER([demo], [demo])
 120 DRIVER([Fluke DMM], [fluke-dmm])
 121 DRIVER([fx2lafw], [fx2lafw])
 122 DRIVER([GMC MH 1x/2x], [gmc-mh-1x-2x])
 123 DRIVER([Hameg HMO], [hameg-hmo])
 124 DRIVER([Hantek DSO], [hantek-dso])
 125 DRIVER([Ikalogic Scanalogic-2], [ikalogic-scanalogic2])
 126 DRIVER([Ikalogic Scanaplus], [ikalogic-scanaplus])
 127 DRIVER([Kecheng KC-330B], [kecheng-kc-330b])
 128 DRIVER([Lascar EL-USB], [lascar-el-usb])
 129 DRIVER([Manson HCS-3xxx], [manson-hcs-3xxx])
 130 DRIVER([maynuo-m97], [maynuo-m97])
 131 DRIVER([MIC 985xx], [mic-985xx])
 132 DRIVER([Motech LPS 30x], [motech-lps-30x])
 133 DRIVER([Norma DMM], [norma-dmm])
 134 DRIVER([OpenBench Logic Sniffer], [openbench-logic-sniffer])
 135 DRIVER([Pipistrello-OLS], [pipistrello-ols])
 136 DRIVER([Rigol DS], [rigol-ds])
 137 DRIVER([Saleae Logic16], [saleae-logic16])
 138 DRIVER([SCPI PPS], [scpi-pps])
 139 DRIVER([serial DMM], [serial-dmm])
 140 DRIVER([Sysclk LWLA], [sysclk-lwla])
 141 DRIVER([Teleinfo], [teleinfo])
 142 DRIVER([Testo], [testo])
 143 DRIVER([Tondaj SL-814], [tondaj-sl-814])
 144 DRIVER([UNI-T DMM], [uni-t-dmm])
 145 DRIVER([UNI-T UT32x], [uni-t-ut32x])
 146 DRIVER([Victor DMM], [victor-dmm])
 147 DRIVER([Yokogawa DL/DLM], [yokogawa-dlm])
 148 DRIVER([ZEROPLUS Logic Cube], [zeroplus-logic-cube])
 149
 150 AC_ARG_ENABLE(libserialport,
 151         AC_HELP_STRING([--disable-libserialport],
 152         [disable libserialport support [default=detect]]))
 153
 154 AC_ARG_ENABLE(libftdi,
 155         AC_HELP_STRING([--disable-libftdi],
 156         [disable libftdi support [default=detect]]))
 157
 158 AC_ARG_ENABLE(libusb,
 159         AC_HELP_STRING([--disable-libusb],
 160         [disable libusb support [default=detect]]))
 161
 162 # Language binding '--enable' options:
 163
 164 AC_ARG_ENABLE(bindings,
 165         AC_HELP_STRING([--enable-bindings],
 166         [build language bindings [default=yes]]),
 167         [BINDINGS_ALL="$enableval"], [BINDINGS_ALL="yes"])
 168
 169 AC_ARG_ENABLE(cxx,
 170         AC_HELP_STRING([--enable-cxx],
 171         [build C++ bindings [default=yes]]),
 172         [BINDINGS_CXX="$enableval"], [BINDINGS_CXX=$BINDINGS_ALL])
 173
 174 AC_ARG_ENABLE(python,
 175         AC_HELP_STRING([--enable-python],
 176         [build Python bindings [default=yes]]),
 177         [BINDINGS_PYTHON="$enableval"], [BINDINGS_PYTHON=$BINDINGS_ALL])
 178
 179 AC_ARG_ENABLE(java,
 180         AC_HELP_STRING([--enable-java],
 181         [build Java bindings [default=yes]]),
 182         [BINDINGS_JAVA="$enableval"], [BINDINGS_JAVA=$BINDINGS_ALL])
 183
 184 AC_ARG_WITH(jni-include-path,
 185         AC_HELP_STRING([--with-jni-include-path=path],
 186         [specify include path for JNI [default=autodetect]]),
 187         [JNI_INCLUDE_DIRS="$withval"], [JNI_INCLUDE_DIRS=auto])
 188
 189 # Check if the C++ compiler supports the C++11 standard.
 190
 191 m4_ifdef([AX_CXX_COMPILE_STDCXX_11], [AX_CXX_COMPILE_STDCXX_11(,[optional])],
 192         [AC_MSG_NOTICE([Missing macro m4_toupper(aX_CXX_COMPILE_STDCXX_11), no C++11 check])])
 193
 194 if test "x$HAVE_CXX11" != "x1"; then
 195         BINDINGS_CXX="no"; cxx_msg="C++11 compiler required"
 196 fi
 197
 198 # The C++ bindings use Doxygen to parse libsigrok symbols.
 199 AC_CHECK_PROG([HAVE_DOXYGEN], [doxygen], [yes])
 200 if test "x$HAVE_DOXYGEN" != "xyes"; then
 201         BINDINGS_CXX="no"; cxx_msg="Doxygen required"
 202 fi
 203
 204 # Python is needed for the C++ bindings.
 205 AM_PATH_PYTHON([2.7], [HAVE_PYTHON="yes"],
 206         [HAVE_PYTHON="no"; BINDINGS_CXX="no"; cxx_msg="Python required"])
 207
 208 # The Python bindings need Python development files.
 209 PKG_CHECK_MODULES([python], [python >= 2.7],
 210         [CXXFLAGS="$CXXFLAGS $python_CFLAGS";
 211         CXXLIBS="$CXXLIBS $python_LIBS"],
 212 [PKG_CHECK_MODULES([python27], [python-2.7 >= 2.7],
 213         [CXXFLAGS="$CXXFLAGS $python27_CFLAGS";
 214         CXXLIBS="$CXXLIBS $python27_LIBS"],
 215                 [BINDINGS_PYTHON="no"; python_msg="Python headers required"])])
 216
 217 # The Python bindings need the setuptools Python module.
 218 m4_ifdef([AX_PYTHON_MODULE], [AX_PYTHON_MODULE([setuptools])],
 219         # We'll let it go through even if the macro wasn't found, the Python
 220         # module may still be there.
 221         [HAVE_PYTHON_SETUPTOOLS="yes";
 222                 AC_MSG_NOTICE([Missing macro m4_toupper(aX_PYTHON_MODULE), no setuptools check])]
 223 )
 224 if test "x$HAVE_PYMOD_SETUPTOOLS" != "xyes"; then
 225         BINDINGS_PYTHON="no"; python_msg="Python setuptools module required"
 226 fi
 227
 228 # The Python and Java bindings use SWIG to generate code.
 229 AC_CHECK_PROG([HAVE_SWIG], [swig], [yes])
 230 if test "x$HAVE_SWIG" != "xyes"; then
 231         BINDINGS_PYTHON="no"; python_msg="SWIG required"
 232         BINDINGS_JAVA="no"; java_msg="SWIG required"
 233 fi
 234
 235 # Checks for libraries.
 236
 237 case "$host" in
 238 *mingw*)
 239         # We need to link against the Winsock2 library for SCPI over TCP.
 240         LIBS="$LIBS -lws2_32";;
 241 esac
 242
 243 # This variable collects the pkg-config names of all detected libs.
 244 # It is then used to construct the "Requires.private:" field in the
 245 # libsigrok.pc file.
 246 SR_PKGLIBS=""
 247
 248 # libm (the standard math library) is always needed.
 249 AC_SEARCH_LIBS([pow], [m])
 250
 251 # RPC is only needed for VXI support.
 252 AC_MSG_CHECKING([for RPC support])
 253 AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <rpc/rpc.h>],
 254                         [CLIENT *rpc_test(void)],
 255                         [{ return clnt_create("", 0, 0, ""); }])],
 256                 [AC_MSG_RESULT([yes]); have_rpc=1],
 257                 [AC_MSG_RESULT([no]);  have_rpc=0])
 258 # Define HAVE_RPC in config.h if we found RPC support.
 259 AC_DEFINE_UNQUOTED(HAVE_RPC, [$have_rpc], [Specifies whether we have RPC support.])
 260 # VXI support is only compiled if RPC support was found.
 261 AM_CONDITIONAL(NEED_RPC, test "x$have_rpc" != "x0")
 262
 263 # libglib-2.0 is always needed. Abort if it's not found.
 264 # Note: glib-2.0 is part of the libsigrok API (hard pkg-config requirement).
 265 # We require at least 2.32.0 due to e.g. g_variant_new_fixed_array().
 266 AM_PATH_GLIB_2_0([2.32.0],
 267         [LIB_CFLAGS="$LIB_CFLAGS $GLIB_CFLAGS"; LIBS="$LIBS $GLIB_LIBS"])
 268
 269 # libzip is always needed. Abort if it's not found.
 270 PKG_CHECK_MODULES([libzip], [libzip >= 0.10],
 271         [LIB_CFLAGS="$LIB_CFLAGS $libzip_CFLAGS"; LIBS="$LIBS $libzip_LIBS";
 272         SR_PKGLIBS="$SR_PKGLIBS libzip"])
 273
 274 # libserialport is only needed for some hardware drivers. Disable the
 275 # respective drivers if it is not found.
 276 if test "x$enable_libserialport" != "xno"; then
 277         PKG_CHECK_MODULES([libserialport], [libserialport >= 0.1.1],
 278                 [have_libserialport="yes"; LIB_CFLAGS="$LIB_CFLAGS $libserialport_CFLAGS";
 279                 LIBS="$LIBS $libserialport_LIBS";
 280                 SR_PKGLIBS="$SR_PKGLIBS libserialport"],
 281                 [have_libserialport="no"])
 282         if test "x$enable_libserialport$have_libserialport" = "xyesno"; then
 283                 AC_MSG_ERROR([libserialport support requested, but it was not found.])
 284         fi
 285 else
 286         have_libserialport="no"
 287 fi
 288 if test "x$have_libserialport" = "xno"; then
 289         HW_AGILENT_DMM="no"; HW_APPA_55II="no";
 290         HW_ATTEN_PPS3XXX="no"; HW_BRYMEN_DMM="no"; HW_CEM_DT_885X="no";
 291         HW_CENTER_3XX="no"; HW_COLEAD_SLM="no"; HW_CONRAD_DIGI_35_CPU="no";
 292         HW_DEREE_DE5000="no"; HW_FLUKE_DMM="no"; HW_GMC_MH_1X_2X="no";
 293         HW_HAMEG_HMO="no"; HW_MANSON_HCS_3XXX="no"; HW_MIC_985XX="no";
 294         HW_MOTECH_LPS_30X="no"; HW_NORMA_DMM="no";
 295         HW_OPENBENCH_LOGIC_SNIFFER="no"; HW_SERIAL_DMM="no";
 296         HW_TELEINFO="no"; HW_TONDAJ_SL_814="no";
 297 else
 298         # Define HAVE_LIBSERIALPORT in config.h if we found libserialport.
 299         AC_DEFINE_UNQUOTED(HAVE_LIBSERIALPORT, [1],
 300                 [Specifies whether we have libserialport.])
 301 fi
 302
 303 # Serial port helper code is only compiled in if libserialport was found.
 304 AM_CONDITIONAL(NEED_SERIAL, test "x$have_libserialport" != xno)
 305
 306 # The VISA SCPI backend is only compiled in if librevisa was found.
 307 PKG_CHECK_MODULES([librevisa], [librevisa >= 0.0.20130412],
 308         [have_librevisa="yes"; LIB_CFLAGS="$LIB_CFLAGS $librevisa_CFLAGS";
 309         LIBS="$LIBS $librevisa_LIBS";
 310         SR_PKGLIBS="$SR_PKGLIBS librevisa"],
 311         [have_librevisa="no"])
 312 AM_CONDITIONAL(NEED_VISA, test "x$have_librevisa" != xno)
 313 if test "x$have_librevisa" != "xno"; then
 314         # Define HAVE_LIBREVISA in config.h if we found librevisa.
 315         AC_DEFINE_UNQUOTED(HAVE_LIBREVISA, [1],
 316                 [Specifies whether we have librevisa.])
 317 fi
 318
 319 # The GPIB SCPI backend is only compiled in if libgpib is found.
 320 PKG_CHECK_MODULES([libgpib], [libgpib],
 321         [have_libgpib="yes"; LIB_CFLAGS="$LIB_CFLAGS $libgpib_CFLAGS";
 322         LIBS="$LIBS $libgpib_LIBS";
 323         SR_PKGLIBS="$SR_PKGLIBS libgpib"],
 324         [have_libgpib="no"])
 325 AM_CONDITIONAL(NEED_GPIB, test "x$have_libgpib" != xno)
 326 if test "x$have_libgpib" != "xno"; then
 327         # Define HAVE_LIBGPIB in config.h if we found libgpib.
 328         AC_DEFINE_UNQUOTED(HAVE_LIBGPIB, [1],
 329                 [Specifies whether we have libgpib.])
 330 fi
 331
 332 # libusb-1.0 is only needed for some hardware drivers. Disable the respective
 333 # drivers if it is not found.
 334 if test "x$enable_libusb" != "xno"; then
 335         case "$host" in
 336         *freebsd*)
 337                 # FreeBSD comes with an "integrated" libusb-1.0-style USB API.
 338                 # This means libusb-1.0 is always available, no need to check for it,
 339                 # and no need to (potentially) disable any drivers if it's not found.
 340                 have_libusb1_0="yes"
 341                 ;;
 342         *)
 343                 PKG_CHECK_MODULES([libusb], [libusb-1.0 >= 1.0.16],
 344                         [have_libusb1_0="yes"; LIB_CFLAGS="$LIB_CFLAGS $libusb_CFLAGS";
 345                         LIBS="$LIBS $libusb_LIBS";
 346                         SR_PKGLIBS="$SR_PKGLIBS libusb-1.0"],
 347                         [have_libusb1_0="no"])
 348                 if test "x$enable_libusb$have_libusb1_0" = "xyesno"; then
 349                         AC_MSG_ERROR([libusb support requested, but it was not found.])
 350                 fi
 351                 ;;
 352         esac
 353 else
 354         have_libusb1_0="no"
 355 fi
 356 if test "x$have_libusb1_0" = "xno"; then
 357         HW_BRYMEN_BM86X="no"; HW_FX2LAFW="no";
 358         HW_HANTEK_DSO="no"; HW_IKALOGIC_SCANALOGIC2="no";
 359         HW_KECHENG_KC_330B="no"; HW_LASCAR_EL_USB="no";
 360         HW_SYSCLK_LWLA="no"; HW_TESTO="no"; HW_UNI_T_DMM="no";
 361         HW_UNI_T_UT32X="no"; HW_VICTOR_DMM="no";
 362         HW_ZEROPLUS_LOGIC_CUBE="no"; HW_SALEAE_LOGIC16="no";
 363 else
 364         # Define HAVE_LIBUSB_1_0 in config.h if we found libusb-1.0.
 365         AC_DEFINE_UNQUOTED(HAVE_LIBUSB_1_0, [1],
 366                 [Specifies whether we have libusb-1.0.])
 367 fi
 368
 369 # USB + FX2 firmware helper code is only compiled in if libusb-1.0 was found.
 370 AM_CONDITIONAL(NEED_USB, test "x$have_libusb1_0" != xno)
 371
 372 # libftdi is only needed for some hardware drivers. Disable them if not found.
 373 if test "x$enable_libftdi" != "xno"; then
 374         PKG_CHECK_MODULES([libftdi], [libftdi >= 0.16],
 375                 [have_libftdi="yes"; LIB_CFLAGS="$LIB_CFLAGS $libftdi_CFLAGS";
 376                 LIBS="$LIBS $libftdi_LIBS";
 377                 SR_PKGLIBS="$SR_PKGLIBS libftdi"],
 378                 [PKG_CHECK_MODULES([libftdi1], [libftdi1 >= 1.0],
 379                         [LIB_CFLAGS="$LIB_CFLAGS $libftdi1_CFLAGS";
 380                         LIBS="$LIBS $libftdi1_LIBS";
 381                         SR_PKGLIBS="$SR_PKGLIBS libftdi1"],
 382                         [have_libftdi="no"])])
 383         if test "x$enable_libftdi$have_libftdi" = "xyesno"; then
 384                 AC_MSG_ERROR([libftdi support requested, but it was not found.])
 385         fi
 386 else
 387         have_libftdi="no"
 388 fi
 389 if test "x$have_libftdi" = "xno"; then
 390         HW_ASIX_SIGMA="no"; HW_CHRONOVU_LA="no"; HW_IKALOGIC_SCANAPLUS="no";
 391         HW_PIPISTRELLO_OLS="no";
 392 fi
 393
 394 # glibmm-2.4 is needed for the C++ bindings.
 395 PKG_CHECK_MODULES([glibmm], [glibmm-2.4 >= 2.32.0],
 396         [CXXFLAGS="$CXXFLAGS $glibmm_CFLAGS";
 397         CXXLIBS="$CXXLIBS $glibmm_LIBS"],
 398         [BINDINGS_CXX="no"; cxx_msg="glibmm required"])
 399
 400 # C++ bindings want stoi and stod.
 401 if test "x$BINDINGS_CXX" = "xyes"; then
 402         AC_LANG_PUSH([C++])
 403         AC_MSG_CHECKING([for stoi and stod])
 404         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <string>],
 405                 [{ return std::stoi("1") + std::stod("1.0"); }])],
 406                 [AC_MSG_RESULT([yes]);
 407                 AC_DEFINE_UNQUOTED(HAVE_STOI_STOD, [1],
 408                 [Specifies whether we have the stoi and stod functions.])],
 409                 [AC_MSG_RESULT([no])])
 410         AC_LANG_POP([C++])
 411 fi
 412
 413 # PyGObject is needed for the Python bindings.
 414 PKG_CHECK_MODULES([pygobject], [pygobject-3.0 >= 3.0.0],
 415         [CXXFLAGS="$CXXFLAGS $pygobject_CFLAGS";
 416         CXXLIBS="$CXXLIBS $pygobject_LIBS";
 417         PKG_CHECK_MODULES([pygobject_3_7_91], [pygobject-3.0 >= 3.7.91],
 418                 [pyg_flags_signed=0], [pyg_flags_signed=1]);
 419         AC_DEFINE_UNQUOTED(PYGOBJECT_FLAGS_SIGNED, [$pyg_flags_signed],
 420                 [Whether last argument to pyg_flags_get_value() is signed.])],
 421         [BINDINGS_PYTHON="no"; python_msg="Python pygobject module required"])
 422
 423 # The Check unit testing framework is optional. Disable if not found.
 424 PKG_CHECK_MODULES([check], [check >= 0.9.4],
 425         [have_check="yes"], [have_check="no"])
 426 AM_CONDITIONAL(HAVE_CHECK, test x"$have_check" = "xyes")
 427
 428 # The BeagleLogic driver needs sys/mman.h and sys/ioctl.h. Don't try to
 429 # build it if these headers aren't available.
 430 AC_CHECK_HEADERS([sys/mman.h sys/ioctl.h], [], [HW_BEAGLELOGIC="no"])
 431
 432 # The ACME driver can only be built for Linux.
 433 case "$host" in
 434         *linux*) ;;
 435         *) HW_BAYLIBRE_ACME="no" ;;
 436 esac
 437
 438 AC_SUBST(SR_PKGLIBS)
 439
 440 CFLAGS="$CFLAGS -Iinclude/libsigrok -I${srcdir}/include/libsigrok $LIB_CFLAGS"
 441 CXXFLAGS="$CXXFLAGS -Iinclude/libsigrok -I${srcdir}/include -Ibindings/cxx -Ibindings/cxx/include/libsigrokcxx -I${srcdir}/bindings/cxx/include $LIB_CFLAGS"
 442
 443 # Find Java compiler and JNI includes for Java bindings.
 444 AC_CHECK_PROG([HAVE_JAVAC], [javac], [yes], [no])
 445 if test "x$HAVE_JAVAC" = "xyes" && test "x$BINDINGS_JAVA" = "xyes"; then
 446         AX_PROG_JAVAC
 447         if test "x$JNI_INCLUDE_DIRS" = "xauto"; then
 448                 if test "x$cross_compiling" = "xyes"; then
 449                         JNI_INCLUDE_DIRS=
 450                 else
 451                         AX_JNI_INCLUDE_DIR
 452                 fi
 453         fi
 454         for JNI_INCLUDE_DIR in $JNI_INCLUDE_DIRS; do
 455                 CXXFLAGS="$CXXFLAGS -I$JNI_INCLUDE_DIR"
 456         done
 457         AC_LANG_PUSH([C++])
 458         AC_CHECK_HEADERS([jni.h], [], [BINDINGS_JAVA="no"; java_msg="Java JNI headers required"])
 459         AC_LANG_POP([C++])
 460 else
 461         BINDINGS_JAVA="no"; java_msg="Java compiler required"
 462 fi
 463
 464 # Python and Java bindings depend on C++ bindings.
 465 if test "x$BINDINGS_CXX" != "xyes"; then
 466         BINDINGS_PYTHON="no"; python_msg="C++ bindings required"
 467         BINDINGS_JAVA="no"; java_msg="C++ bindings required"
 468 fi
 469
 470 # Now set AM_CONDITIONALs and AC_DEFINEs for the enabled/disabled drivers.
 471
 472 AC_DEFUN([DRIVER2], [
 473         AM_CONDITIONAL($1, test "x$2" = "xyes")
 474         if test "x$2" = "xyes"; then AC_DEFINE($3, 1, [.]) fi
 475 ])
 476
 477 DRIVER2([HW_AGILENT_DMM], [$HW_AGILENT_DMM], [HAVE_HW_AGILENT_DMM])
 478 DRIVER2([HW_APPA_55II], [$HW_APPA_55II], [HAVE_HW_APPA_55II])
 479 DRIVER2([HW_ASIX_SIGMA], [$HW_ASIX_SIGMA], [HAVE_HW_ASIX_SIGMA])
 480 DRIVER2([HW_ATTEN_PPS3XXX], [$HW_ATTEN_PPS3XXX], [HAVE_HW_ATTEN_PPS3XXX])
 481 DRIVER2([HW_BAYLIBRE_ACME], [$HW_BAYLIBRE_ACME], [HAVE_HW_BAYLIBRE_ACME])
 482 DRIVER2([HW_BEAGLELOGIC], [$HW_BEAGLELOGIC], [HAVE_HW_BEAGLELOGIC])
 483 DRIVER2([HW_BRYMEN_BM86X], [$HW_BRYMEN_BM86X], [HAVE_HW_BRYMEN_BM86X])
 484 DRIVER2([HW_BRYMEN_DMM], [$HW_BRYMEN_DMM], [HAVE_HW_BRYMEN_DMM])
 485 DRIVER2([HW_CEM_DT_885X], [$HW_CEM_DT_885X], [HAVE_HW_CEM_DT_885X])
 486 DRIVER2([HW_CENTER_3XX], [$HW_CENTER_3XX], [HAVE_HW_CENTER_3XX])
 487 DRIVER2([HW_CHRONOVU_LA], [$HW_CHRONOVU_LA], [HAVE_HW_CHRONOVU_LA])
 488 DRIVER2([HW_COLEAD_SLM], [$HW_COLEAD_SLM], [HAVE_HW_COLEAD_SLM])
 489 DRIVER2([HW_CONRAD_DIGI_35_CPU], [$HW_CONRAD_DIGI_35_CPU], [HAVE_HW_CONRAD_DIGI_35_CPU])
 490 DRIVER2([HW_DEMO], [$HW_DEMO], [HAVE_HW_DEMO])
 491 DRIVER2([HW_DEREE_DE5000], [$HW_DEREE_DE5000], [HAVE_HW_DEREE_DE5000])
 492 DRIVER2([HW_FLUKE_DMM], [$HW_FLUKE_DMM], [HAVE_HW_FLUKE_DMM])
 493 DRIVER2([HW_FX2LAFW], [$HW_FX2LAFW], [HAVE_HW_FX2LAFW])
 494 DRIVER2([HW_GMC_MH_1X_2X], [$HW_GMC_MH_1X_2X], [HAVE_HW_GMC_MH_1X_2X])
 495 DRIVER2([HW_HAMEG_HMO], [$HW_HAMEG_HMO], [HAVE_HW_HAMEG_HMO])
 496 DRIVER2([HW_HANTEK_DSO], [$HW_HANTEK_DSO], [HAVE_HW_HANTEK_DSO])
 497 DRIVER2([HW_IKALOGIC_SCANALOGIC2], [$HW_IKALOGIC_SCANALOGIC2], [HAVE_HW_IKALOGIC_SCANALOGIC2])
 498 DRIVER2([HW_IKALOGIC_SCANAPLUS], [$HW_IKALOGIC_SCANAPLUS], [HAVE_HW_IKALOGIC_SCANAPLUS])
 499 DRIVER2([HW_KECHENG_KC_330B], [$HW_KECHENG_KC_330B], [HAVE_HW_KECHENG_KC_330B])
 500 DRIVER2([HW_LASCAR_EL_USB], [$HW_LASCAR_EL_USB], [HAVE_HW_LASCAR_EL_USB])
 501 DRIVER2([HW_MANSON_HCS_3XXX], [$HW_MANSON_HCS_3XXX], [HAVE_HW_MANSON_HCS_3XXX])
 502 DRIVER2([HW_MAYNUO_M97], [$HW_MAYNUO_M97], [HAVE_HW_MAYNUO_M97])
 503 DRIVER2([HW_MIC_985XX], [$HW_MIC_985XX], [HAVE_HW_MIC_985XX])
 504 DRIVER2([HW_MOTECH_LPS_30X], [$HW_MOTECH_LPS_30X], [HAVE_HW_MOTECH_LPS_30X])
 505 DRIVER2([HW_NORMA_DMM], [$HW_NORMA_DMM], [HAVE_HW_NORMA_DMM])
 506 DRIVER2([HW_OPENBENCH_LOGIC_SNIFFER], [$HW_OPENBENCH_LOGIC_SNIFFER], [HAVE_HW_OPENBENCH_LOGIC_SNIFFER])
 507 DRIVER2([HW_PIPISTRELLO_OLS], [$HW_PIPISTRELLO_OLS], [HAVE_HW_PIPISTRELLO_OLS])
 508 DRIVER2([HW_RIGOL_DS], [$HW_RIGOL_DS], [HAVE_HW_RIGOL_DS])
 509 DRIVER2([HW_SALEAE_LOGIC16], [$HW_SALEAE_LOGIC16], [HAVE_HW_SALEAE_LOGIC16])
 510 DRIVER2([HW_SCPI_PPS], [$HW_SCPI_PPS], [HAVE_HW_SCPI_PPS])
 511 DRIVER2([HW_SERIAL_DMM], [$HW_SERIAL_DMM], [HAVE_HW_SERIAL_DMM])
 512 DRIVER2([HW_SYSCLK_LWLA], [$HW_SYSCLK_LWLA], [HAVE_HW_SYSCLK_LWLA])
 513 DRIVER2([HW_TELEINFO], [$HW_TELEINFO], [HAVE_HW_TELEINFO])
 514 DRIVER2([HW_TESTO], [$HW_TESTO], [HAVE_HW_TESTO])
 515 DRIVER2([HW_TONDAJ_SL_814], [$HW_TONDAJ_SL_814], [HAVE_HW_TONDAJ_SL_814])
 516 DRIVER2([HW_UNI_T_DMM], [$HW_UNI_T_DMM], [HAVE_HW_UNI_T_DMM])
 517 DRIVER2([HW_UNI_T_UT32X], [$HW_UNI_T_UT32X], [HAVE_HW_UNI_T_UT32X])
 518 DRIVER2([HW_VICTOR_DMM], [$HW_VICTOR_DMM], [HAVE_HW_VICTOR_DMM])
 519 DRIVER2([HW_YOKOGAWA_DLM], [$HW_YOKOGAWA_DLM], [HAVE_HW_YOKOGAWA_DLM])
 520 DRIVER2([HW_ZEROPLUS_LOGIC_CUBE], [$HW_ZEROPLUS_LOGIC_CUBE], [HAVE_HW_ZEROPLUS_LOGIC_CUBE])
 521
 522 AM_CONDITIONAL(BINDINGS_CXX, test x$BINDINGS_CXX = xyes)
 523
 524 AM_CONDITIONAL(BINDINGS_PYTHON, test x$BINDINGS_PYTHON = xyes)
 525
 526 AM_CONDITIONAL(BINDINGS_JAVA, test x$BINDINGS_JAVA = xyes)
 527
 528 # Checks for header files.
 529 # These are already implicitly checked: inttypes.h stdint.h stdlib.h string.h
 530 # unistd.h memory.h strings.h dlfcn.h sys/types.h sys/stat.h.
 531
 532 # Checks for typedefs, structures, and compiler characteristics.
 533 AC_C_BIGENDIAN
 534
 535 AC_SUBST(FIRMWARE_DIR, "$datadir/sigrok-firmware")
 536 AC_SUBST(MAKEFLAGS, '--no-print-directory')
 537 AC_SUBST(AM_LIBTOOLFLAGS, '--silent')
 538
 539 SR_PACKAGE_VERSION_MAJOR=sr_package_version_major
 540 SR_PACKAGE_VERSION_MINOR=sr_package_version_minor
 541 SR_PACKAGE_VERSION_MICRO=sr_package_version_micro
 542 SR_PACKAGE_VERSION=sr_package_version
 543
 544 AC_SUBST(SR_PACKAGE_VERSION_MAJOR)
 545 AC_SUBST(SR_PACKAGE_VERSION_MINOR)
 546 AC_SUBST(SR_PACKAGE_VERSION_MICRO)
 547 AC_SUBST(SR_PACKAGE_VERSION)
 548
 549 AC_CONFIG_FILES([Makefile include/libsigrok/version.h libsigrok.pc
 550         bindings/cxx/libsigrokcxx.pc])
 551
 552 AC_OUTPUT
 553
 554 echo
 555 echo "libsigrok configuration summary:"
 556 echo
 557 echo "  - Package version (major.minor.micro):    $SR_PACKAGE_VERSION"
 558 echo "  - Library version (current:revision:age): $SR_LIB_VERSION"
 559 echo "  - Prefix: $prefix"
 560 echo "  - Building on: $build"
 561 echo "  - Building for: $host"
 562 echo
 563 echo "Detected libraries:"
 564 echo
 565
 566 # Note: This only works for libs with pkg-config integration.
 567 for lib in "glib-2.0 >= 2.32.0" "libzip >= 0.10" "libserialport >= 0.1.1" \
 568         "librevisa >= 0.0.20130412" "libusb-1.0 >= 1.0.16" "libftdi >= 0.16" \
 569         "libftdi1 >= 1.0" "libgpib" "glibmm-2.4 >= 2.32.0" \
 570         "pygobject-3.0 >= 3.0.0" "check >= 0.9.4"
 571 do
 572         optional="OPTIONAL"
 573         if test "x$lib" = "xglib-2.0 >= 2.32.0"; then optional="REQUIRED"; fi
 574         if test "x$lib" = "xlibzip >= 0.10"; then optional="REQUIRED"; fi
 575         if `$PKG_CONFIG --exists $lib`; then
 576                 ver=`$PKG_CONFIG --modversion $lib`
 577                 answer="yes ($ver)"
 578         else
 579                 answer="no"
 580         fi
 581         echo "  - ($optional) $lib: $answer"
 582 done
 583
 584 eval echo -e "@Enabled hardware drivers:@@${driver_summary}" | tr @ \\n
 585
 586 # Prepare final bindings report messages.
 587 final_cxx=""
 588 final_python=""
 589 final_java=""
 590 if test "$enable_bindings" = "no"; then
 591         final_cxx=" (disabled)"
 592         final_python=" (disabled)"
 593         final_java=" (disabled)"
 594 else
 595         if test "$enable_cxx" = "no"; then
 596                 final_cxx=" (disabled)"
 597         elif test "$BINDINGS_CXX" = "no"; then
 598                 final_cxx=" ($cxx_msg)"
 599         fi
 600         if test "$enable_python" = "no"; then
 601                 final_python=" (disabled)"
 602         elif test "$BINDINGS_PYTHON" = "no"; then
 603                 final_python=" ($python_msg)"
 604         fi
 605         if test "$enable_java" = "no"; then
 606                 final_java=" (disabled)"
 607         elif test "$BINDINGS_JAVA" = "no"; then
 608                 final_java=" ($java_msg)"
 609         fi
 610 fi
 611
 612 echo "Enabled SCPI backends:"
 613 echo " - TCP............................. yes"
 614 if test "x$have_rpc" = "x0"; then
 615 echo " - RPC............................. no"
 616 else
 617 echo " - RPC............................. yes"
 618 fi
 619 echo " - serial.......................... $have_libserialport"
 620 echo " - VISA............................ $have_librevisa"
 621 echo " - GPIB............................ $have_libgpib"
 622 echo " - USBTMC.......................... $have_libusb1_0"
 623 echo
 624
 625 echo "Enabled language bindings:"
 626 echo " - C++............................. $BINDINGS_CXX$final_cxx"
 627 echo " - Python.......................... $BINDINGS_PYTHON$final_python"
 628 echo " - Java............................ $BINDINGS_JAVA$final_java"
 629 echo