configure.ac

   1 ##
   2 ## This file is part of the libsigrok project.
   3 ##
   4 ## Copyright (C) 2010-2012 Bert Vermeulen <bert@biot.com>
   5 ## Copyright (C) 2012 Alexandru Gagniuc <mr.nuke.me@gmail.com>
   6 ##
   7 ## This program is free software: you can redistribute it and/or modify
   8 ## it under the terms of the GNU General Public License as published by
   9 ## the Free Software Foundation, either version 3 of the License, or
  10 ## (at your option) any later version.
  11 ##
  12 ## This program is distributed in the hope that it will be useful,
  13 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ## GNU General Public License for more details.
  16 ##
  17 ## You should have received a copy of the GNU General Public License
  18 ## along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19 ##
  20
  21 # We require at least autoconf 2.63 (AC_INIT format changed there).
  22 AC_PREREQ([2.63])
  23
  24 # libsigrok package version number (NOT the same as shared lib version!).
  25 m4_define([sr_package_version_major], [0])
  26 m4_define([sr_package_version_minor], [4])
  27 m4_define([sr_package_version_micro], [0])
  28 m4_define([sr_package_version_suffix], [-git])
  29 m4_define([sr_package_version], [sr_package_version_major.sr_package_version_minor.sr_package_version_micro[]sr_package_version_suffix])
  30
  31 AC_INIT([libsigrok], [sr_package_version], [sigrok-devel@lists.sourceforge.net],
  32         [libsigrok], [http://www.sigrok.org])
  33 AC_CONFIG_HEADER([config.h])
  34 AC_CONFIG_MACRO_DIR([autostuff])
  35 AC_CONFIG_AUX_DIR([autostuff])
  36
  37 # We require at least automake 1.11 (needed for 'silent rules').
  38 AM_INIT_AUTOMAKE([1.11 -Wall -Werror subdir-objects check-news color-tests])
  39 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  40 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  41
  42 AH_TOP([#ifndef SR_CONFIG_H
  43 #define SR_CONFIG_H    /* To stop multiple inclusions. */])
  44 AH_BOTTOM([#endif /* SR_CONFIG_H */])
  45
  46 # Enable more compiler warnings via -Wall and -Wextra. Add -fvisibility=hidden
  47 # and enforce use of SR_API to explicitly mark all public API functions.
  48 COMMON_FLAGS="$CFLAGS -Wall -Wextra -fvisibility=hidden"
  49 CFLAGS="$COMMON_FLAGS -std=c11 -D_POSIX_C_SOURCE=200112L -Wmissing-prototypes"
  50 CXXFLAGS="-std=c++11 $COMMON_FLAGS"
  51
  52 # Checks for programs.
  53 AC_PROG_CC
  54 AC_PROG_CPP
  55 AC_PROG_CXX
  56 AC_PROG_INSTALL
  57 AC_PROG_LN_S
  58
  59 # Required for per-target flags or subdir-objects with C sources.
  60 AM_PROG_CC_C_O
  61
  62 # Initialize libtool.
  63 LT_INIT
  64
  65 # Initialize pkg-config.
  66 # We require at least 0.22, as "Requires.private" behaviour changed there.
  67 PKG_PROG_PKG_CONFIG([0.22])
  68
  69 # Library version for libsigrok (NOT the same as the package version).
  70 # Carefully read the libtool docs before updating these numbers!
  71 # The algorithm for determining which number to change (and how) is nontrivial!
  72 # http://www.gnu.org/software/libtool/manual/libtool.html#Updating-version-info
  73 SR_LIB_VERSION_CURRENT=2
  74 SR_LIB_VERSION_REVISION=0
  75 SR_LIB_VERSION_AGE=0
  76 SR_LIB_VERSION="$SR_LIB_VERSION_CURRENT:$SR_LIB_VERSION_REVISION:$SR_LIB_VERSION_AGE"
  77 SR_LIB_LDFLAGS="-version-info $SR_LIB_VERSION"
  78 AC_SUBST(SR_LIB_VERSION_CURRENT)
  79 AC_SUBST(SR_LIB_VERSION_REVISION)
  80 AC_SUBST(SR_LIB_VERSION_AGE)
  81 AC_SUBST(SR_LIB_VERSION)
  82 AC_SUBST(SR_LIB_LDFLAGS)
  83
  84 AC_ARG_ENABLE(all-drivers, AC_HELP_STRING([--enable-all-drivers],
  85         [enable all drivers by default [default=yes]]),
  86         [HW_ENABLED_DEFAULT="$enableval"],
  87         [HW_ENABLED_DEFAULT="yes"])
  88
  89 # Usage: DRIVER([Device name], [driver-name])
  90 # An optional third argument [no] disables that driver.
  91 m4_define([driverize], [m4_tolower(m4_bpatsubst([$1], [[^0-9a-zA-Z-]+], [-]))])
  92 m4_define([upperize], [m4_toupper(m4_bpatsubst([$1], [[^0-9a-zA-Z_]+], [_]))])
  93 AC_DEFUN([DRIVER], [
  94         if test -z "$3"; then
  95                 default=$HW_ENABLED_DEFAULT
  96         else
  97                 default="$3"
  98         fi
  99         AC_ARG_ENABLE($2, AC_HELP_STRING([--enable-$2], [enable $1 support]),
 100                 [m4_join([], [HW_], upperize([$2]))="$enableval"],
 101                 [m4_join([], [HW_], upperize([$2]))=$default])
 102         dots=$(echo -n ".............................." | cut -c 1-$(expr 32 - $(echo -n $2|wc -c)))
 103         driver_summary="${driver_summary}  - $2${dots} \${m4_join([], [HW_], upperize([$2]))}@"
 104 ])
 105
 106 DRIVER([Agilent DMM], [agilent-dmm])
 107 DRIVER([Appa 55II], [appa-55ii])
 108 DRIVER([ASIX SIGMA/SIGMA2], [asix-sigma])
 109 DRIVER([Atten PPS3xxx], [atten-pps3xxx])
 110 DRIVER([BayLibre ACME], [baylibre-acme])
 111 DRIVER([BeagleLogic], [beaglelogic])
 112 DRIVER([Brymen BM86x], [brymen-bm86x])
 113 DRIVER([Brymen DMM], [brymen-dmm])
 114 DRIVER([CEM DT-885x], [cem-dt-885x])
 115 DRIVER([Center 3xx], [center-3xx])
 116 DRIVER([ChronoVu LA], [chronovu-la])
 117 DRIVER([Colead SLM], [colead-slm])
 118 DRIVER([Conrad DIGI 35 CPU], [conrad-digi-35-cpu])
 119 DRIVER([DER EE DE-5000], [deree-de5000])
 120 DRIVER([demo], [demo])
 121 DRIVER([Fluke DMM], [fluke-dmm])
 122 DRIVER([fx2lafw], [fx2lafw])
 123 DRIVER([GMC MH 1x/2x], [gmc-mh-1x-2x])
 124 DRIVER([Hameg HMO], [hameg-hmo])
 125 DRIVER([Hantek DSO], [hantek-dso])
 126 DRIVER([Ikalogic Scanalogic-2], [ikalogic-scanalogic2])
 127 DRIVER([Ikalogic Scanaplus], [ikalogic-scanaplus])
 128 DRIVER([Kecheng KC-330B], [kecheng-kc-330b])
 129 DRIVER([Lascar EL-USB], [lascar-el-usb])
 130 DRIVER([Manson HCS-3xxx], [manson-hcs-3xxx])
 131 DRIVER([maynuo-m97], [maynuo-m97])
 132 DRIVER([MIC 985xx], [mic-985xx])
 133 DRIVER([Motech LPS 30x], [motech-lps-30x])
 134 DRIVER([Norma DMM], [norma-dmm])
 135 DRIVER([OpenBench Logic Sniffer], [openbench-logic-sniffer])
 136 DRIVER([Pipistrello-OLS], [pipistrello-ols])
 137 DRIVER([Rigol DS], [rigol-ds])
 138 DRIVER([Saleae Logic16], [saleae-logic16])
 139 DRIVER([SCPI PPS], [scpi-pps])
 140 DRIVER([serial DMM], [serial-dmm])
 141 DRIVER([Sysclk LWLA], [sysclk-lwla])
 142 DRIVER([Teleinfo], [teleinfo])
 143 DRIVER([Testo], [testo])
 144 DRIVER([Tondaj SL-814], [tondaj-sl-814])
 145 DRIVER([UNI-T DMM], [uni-t-dmm])
 146 DRIVER([UNI-T UT32x], [uni-t-ut32x])
 147 DRIVER([Victor DMM], [victor-dmm])
 148 DRIVER([Yokogawa DL/DLM], [yokogawa-dlm])
 149 DRIVER([ZEROPLUS Logic Cube], [zeroplus-logic-cube])
 150
 151 AC_ARG_ENABLE(libserialport,
 152         AC_HELP_STRING([--disable-libserialport],
 153         [disable libserialport support [default=detect]]))
 154
 155 AC_ARG_ENABLE(libftdi,
 156         AC_HELP_STRING([--disable-libftdi],
 157         [disable libftdi support [default=detect]]))
 158
 159 AC_ARG_ENABLE(libusb,
 160         AC_HELP_STRING([--disable-libusb],
 161         [disable libusb support [default=detect]]))
 162
 163 # Language binding '--enable' options:
 164
 165 AC_ARG_ENABLE(bindings,
 166         AC_HELP_STRING([--enable-bindings],
 167         [build language bindings [default=yes]]),
 168         [BINDINGS_ALL="$enableval"], [BINDINGS_ALL="yes"])
 169
 170 AC_ARG_ENABLE(cxx,
 171         AC_HELP_STRING([--enable-cxx],
 172         [build C++ bindings [default=yes]]),
 173         [BINDINGS_CXX="$enableval"], [BINDINGS_CXX=$BINDINGS_ALL])
 174
 175 AC_ARG_ENABLE(python,
 176         AC_HELP_STRING([--enable-python],
 177         [build Python bindings [default=yes]]),
 178         [BINDINGS_PYTHON="$enableval"], [BINDINGS_PYTHON=$BINDINGS_ALL])
 179
 180 AC_ARG_ENABLE(java,
 181         AC_HELP_STRING([--enable-java],
 182         [build Java bindings [default=yes]]),
 183         [BINDINGS_JAVA="$enableval"], [BINDINGS_JAVA=$BINDINGS_ALL])
 184
 185 AC_ARG_WITH(jni-include-path,
 186         AC_HELP_STRING([--with-jni-include-path=path],
 187         [specify include path for JNI [default=autodetect]]),
 188         [JNI_INCLUDE_DIRS="$withval"], [JNI_INCLUDE_DIRS=auto])
 189
 190 # Check if the C++ compiler supports the C++11 standard.
 191
 192 m4_ifdef([AX_CXX_COMPILE_STDCXX_11], [AX_CXX_COMPILE_STDCXX_11(,[optional])],
 193         [AC_MSG_NOTICE([Missing macro m4_toupper(aX_CXX_COMPILE_STDCXX_11), no C++11 check])])
 194
 195 if test "x$HAVE_CXX11" != "x1"; then
 196         BINDINGS_CXX="no"; cxx_msg="C++11 compiler required"
 197 fi
 198
 199 # The C++ bindings use Doxygen to parse libsigrok symbols.
 200 AC_CHECK_PROG([HAVE_DOXYGEN], [doxygen], [yes])
 201 if test "x$HAVE_DOXYGEN" != "xyes"; then
 202         BINDINGS_CXX="no"; cxx_msg="Doxygen required"
 203 fi
 204
 205 # Python is needed for the C++ bindings.
 206 AM_PATH_PYTHON([2.7], [HAVE_PYTHON="yes"],
 207         [HAVE_PYTHON="no"; BINDINGS_CXX="no"; cxx_msg="Python required"])
 208
 209 # The Python bindings need Python development files.
 210 PKG_CHECK_MODULES([python], [python >= 2.7],
 211         [CXXFLAGS="$CXXFLAGS $python_CFLAGS";
 212         CXXLIBS="$CXXLIBS $python_LIBS"],
 213 [PKG_CHECK_MODULES([python27], [python-2.7 >= 2.7],
 214         [CXXFLAGS="$CXXFLAGS $python27_CFLAGS";
 215         CXXLIBS="$CXXLIBS $python27_LIBS"],
 216                 [BINDINGS_PYTHON="no"; python_msg="Python headers required"])])
 217
 218 # The Python bindings need the setuptools Python module.
 219 m4_ifdef([AX_PYTHON_MODULE], [AX_PYTHON_MODULE([setuptools])],
 220         # We'll let it go through even if the macro wasn't found, the Python
 221         # module may still be there.
 222         [HAVE_PYTHON_SETUPTOOLS="yes";
 223                 AC_MSG_NOTICE([Missing macro m4_toupper(aX_PYTHON_MODULE), no setuptools check])]
 224 )
 225 if test "x$HAVE_PYMOD_SETUPTOOLS" != "xyes"; then
 226         BINDINGS_PYTHON="no"; python_msg="Python setuptools module required"
 227 fi
 228
 229 # The Python and Java bindings use SWIG to generate code.
 230 AC_CHECK_PROG([HAVE_SWIG], [swig], [yes])
 231 if test "x$HAVE_SWIG" != "xyes"; then
 232         BINDINGS_PYTHON="no"; python_msg="SWIG required"
 233         BINDINGS_JAVA="no"; java_msg="SWIG required"
 234 fi
 235
 236 # Checks for libraries.
 237
 238 case "$host" in
 239 *mingw*)
 240         # We need to link against the Winsock2 library for SCPI over TCP.
 241         LIBS="$LIBS -lws2_32";;
 242 esac
 243
 244 # This variable collects the pkg-config names of all detected libs.
 245 # It is then used to construct the "Requires.private:" field in the
 246 # libsigrok.pc file.
 247 SR_PKGLIBS=""
 248
 249 # libm (the standard math library) is always needed.
 250 AC_SEARCH_LIBS([pow], [m])
 251
 252 # RPC is only needed for VXI support.
 253 AC_MSG_CHECKING([for RPC support])
 254 AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <rpc/rpc.h>],
 255                         [CLIENT *rpc_test(void)],
 256                         [{ return clnt_create("", 0, 0, ""); }])],
 257                 [AC_MSG_RESULT([yes]); have_rpc=1],
 258                 [AC_MSG_RESULT([no]);  have_rpc=0])
 259 # Define HAVE_RPC in config.h if we found RPC support.
 260 AC_DEFINE_UNQUOTED(HAVE_RPC, [$have_rpc], [Specifies whether we have RPC support.])
 261 # VXI support is only compiled if RPC support was found.
 262 AM_CONDITIONAL(NEED_RPC, test "x$have_rpc" != "x0")
 263
 264 # libglib-2.0 is always needed. Abort if it's not found.
 265 # Note: glib-2.0 is part of the libsigrok API (hard pkg-config requirement).
 266 # We require at least 2.32.0 due to e.g. g_variant_new_fixed_array().
 267 AM_PATH_GLIB_2_0([2.32.0],
 268         [LIB_CFLAGS="$LIB_CFLAGS $GLIB_CFLAGS"; LIBS="$LIBS $GLIB_LIBS"])
 269
 270 # libzip is always needed. Abort if it's not found.
 271 PKG_CHECK_MODULES([libzip], [libzip >= 0.10],
 272         [LIB_CFLAGS="$LIB_CFLAGS $libzip_CFLAGS"; LIBS="$LIBS $libzip_LIBS";
 273         SR_PKGLIBS="$SR_PKGLIBS libzip"])
 274
 275 # libserialport is only needed for some hardware drivers. Disable the
 276 # respective drivers if it is not found.
 277 if test "x$enable_libserialport" != "xno"; then
 278         PKG_CHECK_MODULES([libserialport], [libserialport >= 0.1.1],
 279                 [have_libserialport="yes"; LIB_CFLAGS="$LIB_CFLAGS $libserialport_CFLAGS";
 280                 LIBS="$LIBS $libserialport_LIBS";
 281                 SR_PKGLIBS="$SR_PKGLIBS libserialport"],
 282                 [have_libserialport="no"])
 283         if test "x$enable_libserialport$have_libserialport" = "xyesno"; then
 284                 AC_MSG_ERROR([libserialport support requested, but it was not found.])
 285         fi
 286 else
 287         have_libserialport="no"
 288 fi
 289 if test "x$have_libserialport" = "xno"; then
 290         HW_AGILENT_DMM="no"; HW_APPA_55II="no";
 291         HW_ATTEN_PPS3XXX="no"; HW_BRYMEN_DMM="no"; HW_CEM_DT_885X="no";
 292         HW_CENTER_3XX="no"; HW_COLEAD_SLM="no"; HW_CONRAD_DIGI_35_CPU="no";
 293         HW_DEREE_DE5000="no"; HW_FLUKE_DMM="no"; HW_GMC_MH_1X_2X="no";
 294         HW_HAMEG_HMO="no"; HW_MANSON_HCS_3XXX="no"; HW_MIC_985XX="no";
 295         HW_MOTECH_LPS_30X="no"; HW_NORMA_DMM="no";
 296         HW_OPENBENCH_LOGIC_SNIFFER="no"; HW_SERIAL_DMM="no";
 297         HW_TELEINFO="no"; HW_TONDAJ_SL_814="no";
 298 else
 299         # Define HAVE_LIBSERIALPORT in config.h if we found libserialport.
 300         AC_DEFINE_UNQUOTED(HAVE_LIBSERIALPORT, [1],
 301                 [Specifies whether we have libserialport.])
 302 fi
 303
 304 # Serial port helper code is only compiled in if libserialport was found.
 305 AM_CONDITIONAL(NEED_SERIAL, test "x$have_libserialport" != xno)
 306
 307 # The VISA SCPI backend is only compiled in if librevisa was found.
 308 PKG_CHECK_MODULES([librevisa], [librevisa >= 0.0.20130412],
 309         [have_librevisa="yes"; LIB_CFLAGS="$LIB_CFLAGS $librevisa_CFLAGS";
 310         LIBS="$LIBS $librevisa_LIBS";
 311         SR_PKGLIBS="$SR_PKGLIBS librevisa"],
 312         [have_librevisa="no"])
 313 AM_CONDITIONAL(NEED_VISA, test "x$have_librevisa" != xno)
 314 if test "x$have_librevisa" != "xno"; then
 315         # Define HAVE_LIBREVISA in config.h if we found librevisa.
 316         AC_DEFINE_UNQUOTED(HAVE_LIBREVISA, [1],
 317                 [Specifies whether we have librevisa.])
 318 fi
 319
 320 # The GPIB SCPI backend is only compiled in if libgpib is found.
 321 PKG_CHECK_MODULES([libgpib], [libgpib],
 322         [have_libgpib="yes"; LIB_CFLAGS="$LIB_CFLAGS $libgpib_CFLAGS";
 323         LIBS="$LIBS $libgpib_LIBS";
 324         SR_PKGLIBS="$SR_PKGLIBS libgpib"],
 325         [have_libgpib="no"])
 326 AM_CONDITIONAL(NEED_GPIB, test "x$have_libgpib" != xno)
 327 if test "x$have_libgpib" != "xno"; then
 328         # Define HAVE_LIBGPIB in config.h if we found libgpib.
 329         AC_DEFINE_UNQUOTED(HAVE_LIBGPIB, [1],
 330                 [Specifies whether we have libgpib.])
 331 fi
 332
 333 # libusb-1.0 is only needed for some hardware drivers. Disable the respective
 334 # drivers if it is not found.
 335 if test "x$enable_libusb" != "xno"; then
 336         case "$host" in
 337         *freebsd*)
 338                 # FreeBSD comes with an "integrated" libusb-1.0-style USB API.
 339                 # This means libusb-1.0 is always available, no need to check for it,
 340                 # and no need to (potentially) disable any drivers if it's not found.
 341                 have_libusb1_0="yes"
 342                 ;;
 343         *)
 344                 PKG_CHECK_MODULES([libusb], [libusb-1.0 >= 1.0.16],
 345                         [have_libusb1_0="yes"; LIB_CFLAGS="$LIB_CFLAGS $libusb_CFLAGS";
 346                         LIBS="$LIBS $libusb_LIBS";
 347                         SR_PKGLIBS="$SR_PKGLIBS libusb-1.0"],
 348                         [have_libusb1_0="no"])
 349                 if test "x$enable_libusb$have_libusb1_0" = "xyesno"; then
 350                         AC_MSG_ERROR([libusb support requested, but it was not found.])
 351                 fi
 352                 ;;
 353         esac
 354 else
 355         have_libusb1_0="no"
 356 fi
 357 if test "x$have_libusb1_0" = "xno"; then
 358         HW_BRYMEN_BM86X="no"; HW_FX2LAFW="no";
 359         HW_HANTEK_DSO="no"; HW_IKALOGIC_SCANALOGIC2="no";
 360         HW_KECHENG_KC_330B="no"; HW_LASCAR_EL_USB="no";
 361         HW_SYSCLK_LWLA="no"; HW_TESTO="no"; HW_UNI_T_DMM="no";
 362         HW_UNI_T_UT32X="no"; HW_VICTOR_DMM="no";
 363         HW_ZEROPLUS_LOGIC_CUBE="no"; HW_SALEAE_LOGIC16="no";
 364 else
 365         # Define HAVE_LIBUSB_1_0 in config.h if we found libusb-1.0.
 366         AC_DEFINE_UNQUOTED(HAVE_LIBUSB_1_0, [1],
 367                 [Specifies whether we have libusb-1.0.])
 368 fi
 369
 370 # USB + FX2 firmware helper code is only compiled in if libusb-1.0 was found.
 371 AM_CONDITIONAL(NEED_USB, test "x$have_libusb1_0" != xno)
 372
 373 # libftdi is only needed for some hardware drivers. Disable them if not found.
 374 if test "x$enable_libftdi" != "xno"; then
 375         PKG_CHECK_MODULES([libftdi], [libftdi >= 0.16],
 376                 [have_libftdi="yes"; LIB_CFLAGS="$LIB_CFLAGS $libftdi_CFLAGS";
 377                 LIBS="$LIBS $libftdi_LIBS";
 378                 SR_PKGLIBS="$SR_PKGLIBS libftdi"],
 379                 [PKG_CHECK_MODULES([libftdi1], [libftdi1 >= 1.0],
 380                         [LIB_CFLAGS="$LIB_CFLAGS $libftdi1_CFLAGS";
 381                         LIBS="$LIBS $libftdi1_LIBS";
 382                         SR_PKGLIBS="$SR_PKGLIBS libftdi1"],
 383                         [have_libftdi="no"])])
 384         if test "x$enable_libftdi$have_libftdi" = "xyesno"; then
 385                 AC_MSG_ERROR([libftdi support requested, but it was not found.])
 386         fi
 387 else
 388         have_libftdi="no"
 389 fi
 390 if test "x$have_libftdi" = "xno"; then
 391         HW_ASIX_SIGMA="no"; HW_CHRONOVU_LA="no"; HW_IKALOGIC_SCANAPLUS="no";
 392         HW_PIPISTRELLO_OLS="no";
 393 fi
 394
 395 # glibmm-2.4 is needed for the C++ bindings.
 396 PKG_CHECK_MODULES([glibmm], [glibmm-2.4 >= 2.32.0],
 397         [CXXFLAGS="$CXXFLAGS $glibmm_CFLAGS";
 398         CXXLIBS="$CXXLIBS $glibmm_LIBS"],
 399         [BINDINGS_CXX="no"; cxx_msg="glibmm required"])
 400
 401 # C++ bindings want stoi and stod.
 402 if test "x$BINDINGS_CXX" = "xyes"; then
 403         AC_LANG_PUSH([C++])
 404         AC_MSG_CHECKING([for stoi and stod])
 405         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <string>],
 406                 [{ return std::stoi("1") + std::stod("1.0"); }])],
 407                 [AC_MSG_RESULT([yes]);
 408                 AC_DEFINE_UNQUOTED(HAVE_STOI_STOD, [1],
 409                 [Specifies whether we have the stoi and stod functions.])],
 410                 [AC_MSG_RESULT([no])])
 411         AC_LANG_POP([C++])
 412 fi
 413
 414 # PyGObject is needed for the Python bindings.
 415 PKG_CHECK_MODULES([pygobject], [pygobject-3.0 >= 3.0.0],
 416         [CXXFLAGS="$CXXFLAGS $pygobject_CFLAGS";
 417         CXXLIBS="$CXXLIBS $pygobject_LIBS";
 418         PKG_CHECK_MODULES([pygobject_3_7_91], [pygobject-3.0 >= 3.7.91],
 419                 [pyg_flags_signed=0], [pyg_flags_signed=1]);
 420         AC_DEFINE_UNQUOTED(PYGOBJECT_FLAGS_SIGNED, [$pyg_flags_signed],
 421                 [Whether last argument to pyg_flags_get_value() is signed.])],
 422         [BINDINGS_PYTHON="no"; python_msg="Python pygobject module required"])
 423
 424 # The Check unit testing framework is optional. Disable if not found.
 425 PKG_CHECK_MODULES([check], [check >= 0.9.4],
 426         [have_check="yes"], [have_check="no"])
 427 AM_CONDITIONAL(HAVE_CHECK, test x"$have_check" = "xyes")
 428
 429 # The BeagleLogic driver needs sys/mman.h and sys/ioctl.h. Don't try to
 430 # build it if these headers aren't available.
 431 AC_CHECK_HEADERS([sys/mman.h sys/ioctl.h], [], [HW_BEAGLELOGIC="no"])
 432
 433 # The BayLibre ACME driver needs sys/timerfd.h. Don't try to build it if
 434 # this header isn't available.
 435 AC_CHECK_HEADERS([sys/timerfd.h], [], [HW_BAYLIBRE_ACME="no"])
 436
 437 # The ACME driver can only be built for Linux.
 438 case "$host" in
 439         *linux*) ;;
 440         *) HW_BAYLIBRE_ACME="no" ;;
 441 esac
 442
 443 AC_SUBST(SR_PKGLIBS)
 444
 445 CFLAGS="$CFLAGS -Iinclude/libsigrok -I${srcdir}/include/libsigrok $LIB_CFLAGS"
 446 CXXFLAGS="$CXXFLAGS -Iinclude/libsigrok -I${srcdir}/include -Ibindings/cxx -Ibindings/cxx/include/libsigrokcxx -I${srcdir}/bindings/cxx/include $LIB_CFLAGS"
 447
 448 # Find Java compiler and JNI includes for Java bindings.
 449 AC_CHECK_PROG([HAVE_JAVAC], [javac], [yes], [no])
 450 if test "x$HAVE_JAVAC" = "xyes" && test "x$BINDINGS_JAVA" = "xyes"; then
 451         AX_PROG_JAVAC
 452         if test "x$JNI_INCLUDE_DIRS" = "xauto"; then
 453                 if test "x$cross_compiling" = "xyes"; then
 454                         JNI_INCLUDE_DIRS=
 455                 else
 456                         AX_JNI_INCLUDE_DIR
 457                 fi
 458         fi
 459         for JNI_INCLUDE_DIR in $JNI_INCLUDE_DIRS; do
 460                 CXXFLAGS="$CXXFLAGS -I$JNI_INCLUDE_DIR"
 461         done
 462         AC_LANG_PUSH([C++])
 463         AC_CHECK_HEADERS([jni.h], [], [BINDINGS_JAVA="no"; java_msg="Java JNI headers required"])
 464         AC_LANG_POP([C++])
 465 else
 466         BINDINGS_JAVA="no"; java_msg="Java compiler required"
 467 fi
 468
 469 # Python and Java bindings depend on C++ bindings.
 470 if test "x$BINDINGS_CXX" != "xyes"; then
 471         BINDINGS_PYTHON="no"; python_msg="C++ bindings required"
 472         BINDINGS_JAVA="no"; java_msg="C++ bindings required"
 473 fi
 474
 475 # Now set AM_CONDITIONALs and AC_DEFINEs for the enabled/disabled drivers.
 476
 477 AC_DEFUN([DRIVER2], [
 478         AM_CONDITIONAL($1, test "x$2" = "xyes")
 479         if test "x$2" = "xyes"; then AC_DEFINE($3, 1, [.]) fi
 480 ])
 481
 482 DRIVER2([HW_AGILENT_DMM], [$HW_AGILENT_DMM], [HAVE_HW_AGILENT_DMM])
 483 DRIVER2([HW_APPA_55II], [$HW_APPA_55II], [HAVE_HW_APPA_55II])
 484 DRIVER2([HW_ASIX_SIGMA], [$HW_ASIX_SIGMA], [HAVE_HW_ASIX_SIGMA])
 485 DRIVER2([HW_ATTEN_PPS3XXX], [$HW_ATTEN_PPS3XXX], [HAVE_HW_ATTEN_PPS3XXX])
 486 DRIVER2([HW_BAYLIBRE_ACME], [$HW_BAYLIBRE_ACME], [HAVE_HW_BAYLIBRE_ACME])
 487 DRIVER2([HW_BEAGLELOGIC], [$HW_BEAGLELOGIC], [HAVE_HW_BEAGLELOGIC])
 488 DRIVER2([HW_BRYMEN_BM86X], [$HW_BRYMEN_BM86X], [HAVE_HW_BRYMEN_BM86X])
 489 DRIVER2([HW_BRYMEN_DMM], [$HW_BRYMEN_DMM], [HAVE_HW_BRYMEN_DMM])
 490 DRIVER2([HW_CEM_DT_885X], [$HW_CEM_DT_885X], [HAVE_HW_CEM_DT_885X])
 491 DRIVER2([HW_CENTER_3XX], [$HW_CENTER_3XX], [HAVE_HW_CENTER_3XX])
 492 DRIVER2([HW_CHRONOVU_LA], [$HW_CHRONOVU_LA], [HAVE_HW_CHRONOVU_LA])
 493 DRIVER2([HW_COLEAD_SLM], [$HW_COLEAD_SLM], [HAVE_HW_COLEAD_SLM])
 494 DRIVER2([HW_CONRAD_DIGI_35_CPU], [$HW_CONRAD_DIGI_35_CPU], [HAVE_HW_CONRAD_DIGI_35_CPU])
 495 DRIVER2([HW_DEMO], [$HW_DEMO], [HAVE_HW_DEMO])
 496 DRIVER2([HW_DEREE_DE5000], [$HW_DEREE_DE5000], [HAVE_HW_DEREE_DE5000])
 497 DRIVER2([HW_FLUKE_DMM], [$HW_FLUKE_DMM], [HAVE_HW_FLUKE_DMM])
 498 DRIVER2([HW_FX2LAFW], [$HW_FX2LAFW], [HAVE_HW_FX2LAFW])
 499 DRIVER2([HW_GMC_MH_1X_2X], [$HW_GMC_MH_1X_2X], [HAVE_HW_GMC_MH_1X_2X])
 500 DRIVER2([HW_HAMEG_HMO], [$HW_HAMEG_HMO], [HAVE_HW_HAMEG_HMO])
 501 DRIVER2([HW_HANTEK_DSO], [$HW_HANTEK_DSO], [HAVE_HW_HANTEK_DSO])
 502 DRIVER2([HW_IKALOGIC_SCANALOGIC2], [$HW_IKALOGIC_SCANALOGIC2], [HAVE_HW_IKALOGIC_SCANALOGIC2])
 503 DRIVER2([HW_IKALOGIC_SCANAPLUS], [$HW_IKALOGIC_SCANAPLUS], [HAVE_HW_IKALOGIC_SCANAPLUS])
 504 DRIVER2([HW_KECHENG_KC_330B], [$HW_KECHENG_KC_330B], [HAVE_HW_KECHENG_KC_330B])
 505 DRIVER2([HW_LASCAR_EL_USB], [$HW_LASCAR_EL_USB], [HAVE_HW_LASCAR_EL_USB])
 506 DRIVER2([HW_MANSON_HCS_3XXX], [$HW_MANSON_HCS_3XXX], [HAVE_HW_MANSON_HCS_3XXX])
 507 DRIVER2([HW_MAYNUO_M97], [$HW_MAYNUO_M97], [HAVE_HW_MAYNUO_M97])
 508 DRIVER2([HW_MIC_985XX], [$HW_MIC_985XX], [HAVE_HW_MIC_985XX])
 509 DRIVER2([HW_MOTECH_LPS_30X], [$HW_MOTECH_LPS_30X], [HAVE_HW_MOTECH_LPS_30X])
 510 DRIVER2([HW_NORMA_DMM], [$HW_NORMA_DMM], [HAVE_HW_NORMA_DMM])
 511 DRIVER2([HW_OPENBENCH_LOGIC_SNIFFER], [$HW_OPENBENCH_LOGIC_SNIFFER], [HAVE_HW_OPENBENCH_LOGIC_SNIFFER])
 512 DRIVER2([HW_PIPISTRELLO_OLS], [$HW_PIPISTRELLO_OLS], [HAVE_HW_PIPISTRELLO_OLS])
 513 DRIVER2([HW_RIGOL_DS], [$HW_RIGOL_DS], [HAVE_HW_RIGOL_DS])
 514 DRIVER2([HW_SALEAE_LOGIC16], [$HW_SALEAE_LOGIC16], [HAVE_HW_SALEAE_LOGIC16])
 515 DRIVER2([HW_SCPI_PPS], [$HW_SCPI_PPS], [HAVE_HW_SCPI_PPS])
 516 DRIVER2([HW_SERIAL_DMM], [$HW_SERIAL_DMM], [HAVE_HW_SERIAL_DMM])
 517 DRIVER2([HW_SYSCLK_LWLA], [$HW_SYSCLK_LWLA], [HAVE_HW_SYSCLK_LWLA])
 518 DRIVER2([HW_TELEINFO], [$HW_TELEINFO], [HAVE_HW_TELEINFO])
 519 DRIVER2([HW_TESTO], [$HW_TESTO], [HAVE_HW_TESTO])
 520 DRIVER2([HW_TONDAJ_SL_814], [$HW_TONDAJ_SL_814], [HAVE_HW_TONDAJ_SL_814])
 521 DRIVER2([HW_UNI_T_DMM], [$HW_UNI_T_DMM], [HAVE_HW_UNI_T_DMM])
 522 DRIVER2([HW_UNI_T_UT32X], [$HW_UNI_T_UT32X], [HAVE_HW_UNI_T_UT32X])
 523 DRIVER2([HW_VICTOR_DMM], [$HW_VICTOR_DMM], [HAVE_HW_VICTOR_DMM])
 524 DRIVER2([HW_YOKOGAWA_DLM], [$HW_YOKOGAWA_DLM], [HAVE_HW_YOKOGAWA_DLM])
 525 DRIVER2([HW_ZEROPLUS_LOGIC_CUBE], [$HW_ZEROPLUS_LOGIC_CUBE], [HAVE_HW_ZEROPLUS_LOGIC_CUBE])
 526
 527 AM_CONDITIONAL(BINDINGS_CXX, test x$BINDINGS_CXX = xyes)
 528
 529 AM_CONDITIONAL(BINDINGS_PYTHON, test x$BINDINGS_PYTHON = xyes)
 530
 531 AM_CONDITIONAL(BINDINGS_JAVA, test x$BINDINGS_JAVA = xyes)
 532
 533 # Checks for header files.
 534 # These are already implicitly checked: inttypes.h stdint.h stdlib.h string.h
 535 # unistd.h memory.h strings.h dlfcn.h sys/types.h sys/stat.h.
 536
 537 # Checks for typedefs, structures, and compiler characteristics.
 538 AC_C_BIGENDIAN
 539
 540 AC_SUBST(FIRMWARE_DIR, "$datadir/sigrok-firmware")
 541 AC_SUBST(MAKEFLAGS, '--no-print-directory')
 542 AC_SUBST(AM_LIBTOOLFLAGS, '--silent')
 543
 544 SR_PACKAGE_VERSION_MAJOR=sr_package_version_major
 545 SR_PACKAGE_VERSION_MINOR=sr_package_version_minor
 546 SR_PACKAGE_VERSION_MICRO=sr_package_version_micro
 547 SR_PACKAGE_VERSION=sr_package_version
 548
 549 AC_SUBST(SR_PACKAGE_VERSION_MAJOR)
 550 AC_SUBST(SR_PACKAGE_VERSION_MINOR)
 551 AC_SUBST(SR_PACKAGE_VERSION_MICRO)
 552 AC_SUBST(SR_PACKAGE_VERSION)
 553
 554 AC_CONFIG_FILES([Makefile include/libsigrok/version.h libsigrok.pc
 555         bindings/cxx/libsigrokcxx.pc])
 556
 557 AC_OUTPUT
 558
 559 echo
 560 echo "libsigrok configuration summary:"
 561 echo
 562 echo "  - Package version (major.minor.micro):    $SR_PACKAGE_VERSION"
 563 echo "  - Library version (current:revision:age): $SR_LIB_VERSION"
 564 echo "  - Prefix: $prefix"
 565 echo "  - Building on: $build"
 566 echo "  - Building for: $host"
 567 echo
 568 echo "Detected libraries:"
 569 echo
 570
 571 # Note: This only works for libs with pkg-config integration.
 572 for lib in "glib-2.0 >= 2.32.0" "libzip >= 0.10" "libserialport >= 0.1.1" \
 573         "librevisa >= 0.0.20130412" "libusb-1.0 >= 1.0.16" "libftdi >= 0.16" \
 574         "libftdi1 >= 1.0" "libgpib" "glibmm-2.4 >= 2.32.0" \
 575         "pygobject-3.0 >= 3.0.0" "check >= 0.9.4"
 576 do
 577         optional="OPTIONAL"
 578         if test "x$lib" = "xglib-2.0 >= 2.32.0"; then optional="REQUIRED"; fi
 579         if test "x$lib" = "xlibzip >= 0.10"; then optional="REQUIRED"; fi
 580         if `$PKG_CONFIG --exists $lib`; then
 581                 ver=`$PKG_CONFIG --modversion $lib`
 582                 answer="yes ($ver)"
 583         else
 584                 answer="no"
 585         fi
 586         echo "  - ($optional) $lib: $answer"
 587 done
 588
 589 eval echo -e "@Enabled hardware drivers:@@${driver_summary}" | tr @ \\n
 590
 591 # Prepare final bindings report messages.
 592 final_cxx=""
 593 final_python=""
 594 final_java=""
 595 if test "$enable_bindings" = "no"; then
 596         final_cxx=" (disabled)"
 597         final_python=" (disabled)"
 598         final_java=" (disabled)"
 599 else
 600         if test "$enable_cxx" = "no"; then
 601                 final_cxx=" (disabled)"
 602         elif test "$BINDINGS_CXX" = "no"; then
 603                 final_cxx=" ($cxx_msg)"
 604         fi
 605         if test "$enable_python" = "no"; then
 606                 final_python=" (disabled)"
 607         elif test "$BINDINGS_PYTHON" = "no"; then
 608                 final_python=" ($python_msg)"
 609         fi
 610         if test "$enable_java" = "no"; then
 611                 final_java=" (disabled)"
 612         elif test "$BINDINGS_JAVA" = "no"; then
 613                 final_java=" ($java_msg)"
 614         fi
 615 fi
 616
 617 echo "Enabled SCPI backends:"
 618 echo " - TCP............................. yes"
 619 if test "x$have_rpc" = "x0"; then
 620 echo " - RPC............................. no"
 621 else
 622 echo " - RPC............................. yes"
 623 fi
 624 echo " - serial.......................... $have_libserialport"
 625 echo " - VISA............................ $have_librevisa"
 626 echo " - GPIB............................ $have_libgpib"
 627 echo " - USBTMC.......................... $have_libusb1_0"
 628 echo
 629
 630 echo "Enabled language bindings:"
 631 echo " - C++............................. $BINDINGS_CXX$final_cxx"
 632 echo " - Python.......................... $BINDINGS_PYTHON$final_python"
 633 echo " - Java............................ $BINDINGS_JAVA$final_java"
 634 echo