configure.ac

   1 ##
   2 ## This file is part of the libsigrok project.
   3 ##
   4 ## Copyright (C) 2010-2012 Bert Vermeulen <bert@biot.com>
   5 ## Copyright (C) 2012 Alexandru Gagniuc <mr.nuke.me@gmail.com>
   6 ##
   7 ## This program is free software: you can redistribute it and/or modify
   8 ## it under the terms of the GNU General Public License as published by
   9 ## the Free Software Foundation, either version 3 of the License, or
  10 ## (at your option) any later version.
  11 ##
  12 ## This program is distributed in the hope that it will be useful,
  13 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ## GNU General Public License for more details.
  16 ##
  17 ## You should have received a copy of the GNU General Public License
  18 ## along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19 ##
  20
  21 # We require at least autoconf 2.63 (AC_INIT format changed there).
  22 AC_PREREQ([2.63])
  23
  24 # libsigrok package version number (NOT the same as shared lib version!).
  25 m4_define([sr_package_version_major], [0])
  26 m4_define([sr_package_version_minor], [3])
  27 m4_define([sr_package_version_micro], [0])
  28 m4_define([sr_package_version], [sr_package_version_major.sr_package_version_minor.sr_package_version_micro])
  29
  30 AC_INIT([libsigrok], [sr_package_version], [sigrok-devel@lists.sourceforge.net],
  31         [libsigrok], [http://www.sigrok.org])
  32 AC_CONFIG_HEADER([config.h])
  33 AC_CONFIG_MACRO_DIR([autostuff])
  34 AC_CONFIG_AUX_DIR([autostuff])
  35
  36 # We require at least automake 1.11 (needed for 'silent rules').
  37 AM_INIT_AUTOMAKE([1.11 -Wall -Werror subdir-objects check-news color-tests])
  38 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  39 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  40
  41 AH_TOP([#ifndef SR_CONFIG_H
  42 #define SR_CONFIG_H    /* To stop multiple inclusions. */])
  43 AH_BOTTOM([#endif /* SR_CONFIG_H */])
  44
  45 # Enable more compiler warnings via -Wall and -Wextra. Add -fvisibility=hidden
  46 # and enforce use of SR_API to explicitly mark all public API functions.
  47 COMMON_FLAGS="$CFLAGS -Wall -Wextra -fvisibility=hidden"
  48 CFLAGS="$COMMON_FLAGS -Wmissing-prototypes"
  49 CXXFLAGS="-std=c++11 $COMMON_FLAGS"
  50
  51 # Checks for programs.
  52 AC_PROG_CC
  53 AC_PROG_CPP
  54 AC_PROG_CXX
  55 AC_PROG_INSTALL
  56 AC_PROG_LN_S
  57
  58 # Required for per-target flags or subdir-objects with C sources.
  59 AM_PROG_CC_C_O
  60
  61 # Initialize libtool.
  62 LT_INIT
  63
  64 # Initialize pkg-config.
  65 # We require at least 0.22, as "Requires.private" behaviour changed there.
  66 PKG_PROG_PKG_CONFIG([0.22])
  67
  68 # Library version for libsigrok (NOT the same as the package version).
  69 # Carefully read the libtool docs before updating these numbers!
  70 # The algorithm for determining which number to change (and how) is nontrivial!
  71 # http://www.gnu.org/software/libtool/manual/libtool.html#Updating-version-info
  72 SR_LIB_VERSION_CURRENT=2
  73 SR_LIB_VERSION_REVISION=0
  74 SR_LIB_VERSION_AGE=0
  75 SR_LIB_VERSION="$SR_LIB_VERSION_CURRENT:$SR_LIB_VERSION_REVISION:$SR_LIB_VERSION_AGE"
  76 SR_LIB_LDFLAGS="-version-info $SR_LIB_VERSION"
  77 AC_SUBST(SR_LIB_VERSION_CURRENT)
  78 AC_SUBST(SR_LIB_VERSION_REVISION)
  79 AC_SUBST(SR_LIB_VERSION_AGE)
  80 AC_SUBST(SR_LIB_VERSION)
  81 AC_SUBST(SR_LIB_LDFLAGS)
  82
  83 AC_ARG_ENABLE(all-drivers, AC_HELP_STRING([--enable-all-drivers],
  84         [enable all drivers by default [default=yes]]),
  85         [HW_ENABLED_DEFAULT="$enableval"],
  86         [HW_ENABLED_DEFAULT="yes"])
  87
  88 # Usage: DRIVER([Device name], [driver-name])
  89 # An optional third argument [no] disables that driver.
  90 m4_define([driverize], [m4_tolower(m4_bpatsubst([$1], [[^0-9a-zA-Z-]+], [-]))])
  91 m4_define([upperize], [m4_toupper(m4_bpatsubst([$1], [[^0-9a-zA-Z_]+], [_]))])
  92 AC_DEFUN([DRIVER], [
  93         if test -z "$3"; then
  94                 default=$HW_ENABLED_DEFAULT
  95         else
  96                 default="$3"
  97         fi
  98         AC_ARG_ENABLE($2, AC_HELP_STRING([--enable-$2], [enable $1 support]),
  99                 [m4_join([], [HW_], upperize([$2]))="$enableval"],
 100                 [m4_join([], [HW_], upperize([$2]))=$default])
 101         dots=$(echo -n ".............................." | cut -c 1-$(expr 32 - $(echo -n $2|wc -c)))
 102         driver_summary="${driver_summary}  - $2${dots} \${m4_join([], [HW_], upperize([$2]))}@"
 103 ])
 104
 105 DRIVER([Agilent DMM], [agilent-dmm])
 106 DRIVER([Appa 55II], [appa-55ii])
 107 DRIVER([ASIX SIGMA/SIGMA2], [asix-sigma])
 108 DRIVER([Atten PPS3xxx], [atten-pps3xxx])
 109 DRIVER([BeagleLogic], [beaglelogic])
 110 DRIVER([Brymen BM86x], [brymen-bm86x])
 111 DRIVER([Brymen DMM], [brymen-dmm])
 112 DRIVER([CEM DT-885x], [cem-dt-885x])
 113 DRIVER([Center 3xx], [center-3xx])
 114 DRIVER([ChronoVu LA], [chronovu-la])
 115 DRIVER([Colead SLM], [colead-slm])
 116 DRIVER([Conrad DIGI 35 CPU], [conrad-digi-35-cpu])
 117 DRIVER([DER EE DE-5000], [deree-de5000])
 118 DRIVER([demo], [demo])
 119 DRIVER([Fluke DMM], [fluke-dmm])
 120 DRIVER([fx2lafw], [fx2lafw])
 121 DRIVER([GMC MH 1x/2x], [gmc-mh-1x-2x])
 122 DRIVER([Hameg HMO], [hameg-hmo])
 123 DRIVER([Hantek DSO], [hantek-dso])
 124 DRIVER([Ikalogic Scanalogic-2], [ikalogic-scanalogic2])
 125 DRIVER([Ikalogic Scanaplus], [ikalogic-scanaplus])
 126 DRIVER([Kecheng KC-330B], [kecheng-kc-330b])
 127 DRIVER([Lascar EL-USB], [lascar-el-usb])
 128 DRIVER([Manson HCS-3xxx], [manson-hcs-3xxx])
 129 DRIVER([MIC 985xx], [mic-985xx])
 130 DRIVER([Motech LPS 30x], [motech-lps-30x])
 131 DRIVER([Norma DMM], [norma-dmm])
 132 DRIVER([OpenBench Logic Sniffer], [openbench-logic-sniffer])
 133 DRIVER([Pipistrello-OLS], [pipistrello-ols])
 134 DRIVER([Rigol DS], [rigol-ds])
 135 DRIVER([Saleae Logic16], [saleae-logic16])
 136 DRIVER([SCPI PPS], [scpi-pps])
 137 DRIVER([serial DMM], [serial-dmm])
 138 DRIVER([Sysclk LWLA], [sysclk-lwla])
 139 DRIVER([Teleinfo], [teleinfo])
 140 DRIVER([Testo], [testo])
 141 DRIVER([Tondaj SL-814], [tondaj-sl-814])
 142 DRIVER([UNI-T DMM], [uni-t-dmm])
 143 DRIVER([UNI-T UT32x], [uni-t-ut32x])
 144 DRIVER([Victor DMM], [victor-dmm])
 145 DRIVER([Yokogawa DL/DLM], [yokogawa-dlm])
 146 DRIVER([ZEROPLUS Logic Cube], [zeroplus-logic-cube])
 147
 148 AC_ARG_ENABLE(libserialport,
 149         AC_HELP_STRING([--disable-libserialport],
 150         [disable libserialport support [default=detect]]))
 151
 152 AC_ARG_ENABLE(libftdi,
 153         AC_HELP_STRING([--disable-libftdi],
 154         [disable libftdi support [default=detect]]))
 155
 156 AC_ARG_ENABLE(libusb,
 157         AC_HELP_STRING([--disable-libusb],
 158         [disable libusb support [default=detect]]))
 159
 160 # Language binding '--enable' options:
 161
 162 AC_ARG_ENABLE(bindings,
 163         AC_HELP_STRING([--enable-bindings],
 164         [build language bindings [default=yes]]),
 165         [BINDINGS_ALL="$enableval"], [BINDINGS_ALL="yes"])
 166
 167 AC_ARG_ENABLE(cxx,
 168         AC_HELP_STRING([--enable-cxx],
 169         [build C++ bindings [default=yes]]),
 170         [BINDINGS_CXX="$enableval"], [BINDINGS_CXX=$BINDINGS_ALL])
 171
 172 AC_ARG_ENABLE(python,
 173         AC_HELP_STRING([--enable-python],
 174         [build Python bindings [default=yes]]),
 175         [BINDINGS_PYTHON="$enableval"], [BINDINGS_PYTHON=$BINDINGS_ALL])
 176
 177 AC_ARG_ENABLE(java,
 178         AC_HELP_STRING([--enable-java],
 179         [build Java bindings [default=yes]]),
 180         [BINDINGS_JAVA="$enableval"], [BINDINGS_JAVA=$BINDINGS_ALL])
 181
 182 AC_ARG_WITH(jni-include-path,
 183         AC_HELP_STRING([--with-jni-include-path=path],
 184         [specify include path for JNI [default=autodetect]]),
 185         [JNI_INCLUDE_DIRS="$withval"], [JNI_INCLUDE_DIRS=auto])
 186
 187 # Check if the C++ compiler supports the C++11 standard.
 188
 189 m4_ifdef([AX_CXX_COMPILE_STDCXX_11], [AX_CXX_COMPILE_STDCXX_11(,[optional])],
 190         [AC_MSG_NOTICE([Missing macro m4_toupper(aX_CXX_COMPILE_STDCXX_11), no C++11 check])])
 191
 192 if test "x$HAVE_CXX11" != "x1"; then
 193         BINDINGS_CXX="no"; cxx_msg="C++11 compiler required"
 194 fi
 195
 196 # The C++ bindings use Doxygen to parse libsigrok symbols.
 197 AC_CHECK_PROG([HAVE_DOXYGEN], [doxygen], [yes])
 198 if test "x$HAVE_DOXYGEN" != "xyes"; then
 199         BINDINGS_CXX="no"; cxx_msg="Doxygen required"
 200 fi
 201
 202 # Python is needed for the C++ bindings.
 203 AM_PATH_PYTHON([2.7], [HAVE_PYTHON="yes"],
 204         [HAVE_PYTHON="no"; BINDINGS_CXX="no"; cxx_msg="Python required"])
 205
 206 # The Python bindings need Python development files.
 207 PKG_CHECK_MODULES([python], [python >= 2.7],
 208         [CXXFLAGS="$CXXFLAGS $python_CFLAGS";
 209         CXXLIBS="$CXXLIBS $python_LIBS"],
 210 [PKG_CHECK_MODULES([python27], [python-2.7 >= 2.7],
 211         [CXXFLAGS="$CXXFLAGS $python27_CFLAGS";
 212         CXXLIBS="$CXXLIBS $python27_LIBS"],
 213                 [BINDINGS_PYTHON="no"; python_msg="Python headers required"])])
 214
 215 # The Python bindings need the setuptools Python module.
 216 m4_ifdef([AX_PYTHON_MODULE], [AX_PYTHON_MODULE([setuptools])],
 217         # We'll let it go through even if the macro wasn't found, the Python
 218         # module may still be there.
 219         [HAVE_PYTHON_SETUPTOOLS="yes";
 220                 AC_MSG_NOTICE([Missing macro m4_toupper(aX_PYTHON_MODULE), no setuptools check])]
 221 )
 222 if test "x$HAVE_PYMOD_SETUPTOOLS" != "xyes"; then
 223         BINDINGS_PYTHON="no"; python_msg="Python setuptools module required"
 224 fi
 225
 226 # The Python and Java bindings use SWIG to generate code.
 227 AC_CHECK_PROG([HAVE_SWIG], [swig], [yes])
 228 if test "x$HAVE_SWIG" != "xyes"; then
 229         BINDINGS_PYTHON="no"; python_msg="SWIG required"
 230         BINDINGS_JAVA="no"; java_msg="SWIG required"
 231 fi
 232
 233 # Checks for libraries.
 234
 235 case "$host" in
 236 *mingw*)
 237         # We need to link against the Winsock2 library for SCPI over TCP.
 238         LIBS="$LIBS -lws2_32";;
 239 esac
 240
 241 # This variable collects the pkg-config names of all detected libs.
 242 # It is then used to construct the "Requires.private:" field in the
 243 # libsigrok.pc file.
 244 SR_PKGLIBS=""
 245
 246 # libm (the standard math library) is always needed.
 247 AC_SEARCH_LIBS([pow], [m])
 248
 249 # RPC is only needed for VXI support.
 250 AC_MSG_CHECKING([for RPC support])
 251 AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <rpc/rpc.h>],
 252                         [CLIENT *rpc_test(void)],
 253                         [{ return clnt_create("", 0, 0, ""); }])],
 254                 [AC_MSG_RESULT([yes]); have_rpc=1],
 255                 [AC_MSG_RESULT([no]);  have_rpc=0])
 256 # Define HAVE_RPC in config.h if we found RPC support.
 257 AC_DEFINE_UNQUOTED(HAVE_RPC, [$have_rpc], [Specifies whether we have RPC support.])
 258 # VXI support is only compiled if RPC support was found.
 259 AM_CONDITIONAL(NEED_RPC, test "x$have_rpc" != "x0")
 260
 261 # libglib-2.0 is always needed. Abort if it's not found.
 262 # Note: glib-2.0 is part of the libsigrok API (hard pkg-config requirement).
 263 # We require at least 2.34.0 due to e.g. g_slist_deep_copy().
 264 AM_PATH_GLIB_2_0([2.34.0],
 265         [LIB_CFLAGS="$LIB_CFLAGS $GLIB_CFLAGS"; LIBS="$LIBS $GLIB_LIBS"])
 266
 267 # libzip is always needed. Abort if it's not found.
 268 PKG_CHECK_MODULES([libzip], [libzip >= 0.10],
 269         [LIB_CFLAGS="$LIB_CFLAGS $libzip_CFLAGS"; LIBS="$LIBS $libzip_LIBS";
 270         SR_PKGLIBS="$SR_PKGLIBS libzip"])
 271
 272 # libserialport is only needed for some hardware drivers. Disable the
 273 # respective drivers if it is not found.
 274 if test "x$enable_libserialport" != "xno"; then
 275         PKG_CHECK_MODULES([libserialport], [libserialport >= 0.2.0],
 276                 [have_libserialport="yes"; LIB_CFLAGS="$LIB_CFLAGS $libserialport_CFLAGS";
 277                 LIBS="$LIBS $libserialport_LIBS";
 278                 SR_PKGLIBS="$SR_PKGLIBS libserialport"],
 279                 [have_libserialport="no"])
 280         if test "x$enable_libserialport$have_libserialport" = "xyesno"; then
 281                 AC_MSG_ERROR([libserialport support requested, but it was not found.])
 282         fi
 283 else
 284         have_libserialport="no"
 285 fi
 286 if test "x$have_libserialport" = "xno"; then
 287         HW_AGILENT_DMM="no"; HW_APPA_55II="no";
 288         HW_ATTEN_PPS3XXX="no"; HW_BRYMEN_DMM="no"; HW_CEM_DT_885X="no";
 289         HW_CENTER_3XX="no"; HW_COLEAD_SLM="no"; HW_CONRAD_DIGI_35_CPU="no";
 290         HW_DEREE_DE5000="no"; HW_FLUKE_DMM="no"; HW_GMC_MH_1X_2X="no";
 291         HW_HAMEG_HMO="no"; HW_MANSON_HCS_3XXX="no"; HW_MIC_985XX="no";
 292         HW_MOTECH_LPS_30X="no"; HW_NORMA_DMM="no";
 293         HW_OPENBENCH_LOGIC_SNIFFER="no"; HW_SERIAL_DMM="no";
 294         HW_TELEINFO="no"; HW_TONDAJ_SL_814="no";
 295 else
 296         # Define HAVE_LIBSERIALPORT in config.h if we found libserialport.
 297         AC_DEFINE_UNQUOTED(HAVE_LIBSERIALPORT, [1],
 298                 [Specifies whether we have libserialport.])
 299 fi
 300
 301 # Serial port helper code is only compiled in if libserialport was found.
 302 AM_CONDITIONAL(NEED_SERIAL, test "x$have_libserialport" != xno)
 303
 304 # The VISA SCPI backend is only compiled in if librevisa was found.
 305 PKG_CHECK_MODULES([librevisa], [librevisa >= 0.0.20130812],
 306         [have_librevisa="yes"; LIB_CFLAGS="$LIB_CFLAGS $librevisa_CFLAGS";
 307         LIBS="$LIBS $librevisa_LIBS";
 308         SR_PKGLIBS="$SR_PKGLIBS librevisa"],
 309         [have_librevisa="no"])
 310 AM_CONDITIONAL(NEED_VISA, test "x$have_librevisa" != xno)
 311 if test "x$have_librevisa" != "xno"; then
 312         # Define HAVE_LIBREVISA in config.h if we found librevisa.
 313         AC_DEFINE_UNQUOTED(HAVE_LIBREVISA, [1],
 314                 [Specifies whether we have librevisa.])
 315 fi
 316
 317 # The GPIB SCPI backend is only compiled in if libgpib is found.
 318 PKG_CHECK_MODULES([libgpib], [libgpib],
 319         [have_libgpib="yes"; LIB_CFLAGS="$LIB_CFLAGS $libgpib_CFLAGS";
 320         LIBS="$LIBS $libgpib_LIBS";
 321         SR_PKGLIBS="$SR_PKGLIBS libgpib"],
 322         [have_libgpib="no"])
 323 AM_CONDITIONAL(NEED_GPIB, test "x$have_libgpib" != xno)
 324 if test "x$have_libgpib" != "xno"; then
 325         # Define HAVE_LIBGPIB in config.h if we found libgpib.
 326         AC_DEFINE_UNQUOTED(HAVE_LIBGPIB, [1],
 327                 [Specifies whether we have libgpib.])
 328 fi
 329
 330 # libusb-1.0 is only needed for some hardware drivers. Disable the respective
 331 # drivers if it is not found.
 332 if test "x$enable_libusb" != "xno"; then
 333         case "$host" in
 334         *freebsd*)
 335                 # FreeBSD comes with an "integrated" libusb-1.0-style USB API.
 336                 # This means libusb-1.0 is always available, no need to check for it,
 337                 # and no need to (potentially) disable any drivers if it's not found.
 338                 have_libusb1_0="yes"
 339                 ;;
 340         *)
 341                 PKG_CHECK_MODULES([libusb], [libusb-1.0 >= 1.0.16],
 342                         [have_libusb1_0="yes"; LIB_CFLAGS="$LIB_CFLAGS $libusb_CFLAGS";
 343                         LIBS="$LIBS $libusb_LIBS";
 344                         SR_PKGLIBS="$SR_PKGLIBS libusb-1.0"],
 345                         [have_libusb1_0="no"])
 346                 if test "x$enable_libusb$have_libusb1_0" = "xyesno"; then
 347                         AC_MSG_ERROR([libusb support requested, but it was not found.])
 348                 fi
 349                 ;;
 350         esac
 351 else
 352         have_libusb1_0="no"
 353 fi
 354 if test "x$have_libusb1_0" = "xno"; then
 355         HW_BRYMEN_BM86X="no"; HW_FX2LAFW="no";
 356         HW_HANTEK_DSO="no"; HW_IKALOGIC_SCANALOGIC2="no";
 357         HW_KECHENG_KC_330B="no"; HW_LASCAR_EL_USB="no";
 358         HW_SYSCLK_LWLA="no"; HW_TESTO="no"; HW_UNI_T_DMM="no";
 359         HW_UNI_T_UT32X="no"; HW_VICTOR_DMM="no";
 360         HW_ZEROPLUS_LOGIC_CUBE="no"; HW_SALEAE_LOGIC16="no";
 361 else
 362         # Define HAVE_LIBUSB_1_0 in config.h if we found libusb-1.0.
 363         AC_DEFINE_UNQUOTED(HAVE_LIBUSB_1_0, [1],
 364                 [Specifies whether we have libusb-1.0.])
 365 fi
 366
 367 # USB + FX2 firmware helper code is only compiled in if libusb-1.0 was found.
 368 AM_CONDITIONAL(NEED_USB, test "x$have_libusb1_0" != xno)
 369
 370 # libftdi is only needed for some hardware drivers. Disable them if not found.
 371 if test "x$enable_libftdi" != "xno"; then
 372         PKG_CHECK_MODULES([libftdi], [libftdi >= 0.16],
 373                 [have_libftdi="yes"; LIB_CFLAGS="$LIB_CFLAGS $libftdi_CFLAGS";
 374                 LIBS="$LIBS $libftdi_LIBS";
 375                 SR_PKGLIBS="$SR_PKGLIBS libftdi"],
 376                 [PKG_CHECK_MODULES([libftdi1], [libftdi1 >= 1.0],
 377                         [LIB_CFLAGS="$LIB_CFLAGS $libftdi1_CFLAGS";
 378                         LIBS="$LIBS $libftdi1_LIBS";
 379                         SR_PKGLIBS="$SR_PKGLIBS libftdi1"],
 380                         [have_libftdi="no"])])
 381         if test "x$enable_libftdi$have_libftdi" = "xyesno"; then
 382                 AC_MSG_ERROR([libftdi support requested, but it was not found.])
 383         fi
 384 else
 385         have_libftdi="no"
 386 fi
 387 if test "x$have_libftdi" = "xno"; then
 388         HW_ASIX_SIGMA="no"; HW_CHRONOVU_LA="no"; HW_IKALOGIC_SCANAPLUS="no";
 389         HW_PIPISTRELLO_OLS="no";
 390 fi
 391
 392 # glibmm-2.4 is needed for the C++ bindings.
 393 PKG_CHECK_MODULES([glibmm], [glibmm-2.4 >= 2.32.0],
 394         [CXXFLAGS="$CXXFLAGS $glibmm_CFLAGS";
 395         CXXLIBS="$CXXLIBS $glibmm_LIBS"],
 396         [BINDINGS_CXX="no"; cxx_msg="glibmm required"])
 397
 398 # C++ bindings want stoi and stod.
 399 if test "x$BINDINGS_CXX" == "xyes"; then
 400         AC_LANG_PUSH([C++])
 401         AC_MSG_CHECKING([for stoi and stod])
 402         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <string>],
 403                 [{ return std::stoi("1") + std::stod("1.0"); }])],
 404                 [AC_MSG_RESULT([yes]);
 405                 AC_DEFINE_UNQUOTED(HAVE_STOI_STOD, [1],
 406                 [Specifies whether we have the stoi and stod functions.])],
 407                 [AC_MSG_RESULT([no])])
 408         AC_LANG_POP([C++])
 409 fi
 410
 411 # PyGObject is needed for the Python bindings.
 412 PKG_CHECK_MODULES([pygobject], [pygobject-3.0 >= 3.0.0],
 413         [CXXFLAGS="$CXXFLAGS $pygobject_CFLAGS";
 414         CXXLIBS="$CXXLIBS $pygobject_LIBS";
 415         PKG_CHECK_MODULES([pygobject_3_7_91], [pygobject-3.0 >= 3.7.91],
 416                 [pyg_flags_signed=0], [pyg_flags_signed=1]);
 417         AC_DEFINE_UNQUOTED(PYGOBJECT_FLAGS_SIGNED, [$pyg_flags_signed],
 418                 [Whether last argument to pyg_flags_get_value() is signed.])],
 419         [BINDINGS_PYTHON="no"; python_msg="Python pygobject module required"])
 420
 421 # The Check unit testing framework is optional. Disable if not found.
 422 PKG_CHECK_MODULES([check], [check >= 0.9.4],
 423         [have_check="yes"], [have_check="no"])
 424 AM_CONDITIONAL(HAVE_CHECK, test x"$have_check" = "xyes")
 425
 426 # The BeagleLogic driver needs sys/mman.h and sys/ioctl.h. Don't try to
 427 # build it if these headers aren't available.
 428 AC_CHECK_HEADERS([sys/mman.h sys/ioctl.h], [], [HW_BEAGLELOGIC="no"])
 429
 430 AC_SUBST(SR_PKGLIBS)
 431
 432 CFLAGS="$CFLAGS -Iinclude/libsigrok -I${srcdir}/include/libsigrok $LIB_CFLAGS"
 433 CXXFLAGS="$CXXFLAGS -Iinclude/libsigrok -I${srcdir}/include -Ibindings/cxx -Ibindings/cxx/include/libsigrok -I${srcdir}/bindings/cxx/include $LIB_CFLAGS"
 434
 435 # Find Java compiler and JNI includes for Java bindings.
 436 AC_CHECK_PROG([HAVE_JAVAC], [javac], [yes], [no])
 437 if test "x$HAVE_JAVAC" = "xyes"; then
 438         AX_PROG_JAVAC
 439         if test "x$JNI_INCLUDE_DIRS" = "xauto"; then
 440                 if test "x$cross_compiling" = "xyes"; then
 441                         JNI_INCLUDE_DIRS=
 442                 else
 443                         AX_JNI_INCLUDE_DIR
 444                 fi
 445         fi
 446         for JNI_INCLUDE_DIR in $JNI_INCLUDE_DIRS; do
 447                 CXXFLAGS="$CXXFLAGS -I$JNI_INCLUDE_DIR"
 448         done
 449         AC_LANG_PUSH([C++])
 450         AC_CHECK_HEADERS([jni.h], [], [BINDINGS_JAVA="no"; java_msg="Java JNI headers required"])
 451         AC_LANG_POP([C++])
 452 else
 453         BINDINGS_JAVA="no"; java_msg="Java compiler required"
 454 fi
 455
 456 # Python and Java bindings depend on C++ bindings.
 457 if test "x$BINDINGS_CXX" != "xyes"; then
 458         BINDINGS_PYTHON="no"; python_msg="C++ bindings required"
 459         BINDINGS_JAVA="no"; java_msg="C++ bindings required"
 460 fi
 461
 462 # Now set AM_CONDITIONALs and AC_DEFINEs for the enabled/disabled drivers.
 463
 464 AC_DEFUN([DRIVER2], [
 465         AM_CONDITIONAL($1, test "x$2" = "xyes")
 466         if test "x$2" = "xyes"; then AC_DEFINE($3, 1, [.]) fi
 467 ])
 468
 469 DRIVER2([HW_AGILENT_DMM], [$HW_AGILENT_DMM], [HAVE_HW_AGILENT_DMM])
 470 DRIVER2([HW_APPA_55II], [$HW_APPA_55II], [HAVE_HW_APPA_55II])
 471 DRIVER2([HW_ASIX_SIGMA], [$HW_ASIX_SIGMA], [HAVE_HW_ASIX_SIGMA])
 472 DRIVER2([HW_ATTEN_PPS3XXX], [$HW_ATTEN_PPS3XXX], [HAVE_HW_ATTEN_PPS3XXX])
 473 DRIVER2([HW_BEAGLELOGIC], [$HW_BEAGLELOGIC], [HAVE_HW_BEAGLELOGIC])
 474 DRIVER2([HW_BRYMEN_BM86X], [$HW_BRYMEN_BM86X], [HAVE_HW_BRYMEN_BM86X])
 475 DRIVER2([HW_BRYMEN_DMM], [$HW_BRYMEN_DMM], [HAVE_HW_BRYMEN_DMM])
 476 DRIVER2([HW_CEM_DT_885X], [$HW_CEM_DT_885X], [HAVE_HW_CEM_DT_885X])
 477 DRIVER2([HW_CENTER_3XX], [$HW_CENTER_3XX], [HAVE_HW_CENTER_3XX])
 478 DRIVER2([HW_CHRONOVU_LA], [$HW_CHRONOVU_LA], [HAVE_HW_CHRONOVU_LA])
 479 DRIVER2([HW_COLEAD_SLM], [$HW_COLEAD_SLM], [HAVE_HW_COLEAD_SLM])
 480 DRIVER2([HW_CONRAD_DIGI_35_CPU], [$HW_CONRAD_DIGI_35_CPU], [HAVE_HW_CONRAD_DIGI_35_CPU])
 481 DRIVER2([HW_DEMO], [$HW_DEMO], [HAVE_HW_DEMO])
 482 DRIVER2([HW_DEREE_DE5000], [$HW_DEREE_DE5000], [HAVE_HW_DEREE_DE5000])
 483 DRIVER2([HW_FLUKE_DMM], [$HW_FLUKE_DMM], [HAVE_HW_FLUKE_DMM])
 484 DRIVER2([HW_FX2LAFW], [$HW_FX2LAFW], [HAVE_HW_FX2LAFW])
 485 DRIVER2([HW_GMC_MH_1X_2X], [$HW_GMC_MH_1X_2X], [HAVE_HW_GMC_MH_1X_2X])
 486 DRIVER2([HW_HAMEG_HMO], [$HW_HAMEG_HMO], [HAVE_HW_HAMEG_HMO])
 487 DRIVER2([HW_HANTEK_DSO], [$HW_HANTEK_DSO], [HAVE_HW_HANTEK_DSO])
 488 DRIVER2([HW_IKALOGIC_SCANALOGIC2], [$HW_IKALOGIC_SCANALOGIC2], [HAVE_HW_IKALOGIC_SCANALOGIC2])
 489 DRIVER2([HW_IKALOGIC_SCANAPLUS], [$HW_IKALOGIC_SCANAPLUS], [HAVE_HW_IKALOGIC_SCANAPLUS])
 490 DRIVER2([HW_KECHENG_KC_330B], [$HW_KECHENG_KC_330B], [HAVE_HW_KECHENG_KC_330B])
 491 DRIVER2([HW_LASCAR_EL_USB], [$HW_LASCAR_EL_USB], [HAVE_HW_LASCAR_EL_USB])
 492 DRIVER2([HW_MANSON_HCS_3XXX], [$HW_MANSON_HCS_3XXX], [HAVE_HW_MANSON_HCS_3XXX])
 493 DRIVER2([HW_MIC_985XX], [$HW_MIC_985XX], [HAVE_HW_MIC_985XX])
 494 DRIVER2([HW_MOTECH_LPS_30X], [$HW_MOTECH_LPS_30X], [HAVE_HW_MOTECH_LPS_30X])
 495 DRIVER2([HW_NORMA_DMM], [$HW_NORMA_DMM], [HAVE_HW_NORMA_DMM])
 496 DRIVER2([HW_OPENBENCH_LOGIC_SNIFFER], [$HW_OPENBENCH_LOGIC_SNIFFER], [HAVE_HW_OPENBENCH_LOGIC_SNIFFER])
 497 DRIVER2([HW_PIPISTRELLO_OLS], [$HW_PIPISTRELLO_OLS], [HAVE_HW_PIPISTRELLO_OLS])
 498 DRIVER2([HW_RIGOL_DS], [$HW_RIGOL_DS], [HAVE_HW_RIGOL_DS])
 499 DRIVER2([HW_SALEAE_LOGIC16], [$HW_SALEAE_LOGIC16], [HAVE_HW_SALEAE_LOGIC16])
 500 DRIVER2([HW_SCPI_PPS], [$HW_SCPI_PPS], [HAVE_HW_SCPI_PPS])
 501 DRIVER2([HW_SERIAL_DMM], [$HW_SERIAL_DMM], [HAVE_HW_SERIAL_DMM])
 502 DRIVER2([HW_SYSCLK_LWLA], [$HW_SYSCLK_LWLA], [HAVE_HW_SYSCLK_LWLA])
 503 DRIVER2([HW_TELEINFO], [$HW_TELEINFO], [HAVE_HW_TELEINFO])
 504 DRIVER2([HW_TESTO], [$HW_TESTO], [HAVE_HW_TESTO])
 505 DRIVER2([HW_TONDAJ_SL_814], [$HW_TONDAJ_SL_814], [HAVE_HW_TONDAJ_SL_814])
 506 DRIVER2([HW_UNI_T_DMM], [$HW_UNI_T_DMM], [HAVE_HW_UNI_T_DMM])
 507 DRIVER2([HW_UNI_T_UT32X], [$HW_UNI_T_UT32X], [HAVE_HW_UNI_T_UT32X])
 508 DRIVER2([HW_VICTOR_DMM], [$HW_VICTOR_DMM], [HAVE_HW_VICTOR_DMM])
 509 DRIVER2([HW_YOKOGAWA_DLM], [$HW_YOKOGAWA_DLM], [HAVE_HW_YOKOGAWA_DLM])
 510 DRIVER2([HW_ZEROPLUS_LOGIC_CUBE], [$HW_ZEROPLUS_LOGIC_CUBE], [HAVE_HW_ZEROPLUS_LOGIC_CUBE])
 511
 512 AM_CONDITIONAL(BINDINGS_CXX, test x$BINDINGS_CXX = xyes)
 513
 514 AM_CONDITIONAL(BINDINGS_PYTHON, test x$BINDINGS_PYTHON = xyes)
 515
 516 AM_CONDITIONAL(BINDINGS_JAVA, test x$BINDINGS_JAVA = xyes)
 517
 518 # Checks for header files.
 519 # These are already implicitly checked: inttypes.h stdint.h stdlib.h string.h
 520 # unistd.h memory.h strings.h dlfcn.h sys/types.h sys/stat.h.
 521
 522 # Checks for typedefs, structures, and compiler characteristics.
 523 AC_C_BIGENDIAN
 524
 525 AC_SUBST(FIRMWARE_DIR, "$datadir/sigrok-firmware")
 526 AC_SUBST(MAKEFLAGS, '--no-print-directory')
 527 AC_SUBST(AM_LIBTOOLFLAGS, '--silent')
 528
 529 SR_PACKAGE_VERSION_MAJOR=sr_package_version_major
 530 SR_PACKAGE_VERSION_MINOR=sr_package_version_minor
 531 SR_PACKAGE_VERSION_MICRO=sr_package_version_micro
 532 SR_PACKAGE_VERSION=sr_package_version
 533
 534 AC_SUBST(SR_PACKAGE_VERSION_MAJOR)
 535 AC_SUBST(SR_PACKAGE_VERSION_MINOR)
 536 AC_SUBST(SR_PACKAGE_VERSION_MICRO)
 537 AC_SUBST(SR_PACKAGE_VERSION)
 538
 539 AC_CONFIG_FILES([Makefile include/libsigrok/version.h libsigrok.pc
 540         bindings/cxx/libsigrokxx.pc])
 541
 542 AC_OUTPUT
 543
 544 echo
 545 echo "libsigrok configuration summary:"
 546 echo
 547 echo "  - Package version (major.minor.micro):    $SR_PACKAGE_VERSION"
 548 echo "  - Library version (current:revision:age): $SR_LIB_VERSION"
 549 echo "  - Prefix: $prefix"
 550 echo "  - Building on: $build"
 551 echo "  - Building for: $host"
 552 echo
 553 echo "Detected libraries:"
 554 echo
 555
 556 # Note: This only works for libs with pkg-config integration.
 557 for lib in "glib-2.0 >= 2.34.0" "libzip >= 0.10" "libserialport >= 0.2.0" \
 558         "librevisa >= 0.0.20130812" "libusb-1.0 >= 1.0.16" "libftdi >= 0.16" \
 559         "libftdi1 >= 1.0" "libgpib" "glibmm-2.4 >= 2.32.0" \
 560         "pygobject-3.0 >= 3.0.0" "check >= 0.9.4"
 561 do
 562         optional="OPTIONAL"
 563         if test "x$lib" = "xglib-2.0 >= 2.34.0"; then optional="REQUIRED"; fi
 564         if test "x$lib" = "xlibzip >= 0.10"; then optional="REQUIRED"; fi
 565         if `$PKG_CONFIG --exists $lib`; then
 566                 ver=`$PKG_CONFIG --modversion $lib`
 567                 answer="yes ($ver)"
 568         else
 569                 answer="no"
 570         fi
 571         echo "  - ($optional) $lib: $answer"
 572 done
 573
 574 eval echo -e "@Enabled hardware drivers:@@${driver_summary}" | tr @ \\n
 575
 576 # Prepare final bindings report messages.
 577 final_cxx=""
 578 final_python=""
 579 final_java=""
 580 if test "$enable_bindings" = "no"; then
 581         final_cxx=" (disabled)"
 582         final_python=" (disabled)"
 583         final_java=" (disabled)"
 584 else
 585         if test "$enable_cxx" = "no"; then
 586                 final_cxx=" (disabled)"
 587         elif test "$BINDINGS_CXX" = "no"; then
 588                 final_cxx=" ($cxx_msg)"
 589         fi
 590         if test "$enable_python" = "no"; then
 591                 final_python=" (disabled)"
 592         elif test "$BINDINGS_PYTHON" = "no"; then
 593                 final_python=" ($python_msg)"
 594         fi
 595         if test "$enable_java" = "no"; then
 596                 final_java=" (disabled)"
 597         elif test "$BINDINGS_JAVA" = "no"; then
 598                 final_java=" ($java_msg)"
 599         fi
 600 fi
 601
 602 echo "Enabled SCPI backends:"
 603 echo " - TCP............................. yes"
 604 if test "x$have_rpc" = "x0"; then
 605 echo " - RPC............................. no"
 606 else
 607 echo " - RPC............................. yes"
 608 fi
 609 echo " - serial.......................... $have_libserialport"
 610 echo " - VISA............................ $have_librevisa"
 611 echo " - GPIB............................ $have_libgpib"
 612 echo " - USBTMC.......................... $have_libusb1_0"
 613 echo
 614
 615 echo "Enabled language bindings:"
 616 echo " - C++............................. $BINDINGS_CXX$final_cxx"
 617 echo " - Python.......................... $BINDINGS_PYTHON$final_python"
 618 echo " - Java............................ $BINDINGS_JAVA$final_java"
 619 echo