configure.ac

   1 ##
   2 ## This file is part of the libsigrok project.
   3 ##
   4 ## Copyright (C) 2010-2012 Bert Vermeulen <bert@biot.com>
   5 ## Copyright (C) 2012 Alexandru Gagniuc <mr.nuke.me@gmail.com>
   6 ##
   7 ## This program is free software: you can redistribute it and/or modify
   8 ## it under the terms of the GNU General Public License as published by
   9 ## the Free Software Foundation, either version 3 of the License, or
  10 ## (at your option) any later version.
  11 ##
  12 ## This program is distributed in the hope that it will be useful,
  13 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ## GNU General Public License for more details.
  16 ##
  17 ## You should have received a copy of the GNU General Public License
  18 ## along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19 ##
  20
  21 # We require at least autoconf 2.63 (AC_INIT format changed there).
  22 AC_PREREQ([2.63])
  23
  24 AC_INIT([libsigrok], [0.5.0],
  25         [sigrok-devel@lists.sourceforge.net],
  26         [libsigrok], [http://www.sigrok.org])
  27 AC_CONFIG_MACRO_DIR([m4])
  28 AC_CONFIG_AUX_DIR([autostuff])
  29 AC_CONFIG_HEADERS([config.h include/libsigrok/version.h])
  30
  31 # We require at least automake 1.11 (needed for 'silent rules').
  32 AM_INIT_AUTOMAKE([1.11 -Wall -Werror no-define nostdinc subdir-objects check-news color-tests])
  33 AM_SILENT_RULES([yes])
  34 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  35
  36 AC_CANONICAL_HOST
  37
  38 # Checks for programs.
  39 AC_PROG_CC
  40 AC_PROG_CXX
  41 AC_PROG_INSTALL
  42 AC_PROG_LN_S
  43
  44 # Required for per-target flags or subdir-objects with C sources.
  45 AM_PROG_CC_C_O
  46
  47 # Set the standard the C library headers should conform to.
  48 AH_VERBATIM([_POSIX_C_SOURCE], [/* The targeted POSIX standard. */
  49 #ifndef _POSIX_C_SOURCE
  50 # define _POSIX_C_SOURCE 200112L
  51 #endif])
  52
  53 # Get compiler versions.
  54 SR_PROG_VERSION([$CC], [sr_cc_version])
  55 SR_PROG_VERSION([$CXX], [sr_cxx_version])
  56
  57 # Check for optional make features.
  58 SR_PROG_MAKE_ORDER_ONLY
  59
  60 # Initialize libtool.
  61 LT_INIT
  62
  63 # Set up the libsigrok version defines.
  64 SR_PKG_VERSION_SET([SR_PACKAGE_VERSION], [AC_PACKAGE_VERSION])
  65
  66 # Library version for libsigrok (NOT the same as the package version).
  67 # Carefully read the libtool docs before updating these numbers!
  68 # The algorithm for determining which number to change (and how) is nontrivial!
  69 # http://www.gnu.org/software/libtool/manual/libtool.html#Updating-version-info
  70 # Format: current:revision:age.
  71 SR_LIB_VERSION_SET([SR_LIB_VERSION], [3:0:0])
  72
  73 AM_CONDITIONAL([WIN32], [test -z "${host_os##mingw*}" || test -z "${host_os##cygwin*}"])
  74
  75 #############################
  76 ##  Optional dependencies  ##
  77 #############################
  78
  79 AC_LANG([C])
  80
  81 # Initialize pkg-config.
  82 # We require at least 0.22, as "Requires.private" behaviour changed there.
  83 PKG_PROG_PKG_CONFIG([0.22])
  84
  85 # Keep track of all checked modules so we can list them at the end.
  86 SR_PKG_CHECK_SUMMARY([sr_pkglibs_summary])
  87
  88 # Collect the pkg-config module names of all dependencies in SR_PKGLIBS.
  89 # These are used to derive the compiler flags and for the "Requires.private"
  90 # field in the generated libsigrok.pc file.
  91 SR_VAR_OPT_PKG([SR_PKGLIBS], [sr_deps_avail])
  92 SR_PKGLIBS_TESTS=
  93 SR_PKGLIBS_CXX=
  94 SR_PKGLIBS_PYTHON=
  95 SR_PKGLIBS_RUBY=
  96 SR_EXTRA_LIBS=
  97 SR_EXTRA_CXX_LIBS=
  98
  99 SR_ARG_OPT_PKG([libserialport], [LIBSERIALPORT], [NEED_SERIAL],
 100         [libserialport >= 0.1.1])
 101
 102 SR_ARG_OPT_PKG([libftdi], [LIBFTDI],,
 103         [libftdi1 >= 1.0], [libftdi >= 0.16])
 104
 105 # FreeBSD comes with an "integrated" libusb-1.0-style USB API.
 106 # This means libusb-1.0 is always available; no need to check for it.
 107 # On Windows, require the latest version we can get our hands on,
 108 # until the new generic event handling has seen an official release.
 109 AS_CASE([$host_os],
 110         [freebsd*], [sr_libusb_req='libusb-1.0' sr_have_libusb=yes],
 111         [mingw*], [sr_libusb_req='libusb-1.0 >= 1.0.20'],
 112         [sr_libusb_req='libusb-1.0 >= 1.0.16'])
 113
 114 SR_ARG_OPT_PKG([libusb], [LIBUSB_1_0], [NEED_USB],
 115         [$sr_libusb_req])
 116
 117 SR_ARG_OPT_PKG([librevisa], [LIBREVISA], [NEED_VISA],
 118         [librevisa >= 0.0.20130412])
 119
 120 SR_ARG_OPT_PKG([libgpib], [LIBGPIB], [NEED_GPIB],
 121         [libgpib])
 122
 123 SR_ARG_OPT_CHECK([libieee1284], [LIBIEEE1284],, [
 124         sr_save_LIBS=$LIBS
 125         LIBS="-lieee1284 $LIBS"
 126         AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <ieee1284.h>]],
 127                                 [[(void) ieee1284_open(0, 0, 0);]])],
 128                 [sr_have_libieee1284=yes], [sr_have_libieee1284=no])
 129         LIBS=$sr_save_LIBS
 130 ])
 131 AS_IF([test "x$sr_have_libieee1284" = xyes],
 132         [SR_PREPEND([SR_EXTRA_LIBS], [-lieee1284])])
 133
 134 ######################
 135 ##  Feature checks  ##
 136 ######################
 137
 138 # The Check unit testing framework is optional. Disable if not found.
 139 SR_PKG_CHECK([check], [SR_PKGLIBS_TESTS], [check >= 0.9.4])
 140 AM_CONDITIONAL([HAVE_CHECK], [test "x$sr_have_check" = xyes])
 141
 142 # Enable the C99 standard if possible, and enforce the use
 143 # of SR_API to explicitly mark all public API functions.
 144 SR_EXTRA_CFLAGS=
 145 SR_CHECK_COMPILE_FLAGS([SR_EXTRA_CFLAGS], [C99], [-std=c99 -c99 -AC99 -qlanglvl=extc99])
 146 SR_CHECK_COMPILE_FLAGS([SR_EXTRA_CFLAGS], [visibility], [-fvisibility=hidden])
 147
 148 SR_ARG_ENABLE_WARNINGS([SR_WFLAGS], [-Wall], [-Wall -Wextra -Wmissing-prototypes])
 149
 150 # Check host characteristics.
 151 AC_SYS_LARGEFILE
 152 AC_C_BIGENDIAN
 153
 154 AC_CHECK_HEADERS([sys/mman.h], [SR_APPEND([sr_deps_avail], [sys_mman_h])])
 155 AC_CHECK_HEADERS([sys/ioctl.h], [SR_APPEND([sr_deps_avail], [sys_ioctl_h])])
 156 AC_CHECK_HEADERS([sys/timerfd.h], [SR_APPEND([sr_deps_avail], [sys_timerfd_h])])
 157
 158 # We need to link against the Winsock2 library for SCPI over TCP.
 159 AS_CASE([$host_os], [mingw*], [SR_PREPEND([SR_EXTRA_LIBS], [-lws2_32])])
 160
 161 # libm (the standard math library) is always needed.
 162 SR_SEARCH_LIBS([SR_EXTRA_LIBS], [pow], [m])
 163
 164 # RPC is only needed for VXI support.
 165 AC_CACHE_CHECK([for RPC support], [sr_cv_have_rpc],
 166         [AC_LINK_IFELSE([AC_LANG_PROGRAM(
 167                         [[#include <rpc/rpc.h>]m4_newline[CLIENT *rpc_test(void);]],
 168                         [[(void) clnt_create("", 0, 0, "");]])],
 169                 [sr_cv_have_rpc=yes], [sr_cv_have_rpc=no])])
 170 AS_IF([test "x$sr_cv_have_rpc" = xyes],
 171         [AC_DEFINE([HAVE_RPC], [1], [Specifies whether we have RPC support.])])
 172 # VXI support is only compiled if RPC support was found.
 173 AM_CONDITIONAL([NEED_RPC], [test "x$sr_cv_have_rpc" = xyes])
 174
 175 # Check for compiler support of 128 bit integers
 176 AC_CHECK_TYPES([__int128_t, __uint128_t], [], [], [])
 177
 178 ########################
 179 ##  Hardware drivers  ##
 180 ########################
 181
 182 # Keep track of all drivers so we can list them at the end.
 183 SR_VAR_SUMMARY([sr_driver_summary])
 184
 185 # Check whether the sr_deps_avail list contains all of the arguments.
 186 # Unavailable dependencies are collected in sr_deps_missing.
 187 sr_check_driver_deps() {
 188         sr_deps_missing=
 189         for sr_dep
 190         do
 191                 AS_CASE([" $sr_deps_avail "], [*" $sr_dep "*],,
 192                         [SR_APPEND([sr_deps_missing], [', '], [$sr_dep])])
 193         done
 194         test -z "$sr_deps_missing" || return 1
 195 }
 196
 197 AC_ARG_ENABLE([all-drivers],
 198         [AS_HELP_STRING([--enable-all-drivers],
 199                         [enable all drivers by default [default=yes]])],
 200         [], [enable_all_drivers=yes])
 201
 202 ## _SR_DRIVER(Device name, driver-name, var-name, [dependencies...])
 203 m4_define([_SR_DRIVER], [
 204         AC_ARG_ENABLE([$2],
 205                 [AS_HELP_STRING([--enable-$2], [enable $1 support])],
 206                 [$3=$enableval], [$3=$enable_all_drivers])
 207
 208         AS_IF([test "x[$]$3" = xyes], [sr_hw_info=yes[]m4_ifval([$4], [
 209                 sr_check_driver_deps $4 \
 210                         || $3=no sr_hw_info="no (missing: $sr_deps_missing)"
 211         ])], [sr_hw_info='no (disabled)'])
 212         sr_driver_summary_append "$2" "$sr_hw_info"
 213
 214         AM_CONDITIONAL([$3], [test "x[$]$3" = xyes])
 215         AM_COND_IF([$3], [AC_DEFINE([HAVE_$3], [1], [Whether to support $1 device.]) AC_DEFINE([HAVE_DRIVERS], [1], [Whether at least one driver is enabled.])])
 216 ])
 217
 218 ## SR_DRIVER(Device name, driver-name, [dependencies...])
 219 m4_define([SR_DRIVER],
 220         [_SR_DRIVER([$1], [$2], m4_expand([AS_TR_CPP([HW_$2])]), [$3])])
 221
 222 SR_DRIVER([Agilent DMM], [agilent-dmm], [libserialport])
 223 SR_DRIVER([Appa 55II], [appa-55ii], [libserialport])
 224 SR_DRIVER([Arachnid Labs Re:load Pro], [arachnid-labs-re-load-pro], [libserialport])
 225 SR_DRIVER([ASIX SIGMA/SIGMA2], [asix-sigma], [libftdi])
 226 SR_DRIVER([Atten PPS3xxx], [atten-pps3xxx], [libserialport])
 227 SR_DRIVER([BayLibre ACME], [baylibre-acme], [sys_timerfd_h])
 228 SR_DRIVER([BeagleLogic], [beaglelogic], [sys_mman_h sys_ioctl_h])
 229 SR_DRIVER([Brymen BM86x], [brymen-bm86x], [libusb])
 230 SR_DRIVER([Brymen DMM], [brymen-dmm], [libserialport])
 231 SR_DRIVER([CEM DT-885x], [cem-dt-885x], [libserialport])
 232 SR_DRIVER([Center 3xx], [center-3xx], [libserialport])
 233 SR_DRIVER([ChronoVu LA], [chronovu-la], [libusb libftdi])
 234 SR_DRIVER([Colead SLM], [colead-slm], [libserialport])
 235 SR_DRIVER([Conrad DIGI 35 CPU], [conrad-digi-35-cpu], [libserialport])
 236 SR_DRIVER([demo], [demo])
 237 SR_DRIVER([Fluke DMM], [fluke-dmm], [libserialport])
 238 SR_DRIVER([FTDI LA], [ftdi-la], [libusb libftdi])
 239 SR_DRIVER([fx2lafw], [fx2lafw], [libusb])
 240 SR_DRIVER([GMC MH 1x/2x], [gmc-mh-1x-2x], [libserialport])
 241 SR_DRIVER([GW Instek GDS-800], [gwinstek-gds-800], [libserialport])
 242 SR_DRIVER([Hameg HMO], [hameg-hmo], [libserialport])
 243 SR_DRIVER([Hantek 6xxx], [hantek-6xxx], [libusb])
 244 SR_DRIVER([Hantek DSO], [hantek-dso], [libusb])
 245 SR_DRIVER([HP 3457A], [hp-3457a])
 246 SR_DRIVER([Hung-Chang DSO-2100], [hung-chang-dso-2100], [libieee1284])
 247 SR_DRIVER([Ikalogic Scanalogic-2], [ikalogic-scanalogic2], [libusb])
 248 SR_DRIVER([Ikalogic Scanaplus], [ikalogic-scanaplus], [libftdi])
 249 SR_DRIVER([Kecheng KC-330B], [kecheng-kc-330b], [libusb])
 250 SR_DRIVER([KERN scale], [kern-scale], [libserialport])
 251 SR_DRIVER([Korad KAxxxxP], [korad-kaxxxxp], [libserialport])
 252 SR_DRIVER([Lascar EL-USB], [lascar-el-usb], [libusb])
 253 SR_DRIVER([LeCroy LogicStudio], [lecroy-logicstudio], [libusb])
 254 SR_DRIVER([Manson HCS-3xxx], [manson-hcs-3xxx], [libserialport])
 255 SR_DRIVER([maynuo-m97], [maynuo-m97])
 256 SR_DRIVER([MIC 985xx], [mic-985xx], [libserialport])
 257 SR_DRIVER([Motech LPS 30x], [motech-lps-30x], [libserialport])
 258 SR_DRIVER([Norma DMM], [norma-dmm], [libserialport])
 259 SR_DRIVER([OpenBench Logic Sniffer], [openbench-logic-sniffer], [libserialport])
 260 SR_DRIVER([PCE PCE-322A], [pce-322a], [libserialport])
 261 SR_DRIVER([Pipistrello-OLS], [pipistrello-ols], [libftdi])
 262 SR_DRIVER([Rigol DS], [rigol-ds])
 263 SR_DRIVER([Saleae Logic16], [saleae-logic16], [libusb])
 264 SR_DRIVER([SCPI PPS], [scpi-pps])
 265 SR_DRIVER([serial DMM], [serial-dmm], [libserialport])
 266 SR_DRIVER([serial LCR], [serial-lcr], [libserialport])
 267 SR_DRIVER([Sysclk LWLA], [sysclk-lwla], [libusb])
 268 SR_DRIVER([Teleinfo], [teleinfo], [libserialport])
 269 SR_DRIVER([Testo], [testo], [libusb])
 270 SR_DRIVER([Tondaj SL-814], [tondaj-sl-814], [libserialport])
 271 SR_DRIVER([UNI-T DMM], [uni-t-dmm], [libusb])
 272 SR_DRIVER([UNI-T UT32x], [uni-t-ut32x], [libusb])
 273 SR_DRIVER([Victor DMM], [victor-dmm], [libusb])
 274 SR_DRIVER([Yokogawa DL/DLM], [yokogawa-dlm])
 275 SR_DRIVER([ZEROPLUS Logic Cube], [zeroplus-logic-cube], [libusb])
 276
 277 ###############################
 278 ##  Language bindings setup  ##
 279 ###############################
 280
 281 AC_LANG([C++])
 282 SR_ARG_ENABLE_WARNINGS([SR_WXXFLAGS], [-Wall], [-Wall -Wextra])
 283
 284 AC_ARG_ENABLE([bindings],
 285         [AS_HELP_STRING([--enable-bindings], [build language bindings [default=yes]])],
 286         [], [enable_bindings=yes])
 287
 288 AC_ARG_ENABLE([cxx],
 289         [AS_HELP_STRING([--enable-cxx], [build C++ bindings [default=yes]])],
 290         [], [enable_cxx=$enable_bindings])
 291
 292 AC_ARG_ENABLE([python],
 293         [AS_HELP_STRING([--enable-python], [build Python bindings [default=yes]])],
 294         [], [enable_python=$enable_bindings])
 295
 296 AC_ARG_ENABLE([ruby],
 297         [AS_HELP_STRING([--enable-ruby], [build Ruby bindings [default=yes]])],
 298         [], [enable_ruby=$enable_bindings])
 299
 300 AC_ARG_ENABLE([java],
 301         [AS_HELP_STRING([--enable-java], [build Java bindings [default=yes]])],
 302         [], [enable_java=$enable_bindings])
 303
 304 ####################
 305 ##  C++ bindings  ##
 306 ####################
 307
 308 sr_cxx_missing=
 309
 310 # Check if the C++ compiler supports the C++11 standard.
 311 AX_CXX_COMPILE_STDCXX([11], [noext], [optional])
 312 AS_IF([test "x$HAVE_CXX11" != x1],
 313         [SR_APPEND([sr_cxx_missing], [', '], ['C++11'])])
 314
 315 # The C++ bindings need glibmm.
 316 SR_PKG_CHECK([glibmm], [SR_PKGLIBS_CXX], [glibmm-2.4 >= 2.32.0])
 317 AS_IF([test "x$sr_have_glibmm" != xyes],
 318         [SR_APPEND([sr_cxx_missing], [', '], [glibmm])])
 319
 320 # The C++ bindings use Doxygen to parse libsigrok symbols.
 321 AC_CHECK_PROG([HAVE_DOXYGEN], [doxygen], [yes], [no])
 322 AS_IF([test "x$HAVE_DOXYGEN" != xyes],
 323         [SR_APPEND([sr_cxx_missing], [', '], [Doxygen])])
 324
 325 # Link C++ code with gnustl_shared if it exists (Android)
 326 SR_SEARCH_LIBS([SR_EXTRA_CXX_LIBS], [__cxa_throw], [gnustl_shared])
 327
 328 # Python is needed for the C++ bindings.
 329 AM_PATH_PYTHON([2.7],
 330         [HAVE_PYTHON=yes],
 331         [HAVE_PYTHON=no
 332         SR_APPEND([sr_cxx_missing], [', '], [Python])])
 333
 334 AS_IF([test -z "$sr_cxx_missing"],
 335         [BINDINGS_CXX=$enable_cxx], [BINDINGS_CXX=no])
 336 AM_CONDITIONAL([BINDINGS_CXX], [test "x$BINDINGS_CXX" = xyes])
 337
 338 # C++ bindings want stoi and stod.
 339 AM_COND_IF([BINDINGS_CXX], [
 340         AC_CACHE_CHECK([for stoi and stod], [sr_cv_have_stoi_stod],
 341                 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <string>]],
 342                                 [[(void) std::stoi("1"); (void) std::stod("1.0");]])],
 343                         [sr_cv_have_stoi_stod=yes], [sr_cv_have_stoi_stod=no])])
 344         AS_IF([test "x$sr_cv_have_stoi_stod" = xyes],
 345                 [AC_DEFINE([HAVE_STOI_STOD], [1],
 346                         [Specifies whether we have the stoi and stod functions.])])
 347 ])
 348
 349 #######################
 350 ##  Python bindings  ##
 351 #######################
 352
 353 AS_IF([test "x$BINDINGS_CXX" = xyes],
 354         [sr_python_missing=],
 355         [sr_python_missing='C++ bindings'])
 356
 357 # Extract major and minor version number of the Python interpreter.
 358 sr_pymajor=${PYTHON_VERSION%%.*}
 359 sr_pyminor=${PYTHON_VERSION#*.}
 360
 361 # The Python bindings need Python development files. Check for either
 362 # Python 3 or Python 2 headers depending on the interpreter version.
 363 SR_PKG_CHECK([python_dev], [SR_PKGLIBS_PYTHON],
 364         [python = $PYTHON_VERSION],
 365         [python$sr_pymajor = $PYTHON_VERSION],
 366         [python$sr_pymajor$sr_pyminor = $PYTHON_VERSION],
 367         [python-$PYTHON_VERSION = $PYTHON_VERSION])
 368
 369 AS_IF([test "x$sr_have_python_dev" != xyes],
 370         [SR_APPEND([sr_python_missing], [', '], [Headers])])
 371
 372 # PyGObject is needed for the Python bindings.
 373 SR_PKG_CHECK([pygobject], [SR_PKGLIBS_PYTHON], [pygobject-3.0 >= 3.0.0])
 374 AS_IF([test "x$sr_have_pygobject" != xyes],
 375         [SR_APPEND([sr_python_missing], [', '], [PyGObject])])
 376
 377 PKG_CHECK_EXISTS([pygobject-3.0 < 3.7.91],
 378         [AC_DEFINE([PYGOBJECT_FLAGS_SIGNED], [1],
 379                 [Whether last argument to pyg_flags_get_value() is signed.])])
 380
 381 # The Python bindings need the setuptools and numpy Python modules.
 382 # We'll let it go through even if the AX macro wasn't found, as the
 383 # Python modules may still be there.
 384 m4_ifdef([AX_PYTHON_MODULE], [
 385         AX_PYTHON_MODULE([setuptools])
 386         AX_PYTHON_MODULE([numpy])
 387 ], [
 388         HAVE_PYMOD_SETUPTOOLS=yes
 389         HAVE_PYMOD_NUMPY=yes
 390         m4_warn([unsupported],
 391                 [Missing macro AX_PYTHON_MODULE: no check for setuptools and numpy])
 392 ])
 393 AS_IF([test "x$HAVE_PYMOD_SETUPTOOLS" != xyes],
 394         [SR_APPEND([sr_python_missing], [', '], [setuptools])])
 395 AS_IF([test "x$HAVE_PYMOD_NUMPY" != xyes],
 396         [SR_APPEND([sr_python_missing], [', '], [numpy])])
 397
 398 # The Python bindings use SWIG to generate code.
 399 AC_CHECK_PROGS([SWIG], [swig swig3.0 swig2.0])
 400 AS_IF([test "x$SWIG" != x],
 401     AC_MSG_CHECKING([for $SWIG version])
 402     [SWIG_VERSION=`$SWIG -version 2>&1 | sed -n 's/SWIG Version //p'`]
 403     AC_MSG_RESULT([$SWIG_VERSION]))
 404 AS_IF([test "x$SWIG" = x],
 405         [SR_APPEND([sr_python_missing], [', '], [SWIG])])
 406
 407 AS_IF([test -z "$sr_python_missing"],
 408         [BINDINGS_PYTHON=$enable_python], [BINDINGS_PYTHON=no])
 409 AM_CONDITIONAL([BINDINGS_PYTHON], [test "x$BINDINGS_PYTHON" = xyes])
 410
 411 #####################
 412 ##  Ruby bindings  ##
 413 #####################
 414
 415 AS_IF([test "x$BINDINGS_CXX" = xyes],
 416         [sr_ruby_missing=],
 417         [sr_ruby_missing='C++ bindings'])
 418
 419 AC_PATH_PROGS(RUBY, ["${RUBY-ruby}"], [])
 420 AS_IF([test "x$RUBY" != x],
 421         AC_MSG_CHECKING([for Ruby version])
 422     [RUBY_VERSION=`$RUBY -e 'puts RUBY_VERSION'`]
 423     AC_MSG_RESULT([$RUBY_VERSION])
 424     [RUBY_DLEXT=`$RUBY -rrbconfig -e 'puts RbConfig::CONFIG[["DLEXT"]]'`]
 425     AC_SUBST(RUBY_DLEXT))
 426
 427 AS_IF([test "x$RUBY" = x],
 428         [SR_APPEND([sr_ruby_missing], [', '], [Ruby])])
 429
 430 # Extract major and minor version number of the Ruby interpreter.
 431 sr_rbmajor=${RUBY_VERSION%%.*}
 432 sr_rbminor=${RUBY_VERSION#*.}
 433 sr_rbminor=${sr_rbminor%%.*}
 434
 435 # The Ruby bindings need Ruby development files.
 436 SR_PKG_CHECK([ruby_dev], [SR_PKGLIBS_RUBY],
 437         [ruby],
 438         [ruby-$sr_rbmajor.$sr_rbminor])
 439
 440 AS_IF([test "x$sr_have_ruby_dev" != xyes],
 441         [SR_APPEND([sr_ruby_missing], [', '], [Headers])])
 442
 443 # The Ruby bindings use SWIG >= 3.0.8 to generate code.
 444 AS_IF([test "x$SWIG" = x],
 445         [SR_APPEND([sr_ruby_missing], [', '], [SWIG])],
 446         [AS_VERSION_COMPARE($SWIG_VERSION, "3.0.8",
 447                 [SR_APPEND([sr_ruby_missing], [', '], ['SWIG >= 3.0.8'])])])
 448
 449 AS_IF([test -z "$sr_ruby_missing"],
 450         [BINDINGS_RUBY=$enable_ruby], [BINDINGS_RUBY=no])
 451 AM_CONDITIONAL([BINDINGS_RUBY], [test "x$BINDINGS_RUBY" = xyes])
 452
 453 ####################
 454 ##  Java bindings ##
 455 ####################
 456
 457 AS_IF([test "x$BINDINGS_CXX" = xyes],
 458         [sr_java_missing=],
 459         [sr_java_missing='C++ bindings'])
 460
 461 # The Java bindings use SWIG to generate code.
 462 AS_IF([test "x$SWIG" = x],
 463         [SR_APPEND([sr_java_missing], [', '], [SWIG])])
 464
 465 # Find Java compiler and JNI includes for Java bindings.
 466 AC_CHECK_PROG([HAVE_JAVAC], [javac], [yes], [no])
 467 AS_IF([test "x$HAVE_JAVAC" = xno],
 468         [SR_APPEND([sr_java_missing], [', '], [JavaC])])
 469
 470 AC_ARG_WITH([jni-include-path],
 471         [AS_HELP_STRING([[--with-jni-include-path=DIR-LIST (space-separated)]],
 472                 [specify JNI include directories [default=detect]])],
 473         [JNI_INCLUDE_DIRS=" $withval"], [JNI_INCLUDE_DIRS=])
 474
 475 JNI_CPPFLAGS=
 476 AS_IF([test "x$enable_java$HAVE_JAVAC" = xyesyes], [
 477         AX_PROG_JAVAC
 478         AS_IF([test -z "$JNI_INCLUDE_DIRS" && test "x$cross_compiling" != xyes], [
 479                 ## Work around the totally broken logic in AX_JNI_INCLUDE_DIR:
 480                 ## If we can find jni.h without any special search path, skip
 481                 ## the execution of the broken macro to increase our chances of
 482                 ## success.
 483                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <jni.h>]], [])],,
 484                         [AX_JNI_INCLUDE_DIR])
 485         ])
 486 ])
 487 for sr_dir in $JNI_INCLUDE_DIRS
 488 do
 489         SR_APPEND([JNI_CPPFLAGS], ["-I$sr_dir"])
 490 done
 491 AC_SUBST([JNI_CPPFLAGS])
 492
 493 sr_save_cppflags=$CPPFLAGS
 494 SR_APPEND([CPPFLAGS], [$JNI_CPPFLAGS])
 495 AC_CHECK_HEADER([jni.h],,
 496         [SR_APPEND([sr_java_missing], [', '], ['JNI headers'])])
 497 CPPFLAGS=$sr_save_cppflags
 498
 499 AS_IF([test -z "$sr_java_missing"],
 500         [BINDINGS_JAVA=$enable_java], [BINDINGS_JAVA=no])
 501 AM_CONDITIONAL([BINDINGS_JAVA], [test "x$BINDINGS_JAVA" = xyes])
 502
 503 ##############################
 504 ##  Finalize configuration  ##
 505 ##############################
 506
 507 # Add mandatory dependencies to module list.
 508 SR_APPEND([SR_PKGLIBS], ['libzip >= 0.10'])
 509 AC_SUBST([SR_PKGLIBS])
 510
 511 # Retrieve the compile and link flags for all modules combined.
 512 # Also, bail out at this point if any module dependency is not met.
 513 PKG_CHECK_MODULES([LIBSIGROK], [glib-2.0 >= 2.32.0 $SR_PKGLIBS])
 514 PKG_CHECK_MODULES([TESTS], [$SR_PKGLIBS_TESTS glib-2.0 $SR_PKGLIBS])
 515
 516 # SR_PKGLIBS_CXX may be empty, so only invoke these checks when
 517 # the C++ bindings are enabled.
 518 AM_COND_IF([BINDINGS_CXX], [
 519         PKG_CHECK_MODULES([LIBSIGROKCXX], [$SR_PKGLIBS_CXX])
 520         PKG_CHECK_MODULES([PYSIGROK], [$SR_PKGLIBS_PYTHON $SR_PKGLIBS_CXX])
 521         PKG_CHECK_MODULES([RBSIGROK], [$SR_PKGLIBS_RUBY $SR_PKGLIBS_CXX], [AC_SUBST(RBSIGROK_EXTDIR, "lib/$($PKG_CONFIG --variable=sitearch $SR_PKGLIBS_RUBY)/$($PKG_CONFIG --variable=RUBY_BASE_NAME $SR_PKGLIBS_RUBY)/vendor_ruby/$($PKG_CONFIG --variable=ruby_version $SR_PKGLIBS_RUBY)")])
 522 ])
 523
 524 # Check for specific libusb features, now that we know the CFLAGS.
 525 AC_LANG([C])
 526 sr_save_cflags=$CFLAGS
 527 sr_save_libs=$LIBS
 528 CFLAGS="$LIBSIGROK_CFLAGS $CFLAGS"
 529 LIBS="$LIBSIGROK_LIBS $LIBS"
 530 AC_CHECK_TYPES([libusb_os_handle],
 531         [sr_have_libusb_os_handle=yes], [sr_have_libusb_os_handle=no],
 532         [[#include <libusb.h>]])
 533 AC_CHECK_FUNCS([zip_discard])
 534 LIBS=$sr_save_libs
 535 CFLAGS=$sr_save_cflags
 536
 537 AM_COND_IF([NEED_USB], [AS_CASE([$sr_have_libusb_os_handle:$host_os], [no:mingw*],
 538         [AC_MSG_ERROR([Windows builds require the event-abstraction branch of libusb])])])
 539
 540 sr_glib_version=`$PKG_CONFIG --modversion glib-2.0 2>&AS_MESSAGE_LOG_FD`
 541 sr_libzip_version=`$PKG_CONFIG --modversion libzip 2>&AS_MESSAGE_LOG_FD`
 542
 543 AC_DEFINE_UNQUOTED([CONF_LIBZIP_VERSION], ["$sr_libzip_version"],
 544         [Build-time version of libzip.])
 545 AC_DEFINE_UNQUOTED([CONF_HOST], ["$host"],
 546         [The canonical host libsigrok will run on.])
 547
 548 AC_CONFIG_FILES([Makefile libsigrok.pc bindings/cxx/libsigrokcxx.pc])
 549
 550 AC_OUTPUT
 551
 552 # Prepare bindings report messages.
 553 m4_define([SR_PREPARE_BINDING_REPORT], [
 554         sr_report_$1=
 555         test -z "$sr_$1_missing" || sr_report_$1=" (missing: $sr_$1_missing)"
 556         test "x$enable_$1" = xyes || sr_report_$1=' (disabled)'
 557 ])
 558 m4_map_args([SR_PREPARE_BINDING_REPORT], [cxx], [python], [ruby], [java])
 559
 560 cat >&AS_MESSAGE_FD <<_EOF
 561
 562 libsigrok configuration summary:
 563  - Package version................. $SR_PACKAGE_VERSION
 564  - Library ABI version............. $SR_LIB_VERSION
 565  - Prefix.......................... $prefix
 566  - Building on..................... $build
 567  - Building for.................... $host
 568
 569 Compile configuration:
 570  - C compiler...................... $CC
 571  - C compiler version.............. $sr_cc_version
 572  - C compiler flags................ $CFLAGS
 573  - Additional C compiler flags..... $SR_EXTRA_CFLAGS
 574  - C compiler warnings............. $SR_WFLAGS
 575  - C++ compiler.................... $CXX
 576  - C++ compiler version............ $sr_cxx_version
 577  - C++ compiler flags.............. $CXXFLAGS
 578  - C++ compiler warnings........... $SR_WXXFLAGS
 579
 580 Detected libraries (required):
 581  - glib-2.0 >= 2.32.0.............. $sr_glib_version
 582  - libzip >= 0.10.................. $sr_libzip_version
 583
 584 Detected libraries (optional):
 585 $sr_pkglibs_summary
 586 Enabled hardware drivers:
 587 $sr_driver_summary
 588 Enabled SCPI backends:
 589  - TCP............................. yes
 590  - RPC............................. $sr_cv_have_rpc
 591  - serial.......................... $sr_have_libserialport
 592  - VISA............................ $sr_have_librevisa
 593  - GPIB............................ $sr_have_libgpib
 594  - USBTMC.......................... $sr_have_libusb
 595
 596 Enabled language bindings:
 597  - C++............................. $BINDINGS_CXX$sr_report_cxx
 598  - Python.......................... $BINDINGS_PYTHON$sr_report_python
 599  - Ruby............................ $BINDINGS_RUBY$sr_report_ruby
 600  - Java............................ $BINDINGS_JAVA$sr_report_java
 601
 602 _EOF