configure.ac

   1 ##
   2 ## This file is part of the libsigrok project.
   3 ##
   4 ## Copyright (C) 2010-2012 Bert Vermeulen <bert@biot.com>
   5 ## Copyright (C) 2012 Alexandru Gagniuc <mr.nuke.me@gmail.com>
   6 ##
   7 ## This program is free software: you can redistribute it and/or modify
   8 ## it under the terms of the GNU General Public License as published by
   9 ## the Free Software Foundation, either version 3 of the License, or
  10 ## (at your option) any later version.
  11 ##
  12 ## This program is distributed in the hope that it will be useful,
  13 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ## GNU General Public License for more details.
  16 ##
  17 ## You should have received a copy of the GNU General Public License
  18 ## along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19 ##
  20
  21 # We require at least autoconf 2.63 (AC_INIT format changed there).
  22 AC_PREREQ([2.63])
  23
  24 # libsigrok package version number (NOT the same as shared lib version!).
  25 m4_define([sr_package_version_major], [0])
  26 m4_define([sr_package_version_minor], [3])
  27 m4_define([sr_package_version_micro], [0])
  28 m4_define([sr_package_version], [sr_package_version_major.sr_package_version_minor.sr_package_version_micro])
  29
  30 AC_INIT([libsigrok], [sr_package_version], [sigrok-devel@lists.sourceforge.net],
  31         [libsigrok], [http://www.sigrok.org])
  32 AC_CONFIG_HEADER([config.h])
  33 AC_CONFIG_MACRO_DIR([autostuff])
  34 AC_CONFIG_AUX_DIR([autostuff])
  35
  36 # We require this to know the target settings if we're cross-compiling.
  37 AC_CANONICAL_SYSTEM
  38
  39 # We require at least automake 1.11 (needed for 'silent rules').
  40 AM_INIT_AUTOMAKE([1.11 -Wall -Werror subdir-objects check-news color-tests])
  41 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  42 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  43
  44 AH_TOP([#ifndef SR_CONFIG_H
  45 #define SR_CONFIG_H    /* To stop multiple inclusions. */])
  46 AH_BOTTOM([#endif /* SR_CONFIG_H */])
  47
  48 # Enable more compiler warnings via -Wall and -Wextra. Add -fvisibility=hidden
  49 # and enforce use of SR_API to explicitly mark all public API functions.
  50 COMMON_FLAGS="$CFLAGS -Wall -Wextra -fvisibility=hidden"
  51 CFLAGS="$COMMON_FLAGS -Wmissing-prototypes"
  52 CXXFLAGS="-std=c++11 $COMMON_FLAGS"
  53
  54 # Checks for programs.
  55 AC_PROG_CC
  56 AC_PROG_CPP
  57 AC_PROG_CXX
  58 AC_PROG_INSTALL
  59 AC_PROG_LN_S
  60
  61 # Required for per-target flags or subdir-objects with C sources.
  62 AM_PROG_CC_C_O
  63
  64 # Initialize libtool.
  65 LT_INIT
  66
  67 # Initialize pkg-config.
  68 # We require at least 0.22, as "Requires.private" behaviour changed there.
  69 PKG_PROG_PKG_CONFIG([0.22])
  70
  71 # Library version for libsigrok (NOT the same as the package version).
  72 # Carefully read the libtool docs before updating these numbers!
  73 # The algorithm for determining which number to change (and how) is nontrivial!
  74 # http://www.gnu.org/software/libtool/manual/libtool.html#Updating-version-info
  75 SR_LIB_VERSION_CURRENT=2
  76 SR_LIB_VERSION_REVISION=0
  77 SR_LIB_VERSION_AGE=0
  78 SR_LIB_VERSION="$SR_LIB_VERSION_CURRENT:$SR_LIB_VERSION_REVISION:$SR_LIB_VERSION_AGE"
  79 SR_LIB_LDFLAGS="-version-info $SR_LIB_VERSION"
  80 AC_SUBST(SR_LIB_VERSION_CURRENT)
  81 AC_SUBST(SR_LIB_VERSION_REVISION)
  82 AC_SUBST(SR_LIB_VERSION_AGE)
  83 AC_SUBST(SR_LIB_VERSION)
  84 AC_SUBST(SR_LIB_LDFLAGS)
  85
  86 AC_ARG_ENABLE(all-drivers, AC_HELP_STRING([--enable-all-drivers],
  87         [enable all drivers by default [default=yes]]),
  88         [HW_ENABLED_DEFAULT="$enableval"],
  89         [HW_ENABLED_DEFAULT="yes"])
  90
  91 # Usage: DRIVER([Device name], [driver-name])
  92 # An optional third argument [no] disables that driver.
  93 m4_define([driverize], [m4_tolower(m4_bpatsubst([$1], [[^0-9a-zA-Z-]+], [-]))])
  94 m4_define([upperize], [m4_toupper(m4_bpatsubst([$1], [[^0-9a-zA-Z_]+], [_]))])
  95 AC_DEFUN([DRIVER], [
  96         if test -z "$3"; then
  97                 default=$HW_ENABLED_DEFAULT
  98         else
  99                 default="$3"
 100         fi
 101         AC_ARG_ENABLE($2, AC_HELP_STRING([--enable-$2], [enable $1 support]),
 102                 [m4_join([], [HW_], upperize([$2]))="$enableval"],
 103                 [m4_join([], [HW_], upperize([$2]))=$default])
 104         dots=$(echo -n ".............................." | cut -c 1-$(expr 32 - $(echo -n $2|wc -c)))
 105         driver_summary="${driver_summary}  - $2${dots} \${m4_join([], [HW_], upperize([$2]))}@"
 106 ])
 107
 108 DRIVER([Agilent DMM], [agilent-dmm])
 109 DRIVER([Appa 55II], [appa-55ii])
 110 DRIVER([ASIX SIGMA/SIGMA2], [asix-sigma])
 111 DRIVER([Atten PPS3xxx], [atten-pps3xxx])
 112 DRIVER([BayLibre ACME], [baylibre-acme])
 113 DRIVER([BeagleLogic], [beaglelogic])
 114 DRIVER([Brymen BM86x], [brymen-bm86x])
 115 DRIVER([Brymen DMM], [brymen-dmm])
 116 DRIVER([CEM DT-885x], [cem-dt-885x])
 117 DRIVER([Center 3xx], [center-3xx])
 118 DRIVER([ChronoVu LA], [chronovu-la])
 119 DRIVER([Colead SLM], [colead-slm])
 120 DRIVER([Conrad DIGI 35 CPU], [conrad-digi-35-cpu])
 121 DRIVER([DER EE DE-5000], [deree-de5000])
 122 DRIVER([demo], [demo])
 123 DRIVER([Fluke DMM], [fluke-dmm])
 124 DRIVER([fx2lafw], [fx2lafw])
 125 DRIVER([GMC MH 1x/2x], [gmc-mh-1x-2x])
 126 DRIVER([Hameg HMO], [hameg-hmo])
 127 DRIVER([Hantek DSO], [hantek-dso])
 128 DRIVER([Ikalogic Scanalogic-2], [ikalogic-scanalogic2])
 129 DRIVER([Ikalogic Scanaplus], [ikalogic-scanaplus])
 130 DRIVER([Kecheng KC-330B], [kecheng-kc-330b])
 131 DRIVER([Lascar EL-USB], [lascar-el-usb])
 132 DRIVER([Manson HCS-3xxx], [manson-hcs-3xxx])
 133 DRIVER([MIC 985xx], [mic-985xx])
 134 DRIVER([Motech LPS 30x], [motech-lps-30x])
 135 DRIVER([Norma DMM], [norma-dmm])
 136 DRIVER([OpenBench Logic Sniffer], [openbench-logic-sniffer])
 137 DRIVER([Pipistrello-OLS], [pipistrello-ols])
 138 DRIVER([Rigol DS], [rigol-ds])
 139 DRIVER([Saleae Logic16], [saleae-logic16])
 140 DRIVER([SCPI PPS], [scpi-pps])
 141 DRIVER([serial DMM], [serial-dmm])
 142 DRIVER([Sysclk LWLA], [sysclk-lwla])
 143 DRIVER([Teleinfo], [teleinfo])
 144 DRIVER([Testo], [testo])
 145 DRIVER([Tondaj SL-814], [tondaj-sl-814])
 146 DRIVER([UNI-T DMM], [uni-t-dmm])
 147 DRIVER([UNI-T UT32x], [uni-t-ut32x])
 148 DRIVER([Victor DMM], [victor-dmm])
 149 DRIVER([Yokogawa DL/DLM], [yokogawa-dlm])
 150 DRIVER([ZEROPLUS Logic Cube], [zeroplus-logic-cube])
 151
 152 AC_ARG_ENABLE(libserialport,
 153         AC_HELP_STRING([--disable-libserialport],
 154         [disable libserialport support [default=detect]]))
 155
 156 AC_ARG_ENABLE(libftdi,
 157         AC_HELP_STRING([--disable-libftdi],
 158         [disable libftdi support [default=detect]]))
 159
 160 AC_ARG_ENABLE(libusb,
 161         AC_HELP_STRING([--disable-libusb],
 162         [disable libusb support [default=detect]]))
 163
 164 # Language binding '--enable' options:
 165
 166 AC_ARG_ENABLE(bindings,
 167         AC_HELP_STRING([--enable-bindings],
 168         [build language bindings [default=yes]]),
 169         [BINDINGS_ALL="$enableval"], [BINDINGS_ALL="yes"])
 170
 171 AC_ARG_ENABLE(cxx,
 172         AC_HELP_STRING([--enable-cxx],
 173         [build C++ bindings [default=yes]]),
 174         [BINDINGS_CXX="$enableval"], [BINDINGS_CXX=$BINDINGS_ALL])
 175
 176 AC_ARG_ENABLE(python,
 177         AC_HELP_STRING([--enable-python],
 178         [build Python bindings [default=yes]]),
 179         [BINDINGS_PYTHON="$enableval"], [BINDINGS_PYTHON=$BINDINGS_ALL])
 180
 181 AC_ARG_ENABLE(java,
 182         AC_HELP_STRING([--enable-java],
 183         [build Java bindings [default=yes]]),
 184         [BINDINGS_JAVA="$enableval"], [BINDINGS_JAVA=$BINDINGS_ALL])
 185
 186 AC_ARG_WITH(jni-include-path,
 187         AC_HELP_STRING([--with-jni-include-path=path],
 188         [specify include path for JNI [default=autodetect]]),
 189         [JNI_INCLUDE_DIRS="$withval"], [JNI_INCLUDE_DIRS=auto])
 190
 191 # Check if the C++ compiler supports the C++11 standard.
 192
 193 m4_ifdef([AX_CXX_COMPILE_STDCXX_11], [AX_CXX_COMPILE_STDCXX_11(,[optional])],
 194         [AC_MSG_NOTICE([Missing macro m4_toupper(aX_CXX_COMPILE_STDCXX_11), no C++11 check])])
 195
 196 if test "x$HAVE_CXX11" != "x1"; then
 197         BINDINGS_CXX="no"; cxx_msg="C++11 compiler required"
 198 fi
 199
 200 # The C++ bindings use Doxygen to parse libsigrok symbols.
 201 AC_CHECK_PROG([HAVE_DOXYGEN], [doxygen], [yes])
 202 if test "x$HAVE_DOXYGEN" != "xyes"; then
 203         BINDINGS_CXX="no"; cxx_msg="Doxygen required"
 204 fi
 205
 206 # Python is needed for the C++ bindings.
 207 AM_PATH_PYTHON([2.7], [HAVE_PYTHON="yes"],
 208         [HAVE_PYTHON="no"; BINDINGS_CXX="no"; cxx_msg="Python required"])
 209
 210 # The Python bindings need Python development files.
 211 PKG_CHECK_MODULES([python], [python >= 2.7],
 212         [CXXFLAGS="$CXXFLAGS $python_CFLAGS";
 213         CXXLIBS="$CXXLIBS $python_LIBS"],
 214 [PKG_CHECK_MODULES([python27], [python-2.7 >= 2.7],
 215         [CXXFLAGS="$CXXFLAGS $python27_CFLAGS";
 216         CXXLIBS="$CXXLIBS $python27_LIBS"],
 217                 [BINDINGS_PYTHON="no"; python_msg="Python headers required"])])
 218
 219 # The Python bindings need the setuptools Python module.
 220 m4_ifdef([AX_PYTHON_MODULE], [AX_PYTHON_MODULE([setuptools])],
 221         # We'll let it go through even if the macro wasn't found, the Python
 222         # module may still be there.
 223         [HAVE_PYTHON_SETUPTOOLS="yes";
 224                 AC_MSG_NOTICE([Missing macro m4_toupper(aX_PYTHON_MODULE), no setuptools check])]
 225 )
 226 if test "x$HAVE_PYMOD_SETUPTOOLS" != "xyes"; then
 227         BINDINGS_PYTHON="no"; python_msg="Python setuptools module required"
 228 fi
 229
 230 # The Python and Java bindings use SWIG to generate code.
 231 AC_CHECK_PROG([HAVE_SWIG], [swig], [yes])
 232 if test "x$HAVE_SWIG" != "xyes"; then
 233         BINDINGS_PYTHON="no"; python_msg="SWIG required"
 234         BINDINGS_JAVA="no"; java_msg="SWIG required"
 235 fi
 236
 237 # Checks for libraries.
 238
 239 case "$host" in
 240 *mingw*)
 241         # We need to link against the Winsock2 library for SCPI over TCP.
 242         LIBS="$LIBS -lws2_32";;
 243 esac
 244
 245 # This variable collects the pkg-config names of all detected libs.
 246 # It is then used to construct the "Requires.private:" field in the
 247 # libsigrok.pc file.
 248 SR_PKGLIBS=""
 249
 250 # libm (the standard math library) is always needed.
 251 AC_SEARCH_LIBS([pow], [m])
 252
 253 # RPC is only needed for VXI support.
 254 AC_MSG_CHECKING([for RPC support])
 255 AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <rpc/rpc.h>],
 256                         [CLIENT *rpc_test(void)],
 257                         [{ return clnt_create("", 0, 0, ""); }])],
 258                 [AC_MSG_RESULT([yes]); have_rpc=1],
 259                 [AC_MSG_RESULT([no]);  have_rpc=0])
 260 # Define HAVE_RPC in config.h if we found RPC support.
 261 AC_DEFINE_UNQUOTED(HAVE_RPC, [$have_rpc], [Specifies whether we have RPC support.])
 262 # VXI support is only compiled if RPC support was found.
 263 AM_CONDITIONAL(NEED_RPC, test "x$have_rpc" != "x0")
 264
 265 # libglib-2.0 is always needed. Abort if it's not found.
 266 # Note: glib-2.0 is part of the libsigrok API (hard pkg-config requirement).
 267 # We require at least 2.32.0 due to e.g. g_variant_new_fixed_array().
 268 AM_PATH_GLIB_2_0([2.32.0],
 269         [LIB_CFLAGS="$LIB_CFLAGS $GLIB_CFLAGS"; LIBS="$LIBS $GLIB_LIBS"])
 270
 271 # libzip is always needed. Abort if it's not found.
 272 PKG_CHECK_MODULES([libzip], [libzip >= 0.10],
 273         [LIB_CFLAGS="$LIB_CFLAGS $libzip_CFLAGS"; LIBS="$LIBS $libzip_LIBS";
 274         SR_PKGLIBS="$SR_PKGLIBS libzip"])
 275
 276 # libserialport is only needed for some hardware drivers. Disable the
 277 # respective drivers if it is not found.
 278 if test "x$enable_libserialport" != "xno"; then
 279         PKG_CHECK_MODULES([libserialport], [libserialport >= 0.2.0],
 280                 [have_libserialport="yes"; LIB_CFLAGS="$LIB_CFLAGS $libserialport_CFLAGS";
 281                 LIBS="$LIBS $libserialport_LIBS";
 282                 SR_PKGLIBS="$SR_PKGLIBS libserialport"],
 283                 [have_libserialport="no"])
 284         if test "x$enable_libserialport$have_libserialport" = "xyesno"; then
 285                 AC_MSG_ERROR([libserialport support requested, but it was not found.])
 286         fi
 287 else
 288         have_libserialport="no"
 289 fi
 290 if test "x$have_libserialport" = "xno"; then
 291         HW_AGILENT_DMM="no"; HW_APPA_55II="no";
 292         HW_ATTEN_PPS3XXX="no"; HW_BRYMEN_DMM="no"; HW_CEM_DT_885X="no";
 293         HW_CENTER_3XX="no"; HW_COLEAD_SLM="no"; HW_CONRAD_DIGI_35_CPU="no";
 294         HW_DEREE_DE5000="no"; HW_FLUKE_DMM="no"; HW_GMC_MH_1X_2X="no";
 295         HW_HAMEG_HMO="no"; HW_MANSON_HCS_3XXX="no"; HW_MIC_985XX="no";
 296         HW_MOTECH_LPS_30X="no"; HW_NORMA_DMM="no";
 297         HW_OPENBENCH_LOGIC_SNIFFER="no"; HW_SERIAL_DMM="no";
 298         HW_TELEINFO="no"; HW_TONDAJ_SL_814="no";
 299 else
 300         # Define HAVE_LIBSERIALPORT in config.h if we found libserialport.
 301         AC_DEFINE_UNQUOTED(HAVE_LIBSERIALPORT, [1],
 302                 [Specifies whether we have libserialport.])
 303 fi
 304
 305 # Serial port helper code is only compiled in if libserialport was found.
 306 AM_CONDITIONAL(NEED_SERIAL, test "x$have_libserialport" != xno)
 307
 308 # The VISA SCPI backend is only compiled in if librevisa was found.
 309 PKG_CHECK_MODULES([librevisa], [librevisa >= 0.0.20130412],
 310         [have_librevisa="yes"; LIB_CFLAGS="$LIB_CFLAGS $librevisa_CFLAGS";
 311         LIBS="$LIBS $librevisa_LIBS";
 312         SR_PKGLIBS="$SR_PKGLIBS librevisa"],
 313         [have_librevisa="no"])
 314 AM_CONDITIONAL(NEED_VISA, test "x$have_librevisa" != xno)
 315 if test "x$have_librevisa" != "xno"; then
 316         # Define HAVE_LIBREVISA in config.h if we found librevisa.
 317         AC_DEFINE_UNQUOTED(HAVE_LIBREVISA, [1],
 318                 [Specifies whether we have librevisa.])
 319 fi
 320
 321 # The GPIB SCPI backend is only compiled in if libgpib is found.
 322 PKG_CHECK_MODULES([libgpib], [libgpib],
 323         [have_libgpib="yes"; LIB_CFLAGS="$LIB_CFLAGS $libgpib_CFLAGS";
 324         LIBS="$LIBS $libgpib_LIBS";
 325         SR_PKGLIBS="$SR_PKGLIBS libgpib"],
 326         [have_libgpib="no"])
 327 AM_CONDITIONAL(NEED_GPIB, test "x$have_libgpib" != xno)
 328 if test "x$have_libgpib" != "xno"; then
 329         # Define HAVE_LIBGPIB in config.h if we found libgpib.
 330         AC_DEFINE_UNQUOTED(HAVE_LIBGPIB, [1],
 331                 [Specifies whether we have libgpib.])
 332 fi
 333
 334 # libusb-1.0 is only needed for some hardware drivers. Disable the respective
 335 # drivers if it is not found.
 336 if test "x$enable_libusb" != "xno"; then
 337         case "$host" in
 338         *freebsd*)
 339                 # FreeBSD comes with an "integrated" libusb-1.0-style USB API.
 340                 # This means libusb-1.0 is always available, no need to check for it,
 341                 # and no need to (potentially) disable any drivers if it's not found.
 342                 have_libusb1_0="yes"
 343                 ;;
 344         *)
 345                 PKG_CHECK_MODULES([libusb], [libusb-1.0 >= 1.0.16],
 346                         [have_libusb1_0="yes"; LIB_CFLAGS="$LIB_CFLAGS $libusb_CFLAGS";
 347                         LIBS="$LIBS $libusb_LIBS";
 348                         SR_PKGLIBS="$SR_PKGLIBS libusb-1.0"],
 349                         [have_libusb1_0="no"])
 350                 if test "x$enable_libusb$have_libusb1_0" = "xyesno"; then
 351                         AC_MSG_ERROR([libusb support requested, but it was not found.])
 352                 fi
 353                 ;;
 354         esac
 355 else
 356         have_libusb1_0="no"
 357 fi
 358 if test "x$have_libusb1_0" = "xno"; then
 359         HW_BRYMEN_BM86X="no"; HW_FX2LAFW="no";
 360         HW_HANTEK_DSO="no"; HW_IKALOGIC_SCANALOGIC2="no";
 361         HW_KECHENG_KC_330B="no"; HW_LASCAR_EL_USB="no";
 362         HW_SYSCLK_LWLA="no"; HW_TESTO="no"; HW_UNI_T_DMM="no";
 363         HW_UNI_T_UT32X="no"; HW_VICTOR_DMM="no";
 364         HW_ZEROPLUS_LOGIC_CUBE="no"; HW_SALEAE_LOGIC16="no";
 365 else
 366         # Define HAVE_LIBUSB_1_0 in config.h if we found libusb-1.0.
 367         AC_DEFINE_UNQUOTED(HAVE_LIBUSB_1_0, [1],
 368                 [Specifies whether we have libusb-1.0.])
 369 fi
 370
 371 # USB + FX2 firmware helper code is only compiled in if libusb-1.0 was found.
 372 AM_CONDITIONAL(NEED_USB, test "x$have_libusb1_0" != xno)
 373
 374 # libftdi is only needed for some hardware drivers. Disable them if not found.
 375 if test "x$enable_libftdi" != "xno"; then
 376         PKG_CHECK_MODULES([libftdi], [libftdi >= 0.16],
 377                 [have_libftdi="yes"; LIB_CFLAGS="$LIB_CFLAGS $libftdi_CFLAGS";
 378                 LIBS="$LIBS $libftdi_LIBS";
 379                 SR_PKGLIBS="$SR_PKGLIBS libftdi"],
 380                 [PKG_CHECK_MODULES([libftdi1], [libftdi1 >= 1.0],
 381                         [LIB_CFLAGS="$LIB_CFLAGS $libftdi1_CFLAGS";
 382                         LIBS="$LIBS $libftdi1_LIBS";
 383                         SR_PKGLIBS="$SR_PKGLIBS libftdi1"],
 384                         [have_libftdi="no"])])
 385         if test "x$enable_libftdi$have_libftdi" = "xyesno"; then
 386                 AC_MSG_ERROR([libftdi support requested, but it was not found.])
 387         fi
 388 else
 389         have_libftdi="no"
 390 fi
 391 if test "x$have_libftdi" = "xno"; then
 392         HW_ASIX_SIGMA="no"; HW_CHRONOVU_LA="no"; HW_IKALOGIC_SCANAPLUS="no";
 393         HW_PIPISTRELLO_OLS="no";
 394 fi
 395
 396 # glibmm-2.4 is needed for the C++ bindings.
 397 PKG_CHECK_MODULES([glibmm], [glibmm-2.4 >= 2.32.0],
 398         [CXXFLAGS="$CXXFLAGS $glibmm_CFLAGS";
 399         CXXLIBS="$CXXLIBS $glibmm_LIBS"],
 400         [BINDINGS_CXX="no"; cxx_msg="glibmm required"])
 401
 402 # C++ bindings want stoi and stod.
 403 if test "x$BINDINGS_CXX" = "xyes"; then
 404         AC_LANG_PUSH([C++])
 405         AC_MSG_CHECKING([for stoi and stod])
 406         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <string>],
 407                 [{ return std::stoi("1") + std::stod("1.0"); }])],
 408                 [AC_MSG_RESULT([yes]);
 409                 AC_DEFINE_UNQUOTED(HAVE_STOI_STOD, [1],
 410                 [Specifies whether we have the stoi and stod functions.])],
 411                 [AC_MSG_RESULT([no])])
 412         AC_LANG_POP([C++])
 413 fi
 414
 415 # PyGObject is needed for the Python bindings.
 416 PKG_CHECK_MODULES([pygobject], [pygobject-3.0 >= 3.0.0],
 417         [CXXFLAGS="$CXXFLAGS $pygobject_CFLAGS";
 418         CXXLIBS="$CXXLIBS $pygobject_LIBS";
 419         PKG_CHECK_MODULES([pygobject_3_7_91], [pygobject-3.0 >= 3.7.91],
 420                 [pyg_flags_signed=0], [pyg_flags_signed=1]);
 421         AC_DEFINE_UNQUOTED(PYGOBJECT_FLAGS_SIGNED, [$pyg_flags_signed],
 422                 [Whether last argument to pyg_flags_get_value() is signed.])],
 423         [BINDINGS_PYTHON="no"; python_msg="Python pygobject module required"])
 424
 425 # The Check unit testing framework is optional. Disable if not found.
 426 PKG_CHECK_MODULES([check], [check >= 0.9.4],
 427         [have_check="yes"], [have_check="no"])
 428 AM_CONDITIONAL(HAVE_CHECK, test x"$have_check" = "xyes")
 429
 430 # The BeagleLogic driver needs sys/mman.h and sys/ioctl.h. Don't try to
 431 # build it if these headers aren't available.
 432 AC_CHECK_HEADERS([sys/mman.h sys/ioctl.h], [], [HW_BEAGLELOGIC="no"])
 433
 434 # The ACME driver can only be built for Linux.
 435 case "$host" in
 436         *linux*) ;;
 437         *) HW_BAYLIBRE_ACME="no" ;;
 438 esac
 439
 440 AC_SUBST(SR_PKGLIBS)
 441
 442 CFLAGS="$CFLAGS -Iinclude/libsigrok -I${srcdir}/include/libsigrok $LIB_CFLAGS"
 443 CXXFLAGS="$CXXFLAGS -Iinclude/libsigrok -I${srcdir}/include -Ibindings/cxx -Ibindings/cxx/include/libsigrokcxx -I${srcdir}/bindings/cxx/include $LIB_CFLAGS"
 444
 445 # Find Java compiler and JNI includes for Java bindings.
 446 AC_CHECK_PROG([HAVE_JAVAC], [javac], [yes], [no])
 447 if test "x$HAVE_JAVAC" = "xyes" && test "x$BINDINGS_JAVA" = "xyes"; then
 448         AX_PROG_JAVAC
 449         if test "x$JNI_INCLUDE_DIRS" = "xauto"; then
 450                 if test "x$cross_compiling" = "xyes"; then
 451                         JNI_INCLUDE_DIRS=
 452                 else
 453                         AX_JNI_INCLUDE_DIR
 454                 fi
 455         fi
 456         for JNI_INCLUDE_DIR in $JNI_INCLUDE_DIRS; do
 457                 CXXFLAGS="$CXXFLAGS -I$JNI_INCLUDE_DIR"
 458         done
 459         AC_LANG_PUSH([C++])
 460         AC_CHECK_HEADERS([jni.h], [], [BINDINGS_JAVA="no"; java_msg="Java JNI headers required"])
 461         AC_LANG_POP([C++])
 462 else
 463         BINDINGS_JAVA="no"; java_msg="Java compiler required"
 464 fi
 465
 466 # Python and Java bindings depend on C++ bindings.
 467 if test "x$BINDINGS_CXX" != "xyes"; then
 468         BINDINGS_PYTHON="no"; python_msg="C++ bindings required"
 469         BINDINGS_JAVA="no"; java_msg="C++ bindings required"
 470 fi
 471
 472 # Now set AM_CONDITIONALs and AC_DEFINEs for the enabled/disabled drivers.
 473
 474 AC_DEFUN([DRIVER2], [
 475         AM_CONDITIONAL($1, test "x$2" = "xyes")
 476         if test "x$2" = "xyes"; then AC_DEFINE($3, 1, [.]) fi
 477 ])
 478
 479 DRIVER2([HW_AGILENT_DMM], [$HW_AGILENT_DMM], [HAVE_HW_AGILENT_DMM])
 480 DRIVER2([HW_APPA_55II], [$HW_APPA_55II], [HAVE_HW_APPA_55II])
 481 DRIVER2([HW_ASIX_SIGMA], [$HW_ASIX_SIGMA], [HAVE_HW_ASIX_SIGMA])
 482 DRIVER2([HW_ATTEN_PPS3XXX], [$HW_ATTEN_PPS3XXX], [HAVE_HW_ATTEN_PPS3XXX])
 483 DRIVER2([HW_BAYLIBRE_ACME], [$HW_BAYLIBRE_ACME], [HAVE_HW_BAYLIBRE_ACME])
 484 DRIVER2([HW_BEAGLELOGIC], [$HW_BEAGLELOGIC], [HAVE_HW_BEAGLELOGIC])
 485 DRIVER2([HW_BRYMEN_BM86X], [$HW_BRYMEN_BM86X], [HAVE_HW_BRYMEN_BM86X])
 486 DRIVER2([HW_BRYMEN_DMM], [$HW_BRYMEN_DMM], [HAVE_HW_BRYMEN_DMM])
 487 DRIVER2([HW_CEM_DT_885X], [$HW_CEM_DT_885X], [HAVE_HW_CEM_DT_885X])
 488 DRIVER2([HW_CENTER_3XX], [$HW_CENTER_3XX], [HAVE_HW_CENTER_3XX])
 489 DRIVER2([HW_CHRONOVU_LA], [$HW_CHRONOVU_LA], [HAVE_HW_CHRONOVU_LA])
 490 DRIVER2([HW_COLEAD_SLM], [$HW_COLEAD_SLM], [HAVE_HW_COLEAD_SLM])
 491 DRIVER2([HW_CONRAD_DIGI_35_CPU], [$HW_CONRAD_DIGI_35_CPU], [HAVE_HW_CONRAD_DIGI_35_CPU])
 492 DRIVER2([HW_DEMO], [$HW_DEMO], [HAVE_HW_DEMO])
 493 DRIVER2([HW_DEREE_DE5000], [$HW_DEREE_DE5000], [HAVE_HW_DEREE_DE5000])
 494 DRIVER2([HW_FLUKE_DMM], [$HW_FLUKE_DMM], [HAVE_HW_FLUKE_DMM])
 495 DRIVER2([HW_FX2LAFW], [$HW_FX2LAFW], [HAVE_HW_FX2LAFW])
 496 DRIVER2([HW_GMC_MH_1X_2X], [$HW_GMC_MH_1X_2X], [HAVE_HW_GMC_MH_1X_2X])
 497 DRIVER2([HW_HAMEG_HMO], [$HW_HAMEG_HMO], [HAVE_HW_HAMEG_HMO])
 498 DRIVER2([HW_HANTEK_DSO], [$HW_HANTEK_DSO], [HAVE_HW_HANTEK_DSO])
 499 DRIVER2([HW_IKALOGIC_SCANALOGIC2], [$HW_IKALOGIC_SCANALOGIC2], [HAVE_HW_IKALOGIC_SCANALOGIC2])
 500 DRIVER2([HW_IKALOGIC_SCANAPLUS], [$HW_IKALOGIC_SCANAPLUS], [HAVE_HW_IKALOGIC_SCANAPLUS])
 501 DRIVER2([HW_KECHENG_KC_330B], [$HW_KECHENG_KC_330B], [HAVE_HW_KECHENG_KC_330B])
 502 DRIVER2([HW_LASCAR_EL_USB], [$HW_LASCAR_EL_USB], [HAVE_HW_LASCAR_EL_USB])
 503 DRIVER2([HW_MANSON_HCS_3XXX], [$HW_MANSON_HCS_3XXX], [HAVE_HW_MANSON_HCS_3XXX])
 504 DRIVER2([HW_MIC_985XX], [$HW_MIC_985XX], [HAVE_HW_MIC_985XX])
 505 DRIVER2([HW_MOTECH_LPS_30X], [$HW_MOTECH_LPS_30X], [HAVE_HW_MOTECH_LPS_30X])
 506 DRIVER2([HW_NORMA_DMM], [$HW_NORMA_DMM], [HAVE_HW_NORMA_DMM])
 507 DRIVER2([HW_OPENBENCH_LOGIC_SNIFFER], [$HW_OPENBENCH_LOGIC_SNIFFER], [HAVE_HW_OPENBENCH_LOGIC_SNIFFER])
 508 DRIVER2([HW_PIPISTRELLO_OLS], [$HW_PIPISTRELLO_OLS], [HAVE_HW_PIPISTRELLO_OLS])
 509 DRIVER2([HW_RIGOL_DS], [$HW_RIGOL_DS], [HAVE_HW_RIGOL_DS])
 510 DRIVER2([HW_SALEAE_LOGIC16], [$HW_SALEAE_LOGIC16], [HAVE_HW_SALEAE_LOGIC16])
 511 DRIVER2([HW_SCPI_PPS], [$HW_SCPI_PPS], [HAVE_HW_SCPI_PPS])
 512 DRIVER2([HW_SERIAL_DMM], [$HW_SERIAL_DMM], [HAVE_HW_SERIAL_DMM])
 513 DRIVER2([HW_SYSCLK_LWLA], [$HW_SYSCLK_LWLA], [HAVE_HW_SYSCLK_LWLA])
 514 DRIVER2([HW_TELEINFO], [$HW_TELEINFO], [HAVE_HW_TELEINFO])
 515 DRIVER2([HW_TESTO], [$HW_TESTO], [HAVE_HW_TESTO])
 516 DRIVER2([HW_TONDAJ_SL_814], [$HW_TONDAJ_SL_814], [HAVE_HW_TONDAJ_SL_814])
 517 DRIVER2([HW_UNI_T_DMM], [$HW_UNI_T_DMM], [HAVE_HW_UNI_T_DMM])
 518 DRIVER2([HW_UNI_T_UT32X], [$HW_UNI_T_UT32X], [HAVE_HW_UNI_T_UT32X])
 519 DRIVER2([HW_VICTOR_DMM], [$HW_VICTOR_DMM], [HAVE_HW_VICTOR_DMM])
 520 DRIVER2([HW_YOKOGAWA_DLM], [$HW_YOKOGAWA_DLM], [HAVE_HW_YOKOGAWA_DLM])
 521 DRIVER2([HW_ZEROPLUS_LOGIC_CUBE], [$HW_ZEROPLUS_LOGIC_CUBE], [HAVE_HW_ZEROPLUS_LOGIC_CUBE])
 522
 523 AM_CONDITIONAL(BINDINGS_CXX, test x$BINDINGS_CXX = xyes)
 524
 525 AM_CONDITIONAL(BINDINGS_PYTHON, test x$BINDINGS_PYTHON = xyes)
 526
 527 AM_CONDITIONAL(BINDINGS_JAVA, test x$BINDINGS_JAVA = xyes)
 528
 529 # Checks for header files.
 530 # These are already implicitly checked: inttypes.h stdint.h stdlib.h string.h
 531 # unistd.h memory.h strings.h dlfcn.h sys/types.h sys/stat.h.
 532
 533 # Checks for typedefs, structures, and compiler characteristics.
 534 AC_C_BIGENDIAN
 535
 536 AC_SUBST(FIRMWARE_DIR, "$datadir/sigrok-firmware")
 537 AC_SUBST(MAKEFLAGS, '--no-print-directory')
 538 AC_SUBST(AM_LIBTOOLFLAGS, '--silent')
 539
 540 SR_PACKAGE_VERSION_MAJOR=sr_package_version_major
 541 SR_PACKAGE_VERSION_MINOR=sr_package_version_minor
 542 SR_PACKAGE_VERSION_MICRO=sr_package_version_micro
 543 SR_PACKAGE_VERSION=sr_package_version
 544
 545 AC_SUBST(SR_PACKAGE_VERSION_MAJOR)
 546 AC_SUBST(SR_PACKAGE_VERSION_MINOR)
 547 AC_SUBST(SR_PACKAGE_VERSION_MICRO)
 548 AC_SUBST(SR_PACKAGE_VERSION)
 549
 550 AC_CONFIG_FILES([Makefile include/libsigrok/version.h libsigrok.pc
 551         bindings/cxx/libsigrokcxx.pc])
 552
 553 AC_OUTPUT
 554
 555 echo
 556 echo "libsigrok configuration summary:"
 557 echo
 558 echo "  - Package version (major.minor.micro):    $SR_PACKAGE_VERSION"
 559 echo "  - Library version (current:revision:age): $SR_LIB_VERSION"
 560 echo "  - Prefix: $prefix"
 561 echo "  - Building on: $build"
 562 echo "  - Building for: $host"
 563 echo
 564 echo "Detected libraries:"
 565 echo
 566
 567 # Note: This only works for libs with pkg-config integration.
 568 for lib in "glib-2.0 >= 2.32.0" "libzip >= 0.10" "libserialport >= 0.2.0" \
 569         "librevisa >= 0.0.20130412" "libusb-1.0 >= 1.0.16" "libftdi >= 0.16" \
 570         "libftdi1 >= 1.0" "libgpib" "glibmm-2.4 >= 2.32.0" \
 571         "pygobject-3.0 >= 3.0.0" "check >= 0.9.4"
 572 do
 573         optional="OPTIONAL"
 574         if test "x$lib" = "xglib-2.0 >= 2.32.0"; then optional="REQUIRED"; fi
 575         if test "x$lib" = "xlibzip >= 0.10"; then optional="REQUIRED"; fi
 576         if `$PKG_CONFIG --exists $lib`; then
 577                 ver=`$PKG_CONFIG --modversion $lib`
 578                 answer="yes ($ver)"
 579         else
 580                 answer="no"
 581         fi
 582         echo "  - ($optional) $lib: $answer"
 583 done
 584
 585 eval echo -e "@Enabled hardware drivers:@@${driver_summary}" | tr @ \\n
 586
 587 # Prepare final bindings report messages.
 588 final_cxx=""
 589 final_python=""
 590 final_java=""
 591 if test "$enable_bindings" = "no"; then
 592         final_cxx=" (disabled)"
 593         final_python=" (disabled)"
 594         final_java=" (disabled)"
 595 else
 596         if test "$enable_cxx" = "no"; then
 597                 final_cxx=" (disabled)"
 598         elif test "$BINDINGS_CXX" = "no"; then
 599                 final_cxx=" ($cxx_msg)"
 600         fi
 601         if test "$enable_python" = "no"; then
 602                 final_python=" (disabled)"
 603         elif test "$BINDINGS_PYTHON" = "no"; then
 604                 final_python=" ($python_msg)"
 605         fi
 606         if test "$enable_java" = "no"; then
 607                 final_java=" (disabled)"
 608         elif test "$BINDINGS_JAVA" = "no"; then
 609                 final_java=" ($java_msg)"
 610         fi
 611 fi
 612
 613 echo "Enabled SCPI backends:"
 614 echo " - TCP............................. yes"
 615 if test "x$have_rpc" = "x0"; then
 616 echo " - RPC............................. no"
 617 else
 618 echo " - RPC............................. yes"
 619 fi
 620 echo " - serial.......................... $have_libserialport"
 621 echo " - VISA............................ $have_librevisa"
 622 echo " - GPIB............................ $have_libgpib"
 623 echo " - USBTMC.......................... $have_libusb1_0"
 624 echo
 625
 626 echo "Enabled language bindings:"
 627 echo " - C++............................. $BINDINGS_CXX$final_cxx"
 628 echo " - Python.......................... $BINDINGS_PYTHON$final_python"
 629 echo " - Java............................ $BINDINGS_JAVA$final_java"
 630 echo